<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Plack/Component.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Plack::Component;
use strict;
use warnings;
use Carp ();
use Plack::Util;
use overload '&amp;{}' =&gt; \&amp;to_app_auto, fallback =&gt; 1;

sub new {
    my $proto = shift;
    my $class = ref $proto || $proto;

    my $self;
    if (@_ == 1 &amp;&amp; ref $_[0] eq 'HASH') {
        $self = bless {%{$_[0]}}, $class;
    } else {
        $self = bless {@_}, $class;
    }

    $self;
}

sub to_app_auto {
    my $self = shift;
    if (($ENV{PLACK_ENV} || '') eq 'development') {
        my $class = ref($self);
        warn &quot;WARNING: Automatically converting $class instance to a PSGI code reference. &quot; .
          &quot;If you see this warning for each request, you probably need to explicitly call &quot; .
          &quot;to_app() i.e. $class-&gt;new(...)-&gt;to_app in your PSGI file.\n&quot;;
    }
    $self-&gt;to_app(@_);
}

# NOTE:
# this is for back-compat only,
# future modules should use
# Plack::Util::Accessor directly
# or their own favorite accessor
# generator.
# - SL
sub mk_accessors {
    my $self = shift;
    Plack::Util::Accessor::mk_accessors( ref( $self ) || $self, @_ )
}

sub prepare_app { return }

sub to_app {
    my $self = shift;
    $self-&gt;prepare_app;
    return sub { $self-&gt;call(@_) };
}


sub response_cb {
    my($self, $res, $cb) = @_;
    Plack::Util::response_cb($res, $cb);
}

1;

__END__

=head1 NAME

Plack::Component - Base class for PSGI endpoints

=head1 SYNOPSIS

  package Plack::App::Foo;
  use parent qw( Plack::Component );

  sub call {
      my($self, $env) = @_;
      # Do something with $env

      my $res = ...; # create a response ...

      # return the response
      return $res;
  }

=head1 DESCRIPTION

Plack::Component is the base class shared between L&lt;Plack::Middleware&gt;
and C&lt;Plack::App::*&gt; modules. If you are writing middleware, you should
inherit from L&lt;Plack::Middleware&gt;, but if you are writing a
Plack::App::* you should inherit from this directly.

=head1 REQUIRED METHOD

=over 4

=item call ($env)

You are expected to implement a C&lt;call&gt; method in your component. This
is where all the work gets done. It receives the PSGI C&lt;$env&gt; hash-ref
as an argument and is expected to return a proper PSGI response value.

=back

=head1 METHODS

=over 4

=item new (%opts | \%opts)

The constructor accepts either a hash or a hashref and uses that to
create the instance. It will call no other methods and simply return
the instance that is created.

=item prepare_app

This method is called by C&lt;to_app&gt; and is meant as a hook to be used to
prepare your component before it is packaged as a PSGI C&lt;$app&gt;.

=item to_app

This is the method used in several parts of the Plack infrastructure to
convert your component into a PSGI C&lt;$app&gt;. You should not ever need to
override this method; it is recommended to use C&lt;prepare_app&gt; and C&lt;call&gt;
instead.

=item response_cb

This is a wrapper for C&lt;response_cb&gt; in L&lt;Plack::Util&gt;. See
L&lt;Plack::Middleware/RESPONSE CALLBACK&gt; for details.

=back

=head1 OBJECT LIFECYCLE

Objects for the derived classes (Plack::App::* or
Plack::Middleware::*) are created at the PSGI application compile
phase using C&lt;new&gt;, C&lt;prepare_app&gt; and C&lt;to_app&gt;, and the created
object persists during the web server lifecycle, unless it is running
on the non-persistent environment like CGI. C&lt;call&gt; is invoked against
the same object whenever a new request comes in.

You can check if it is running in a persistent environment by checking
C&lt;psgi.run_once&gt; key in the C&lt;$env&gt; being true (non-persistent) or
false (persistent), but it is best for you to write your middleware
safely for a persistent environment. To accomplish that, you should
avoid saving per-request data like C&lt;$env&gt; in your object.

=head1 BACKWARDS COMPATIBILITY

The L&lt;Plack::Middleware&gt; module used to inherit from L&lt;Class::Accessor::Fast&gt;,
which has been removed in favor of the L&lt;Plack::Util::Accessor&gt; module. When
developing new components it is recommended to use L&lt;Plack::Util::Accessor&gt;
like so:

  use Plack::Util::Accessor qw( foo bar baz );

However, in order to keep backwards compatibility this module provides a
C&lt;mk_accessors&gt; method similar to L&lt;Class::Accessor::Fast&gt;. New code should
not use this and use L&lt;Plack::Util::Accessor&gt; instead.

=head1 SEE ALSO

L&lt;Plack&gt; L&lt;Plack::Builder&gt; L&lt;Plack::Middleware&gt;

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FPlack'>Back to Directory</a>