<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Mail/DMARC/Report/Send/SMTP.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Mail::DMARC::Report::Send::SMTP;
use strict;
use warnings;

our $VERSION = '1.20250203';

use Carp;
use English '-no_match_vars';
use Email::MIME;
#use Mail::Sender;  # something to consider
use Sys::Hostname;
use POSIX;

use parent 'Mail::DMARC::Base';

sub get_domain_mx {
    my ( $self, $domain ) = @_;
    print &quot;getting MX for $domain\n&quot;;
    my $query;
    eval {
        $query = $self-&gt;get_resolver-&gt;send( $domain, 'MX' ) or return [];
    } or print $@;

    if ( ! $query ) {
        print &quot;\terror:\n\t$@&quot;;
        return [];
    };

    my @mx;
    for my $rr ( $query-&gt;answer ) {
        next if $rr-&gt;type ne 'MX';
        push @mx, { pref =&gt; $rr-&gt;preference, addr =&gt; $rr-&gt;exchange };
        print $rr-&gt;exchange if $self-&gt;verbose;
    }
    if ( $self-&gt;verbose ) {
        print &quot;found &quot; . scalar @mx . &quot;MX exchanges\n&quot;;
    };
    return \@mx;
}

sub get_smtp_hosts {
    my $self = shift;
    my $email = shift or croak &quot;missing email!&quot;;

    my ($domain) = ( split /@/, $email )[-1];
    my @mx = map  { $_-&gt;{addr} }
             sort { $a-&gt;{pref} &lt;=&gt; $b-&gt;{pref} }
             @{ $self-&gt;get_domain_mx($domain) };

    push @mx, $domain;
    print &quot;\tfound &quot; . scalar @mx . &quot; MX for $email\n&quot; if $self-&gt;verbose;
    return @mx;
}

sub get_subject {
    my ( $self, $agg_ref ) = @_;


    my $rid = $$agg_ref-&gt;metadata-&gt;report_id || $self-&gt;time;
    my $id = POSIX::strftime( &quot;%Y.%m.%d.&quot;, localtime $self-&gt;time ) . $rid;
    my $us = $self-&gt;config-&gt;{organization}{domain};
    if ($us eq 'example.com') {
        die &quot;Please update mail-dmarc.ini&quot;;
    }
    my $pol_dom = $$agg_ref-&gt;policy_published-&gt;domain;
    return &quot;Report Domain: $pol_dom Submitter: $us Report-ID:$id&quot;;
}

sub human_summary {
    my ( $self, $agg_ref ) = @_;

    my $records = scalar @{ $$agg_ref-&gt;{record} };
    my $OrgName = $self-&gt;config-&gt;{organization}{org_name};
    my $pass = grep { 'pass' eq $_-&gt;{row}{policy_evaluated}{dkim}
                   || 'pass' eq $_-&gt;{row}{policy_evaluated}{spf}  }
                   @{ $$agg_ref-&gt;{record} };
    my $fail = grep { 'pass' ne $_-&gt;{row}{policy_evaluated}{dkim}
                   &amp;&amp; 'pass' ne $_-&gt;{row}{policy_evaluated}{spf} }
                   @{ $$agg_ref-&gt;{record} };
    my $ver  = $Mail::DMARC::Base::VERSION || ''; # undef in author environ
    my $from = $$agg_ref-&gt;{policy_published}{domain} or croak;

    return &lt;&lt;&quot;EO_REPORT&quot;

This is a DMARC aggregate report for $from

$records records.
$pass passed.
$fail failed.

Submitted by $OrgName
Generated with Mail::DMARC $ver

EO_REPORT
        ;
}

sub get_filename {
    my ( $self, $agg_ref ) = @_;

    #  2013 DMARC Draft, 12.2.1 Email
    #
    #   filename = receiver &quot;!&quot; policy-domain &quot;!&quot; begin-timestamp &quot;!&quot;
    #              end-timestamp [ &quot;!&quot; unique-id ] &quot;.&quot; extension
    #   filename=&quot;mail.receiver.example!example.com!1013662812!1013749130.gz&quot;
    return join( '!',
        $self-&gt;config-&gt;{organization}{domain},
        $$agg_ref-&gt;policy_published-&gt;domain,
        $$agg_ref-&gt;metadata-&gt;begin,
        $$agg_ref-&gt;metadata-&gt;end,
        $$agg_ref-&gt;metadata-&gt;report_id || $self-&gt;time,
    ) . '.xml';
}

sub assemble_too_big_message_object {
    my ( $self, $to, $body ) = @_;

    my @parts    = Email::MIME-&gt;create(
        attributes =&gt; {
            content_type =&gt; &quot;text/plain&quot;,
            disposition  =&gt; &quot;inline&quot;,
            charset      =&gt; &quot;US-ASCII&quot;,
        },
        body =&gt; $body,
    ) or croak &quot;unable to add body!&quot;;

    my $email = Email::MIME-&gt;create(
        header_str =&gt; [
            From =&gt; $self-&gt;config-&gt;{organization}{email},
            To   =&gt; $to,
            Date =&gt; $self-&gt;get_timestamp_rfc2822,
            Subject =&gt; 'DMARC too big report',
        ],
        parts =&gt; [@parts],
    ) or croak &quot;unable to assemble message\n&quot;;

    return $email;
}

