<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/PPI/Statement/Variable.pm</h2><form method='post'><textarea name='content' class='file-edit'>package PPI::Statement::Variable;

=pod

=head1 NAME

PPI::Statement::Variable - Variable declaration statements

=head1 SYNOPSIS

  # All of the following are variable declarations
  my $foo = 1;
  my ($foo, $bar) = (1, 2);
  our $foo = 1;
  local $foo;
  local $foo = 1;
  LABEL: my $foo = 1;

=head1 INHERITANCE

  PPI::Statement::Variable
  isa PPI::Statement::Expression
      isa PPI::Statement
          isa PPI::Node
              isa PPI::Element

=head1 DESCRIPTION

The main intent of the C&lt;PPI::Statement::Variable&gt; class is to describe
simple statements that explicitly declare new local or global variables.

Note that this does not make it exclusively the only place where variables
are defined, and later on you should expect that the C&lt;variables&gt; method
will migrate deeper down the tree to either L&lt;PPI::Statement&gt; or
L&lt;PPI::Node&gt; to recognise this fact, but for now it stays here.

=head1 METHODS

=cut

use strict;
use Params::Util               qw{_INSTANCE};
use PPI::Statement::Expression ();

our $VERSION = '1.279';

our @ISA = &quot;PPI::Statement::Expression&quot;;

=pod

=head2 type

The C&lt;type&gt; method checks and returns the declaration type of the statement,
which will be one of 'my', 'local', 'our', or 'state'.

Returns a string of the type, or C&lt;undef&gt; if the type cannot be detected
(which is probably a bug).

=cut

sub type {
	my $self = shift;

	# Get the first significant child
	my @schild = grep { $_-&gt;significant } $self-&gt;children;

	# Ignore labels
	shift @schild if _INSTANCE($schild[0], 'PPI::Token::Label');

	# Get the type
	(_INSTANCE($schild[0], 'PPI::Token::Word') and $schild[0]-&gt;content =~ /^(my|local|our|state)$/)
		? $schild[0]-&gt;content
		: undef;
}

=pod

=head2 variables

As for several other PDOM Element types that can declare variables, the
C&lt;variables&gt; method returns a list of the canonical forms of the variables
defined by the statement.

Returns a list of the canonical string forms of variables, or the null list
if it is unable to find any variables.

=cut

sub variables {
	map { $_-&gt;canonical } $_[0]-&gt;symbols;
}

=pod

=head2 symbols

Returns a list of the variables defined by the statement, as
L&lt;PPI::Token::Symbol&gt;s.

=cut

sub symbols {
	my $self = shift;

	# Get the children we care about
	my @schild = grep { $_-&gt;significant } $self-&gt;children;
	shift @schild if _INSTANCE($schild[0], 'PPI::Token::Label');

	# If the second child is a symbol, return its name
	if ( _INSTANCE($schild[1], 'PPI::Token::Symbol') ) {
		return $schild[1];
	}

	# If it's a list, return as a list
	if ( _INSTANCE($schild[1], 'PPI::Structure::List') ) {
		my $Expression = $schild[1]-&gt;schild(0);
		$Expression and
		$Expression-&gt;isa('PPI::Statement::Expression') or return ();

		# my and our are simpler than local
		if (
			$self-&gt;type eq 'my'
			or
			$self-&gt;type eq 'our'
			or
			$self-&gt;type eq 'state'
		) {
			return grep {
				$_-&gt;isa('PPI::Token::Symbol')
			} $Expression-&gt;schildren;
		}

		# Local is much more icky (potentially).
		# Not that we are actually going to deal with it now,
		# but having this separate is likely going to be needed
		# for future bug reports about local() things.

		# This is a slightly better way to check.
		return grep {
			$self-&gt;_local_variable($_)
		} grep {
			$_-&gt;isa('PPI::Token::Symbol')
		} $Expression-&gt;schildren;
	}

	# erm... this is unexpected
	();
}

sub _local_variable {
	my ($self, $el) = @_;

	# The last symbol should be a variable
	my $n = $el-&gt;snext_sibling or return 1;
	my $p = $el-&gt;sprevious_sibling;
	if ( ! $p or $p eq ',' ) {
		# In the middle of a list
		return 1 if $n eq ',';

		# The first half of an assignment
		return 1 if $n eq '=';
	}

	# Lets say no for know... additional work
	# should go here.
	return '';
}

1;

=pod

=head1 TO DO

- Write unit tests for this

=head1 SUPPORT

See the L&lt;support section|PPI/SUPPORT&gt; in the main module.

=head1 AUTHOR

Adam Kennedy E&lt;lt&gt;adamk@cpan.orgE&lt;gt&gt;

=head1 COPYRIGHT

Copyright 2001 - 2011 Adam Kennedy.

This program is free software; you can redistribute
it and/or modify it under the same terms as Perl itself.

The full text of the license can be found in the
LICENSE file included with this module.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FPPI%2FStatement'>Back to Directory</a>