<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Mail/SPF/Server.pm</h2><form method='post'><textarea name='content' class='file-edit'>#
# Mail::SPF::Server
# Server class for processing SPF requests.
#
# (C) 2005-2012 Julian Mehnle &lt;julian@mehnle.net&gt;
#     2005      Shevek &lt;cpan@anarres.org&gt;
# $Id: Server.pm 61 2013-07-22 03:45:15Z julian $
#
##############################################################################

package Mail::SPF::Server;

=head1 NAME

Mail::SPF::Server - Server class for processing SPF requests

=head1 VERSION

version 3.20250505

=cut

use warnings;
use strict;

use base 'Mail::SPF::Base';

use Error ':try';
use Net::DNS::Resolver;

use Mail::SPF::MacroString;
use Mail::SPF::Record;
use Mail::SPF::Result;

use constant TRUE   =&gt; (0 == 0);
use constant FALSE  =&gt; not TRUE;

use constant record_classes_by_version =&gt; {
    1   =&gt; 'Mail::SPF::v1::Record',
    2   =&gt; 'Mail::SPF::v2::Record'
};

use constant result_base_class =&gt; 'Mail::SPF::Result';

use constant query_rr_type_all                      =&gt; 0;
use constant query_rr_type_txt                      =&gt; 1;
use constant query_rr_type_spf                      =&gt; 2;

use constant default_default_authority_explanation  =&gt;
    'Rejected by SPF record.';

sub default_query_rr_types { shift-&gt;query_rr_type_txt };

use constant default_max_dns_interactive_terms      =&gt; 10;  # RFC 4408, 10.1/6
use constant default_max_name_lookups_per_term      =&gt; 10;  # RFC 4408, 10.1/7
sub default_max_name_lookups_per_mx_mech  { shift-&gt;max_name_lookups_per_term };
sub default_max_name_lookups_per_ptr_mech { shift-&gt;max_name_lookups_per_term };

use constant default_max_void_dns_lookups           =&gt; 2;

# Interface:
##############################################################################

=head1 SYNOPSIS

    use Mail::SPF;

    my $spf_server  = Mail::SPF::Server-&gt;new(
        # Optional custom default for authority explanation:
        default_authority_explanation =&gt;
            'See http://www.%{d}/why/id=%{S};ip=%{I};r=%{R}'
    );

    my $result      = $spf_server-&gt;process($request);

=cut

# Implementation:
##############################################################################

=head1 DESCRIPTION

B&lt;Mail::SPF::Server&gt; is a server class for processing SPF requests.  Each
server instance can be configured with specific processing parameters.  Also,
the default I&lt;Net::DNS::Resolver&gt; DNS resolver used for making DNS look-ups can
be overridden with a custom resolver object.

=head2 Constructor

The following constructor is provided:

=over

=item B&lt;new(%options)&gt;: returns I&lt;Mail::SPF::Server&gt;

Creates a new server object for processing SPF requests.

%options is a list of key/value pairs representing any of the following
options:

=over

=item B&lt;default_authority_explanation&gt;

A I&lt;string&gt; denoting the default (not macro-expanded) authority explanation
string to use if the authority domain does not specify an explanation string of
its own.  Defaults to:

    'Rejected by SPF record.'

As can be seen from the default, a non-standard C&lt;_scope&gt; pseudo macro is
supported that expands to the name of the identity's scope.  (Note: Do I&lt;not&gt;
use any non-standard macros in explanation strings published in DNS.)

=item B&lt;hostname&gt;

A I&lt;string&gt; denoting the local system's fully qualified host name that should
be used for expanding the C&lt;r&gt; macro in explanation strings.  Defaults to the
system's configured host name.

=item B&lt;dns_resolver&gt;

An optional DNS resolver object.  If none is specified, a new I&lt;Net::DNS::Resolver&gt;
object is used.  The resolver object may be of a different class, but it must
provide an interface similar to I&lt;Net::DNS::Resolver&gt; -- at least the C&lt;send&gt;
and C&lt;errorstring&gt; methods must be supported, and the C&lt;send&gt; method must
return either an object of class I&lt;Net::DNS::Packet&gt;, or, in the case of an
error, B&lt;undef&gt;.

=item B&lt;query_rr_types&gt;

For which RR types to query when looking up and selecting SPF records.  The
following values are supported:

=over

=item B&lt;&lt; Mail::SPF::Server-&gt;query_rr_type_all &gt;&gt;

Both C&lt;TXT&gt; and C&lt;SPF&gt; type RRs.

=item B&lt;&lt; Mail::SPF::Server-&gt;query_rr_type_txt &gt;&gt; (default)

C&lt;TXT&gt; type RRs only.

=item B&lt;&lt; Mail::SPF::Server-&gt;query_rr_type_spf &gt;&gt;

C&lt;SPF&gt; type RRs only.

=back

For years B&lt;Mail::SPF&gt; has defaulted to looking up both C&lt;SPF&gt; and C&lt;TXT&gt; type
RRs as recommended by RFC 4408.  Experience has shown, however, that a
significant portion of name servers suffer from serious brain damage with
regard to the handling of queries for RR types that are unknown to them, such
as the C&lt;SPF&gt; RR type.  Consequently B&lt;Mail::SPF&gt; now defaults to looking up
only C&lt;TXT&gt; type RRs.  This may be overridden by setting the B&lt;query_rr_types&gt;
option.

See RFC 4408, 3.1.1, for a discussion of the topic, as well as the description
of the L&lt;/select_record&gt; method.

=item B&lt;max_dns_interactive_terms&gt;

An I&lt;integer&gt; denoting the maximum number of terms (mechanisms and modifiers)
per SPF check that perform DNS look-ups, as defined in RFC 4408, 10.1,
paragraph 6.  If B&lt;undef&gt; is specified, there is no limit on the number of such
terms.  Defaults to B&lt;10&gt;, which is the value defined in RFC 4408.

A value above the default is I&lt;strongly discouraged&gt; for security reasons.  A
value below the default has implications with regard to the predictability of
SPF results.  Only deviate from the default if you know what you are doing!

=item B&lt;max_name_lookups_per_term&gt;

An I&lt;integer&gt; denoting the maximum number of DNS name look-ups per term
(mechanism or modifier), as defined in RFC 4408, 10.1, paragraph 7.  If
B&lt;undef&gt; is specified, there is no limit on the number of look-ups performed.
Defaults to B&lt;10&gt;, which is the value defined in RFC 4408.

A value above the default is I&lt;strongly discouraged&gt; for security reasons.  A
value below the default has implications with regard to the predictability of
SPF results.  Only deviate from the default if you know what you are doing!

=item B&lt;max_name_lookups_per_mx_mech&gt;

=item B&lt;max_name_lookups_per_ptr_mech&gt;

An I&lt;integer&gt; denoting the maximum number of DNS name look-ups per B&lt;mx&gt; or B&lt;ptr&gt;
mechanism, respectively.  Defaults to the value of the C&lt;max_name_lookups_per_term&gt;
option.  See there for additional information and security notes.

=item B&lt;max_void_dns_lookups&gt;

An I&lt;integer&gt; denoting the maximum number of &quot;void&quot; DNS look-ups per SPF check,
i.e. the number of DNS look-ups that were caused by DNS-interactive terms and
macros (as defined in RFC 4408, 10.1, paragraphs 6 and 7) and that are allowed
to return an empty answer with RCODE 0 or RCODE 3 (C&lt;NXDOMAIN&gt;) before
processing is aborted with a C&lt;permerror&gt; result.  If B&lt;undef&gt; is specified,
there is no stricter limit on the number of void DNS look-ups beyond the usual
processing limits.  Defaults to B&lt;2&gt;.

Specifically, the DNS look-ups that are subject to this limit are those caused
by the C&lt;a&gt;, C&lt;mx&gt;, C&lt;ptr&gt;, and C&lt;exists&gt; mechanisms and the C&lt;p&gt; macro.

A value of B&lt;2&gt; is likely to prevent effective DoS attacks against third-party
victim domains.  However, a definite limit may cause C&lt;permerror&gt; results even
with certain (overly complex) innocent sender policies where useful results
would normally be returned.

=back

=cut

