<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Mail/DKIM/Signature.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Mail::DKIM::Signature;
use strict;
use warnings;
our $VERSION = '1.20240923'; # VERSION
# ABSTRACT: represents a DKIM-Signature header

# Copyright 2005-2007 Messiah College. All rights reserved.
# Jason Long &lt;jlong@messiah.edu&gt;

# Copyright (c) 2004 Anthony D. Urso. All rights reserved.
# This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.

use Mail::DKIM::PublicKey;
use Mail::DKIM::Algorithm::rsa_sha1;
use Mail::DKIM::Algorithm::rsa_sha256;
use Mail::DKIM::Algorithm::ed25519_sha256;

use base 'Mail::DKIM::KeyValueList';
use Carp;


sub new {
    my $class = shift;
    my %prms  = @_;
    my $self  = {};
    bless $self, $class;

    $self-&gt;version('1');
    $self-&gt;algorithm( $prms{'Algorithm'} || 'rsa-sha1' );
    $self-&gt;signature( $prms{'Signature'} );
    $self-&gt;canonicalization( $prms{'Method'} ) if exists $prms{'Method'};
    $self-&gt;domain( $prms{'Domain'} );
    $self-&gt;headerlist( $prms{'Headers'} );
    $self-&gt;protocol( $prms{'Query'} ) if exists $prms{'Query'};
    $self-&gt;selector( $prms{'Selector'} );
    $self-&gt;identity( $prms{'Identity'} )     if exists $prms{'Identity'};
    $self-&gt;timestamp( $prms{'Timestamp'} )   if defined $prms{'Timestamp'};
    $self-&gt;expiration( $prms{'Expiration'} ) if defined $prms{'Expiration'};
    $self-&gt;tags( $prms{'Tags'} ) if defined $prms{'Tags'};
    $self-&gt;key( $prms{'Key'} )               if defined $prms{'Key'};
    return $self;
}


sub parse {
    my $class = shift;
    croak 'wrong number of arguments' unless ( @_ == 1 );
    my ($string) = @_;

    # remove line terminator, if present
    $string =~ s/\015\012\z//;

    # remove field name, if present
    my $prefix = $class-&gt;prefix();
    if ( $string =~ s/^($prefix)//i ) {

        # save the field name (capitalization), so that it can be
        # restored later
        $prefix = $1;
    }

    my $self = $class-&gt;SUPER::parse($string);
    $self-&gt;{prefix} = $prefix;

    return $self;
}


# deprecated
sub wantheader {
    my $self = shift;
    my $attr = shift;

    $self-&gt;headerlist
      or return 1;

    foreach my $key ( $self-&gt;headerlist ) {
        lc $attr eq lc $key
          and return 1;
    }

    return;
}


sub algorithm {
    my $self = shift;

    if (@_) {
        $self-&gt;set_tag( 'a', shift );
    }

    my $a = $self-&gt;get_tag('a');
    return defined $a ? lc $a : undef;
}


sub as_string {
    my $self = shift;

    return $self-&gt;prefix() . $self-&gt;SUPER::as_string;
}

# undocumented method
sub as_string_debug {
    my $self = shift;

    return $self-&gt;prefix()
      . join( ';', map { '&gt;' . $_-&gt;{raw} . '&lt;' } @{ $self-&gt;{tags} } );
}


sub as_string_without_data {
    my $self = shift;
    croak 'wrong number of arguments' unless ( @_ == 0 );

    my $alt = $self-&gt;clone;
    $alt-&gt;signature('');

    return $alt-&gt;as_string;
}


sub body_count {
    my $self = shift;

    # set new body count if provided
    (@_)
      and $self-&gt;set_tag( 'l', shift );

    return $self-&gt;get_tag('l');
}


sub body_hash {
    my $self = shift;

    # set new body hash if provided
    (@_)
      and $self-&gt;set_tag( 'bh', shift );

    my $result = $self-&gt;get_tag('bh');
    if ( defined $result ) {
        $result =~ s/\s+//gs;
    }
    return $result;
}