sub assemble_message_object {
    my ( $self, $agg_ref, $to, $shrunk ) = @_;

    my $filename = $self-&gt;get_filename($agg_ref);
# WARNING: changes made here MAY affect Send::compress. Check it!
#   my $cf       = ( time &gt; 1372662000 ) ? 'gzip' : 'zip';   # gz after 7/1/13
    my $cf       = 'gzip';
      $filename .= $cf eq 'gzip' ? '.gz' : '.zip';

    my @parts    = Email::MIME-&gt;create(
        attributes =&gt; {
            content_type =&gt; &quot;text/plain&quot;,
            disposition  =&gt; &quot;inline&quot;,
            charset      =&gt; &quot;US-ASCII&quot;,
        },
        body =&gt; $self-&gt;human_summary( $agg_ref ),
    ) or croak &quot;unable to add body!&quot;;

    push @parts,
        Email::MIME-&gt;create(
        attributes =&gt; {
            filename     =&gt; $filename,
            content_type =&gt; &quot;application/$cf&quot;,
            encoding     =&gt; &quot;base64&quot;,
            name         =&gt; $filename,
        },
        body =&gt; $shrunk,
        ) or croak &quot;unable to add report!&quot;;

    my $email = Email::MIME-&gt;create(
        header_str =&gt; [
            From =&gt; $self-&gt;config-&gt;{organization}{email},
            To   =&gt; $to,
            Date =&gt; $self-&gt;get_timestamp_rfc2822,
            Subject =&gt; $self-&gt;get_subject( $agg_ref ),
        ],
        parts =&gt; [@parts],
    ) or croak &quot;unable to assemble message\n&quot;;
    $email-&gt;header_str_set( 'Message-ID' =&gt; $self-&gt;get_message_id );

    return $email;
}

sub get_timestamp_rfc2822 {
    my ($self, @args) = @_;
    my @ts = scalar @args ? @args : localtime $self-&gt;time;
    my $locale = setlocale(LC_CTYPE);
    setlocale(LC_ALL, 'C');
    my $timestamp = POSIX::strftime( '%a, %d %b %Y %H:%M:%S %z', @ts );
    setlocale(LC_ALL, $locale);
    return $timestamp;
}

sub get_helo_hostname {
    my $self = shift;
    my $host = $self-&gt;config-&gt;{smtp}{hostname};
    return $host if $host &amp;&amp; $host ne 'mail.example.com';
    return Sys::Hostname::hostname;
};

sub get_message_id {
    my $self = shift;
    my $host = $self-&gt;get_helo_hostname;

    my ($ss, $mm, $hh, $mday, $mon, $year, $wday, $yday, $isdst) = localtime(time);

    # Generate a &quot;random&quot; Message-ID
    return sprintf(&quot;&lt;%04d%02d%02d%02d%02d.%s\@%s&gt;\n&quot;,
             $year + 1900,
             $mon  + 1,
             $mday,
             $hh,
             $mm,
             rand(),
             $host
    );
}

1;

__END__

=pod

=head1 NAME

Mail::DMARC::Report::Send::SMTP - utility methods for sending reports via SMTP

=head1 VERSION

version 1.20250203

=head2 SUBJECT FIELD

The RFC5322.Subject field for individual report submissions SHOULD conform to the following ABNF:

   dmarc-subject = %x52.65.70.6f.72.74 1*FWS    ; &quot;Report&quot;
                   %x44.6f.6d.61.69.6e.3a 1*FWS ; &quot;Domain:&quot;
                   domain-name 1*FWS            ; from RFC6376
                   %x53.75.62.6d.69.74.74.65.72.3a ; &quot;Submitter:&quot;
                   1*FWS domain-name 1*FWS
                   %x52.65.70.6f.72.74.2d.49.44.3a ; &quot;Report-ID:&quot;
                   msg-id                       ; from RFC5322

The first domain-name indicates the DNS domain name about which the
report was generated.  The second domain-name indicates the DNS
domain name representing the Mail Receiver generating the report.
The purpose of the Report-ID: portion of the field is to enable the
Domain Owner to identify and ignore duplicate reports that might be
sent by a Mail Receiver.

=head1 12.2.1 Email

In the case of a &quot;mailto&quot; URI, the Mail Receiver SHOULD communicate
reports using the method described in [STARTTLS].

The message generated by the Mail Receiver must be a [MIME] formatted
[MAIL] message.  The aggregate report itself MUST be included in one
of the parts of the message.  A human-readable portion MAY be
included as a MIME part (such as a text/plain part).

The aggregate data MUST be an XML file subjected to GZIP compression.
The aggregate data MUST be present using the media type &quot;application/
gzip&quot;, and the filenames SHOULD be constructed using the following
ABNF:

     filename = receiver &quot;!&quot; policy-domain &quot;!&quot; begin-timestamp &quot;!&quot;
                end-timestamp [ &quot;!&quot; unique-id ] &quot;.&quot; extension

     unique-id = token
              ; &quot;token&quot; is imported from [MIME]

     receiver = domain
              ; imported from [MAIL]

     policy-domain = domain

     begin-timestamp = 1*DIGIT
                     ; seconds since 00:00:00 UTC January 1, 1970
                     ; indicating start of the time range contained
                     ; in the report

     end-timestamp = 1*DIGIT
                   ; seconds since 00:00:00 UTC January 1, 1970
                   ; indicating end of the time range contained
                   ; in the report

     extension = &quot;xml&quot; / &quot;gzip&quot;

   For the GZIP file itself, the extension MUST be &quot;gz&quot;; for the XML
   report, the extension MUST be &quot;xml&quot;.

=head1 AUTHORS

=over 4

=item *

Matt Simerson &lt;msimerson@cpan.org&gt;

=item *

Davide Migliavacca &lt;shari@cpan.org&gt;

=item *

Marc Bradshaw &lt;marc@marcbradshaw.net&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2025 by Matt Simerson.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FMail%2FDMARC%2FReport%2FSend'>Back to Directory</a>