sub new {
    my ($self, %options) = @_;
    $self = $self-&gt;SUPER::new(%options);

    # Do not cache a Mail::SPF::MacroString instance with
    # context provided, this causes a circular reference that leaks
    # both objects.
    $self-&gt;{default_authority_explanation} = $self-&gt;default_default_authority_explanation
        if not defined($self-&gt;{default_authority_explanation});

    $self-&gt;{hostname} ||= Mail::SPF::Util-&gt;hostname;

    $self-&gt;{dns_resolver} ||= Net::DNS::Resolver-&gt;new();

    $self-&gt;{query_rr_types} = $self-&gt;default_query_rr_types
        if not defined($self-&gt;{query_rr_types});

    $self-&gt;{max_dns_interactive_terms}      = $self-&gt;default_max_dns_interactive_terms
                                       if not exists($self-&gt;{max_dns_interactive_terms});
    $self-&gt;{max_name_lookups_per_term}      = $self-&gt;default_max_name_lookups_per_term
                                       if not exists($self-&gt;{max_name_lookups_per_term});
    $self-&gt;{max_name_lookups_per_mx_mech}   = $self-&gt;default_max_name_lookups_per_mx_mech
                                       if not exists($self-&gt;{max_name_lookups_per_mx_mech});
    $self-&gt;{max_name_lookups_per_ptr_mech}  = $self-&gt;default_max_name_lookups_per_ptr_mech
                                       if not exists($self-&gt;{max_name_lookups_per_ptr_mech});

    $self-&gt;{max_void_dns_lookups}           = $self-&gt;default_max_void_dns_lookups
                                       if not exists($self-&gt;{max_void_dns_lookups});

    return $self;
}

=back

=head2 Class methods

The following class methods are provided:

=over

=item B&lt;result_class&gt;: returns I&lt;class&gt;

=item B&lt;result_class($name)&gt;: returns I&lt;class&gt;

Returns a I&lt;Mail::SPF::Result&gt; descendent class determined from the given
result name via the server's inherent result base class, or returns the
server's inherent result base class if no result name is given.  This method
may also be used as an instance method.

I&lt;Note&gt;:  Do not write code invoking class methods on I&lt;literal&gt; result class
names as this would ignore any derivative result classes provided by
B&lt;Mail::SPF&gt; extension modules.

=cut

sub result_class {
    my ($self, $name) = @_;
    return
        defined($name) ?
            $self-&gt;result_base_class-&gt;result_classes-&gt;{$name}
        :   $self-&gt;result_base_class;
}

=item B&lt;throw_result($name, $request)&gt;: throws I&lt;Mail::SPF::Result&gt;

=item B&lt;throw_result($name, $request, $text)&gt;: throws I&lt;Mail::SPF::Result&gt;

Throws a I&lt;Mail::SPF::Result&gt; descendant determined from the given result name
via the server's inherent result base class, passing an optional result text
and associating the given I&lt;Mail::SPF::Request&gt; object with the result object.
This method may also be used as an instance method.

I&lt;Note&gt;:  Do not write code invoking C&lt;throw&gt; on I&lt;literal&gt; result class names
as this would ignore any derivative result classes provided by B&lt;Mail::SPF&gt;
extension modules.

=cut

sub throw_result {
    my ($self, $name, $request, @text) = @_;
    $self-&gt;result_class($name)-&gt;throw($self, $request, @text);
}

=back

=head2 Instance methods

The following instance methods are provided:

=over

=item B&lt;process($request)&gt;: returns I&lt;Mail::SPF::Result&gt;

Processes the given I&lt;Mail::SPF::Request&gt; object, queries the authoritative
domain for an SPF sender policy (see the description of the L&lt;/select_record&gt;
method), evaluates the policy with regard to the given identity and other
request parameters, and returns a I&lt;Mail::SPF::Result&gt; object denoting the
result of the policy evaluation.  See RFC 4408, 4, and RFC 4406, 4, for
details.

=cut