sub canonicalization {
    my $self = shift;

    if (@_) {
        $self-&gt;set_tag( 'c', join( '/', @_ ) );
    }

    my $c = $self-&gt;get_tag('c');
    $c = lc $c if defined $c;
    if ( not $c ) {
        $c = 'simple/simple';
    }
    my ( $c1, $c2 ) = split( /\//, $c, 2 );
    if ( not defined $c2 ) {

        # default body canonicalization is &quot;simple&quot;
        $c2 = 'simple';
    }

    if (wantarray) {
        return ( $c1, $c2 );
    }
    else {
        return &quot;$c1/$c2&quot;;
    }
}

use MIME::Base64;

# checks whether this signature specifies a legal canonicalization method
# returns true if the canonicalization is acceptable, false otherwise
#
sub check_canonicalization {
    my $self = shift;

    my ( $c1, $c2 ) = $self-&gt;canonicalization;

    my @known = ( 'nowsp', 'simple', 'relaxed', 'seal' );
    return undef unless ( grep { $_ eq $c1 } @known );
    return undef unless ( grep { $_ eq $c2 } @known );
    return 1;
}

sub set_verify_time {
    my ( $self, $verify_time ) = @_;
    $self-&gt;{_verify_time} = $verify_time;
}

# checks whether the expiration time on this signature is acceptable
# returns a true value if acceptable, false otherwise
#
sub check_expiration {
    my $self = shift;
    my $x    = $self-&gt;expiration;
    return 1 if not defined $x;
    $self-&gt;{_verify_time} ||= time();
    return ( $self-&gt;{_verify_time} &lt;= $x );
}

# Returns a filtered list of protocols that can be used to fetch the
# public key corresponding to this signature. An empty list means that
# all designated protocols are unrecognized.
# Note: at this time, the only recognized protocol is &quot;dns/txt&quot;.
#
sub check_protocol {
    my $self = shift;

    my $v = $self-&gt;version;

    foreach my $prot ( split /:/, $self-&gt;protocol ) {
        my ( $type, $options ) = split( /\//, $prot, 2 );
        if ( $type eq 'dns' ) {
            return ('dns/txt') if $options &amp;&amp; $options eq 'txt';

            # prior to DKIM version 1, the '/txt' part was optional
            if ( !$v ) {
                return ('dns/txt') if !defined($options);
            }
        }
    }

    # unrecognized
    return;
}

# checks whether the version tag has an acceptable value
# returns true if so, otherwise false
#
sub check_version {
    my $self = shift;

    # check version
    if ( my $version = $self-&gt;version ) {
        my @ALLOWED_VERSIONS = ( '0.5', '1' );
        return ( grep { $_ eq $version } @ALLOWED_VERSIONS );
    }

    # we still consider a missing v= tag acceptable,
    # for backwards-compatibility
    return 1;
}


sub data {
    my $self = shift;

    if (@_) {
        $self-&gt;set_tag( 'b', shift );
    }

    my $b = $self-&gt;get_tag('b');
    $b =~ tr/\015\012 \t//d if defined $b;
    return $b;
}

*signature = \*data;

#undocumented, private function
#derived from MIME::Base64::Perl (allowed, thanks to the Perl license)
#
sub decode_qp {
    my $res = shift;

    #TODO- should I worry about non-ASCII systems here?
    $res =~ s/=([\da-fA-F]{2})/pack('C', hex($1))/ge
      if defined $res;
    return $res;
}

#undocumented, private function
#derived from MIME::Base64::Perl (allowed, thanks to the Perl license)
#
sub encode_qp {
    my $res = shift;

    # note- unlike MIME quoted-printable, we don't allow whitespace chars
    my $DISALLOWED = qr/[^!&quot;#\$%&amp;'()*+,\-.\/0-9:;&lt;&gt;?\@A-Z[\\\]^_`a-z{|}~]/;

    #TODO- should I worry about non-ASCII systems here?
    $res =~ s/($DISALLOWED)/sprintf('=%02X', ord($1))/eg
      if defined $res;
    return $res;
}

sub DEFAULT_PREFIX {
    return 'DKIM-Signature:';
}

sub prefix {
    my $class = shift;
    if ( ref($class) ) {
        $class-&gt;{prefix} = shift if @_;
        return $class-&gt;{prefix} if $class-&gt;{prefix};
    }
    return $class-&gt;DEFAULT_PREFIX();
}


sub domain {
    my $self = shift;

    if (@_) {
        $self-&gt;set_tag( 'd', shift );
    }

    my $d = $self-&gt;get_tag('d');
    return defined $d ? lc $d : undef;
}


sub expiration {
    my $self = shift;

    (@_)
      and $self-&gt;set_tag( 'x', shift );

    return $self-&gt;get_tag('x');
}

sub tags {
    my $self = shift;
    my $tags = shift;

    for my $tag (sort keys %$tags) {
      $self-&gt;set_tag( $tag, $tags-&gt;{$tag} );
    }
    (@_)

}

# allows the type of signature to determine what &quot;algorithm&quot; gets used
sub get_algorithm_class {
    my $self = shift;
    croak 'wrong number of arguments' unless ( @_ == 1 );
    my ($algorithm) = @_;

    my $class =
        $algorithm eq 'rsa-sha1'   ? 'Mail::DKIM::Algorithm::rsa_sha1'
      : $algorithm eq 'rsa-sha256' ? 'Mail::DKIM::Algorithm::rsa_sha256'
      : $algorithm eq 'ed25519-sha256' ? 'Mail::DKIM::Algorithm::ed25519_sha256'
      :                              undef;
    return $class;
}

# [private method]
# fetch_public_key() - initiate a DNS query for fetching the key
#
# This method does NOT return the public key.
# Use get_public_key() for that.
#
sub fetch_public_key {
    my $self = shift;
    return if exists $self-&gt;{public_key_query};

    my $on_success = sub {
        if ( $_[0] ) {
            $self-&gt;{public} = $_[0];
        }
        else {
            $self-&gt;{public_error} = &quot;not available\n&quot;;
        }
    };

    my @methods = $self-&gt;check_protocol;
    $self-&gt;{public_key_query} = Mail::DKIM::PublicKey-&gt;fetch_async(
        Protocol  =&gt; $methods[0],
        Selector  =&gt; $self-&gt;selector,
        Domain    =&gt; $self-&gt;domain,
        Callbacks =&gt; {
            Success =&gt; $on_success,
            Error   =&gt; sub { $self-&gt;{public_error} = shift },
        },
    );
    return;
}

#EXPERIMENTAL
sub _refetch_public_key {
    my $self = shift;
    if ( $self-&gt;{public_key_query} ) {

        # clear the existing query by waiting for it to complete
        $self-&gt;{public_key_query}-&gt;();
    }
    delete $self-&gt;{public_key_query};
    delete $self-&gt;{public};
    delete $self-&gt;{public_error};
    $self-&gt;fetch_public_key;
}


sub get_public_key {
    my $self = shift;

    # this ensures we only try fetching once, even if an error occurs
    if ( not exists $self-&gt;{public_key_query} ) {
        $self-&gt;fetch_public_key;
    }

    if ( $self-&gt;{public_key_query} ) {

        # wait for public key query to finish
        $self-&gt;{public_key_query}-&gt;();
        $self-&gt;{public_key_query} = 0;
    }

    if ( exists $self-&gt;{public} ) {
        return $self-&gt;{public};
    }
    else {
        die $self-&gt;{public_error};
    }
}


sub hash_algorithm {
    my $self      = shift;
    my $algorithm = $self-&gt;algorithm;

    return
        $algorithm eq 'rsa-sha1'   ? 'sha1'
      : $algorithm eq 'rsa-sha256' ? 'sha256'
      : $algorithm eq 'ed25519-sha256' ? 'sha256'
      :                              undef;
}


sub headerlist {
    my $self = shift;

    (@_)
      and $self-&gt;set_tag( 'h', shift );

    my $h = $self-&gt;get_tag('h') || '';

    # remove whitespace next to colons
    $h =~ s/\s+:/:/g;
    $h =~ s/:\s+/:/g;
    $h = lc $h;

    if ( wantarray and $h ) {
        my @list = split /:/, $h;
        @list = map { s/^\s+|\s+$//g; $_ } @list;
        return @list;
    }
    elsif (wantarray) {
        return ();
    }

    return $h;
}


sub identity {
    my $self = shift;

    # set new identity if provided
    (@_)
      and $self-&gt;set_tag( 'i', encode_qp(shift) );

    my $i = $self-&gt;get_tag('i');
    if ( defined $i ) {
        return decode_qp($i);
    }
    else {
        return '@' . ( $self-&gt;domain || '' );
    }
}

sub identity_matches {
    my $self = shift;
    my ($addr) = @_;

    my $id = $self-&gt;identity;
    if ( $id =~ /^\@/ ) {

        # the identity is a domain-name only, so it only needs to match
        # the domain part of the sender address
        return ( lc( substr( $addr, -length($id) ) ) eq lc($id) );

        # TODO - compare the parent domains?
    }
    return lc($addr) eq lc($id);
}


sub key {
    my $self = shift;
    if (@_) {
        $self-&gt;{Key}     = shift;
        $self-&gt;{KeyFile} = undef;
    }
    return $self-&gt;{Key};
}


sub method {
    my $self = shift;

    if (@_) {
        $self-&gt;set_tag( 'c', shift );
    }

    return ( lc $self-&gt;get_tag('c') ) || 'simple';
}


sub protocol {
    my $self = shift;

    (@_)
      and $self-&gt;set_tag( 'q', shift );

    my $q = $self-&gt;get_tag('q');
    if ( defined $q ) {
        return $q;
    }
    else {
        return 'dns/txt';
    }
}


sub result {
    my $self = shift;
    @_ and $self-&gt;{verify_result}  = shift;
    @_ and $self-&gt;{verify_details} = shift;
    return $self-&gt;{verify_result};
}


sub result_detail {
    my $self = shift;
    croak 'wrong number of arguments' unless ( @_ == 0 );

    if ( $self-&gt;{verify_result} &amp;&amp; $self-&gt;{verify_details} ) {
        return $self-&gt;{verify_result} . ' (' . $self-&gt;{verify_details} . ')';
    }
    return $self-&gt;{verify_result};
}


sub selector {
    my $self = shift;

    (@_)
      and $self-&gt;set_tag( 's', shift );

    return $self-&gt;get_tag('s');
}


sub prettify {
    my $self = shift;
    $self-&gt;wrap(
        Start =&gt; length( $self-&gt;prefix() ),
        Tags  =&gt; {
            b  =&gt; 'b64',
            bh =&gt; 'b64',
            h  =&gt; 'list',
        },
    );
}


sub prettify_safe {
    my $self = shift;
    $self-&gt;wrap(
        Start =&gt; length( $self-&gt;prefix() ),
        Tags  =&gt; {
            b =&gt; 'b64',
        },
        PreserveNames =&gt; 1,
        Default       =&gt; 'preserve',    #preserves unknown tags
    );
}


sub timestamp {
    my $self = shift;

    (@_)
      and $self-&gt;set_tag( 't', shift );

    return $self-&gt;get_tag('t');
}


sub version {
    my $self = shift;

    (@_)
      and $self-&gt;set_tag( 'v', shift );

    return $self-&gt;get_tag('v');
}


1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Mail::DKIM::Signature - represents a DKIM-Signature header

=head1 VERSION

version 1.20240923

=head1 CONSTRUCTORS

=head2 new() - create a new signature from parameters

  my $signature = Mail::DKIM::Signature-&gt;new(
                      [ Algorithm =&gt; 'rsa-sha1', ]
                      [ Signature =&gt; $base64, ]
                      [ Method =&gt; 'relaxed', ]
                      [ Domain =&gt; 'example.org', ]
                      [ Identity =&gt; 'user@example.org', ]
                      [ Headers =&gt; 'from:subject:date:message-id', ]
                      [ Query =&gt; 'dns', ]
                      [ Selector =&gt; 'alpha', ]
                      [ Timestamp =&gt; time(), ]
                      [ Expiration =&gt; time() + 86400, ]
                  );

=head2 parse() - create a new signature from a DKIM-Signature header

  my $sig = Mail::DKIM::Signature-&gt;parse(
                  'DKIM-Signature: a=rsa-sha1; b=yluiJ7+0=; c=relaxed'
            );

Constructs a signature by parsing the provided DKIM-Signature header
content. You do not have to include the header name (i.e. &quot;DKIM-Signature:&quot;)
but it is recommended, so the header name can be preserved and returned
the same way in as_string().

Note: The input to this constructor is in the same format as the output
of the as_string method.

=head1 METHODS

=head2 algorithm() - get or set the algorithm (a=) field

The algorithm used to generate the signature. Should be one of the
following:
- &quot;rsa-sha1&quot;,an RSA-signed SHA-1 digest
- &quot;rsa-sha256&quot;, an RSA-signed SHA-256 digest
- &quot;ed25519-sha256&quot;, an Ed25519-signed SHA-256 digest

See also hash_algorithm().

=head2 as_string() - the signature header as a string

  print $signature-&gt;as_string . &quot;\n&quot;;

outputs

  DKIM-Signature: a=rsa-sha1; b=yluiJ7+0=; c=relaxed

As shown in the example, the as_string method can be used to generate
the DKIM-Signature that gets prepended to a signed message.

=head2 as_string_without_data() - signature without the signature data

  print $signature-&gt;as_string_without_data . &quot;\n&quot;;

outputs

  DKIM-Signature: a=rsa-sha1; b=; c=relaxed

This is similar to the as_string() method, but it always excludes the &quot;data&quot;
part. This is used by the DKIM canonicalization methods, which require
incorporating this part of the signature into the signed message.

=head2 body_count() - get or set the body count (l=) field

  my $i = $signature-&gt;body_count;

Informs the verifier of the number of bytes in the body of the email
included in the cryptographic hash, starting from 0 immediately
following the CRLF preceding the body. Also known as the l= tag.

When creating a signature, this tag may be either omitted, or set after
the selected canonicalization system has received the entire message
body (but before it canonicalizes the DKIM-Signature).

=head2 body_hash() - get or set the body hash (bh=) field

  my $bh = $signature-&gt;body_hash;

The hash of the body part of the message. Whitespace is ignored in this
value. This tag is required.

When accessing this value, whitespace is stripped from the tag for you.

=head2 canonicalization() - get or set the canonicalization (c=) field

  $signature-&gt;canonicalization('relaxed', 'simple');

  ($header, $body) = $signature-&gt;canonicalization;

Message canonicalization (default is &quot;simple/simple&quot;). This informs the
verifier of the type of canonicalization used to prepare the message for
signing.

In scalar context, this returns header/body canonicalization as a single
string separated by /. In list context, it returns a two element array,
containing first the header canonicalization, then the body.

=head2 data() - get or set the signature data (b=) field

  my $base64 = $signature-&gt;data;
  $signature-&gt;data($base64);

The signature data. Whitespace is automatically stripped from the
returned value. The data is Base64-encoded.

=head2 domain() - get or set the domain (d=) field

  my $d = $signature-&gt;domain;          # gets the domain value
  $signature-&gt;domain('example.org');   # sets the domain value

The domain of the signing entity, as specified in the signature.
This is the domain that will be queried for the public key.

If using an &quot;internationalized domain name&quot;, the domain name must be
converted to ASCII (following section 4.1 of RFC 3490) before passing
it to this method.

=head2 expiration() - get or set the signature expiration (x=) field

Signature expiration (default is undef, meaning no expiration).
The signature expiration, if defined, is an unsigned integer identifying
the standard Unix seconds-since-1970 time when the signature will
expire.

=head2 get_public_key() - fetches the public key referenced by this signature

  my $pubkey = $signature-&gt;get_public_key;

Public key to fetch is determined by the protocol, selector, and domain
fields.

This method caches the result of the fetch, so subsequent calls will not
require additional DNS queries.

This method will C&lt;die&gt; if an error occurs.

=head2 get_tag() - access the raw value of a tag in this signature

  my $raw_identity = $signature-&gt;get_tag('i');

Use this method to access a tag not already supported by Mail::DKIM,
or if you want to bypass decoding of the value by Mail::DKIM.

For example, the raw i= (identity) tag is encoded in quoted-printable
form. If you use the identity() method, Mail::DKIM will decode from
quoted-printable before returning the value. But if you use
get_tag('i'), you can access the encoded quoted-printable form of
the value.

=head2 hash_algorithm() - access the hash algorithm specified in this signature

  my $hash = $signature-&gt;hash_algorithm;

Determines what hashing algorithm is used as part of the signature's
specified algorithm.

For algorithm &quot;rsa-sha1&quot;, the hash algorithm is &quot;sha1&quot;. Likewise, for
algorithm &quot;rsa-sha256&quot;, the hash algorithm is &quot;sha256&quot;. If the algorithm
is not recognized, undef is returned.

=head2 headerlist() - get or set the signed header fields (h=) field

  $signature-&gt;headerlist('a:b:c');

  my $headerlist = $signature-&gt;headerlist;

  my @headers = $signature-&gt;headerlist;

Signed header fields. A colon-separated list of header field names
that identify the header fields presented to the signing algorithm.

In scalar context, the list of header field names will be returned
as a single string, with the names joined together with colons.
In list context, the header field names will be returned as a list.

=head2 identity() - get or set the signing identity (i=) field

  my $i = $signature-&gt;identity;

Identity of the user or agent on behalf of which this message is signed.
The identity has an optional local part, followed by &quot;@&quot;, then a domain
name. The domain name should be the same as or a subdomain of the
domain returned by the C&lt;domain&gt; method.

Ideally, the identity should match the identity listed in the From:
header, or the Sender: header, but this is not required to have a
valid signature. Whether the identity used is &quot;authorized&quot; to sign
for the given message is not determined here.

If using an &quot;internationalized domain name&quot;, the domain name must be
converted to ASCII (following section 4.1 of RFC 3490) before passing
it to this method.

Identity values are encoded in the signature in quoted-printable format.
Using this method will translate to/from quoted-printable as necessary.
If you want the raw quoted-printable version of the identity, use
$signature-&gt;get_tag('i').

=head2 key() - get or set the private key object

  my $key = $signature-&gt;key;

  $signature-&gt;key(Mail::DKIM::PrivateKey-&gt;load(File =&gt; 'private.key'));

The private key is used for signing messages.
It is not used for verifying messages.

The key object can be any object that implements the
L&lt;sign_digest()|Mail::DKIM::PrivateKey/&quot;sign_digest()&quot;&gt; method.
(Providing your own object can be useful if your actual keys
are stored out-of-process.)

=head2 method() - get or set the canonicalization (c=) field

Message canonicalization (default is &quot;simple&quot;). This informs the verifier
of the type of canonicalization used to prepare the message for signing.

=head2 protocol() - get or set the query methods (q=) field

A colon-separated list of query methods used to retrieve the public
key (default is &quot;dns&quot;). Each query method is of the form &quot;type[/options]&quot;,
where the syntax and semantics of the options depends on the type.

=head2 result() - get or set the verification result

  my $result = $signature-&gt;result;

  $signature-&gt;result('pass');

  # to set the result with details
  $signature-&gt;result('invalid', 'no public key');

=head2 result_detail() - access the result, plus details if available

  my $detail = $signature-&gt;result_detail;

An explanation of possible detail messages can be found in the
documentation for L&lt;Mail::DKIM::Verifier/result_detail()&gt;.

=head2 selector() - get or set the selector (s=) field

The selector subdivides the namespace for the &quot;d=&quot; (domain) tag.

=head2 prettify() - alters the signature to look &quot;nicer&quot; as an email header

  $signature-&gt;prettify;

This method may alter the signature in a way that breaks signatures, so
it should be done ONLY when the signature is being generated, BEFORE being
fed to the canonicalization algorithm.

See also prettify_safe(), which will not break signatures.

=head2 prettify_safe() - same as prettify() but only touches the b= part

  $signature-&gt;prettify_safe;

This method will not break the signature, but it only affects the b= part
of the signature.

=head2 timestamp() - get or set the signature timestamp (t=) field

Signature timestamp (default is undef, meaning unknown creation time).
This is the time that the signature was created. The value is an unsigned
integer identifying the number of standard Unix seconds-since-1970.

=head2 version() - get or set the DKIM specification version (v=) field

This is the version of the DKIM specification that applies to this
signature record.

=head1 SEE ALSO

L&lt;Mail::DKIM::DkSignature&gt; for DomainKey-Signature headers

=head1 AUTHORS

=over 4

=item *

Jason Long &lt;jason@long.name&gt;

=item *

Marc Bradshaw &lt;marc@marcbradshaw.net&gt;

=item *

Bron Gondwana &lt;brong@fastmailteam.com&gt; (ARC)

=back

=head1 THANKS

Work on ensuring that this module passes the ARC test suite was
generously sponsored by Valimail (https://www.valimail.com/)

=head1 COPYRIGHT AND LICENSE

=over 4

=item *

Copyright (C) 2013 by Messiah College

=item *

Copyright (C) 2010 by Jason Long

=item *

Copyright (C) 2017 by Standcore LLC

=item *

Copyright (C) 2020 by FastMail Pty Ltd

=back

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.8.6 or,
at your option, any later version of Perl 5 you may have available.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FMail%2FDKIM'>Back to Directory</a>