sub process {
    my ($self, $request) = @_;

    $request-&gt;state('authority_explanation', undef);
    $request-&gt;state('dns_interactive_terms_count', 0);
    $request-&gt;state('void_dns_lookups_count', 0);

    my $result;
    try {
        my $record = $self-&gt;select_record($request);
        $request-&gt;record($record);
        $record-&gt;eval($self, $request);
    }
    catch Mail::SPF::Result with {
        $result = shift;
    }
    catch Mail::SPF::EDNSError with {
        $result = $self-&gt;result_class('temperror')-&gt;new($self, $request, shift-&gt;text);
    }
    catch Mail::SPF::ENoAcceptableRecord with {
	if((not defined $request-&gt;{record}-&gt;{terms}[0]-&gt;{domain_spec}-&gt;{text}) or ($request-&gt;{record}-&gt;{terms}[0]-&gt;{domain_spec}-&gt;{text} !~ /\.\./)) {
          # remove empty record structure in order to stringify it correctly
          undef $request-&gt;{record};
          $result = $self-&gt;result_class('none'     )-&gt;new($self, $request, shift-&gt;text);
        } else {
          $result = $self-&gt;result_class('permerror')-&gt;new($self, $request, shift-&gt;text);
        }
    }
    catch Mail::SPF::ERedundantAcceptableRecords with {
        $result = $self-&gt;result_class('permerror')-&gt;new($self, $request, shift-&gt;text);
    }
    catch Mail::SPF::ESyntaxError with {
        $result = $self-&gt;result_class('permerror')-&gt;new($self, $request, shift-&gt;text);
    }
    catch Mail::SPF::EProcessingLimitExceeded with {
        $result = $self-&gt;result_class('permerror')-&gt;new($self, $request, shift-&gt;text);
    };
    # Propagate other, unknown errors.
    # This should not happen, but if it does, it helps exposing the bug!

    return $result;
}

=item B&lt;select_record($request)&gt;: returns I&lt;Mail::SPF::Record&gt;;
throws I&lt;Mail::SPF::EDNSError&gt;,
I&lt;Mail::SPF::ENoAcceptableRecord&gt;, I&lt;Mail::SPF::ERedundantAcceptableRecords&gt;,
I&lt;Mail::SPF::ESyntaxError&gt;

Queries the authority domain of the given I&lt;Mail::SPF::Request&gt; object for SPF
sender policy records and, if multiple records are available, selects the
record of the highest acceptable record version that covers the requested
scope.

More precisely, the following algorithm is performed (assuming that both C&lt;TXT&gt;
and C&lt;SPF&gt; RR types are being queried):

=over

=item 1.

Determine the authority domain, the set of acceptable SPF record versions, and
the identity scope from the given request object.

=item 2.

Query the authority domain for SPF records of the C&lt;SPF&gt; DNS RR type,
discarding any records that are of an inacceptable version or do not cover the
desired scope.

If this yields no SPF records, query the authority domain for SPF records of
the C&lt;TXT&gt; DNS RR type, discarding any records that are of an inacceptable
version or do not cover the desired scope.

If still no acceptable SPF records could be found, throw a
I&lt;Mail::SPF::ENoAcceptableRecord&gt; exception.

=item 3.

Discard all records but those of the highest acceptable version found.

If exactly one record remains, return it.  Otherwise, throw a
I&lt;Mail::SPF::ERedundantAcceptableRecords&gt; exception.

=back

If the querying of either RR type has been disabled via the L&lt;/new&gt;
constructor's C&lt;query_rr_types&gt; option, the respective part in step 2 will
be skipped.

I&lt;Mail::SPF::EDNSError&gt; exceptions due to DNS look-ups and
I&lt;Mail::SPF::ESyntaxError&gt; exceptions due to invalid acceptable records may
also be thrown.

=cut

sub select_record {
    my ($self, $request) = @_;

    my $domain   = $request-&gt;authority_domain;
    my @versions = $request-&gt;versions;
    my $scope    = $request-&gt;scope;

    # Employ identical behavior for 'v=spf1' and 'spf2.0' records, both of
    # which support SPF (code 99) and TXT type records (this may be different
    # in future revisions of SPF):
    # Query for SPF type records first, then fall back to TXT type records.

    my @records;
    my $query_count = 0;
    my @dns_errors;

    # Query for SPF-type RRs first:
    if (
        $self-&gt;query_rr_types == $self-&gt;query_rr_type_all or
        $self-&gt;query_rr_types &amp;  $self-&gt;query_rr_type_spf
    ) {
        try {
            $query_count++;
            my $packet = $self-&gt;dns_lookup($domain, 'SPF');
            push(
                @records,
                $self-&gt;get_acceptable_records_from_packet(
                    $packet, 'SPF', \@versions, $scope, $domain)
            );
        }
        catch Mail::SPF::EDNSError with {
            push(@dns_errors, shift);
        };
        #catch Mail::SPF::EDNSTimeout with {
        #    # FIXME Ignore DNS time-outs on SPF type lookups?
        #    # Apparrently some brain-dead DNS servers time out on SPF-type queries.
        #};
    }

    # If no usable SPF-type RRs, try TXT-type RRs:
    if (
        not @records and
        (
            $self-&gt;query_rr_types == $self-&gt;query_rr_type_all or
            $self-&gt;query_rr_types &amp;  $self-&gt;query_rr_type_txt
        )
    ) {
        # NOTE:
        #   This deliberately violates RFC 4406 (Sender ID), 4.4/3 (4.4.1):
        #   TXT-type RRs are still tried if there _are_ SPF-type RRs but all of
        #   them are inapplicable (i.e. &quot;Hi!&quot;, or even &quot;spf2.0/pra&quot; for an
        #   'mfrom' scope request).  This conforms to the spirit of the more
        #   sensible algorithm in RFC 4408 (SPF), 4.5.
        #   Implication:  Sender ID processing may make use of existing TXT-
        #   type records where a result of &quot;None&quot; would normally be returned
        #   under a strict interpretation of RFC 4406.

        try {
            $query_count++;
            my $packet = $self-&gt;dns_lookup($domain, 'TXT');
            push(
                @records,
                $self-&gt;get_acceptable_records_from_packet(
                    $packet, 'TXT', \@versions, $scope, $domain)
            );
        }
        catch Mail::SPF::EDNSError with {
            push(@dns_errors, shift);
        };
    }

    @dns_errors &lt; $query_count
        or $dns_errors[0]-&gt;throw;
        # Unless at least one query succeeded, re-throw the first DNS error that occurred.

    @records
        or throw Mail::SPF::ENoAcceptableRecord(
            &quot;No applicable sender policy available&quot;);  # RFC 4408, 4.5/7

    # Discard all records but the highest acceptable version:
    my $preferred_record_class = $records[0]-&gt;class;
    @records = grep($_-&gt;isa($preferred_record_class), @records);

    @records == 1
        or throw Mail::SPF::ERedundantAcceptableRecords(
            &quot;Redundant applicable '&quot; . $preferred_record_class-&gt;version_tag . &quot;' &quot; .
            &quot;sender policies found&quot;);  # RFC 4408, 4.5/6

    return $records[0];
}

=item B&lt;get_acceptable_records_from_packet($packet, $rr_type, \@versions, $scope, $domain)&gt;:
returns I&lt;list&gt; of I&lt;Mail::SPF::Record&gt;

Filters from the given I&lt;Net::DNS::Packet&gt; object all resource records of the
given RR type and for the given domain name, discarding any records that are
not SPF records at all, that are of an inacceptable SPF record version, or that
do not cover the given scope.  Returns a list of acceptable records.

=cut

sub get_acceptable_records_from_packet {
    my ($self, $packet, $rr_type, $versions, $scope, $domain) = @_;

    my @versions = sort { $b &lt;=&gt; $a } @$versions;
        # Try higher record versions first.
        # (This may be too simplistic for future revisions of SPF.)

    my @records;

    foreach my $rr ($packet-&gt;answer) {
        next if $rr-&gt;type ne $rr_type;  # Ignore RRs of unexpected type.

        # char_str_list method is 'historical', use as a fallback for Net::DNS prior to 0.69
        # where txtdata is not available.
        # join with no intervening spaces, RFC 6376
        # must call txtdata() in a list context
        my $text = $rr-&gt;can('txtdata')
                 ? join('', $rr-&gt;txtdata)
                 : join('', $rr-&gt;char_str_list);
        my $record;

        # Try to parse RR as each of the requested record versions,
        # starting from the highest version:
        VERSION:
        foreach my $version (@versions) {
            my $class = $self-&gt;record_classes_by_version-&gt;{$version};
            eval(&quot;require $class&quot;);
            try {
                $record = $class-&gt;new_from_string($text);
            }
            catch Mail::SPF::EInvalidRecordVersion with {};
                # Ignore non-SPF and unknown-version records.
                # Propagate other errors (including syntax errors), though.
            last VERSION if defined($record);
        }

        push(@records, $record)
            if  defined($record)
            and grep($scope eq $_, $record-&gt;scopes);  # record covers requested scope?
    }
    return @records;
}

=item B&lt;dns_lookup($domain, $rr_type)&gt;: returns I&lt;Net::DNS::Packet&gt;;
throws I&lt;Mail::SPF::EDNSTimeout&gt;, I&lt;Mail::SPF::EDNSError&gt;

Queries the DNS using the configured resolver for resource records of the
desired type at the specified domain and returns a I&lt;Net::DNS::Packet&gt; object
if an answer packet was received.  Throws a I&lt;Mail::SPF::EDNSTimeout&gt; exception
if a DNS time-out occurred.  Throws a I&lt;Mail::SPF::EDNSError&gt; exception if an
error (other than RCODE 3 AKA C&lt;NXDOMAIN&gt;) occurred.

=cut

sub dns_lookup {
    my ($self, $domain, $rr_type) = @_;

    my $packet;

    if (UNIVERSAL::isa($domain, 'Mail::SPF::MacroString')) {
        $domain = $domain-&gt;expand;
        # Truncate overlong labels at 63 bytes (RFC 4408, 8.1/27):
        $domain =~ s/([^.]{63})[^.]+/$1/g;
        # Drop labels from the head of domain if longer than 253 bytes (RFC 4408, 8.1/25):
        $domain =~ s/^[^.]+\.(.*)$/$1/
            while length($domain) &gt; 253;
    }

    $domain =~ s/^(.*?)\.?$/\L$1/;  # Normalize domain.

    try {
      $packet = $self-&gt;dns_resolver-&gt;send($domain, $rr_type);
    }
    otherwise {
       throw Mail::SPF::ENoAcceptableRecord($self-&gt;dns_resolver-&gt;errorstring);
    };

    # Throw DNS exception unless an answer packet with RCODE 0 or 3 (NXDOMAIN)
    # was received (thereby treating NXDOMAIN as an acceptable but empty answer packet):
    throw Mail::SPF::EDNSTimeout(&quot;Time-out on DNS '$rr_type' lookup of '$domain'&quot;)
      if defined $self-&gt;dns_resolver-&gt;errorstring &amp;&amp; ($self-&gt;dns_resolver-&gt;errorstring || '') =~ /^(timeout|query timed out)$/;
    throw Mail::SPF::EDNSError(&quot;Unknown error on DNS '$rr_type' lookup of '$domain'&quot;)
      unless defined $packet;
    $packet-&gt;can('header')
        or throw Mail::SPF::EDNSError(
            &quot;Unknown response on DNS '$rr_type' lookup of '$domain': &quot; . $packet-&gt;string());
    throw Mail::SPF::EDNSError(&quot;'&quot; . $packet-&gt;header-&gt;rcode . &quot;' error on DNS '$rr_type' lookup of '$domain'&quot;)
      unless $packet-&gt;header-&gt;rcode =~ /^(NOERROR|NXDOMAIN)$/;

    return $packet;
}

=item B&lt;count_dns_interactive_term($request)&gt;: throws I&lt;Mail::SPF::EProcessingLimitExceeded&gt;

Increments by one the count of DNS-interactive mechanisms and modifiers that
have been processed so far during the evaluation of the given
I&lt;Mail::SPF::Request&gt; object.  If this exceeds the configured limit (see the
L&lt;/new&gt; constructor's C&lt;max_dns_interactive_terms&gt; option), throws a
I&lt;Mail::SPF::EProcessingLimitExceeded&gt; exception.

This method is supposed to be called by the C&lt;match&gt; and C&lt;process&gt; methods of
I&lt;Mail::SPF::Mech&gt; and I&lt;Mail::SPF::Mod&gt; sub-classes before (and only if) they
do any DNS look-ups.

=cut

sub count_dns_interactive_term {
    my ($self, $request) = @_;
    my $dns_interactive_terms_count = ++$request-&gt;root_request-&gt;state('dns_interactive_terms_count');
    my $max_dns_interactive_terms = $self-&gt;max_dns_interactive_terms;
    if (
        defined($max_dns_interactive_terms) and
        $dns_interactive_terms_count &gt; $max_dns_interactive_terms
    ) {
        throw Mail::SPF::EProcessingLimitExceeded(
            &quot;Maximum DNS-interactive terms limit ($max_dns_interactive_terms) exceeded&quot;);
    }
    return;
}

=item B&lt;count_void_dns_lookup($request)&gt;: throws I&lt;Mail::SPF::EProcessingLimitExceeded&gt;

Increments by one the count of &quot;void&quot; DNS look-ups that have occurred so far
during the evaluation of the given I&lt;Mail::SPF::Request&gt; object.  If this
exceeds the configured limit (see the L&lt;/new&gt; constructor's C&lt;max_void_dns_lookups&gt;
option), throws a I&lt;Mail::SPF::EProcessingLimitExceeded&gt; exception.

This method is supposed to be called by any code after any calls to the
L&lt;/dns_lookup&gt; method whenever (i) no answer records were returned, and (ii)
this fact is a possible indication of a DoS attack against a third-party victim
domain, and (iii) the number of &quot;void&quot; look-ups is not already constrained
otherwise (as for example is the case with the C&lt;include&gt; mechanism and the
C&lt;redirect&gt; modifier).  Specifically, this applies to look-ups performed by the
C&lt;a&gt;, C&lt;mx&gt;, C&lt;ptr&gt;, and C&lt;exists&gt; mechanisms and the C&lt;p&gt; macro.

=cut

sub count_void_dns_lookup {
    my ($self, $request) = @_;
    my $void_dns_lookups_count = ++$request-&gt;root_request-&gt;state('void_dns_lookups_count');
    my $max_void_dns_lookups = $self-&gt;max_void_dns_lookups;
    if (
        defined($max_void_dns_lookups) and
        $void_dns_lookups_count &gt; $max_void_dns_lookups
    ) {
        throw Mail::SPF::EProcessingLimitExceeded(
            &quot;Maximum void DNS look-ups limit ($max_void_dns_lookups) exceeded&quot;);
    }
    return;
}

=item B&lt;default_authority_explanation&gt;: returns I&lt;Mail::SPF::MacroString&gt;

Returns the default authority explanation as a I&lt;MacroString&gt; object.  See the
description of the L&lt;/new&gt; constructor's C&lt;default_authority_explanation&gt;
option.

=cut

sub default_authority_explanation {
    my ($self) = @_;

    return Mail::SPF::MacroString-&gt;new(
        text            =&gt; $self-&gt;{default_authority_explanation},
        server          =&gt; $self,
        is_explanation  =&gt; TRUE
    );
}

=item B&lt;hostname&gt;: returns I&lt;string&gt;

Returns the local system's host name.  See the description of the L&lt;/new&gt;
constructor's C&lt;hostname&gt; option.

=item B&lt;dns_resolver&gt;: returns I&lt;Net::DNS::Resolver&gt; or compatible object

Returns the DNS resolver object of the server object.  See the description of
the L&lt;/new&gt; constructor's C&lt;dns_resolver&gt; option.

=item B&lt;query_rr_types&gt;: returns I&lt;integer&gt;

Returns a value denoting the RR types for which to query when looking up and
selecting SPF records.  See the description of the L&lt;/new&gt; constructor's
C&lt;query_rr_types&gt; option.

=item B&lt;max_dns_interactive_terms&gt;: returns I&lt;integer&gt;

=item B&lt;max_name_lookups_per_term&gt;: returns I&lt;integer&gt;

=item B&lt;max_name_lookups_per_mx_mech&gt;: returns I&lt;integer&gt;

=item B&lt;max_name_lookups_per_ptr_mech&gt;: returns I&lt;integer&gt;

=item B&lt;max_void_dns_lookups&gt;: returns I&lt;integer&gt;

Return the limit values of the server object.  See the description of the
L&lt;/new&gt; constructor's corresponding options.

=cut

# Make read-only accessors:
__PACKAGE__-&gt;make_accessor($_, TRUE)
    foreach qw(
        hostname

        dns_resolver
        query_rr_types

        max_dns_interactive_terms
        max_name_lookups_per_term
        max_name_lookups_per_mx_mech
        max_name_lookups_per_ptr_mech

        max_void_dns_lookups
    );

=back

=head1 SEE ALSO

L&lt;Mail::SPF&gt;, L&lt;Mail::SPF::Request&gt;, L&lt;Mail::SPF::Result&gt;

L&lt;http://tools.ietf.org/html/rfc4408&gt;

For availability, support, and license information, see the README file
included with Mail::SPF.

=head1 AUTHORS

Julian Mehnle &lt;julian@mehnle.net&gt;, Shevek &lt;cpan@anarres.org&gt;

=cut

TRUE;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FMail%2FSPF'>Back to Directory</a>