<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Getopt/Long/Descriptive.pm</h2><form method='post'><textarea name='content' class='file-edit'>use strict;
use warnings;
package Getopt::Long::Descriptive 0.116;
# ABSTRACT: Getopt::Long, but simpler and more powerful

use v5.12;

use Carp qw(carp croak);
use File::Basename ();
use Getopt::Long 2.55;
use List::Util qw(first);
use Params::Validate 0.97 qw(:all);
use Scalar::Util ();

use Getopt::Long::Descriptive::Opts;
use Getopt::Long::Descriptive::Usage;

#pod =head1 SYNOPSIS
#pod
#pod   use Getopt::Long::Descriptive;
#pod
#pod   my ($opt, $usage) = describe_options(
#pod     'my-program %o &lt;some-arg&gt;',
#pod     [ 'server|s=s', &quot;the server to connect to&quot;, { required =&gt; 1  } ],
#pod     [ 'port|p=i',   &quot;the port to connect to&quot;,   { default  =&gt; 79 } ],
#pod     [],
#pod     [ 'verbose|v',  &quot;print extra stuff&quot;            ],
#pod     [ 'help',       &quot;print usage message and exit&quot;, { shortcircuit =&gt; 1 } ],
#pod   );
#pod
#pod   print($usage-&gt;text), exit if $opt-&gt;help;
#pod
#pod   Client-&gt;connect( $opt-&gt;server, $opt-&gt;port );
#pod
#pod   print &quot;Connected!\n&quot; if $opt-&gt;verbose;
#pod
#pod ...and running C&lt;my-program --help&gt; will produce:
#pod
#pod   my-program [-psv] [long options...] &lt;some-arg&gt;
#pod     -s --server     the server to connect to
#pod     -p --port       the port to connect to
#pod
#pod     -v --verbose    print extra stuff
#pod     --help          print usage message and exit
#pod
#pod =head1 DESCRIPTION
#pod
#pod Getopt::Long::Descriptive is yet another Getopt library.  It's built atop
#pod Getopt::Long, and gets a lot of its features, but tries to avoid making you
#pod think about its huge array of options.
#pod
#pod It also provides usage (help) messages, data validation, and a few other useful
#pod features.
#pod
#pod =head1 FUNCTIONS
#pod
#pod Getopt::Long::Descriptive only exports one routine by default:
#pod C&lt;describe_options&gt;.  All GLD's exports are exported by L&lt;Sub::Exporter&gt;.
#pod
#pod =head2 describe_options
#pod
#pod   my ($opt, $usage) = describe_options($usage_desc, @opt_spec, \%arg);
#pod
#pod This routine inspects C&lt;@ARGV&gt; for options that match the supplied spec. If all
#pod the options are valid then it returns the options given and an object for
#pod generating usage messages; if not then it dies with an explanation of what was
#pod wrong and a usage message.
#pod
#pod The C&lt;$opt&gt; object will be a dynamically-generated subclass of
#pod L&lt;Getopt::Long::Descriptive::Opts&gt;.  In brief, each of the options in
#pod C&lt;@opt_spec&gt; becomes an accessor method on the object, using the first-given
#pod name, with dashes converted to underscores.  For more information, see the
#pod documentation for the Opts class.
#pod
#pod The C&lt;$usage&gt; object will be a L&lt;Getopt::Long::Descriptive::Usage&gt; object,
#pod which provides a C&lt;text&gt; method to get the text of the usage message and C&lt;die&gt;
#pod to die with it.  For more methods and options, consults the documentation for
#pod the Usage class.
#pod
#pod =head3 $usage_desc
#pod
#pod The C&lt;$usage_desc&gt; parameter to C&lt;describe_options&gt; is a C&lt;sprintf&gt;-like string
#pod that is used in generating the first line of the usage message.  It's a
#pod one-line summary of how the command is to be invoked.  A typical usage
#pod description might be:
#pod
#pod   $usage_desc = &quot;%c %o &lt;source&gt; &lt;desc&gt;&quot;;
#pod
#pod C&lt;%c&gt; will be replaced with what Getopt::Long::Descriptive thinks is the
#pod program name (it's computed from C&lt;$0&gt;, see L&lt;/prog_name&gt;).
#pod
#pod C&lt;%o&gt; will be replaced with a list of the short options, as well as the text
#pod &quot;[long options...]&quot; if any have been defined.
#pod
#pod The rest of the usage description can be used to summarize what arguments are
#pod expected to follow the program's options, and is entirely free-form.
#pod
#pod Literal C&lt;%&gt; characters will need to be written as C&lt;%%&gt;, just like with
#pod C&lt;sprintf&gt;.
#pod
#pod =head3 @opt_spec
#pod
#pod The C&lt;@opt_spec&gt; part of the args to C&lt;describe_options&gt; is used to configure
#pod option parsing and to produce the usage message.  Each entry in the list is an
#pod arrayref describing one option, like this:
#pod
#pod   @opt_spec = (
#pod     [ &quot;verbose|V&quot; =&gt; &quot;be noisy&quot;       ],
#pod     [ &quot;logfile=s&quot; =&gt; &quot;file to log to&quot; ],
#pod   );
#pod
#pod The first value in the arrayref is a Getopt::Long-style option specification.
#pod In brief, they work like this:  each one is a pipe-delimited list of names,
#pod optionally followed by a type declaration.  Type declarations are '=x' or ':x',
#pod where C&lt;=&gt; means a value is required and C&lt;:&gt; means it is optional.  I&lt;x&gt; may
#pod be 's' to indicate a string is required, 'i' for an integer, or 'f' for a
#pod number with a fractional part.  The type spec may end in C&lt;@&gt; to indicate that
#pod the option may appear multiple times.
#pod
#pod For more information on how these work, see the L&lt;Getopt::Long&gt; documentation.
#pod
#pod The first name given should be the canonical name, as it will be used as the
#pod accessor method on the C&lt;$opt&gt; object.  Dashes in the name will be converted to
#pod underscores, and all letters will be lowercased.  For this reason, all options
#pod should generally have a long-form name.
#pod
#pod The second value in the arrayref is a description of the option, for use in the
#pod usage message.
#pod
#pod =head4 Special Option Specifications
#pod
#pod If the option specification (arrayref) is empty, it will have no effect other
#pod than causing a blank line to appear in the usage message.
#pod
#pod If the option specification contains only one element, it will be printed in
#pod the usage message with no other effect.  If the element is a reference, its
#pod referent will be printed as-is.  Otherwise, it will be reformatted like other
#pod text in the usage message.
#pod
#pod If the option specification contains a third element, it adds extra constraints
#pod or modifiers to the interpretation and validation of the value.  These are the
#pod keys that may be present in that hashref, and how they behave:
#pod
#pod =over 4
#pod
#pod =item implies
#pod
#pod   implies =&gt; 'bar'
#pod   implies =&gt; [qw(foo bar)]
#pod   implies =&gt; { foo =&gt; 1, bar =&gt; 2 }
#pod
#pod If option I&lt;A&gt; has an &quot;implies&quot; entry, then if I&lt;A&gt; is given, other options
#pod will be enabled.  The value may be a single option to set, an arrayref of
#pod options to set, or a hashref of options to set to specific values.
#pod
#pod =item required
#pod
#pod   required =&gt; 1
#pod
#pod If an option is required, failure to provide the option will result in
#pod C&lt;describe_options&gt; printing the usage message and exiting.
#pod
#pod =item hidden
#pod
#pod   hidden =&gt; 1
#pod
#pod This option will not show up in the usage text.
#pod
#pod You can achieve the same behavior by using the string &quot;hidden&quot; for the option's
#pod description.
#pod
#pod =item one_of
#pod
#pod   one_of =&gt; \@subopt_specs
#pod
#pod This is useful for a group of options that are related.  Each option
#pod spec is added to the list for normal parsing and validation.
#pod
#pod Your option name will end up with a value of the name of the
#pod option that was chosen.  For example, given the following spec:
#pod
#pod   [ &quot;mode&quot; =&gt; hidden =&gt; { one_of =&gt; [
#pod     [ &quot;get|g&quot;  =&gt; &quot;get the value&quot; ],
#pod     [ &quot;set|s&quot;  =&gt; &quot;set the value&quot; ],
#pod     [ &quot;delete&quot; =&gt; &quot;delete it&quot; ],
#pod   ] } ],
#pod
#pod No usage text for 'mode' will be displayed, but text for get, set, and delete
#pod will be displayed.
#pod
#pod If more than one of get, set, or delete is given, an error will be thrown.
#pod
#pod So, given the C&lt;@opt_spec&gt; above, and an C&lt;@ARGV&gt; of C&lt;('--get')&gt;, the
#pod following would be true:
#pod
#pod   $opt-&gt;get == 1;
#pod
#pod   $opt-&gt;mode eq 'get';
#pod
#pod B&lt;Note&gt;: C&lt;get&gt; would not be set if C&lt;mode&gt; defaulted to 'get' and no arguments
#pod were passed in.
#pod
#pod Even though the option sub-specs for C&lt;one_of&gt; are meant to be 'first
#pod class' specs, some options don't make sense with them, e.g. C&lt;required&gt;.
#pod
#pod As a further shorthand, you may specify C&lt;one_of&gt; options using this form:
#pod
#pod   [ mode =&gt; \@option_specs, \%constraints ]
#pod
#pod
#pod =item shortcircuit
#pod
#pod   shortcircuit =&gt; 1
#pod
#pod If this option is present no other options will be returned.  Other
#pod options present will be checked for proper types, but I&lt;not&gt; for
#pod constraints.  This provides a way of specifying C&lt;--help&gt; style options.
#pod
#pod =item Params::Validate
#pod
#pod In addition, any constraint understood by Params::Validate may be used.
#pod
#pod For example, to accept positive integers:
#pod
#pod   [ 'max-iterations=i', &quot;maximum number of iterations&quot;,
#pod     { callbacks =&gt; { positive =&gt; sub { shift() &gt; 0 } } } ],
#pod
#pod (Internally, all constraints are translated into Params::Validate options or
#pod callbacks.)
#pod
#pod =back
#pod
#pod =head3 %arg
#pod
#pod The C&lt;%arg&gt; to C&lt;describe_options&gt; is optional.  If the last parameter is a
#pod hashref, it contains extra arguments to modify the way C&lt;describe_options&gt;
#pod works.  Valid arguments are:
#pod
#pod   getopt_conf   - an arrayref of strings, passed to Getopt::Long::Configure
#pod   show_defaults - a boolean which controls whether an option's default
#pod                   value (if applicable) is shown as part of the usage message
#pod                   (for backward compatibility this defaults to false)
#pod
#pod =head2 prog_name
#pod
#pod This routine, exported on demand, returns the basename of C&lt;$0&gt;, grabbed at
#pod compile-time.  You can override this guess by calling C&lt;prog_name($string)&gt;
#pod yourself.
#pod
#pod =head1 OTHER EXPORTS
#pod
#pod =head2 C&lt;-types&gt;
#pod
#pod Any of the Params::Validate type constants (C&lt;SCALAR&gt;, etc.) can be imported as
#pod well.  You can get all of them at once by importing C&lt;-types&gt;.
#pod
#pod =head2 C&lt;-all&gt;
#pod
#pod This import group will import C&lt;-type&gt;, C&lt;describe_options&gt;, and C&lt;prog_name&gt;.
#pod
#pod =cut

my $prog_name;
sub prog_name { @_ ? ($prog_name = shift) : $prog_name }

BEGIN {
  # grab this before someone decides to change it
  prog_name(File::Basename::basename($0));
}

use Sub::Exporter::Util ();
use Sub::Exporter 0.972 -setup =&gt; {
  exports =&gt; [
    describe_options =&gt; \'_build_describe_options',
    q(prog_name),
    @{ $Params::Validate::EXPORT_TAGS{types} }
  ],
  groups  =&gt; [
    default =&gt; [ qw(describe_options) ],
    types   =&gt; $Params::Validate::EXPORT_TAGS{types},
  ],
};

my %CONSTRAINT = (
  implies  =&gt; \&amp;_mk_implies,
  only_one =&gt; \&amp;_mk_only_one,
);

our $MungeOptions = 1;

our $TERM_WIDTH;
{
  $TERM_WIDTH = $ENV{COLUMNS} || 80;

  # So, this was the old code:
  #
  #   if (eval { require Term::ReadKey; 1 }) {
  #     my ($width) = Term::ReadKey::GetTerminalSize();
  #     $TERM_WIDTH = $width;
  #   } else {
  #     $TERM_WIDTH = $ENV{COLUMNS} || 80;
  #   }
  #
  # ...but the problem is that Term::ReadKey will carp when it can't get an
  # answer, it can't be trivially made to keep quiet.  (I decline to stick a
  # local $SIG{__WARN__} here, as it's too heavy a hammer.)  With the new (as
  # of 2021-03) formatting code, using the full width is less of an issue,
  # anyway.
}

sub _nohidden {
  return grep { ! $_-&gt;{constraint}-&gt;{hidden} } @_;
}

sub _expand {
  my @expanded;

  for my $opt (@_) {
    push @expanded, {
      spec       =&gt; $opt-&gt;[0] || '',
      desc       =&gt; @$opt &gt; 1 ? $opt-&gt;[1] : 'spacer',
      constraint =&gt; $opt-&gt;[2] || {},

      # if @$_ is 0 then we got [], a spacer
      name       =&gt; @$opt ? _munge((split /[:=|!+]/, $opt-&gt;[0] || '')[0]) : '',
    };
  }

  return @expanded;
}

my %HIDDEN = (
  hidden =&gt; 1,
);

my $SPEC_RE = qr{(?:[:=][0-9\w\+]+[%@]?(\{[0-9]*,[0-9]*\})?|[!+])$};
sub _strip_assignment {
  my ($self, $str) = @_;

  (my $copy = $str) =~ s{$SPEC_RE}{};

  if (wantarray) {
    my $len = length $copy;
    my $assignment = substr($str, $len) // q{};

    return ($copy, $assignment);
  }
  return $copy;
}

# This is here only to deal with people who were calling this fully-qualified
# without importing.  Sucks to them!  -- rjbs, 2009-08-21
sub describe_options {
  my $sub = __PACKAGE__-&gt;_build_describe_options(describe_options =&gt; {} =&gt; {});
  $sub-&gt;(@_);
}

sub usage_class { 'Getopt::Long::Descriptive::Usage' }

sub _build_describe_options {
  my ($class) = @_;

  sub {
    my $format = (ref $_[0] ? '%c %o' : shift(@_));
    my $arg    = (ref $_[-1] and ref $_[-1] eq 'HASH') ? pop @_ : {};
    my @opts;

    my %parent_of;

    # special casing
    # wish we had real loop objects
    my %method_map;
    for my $opt (_expand(@_)) {
      $method_map{ $opt-&gt;{name} } = undef unless $opt-&gt;{desc} eq 'spacer';

      if (ref($opt-&gt;{desc}) eq 'ARRAY') {
        $opt-&gt;{constraint}-&gt;{one_of} = delete $opt-&gt;{desc};
        $opt-&gt;{desc} = 'hidden';
      }

      if ($HIDDEN{$opt-&gt;{desc}}) {
        $opt-&gt;{constraint}-&gt;{hidden}++;
      }

      if ($opt-&gt;{constraint}-&gt;{one_of}) {
        for my $one_opt (_expand(
          @{delete $opt-&gt;{constraint}-&gt;{one_of}}
        )) {
          $parent_of{$one_opt-&gt;{name}} = $opt-&gt;{name};
          $one_opt-&gt;{constraint}-&gt;{implies}
            -&gt;{$opt-&gt;{name}} = $one_opt-&gt;{name};
          for my $wipe (qw(required default)) {
            if ($one_opt-&gt;{constraint}-&gt;{$wipe}) {
              carp &quot;'$wipe' constraint does not make sense in sub-option&quot;;
              delete $one_opt-&gt;{constraint}-&gt;{$wipe};
            }
          }
          $one_opt-&gt;{constraint}-&gt;{one_of} = $opt-&gt;{name};
          push @opts, $one_opt;

          # Ensure that we generate accessors for all one_of sub-options
          $method_map{ $one_opt-&gt;{name} } = undef
            unless $one_opt-&gt;{desc} eq 'spacer';
        }
      }

      if ($opt-&gt;{constraint}{shortcircuit}
        &amp;&amp; exists $opt-&gt;{constraint}{default}
      ) {
        carp('option &quot;' . $opt-&gt;{name} . q[&quot;: 'default' does not make sense for shortcircuit options]);
      }

      push @opts, $opt;
    }

    my @go_conf = @{ $arg-&gt;{getopt_conf} || $arg-&gt;{getopt} || [] };
    if ($arg-&gt;{getopt}) {
      warn &quot;describe_options: 'getopt' is deprecated, please use 'getopt_conf' instead\n&quot;;
    }

    push @go_conf, &quot;bundling&quot; unless grep { /bundling/i } @go_conf;
    push @go_conf, &quot;no_auto_help&quot;  unless grep { /no_auto_help/i } @go_conf;
    push @go_conf, &quot;no_ignore_case&quot;
      unless grep { /no_ignore_case/i } @go_conf;

    # not entirely sure that all of this (until the Usage-&gt;new) shouldn't be
    # moved into Usage -- rjbs, 2009-08-19

    # all specs including hidden
    my @getopt_specs =
      map  { $_-&gt;{spec} }
      grep { $_-&gt;{desc} ne 'spacer' }
      @opts;

    my @specs =
      map  { $_-&gt;{spec} }
      grep { $_-&gt;{desc} ne 'spacer' }
      _nohidden(@opts);

    my @options =
      map   { split /\|/ }
      map   { scalar __PACKAGE__-&gt;_strip_assignment($_) }
      @specs;

    my %opt_count;
    $opt_count{$_}++ for @options;

    my $short = join q{},
      sort  { lc $a cmp lc $b or $a cmp $b }
      grep  { /^.$/ }
      @options;

    my $long = grep /\b[^|]{2,}/, @specs;

    my %replace = (
      &quot;%&quot; =&gt; &quot;%&quot;,
      &quot;c&quot; =&gt; prog_name,
      &quot;o&quot; =&gt; join(q{ },
        ($short ? &quot;[-$short]&quot; : ()),
        ($long  ? &quot;[long options...]&quot; : ())
      ),
    );

    (my $str = $format) =~ s&lt;%(.)&gt;&lt;
      $replace{$1}
      // Carp::croak(&quot;unknown sequence %$1 in first argument to describe_options&quot;)
    &gt;ge;

    $str =~ s/[\x20\t]{2,}/ /g;

    my $usage = $class-&gt;usage_class-&gt;new({
      options       =&gt; [ _nohidden(@opts) ],
      leader_text   =&gt; $str,
      show_defaults =&gt; $arg-&gt;{show_defaults},
    });

    my $old_go_conf = Getopt::Long::Configure(@go_conf);

    my %return;
    $usage-&gt;die unless GetOptions(\%return, grep { length } @getopt_specs);
    my @given_keys = keys %return;

    Getopt::Long::Configure($old_go_conf);

    for my $opt (keys %return) {
      my $newopt = _munge($opt);
      next if $newopt eq $opt;
      $return{$newopt} = delete $return{$opt};
    }

    # ensure that shortcircuit options are handled first
    for my $copt (
      sort {     ($b-&gt;{constraint}{shortcircuit} || 0)
             &lt;=&gt; ($a-&gt;{constraint}{shortcircuit} || 0)
           } grep { $_-&gt;{constraint} } @opts
    ) {
      delete $copt-&gt;{constraint}-&gt;{hidden};
      my $is_shortcircuit = delete $copt-&gt;{constraint}{shortcircuit};
      my $name = $copt-&gt;{name};
      my $new  = _validate_with(
        name   =&gt; $name,
        params =&gt; \%return,
        spec   =&gt; $copt-&gt;{constraint},
        opts   =&gt; \@opts,
        usage  =&gt; $usage,
        given_keys =&gt; \@given_keys,
        parent_of  =&gt; \%parent_of,
      );
      next unless defined $new || exists $return{$name};
      $return{$name} = $new;

      if ($is_shortcircuit) {
        %return = ($name =&gt; $return{$name});
        last;
      }
    }

    my $opt_obj = Getopt::Long::Descriptive::Opts-&gt;___new_opt_obj({
      values =&gt; { %method_map, %return },
      given  =&gt; { map {; $_ =&gt; 1 } @given_keys },
    });

    return($opt_obj, $usage);
  }
}

sub _munge {
  my ($opt) = @_;
  return $opt unless $MungeOptions;
  $opt = lc($opt);
  $opt =~ tr/-/_/;
  return $opt;
}

sub _validate_with {
  my (%arg) = validate(@_, {
    name   =&gt; 1,
    params =&gt; 1,
    spec   =&gt; 1,
    opts   =&gt; 1,
    usage  =&gt; 1,
    given_keys =&gt; 1,
    parent_of  =&gt; 1,
  });

  my $spec = $arg{spec};
  my %pvspec;
  SPEC_ENTRY: for my $ct (keys %{$spec}) {
    if ($ct eq 'required') {
      # This used to be in %CONSTRAINT but this whole system is a bit
      # overcomplex, I think, and moving this here makes life simpler.  Someday
      # (ha ha) this can all be overhauled. -- rjbs, 2024-01-20
      $pvspec{optional} = ! $spec-&gt;{$ct};
      next SPEC_ENTRY;
    }

    if ($CONSTRAINT{$ct} and ref $CONSTRAINT{$ct} eq 'CODE') {
      $pvspec{callbacks} ||= {};
      $pvspec{callbacks} = {
        %{$pvspec{callbacks}},
        $CONSTRAINT{$ct}-&gt;(
          $arg{name},
          $spec-&gt;{$ct},
          $arg{params},
          $arg{opts},
        ),
      };
    } else {
      %pvspec = (
        %pvspec,
        $CONSTRAINT{$ct} ? %{$CONSTRAINT{$ct}} : ($ct =&gt; $spec-&gt;{$ct}),
      );
    }
  }

  $pvspec{optional} = 1 unless exists $pvspec{optional};

  # we need to implement 'default' by ourselves sometimes
  # because otherwise the implies won't be checked/executed
  # XXX this should be more generic -- we'll probably want
  # other callbacks to always run, too
  if (!defined($arg{params}{$arg{name}})
        &amp;&amp; $pvspec{default}
          &amp;&amp; $spec-&gt;{implies}) {

    $arg{params}{$arg{name}} = delete $pvspec{default};
  }

  my %p;
  my $ok = eval {
    %p = validate_with(
      params =&gt; [
        %{$arg{params}},
        '-given_keys', $arg{given_keys},
        '-parent_of',  $arg{parent_of},
      ],
      spec   =&gt; { $arg{name} =&gt; \%pvspec },
      allow_extra =&gt; 1,
      on_fail     =&gt; sub {
        my $fail_msg = shift;
        Getopt::Long::Descriptive::_PV_Error-&gt;throw($fail_msg);
      },
    );
    1;
  };

  if (! $ok) {
    my $error = $@;
    if (
      Scalar::Util::blessed($error)
      &amp;&amp; $error-&gt;isa('Getopt::Long::Descriptive::_PV_Error')
    ) {
      $arg{usage}-&gt;die({ pre_text =&gt; $error-&gt;error . &quot;\n&quot; });
    }

    die $@;
  }

  return $p{$arg{name}};
}

# scalar:   single option = true
# arrayref: multiple options = true
# hashref:  single/multiple options = given values
sub _norm_imply {
  my ($what) = @_;

  return { $what =&gt; 1 } unless my $ref = ref $what;

  return $what                      if $ref eq 'HASH';
  return { map { $_ =&gt; 1 } @$what } if $ref eq 'ARRAY';

  die &quot;can't imply: $what&quot;;
}

sub _mk_implies {
  my $name = shift;
  my $what = _norm_imply(shift);
  my $param = shift;
  my $opts  = shift;

  for my $implied (keys %$what) {
    die(&quot;option specification for $name implies nonexistent option $implied\n&quot;)
      unless first { $_-&gt;{name} eq $implied } @$opts
  }

  my $whatstr = join(q{, }, map { &quot;$_=$what-&gt;{$_}&quot; } keys %$what);

  return &quot;$name implies $whatstr&quot; =&gt; sub {
    my ($pv_val, $rest) = @_;

    # negatable options will be 0 here, which is ok.
    return 1 unless defined $pv_val;

    while (my ($key, $val) = each %$what) {
      # Really, this should be called &quot;-implies&quot; and should include all implies
      # relationships, but they'll have to get handled by setting conflicts.
      my $parent   = $rest-&gt;{'-parent_of'}{$name};
      my @siblings = $parent
                   ? (grep {; defined $rest-&gt;{'-parent_of'}{$_}
                              &amp;&amp; $rest-&gt;{'-parent_of'}{$_} eq $parent }
                      @{ $rest-&gt;{'-given_keys'} })
                   : ();

      if (@siblings &gt; 1) {
        die &quot;these options conflict; each wants to set the $parent: @siblings\n&quot;;
      }

      if (  exists $param-&gt;{$key}
        and $param-&gt;{$key} ne $val
        and grep {; $_ eq $key } @{ $rest-&gt;{'-given_keys'} }
      ) {
        die(
          &quot;option specification for $name implies that $key should be &quot;
          . &quot;set to '$val', but it is '$param-&gt;{$key}' already\n&quot;
        );
      }
      $param-&gt;{$key} = $val;
    }

    return 1;
  };
}

sub _mk_only_one {
  die &quot;unimplemented&quot;;
}

{
  package
    Getopt::Long::Descriptive::_PV_Error;
  sub error { $_[0]-&gt;{error} }
  sub throw {
    my ($class, $error_msg) = @_;
    my $self = { error =&gt; $error_msg };
    bless $self, $class;
    die $self;
  }
}

#pod =head1 CUSTOMIZING
#pod
#pod Getopt::Long::Descriptive uses L&lt;Sub::Exporter|Sub::Exporter&gt; to build and
#pod export the C&lt;describe_options&gt; routine.  By writing a new class that extends
#pod Getopt::Long::Descriptive, the behavior of the constructed C&lt;describe_options&gt;
#pod routine can be changed.
#pod
#pod The following methods can be overridden:
#pod
#pod =head2 usage_class
#pod
#pod   my $class = Getopt::Long::Descriptive-&gt;usage_class;
#pod
#pod This returns the class to be used for constructing a Usage object, and defaults
#pod to Getopt::Long::Descriptive::Usage.
#pod
#pod =head1 SEE ALSO
#pod
#pod =for :list
#pod * L&lt;Getopt::Long&gt;
#pod * L&lt;Params::Validate&gt;
#pod
#pod =cut

1; # End of Getopt::Long::Descriptive

__END__

=pod

=encoding UTF-8

=head1 NAME

Getopt::Long::Descriptive - Getopt::Long, but simpler and more powerful

=head1 VERSION

version 0.116

=head1 SYNOPSIS

  use Getopt::Long::Descriptive;

  my ($opt, $usage) = describe_options(
    'my-program %o &lt;some-arg&gt;',
    [ 'server|s=s', &quot;the server to connect to&quot;, { required =&gt; 1  } ],
    [ 'port|p=i',   &quot;the port to connect to&quot;,   { default  =&gt; 79 } ],
    [],
    [ 'verbose|v',  &quot;print extra stuff&quot;            ],
    [ 'help',       &quot;print usage message and exit&quot;, { shortcircuit =&gt; 1 } ],
  );

  print($usage-&gt;text), exit if $opt-&gt;help;

  Client-&gt;connect( $opt-&gt;server, $opt-&gt;port );

  print &quot;Connected!\n&quot; if $opt-&gt;verbose;

...and running C&lt;my-program --help&gt; will produce:

  my-program [-psv] [long options...] &lt;some-arg&gt;
    -s --server     the server to connect to
    -p --port       the port to connect to

    -v --verbose    print extra stuff
    --help          print usage message and exit

=head1 DESCRIPTION

Getopt::Long::Descriptive is yet another Getopt library.  It's built atop
Getopt::Long, and gets a lot of its features, but tries to avoid making you
think about its huge array of options.

It also provides usage (help) messages, data validation, and a few other useful
features.

=head1 PERL VERSION

This library should run on perls released even a long time ago.  It should
work on any version of perl released in the last five years.

Although it may work on older versions of perl, no guarantee is made that the
minimum required version will not be increased.  The version may be increased
for any reason, and there is no promise that patches will be accepted to
lower the minimum required perl.

=head1 FUNCTIONS

Getopt::Long::Descriptive only exports one routine by default:
C&lt;describe_options&gt;.  All GLD's exports are exported by L&lt;Sub::Exporter&gt;.

=head2 describe_options

  my ($opt, $usage) = describe_options($usage_desc, @opt_spec, \%arg);

This routine inspects C&lt;@ARGV&gt; for options that match the supplied spec. If all
the options are valid then it returns the options given and an object for
generating usage messages; if not then it dies with an explanation of what was
wrong and a usage message.

The C&lt;$opt&gt; object will be a dynamically-generated subclass of
L&lt;Getopt::Long::Descriptive::Opts&gt;.  In brief, each of the options in
C&lt;@opt_spec&gt; becomes an accessor method on the object, using the first-given
name, with dashes converted to underscores.  For more information, see the
documentation for the Opts class.

The C&lt;$usage&gt; object will be a L&lt;Getopt::Long::Descriptive::Usage&gt; object,
which provides a C&lt;text&gt; method to get the text of the usage message and C&lt;die&gt;
to die with it.  For more methods and options, consults the documentation for
the Usage class.

=head3 $usage_desc

The C&lt;$usage_desc&gt; parameter to C&lt;describe_options&gt; is a C&lt;sprintf&gt;-like string
that is used in generating the first line of the usage message.  It's a
one-line summary of how the command is to be invoked.  A typical usage
description might be:

  $usage_desc = &quot;%c %o &lt;source&gt; &lt;desc&gt;&quot;;

C&lt;%c&gt; will be replaced with what Getopt::Long::Descriptive thinks is the
program name (it's computed from C&lt;$0&gt;, see L&lt;/prog_name&gt;).

C&lt;%o&gt; will be replaced with a list of the short options, as well as the text
&quot;[long options...]&quot; if any have been defined.

The rest of the usage description can be used to summarize what arguments are
expected to follow the program's options, and is entirely free-form.

Literal C&lt;%&gt; characters will need to be written as C&lt;%%&gt;, just like with
C&lt;sprintf&gt;.

=head3 @opt_spec

The C&lt;@opt_spec&gt; part of the args to C&lt;describe_options&gt; is used to configure
option parsing and to produce the usage message.  Each entry in the list is an
arrayref describing one option, like this:

  @opt_spec = (
    [ &quot;verbose|V&quot; =&gt; &quot;be noisy&quot;       ],
    [ &quot;logfile=s&quot; =&gt; &quot;file to log to&quot; ],
  );

The first value in the arrayref is a Getopt::Long-style option specification.
In brief, they work like this:  each one is a pipe-delimited list of names,
optionally followed by a type declaration.  Type declarations are '=x' or ':x',
where C&lt;=&gt; means a value is required and C&lt;:&gt; means it is optional.  I&lt;x&gt; may
be 's' to indicate a string is required, 'i' for an integer, or 'f' for a
number with a fractional part.  The type spec may end in C&lt;@&gt; to indicate that
the option may appear multiple times.

For more information on how these work, see the L&lt;Getopt::Long&gt; documentation.

The first name given should be the canonical name, as it will be used as the
accessor method on the C&lt;$opt&gt; object.  Dashes in the name will be converted to
underscores, and all letters will be lowercased.  For this reason, all options
should generally have a long-form name.

The second value in the arrayref is a description of the option, for use in the
usage message.

=head4 Special Option Specifications

If the option specification (arrayref) is empty, it will have no effect other
than causing a blank line to appear in the usage message.

If the option specification contains only one element, it will be printed in
the usage message with no other effect.  If the element is a reference, its
referent will be printed as-is.  Otherwise, it will be reformatted like other
text in the usage message.

If the option specification contains a third element, it adds extra constraints
or modifiers to the interpretation and validation of the value.  These are the
keys that may be present in that hashref, and how they behave:

=over 4

=item implies

  implies =&gt; 'bar'
  implies =&gt; [qw(foo bar)]
  implies =&gt; { foo =&gt; 1, bar =&gt; 2 }

If option I&lt;A&gt; has an &quot;implies&quot; entry, then if I&lt;A&gt; is given, other options
will be enabled.  The value may be a single option to set, an arrayref of
options to set, or a hashref of options to set to specific values.

=item required

  required =&gt; 1

If an option is required, failure to provide the option will result in
C&lt;describe_options&gt; printing the usage message and exiting.

=item hidden

  hidden =&gt; 1

This option will not show up in the usage text.

You can achieve the same behavior by using the string &quot;hidden&quot; for the option's
description.

=item one_of

  one_of =&gt; \@subopt_specs

This is useful for a group of options that are related.  Each option
spec is added to the list for normal parsing and validation.

Your option name will end up with a value of the name of the
option that was chosen.  For example, given the following spec:

  [ &quot;mode&quot; =&gt; hidden =&gt; { one_of =&gt; [
    [ &quot;get|g&quot;  =&gt; &quot;get the value&quot; ],
    [ &quot;set|s&quot;  =&gt; &quot;set the value&quot; ],
    [ &quot;delete&quot; =&gt; &quot;delete it&quot; ],
  ] } ],

No usage text for 'mode' will be displayed, but text for get, set, and delete
will be displayed.

If more than one of get, set, or delete is given, an error will be thrown.

So, given the C&lt;@opt_spec&gt; above, and an C&lt;@ARGV&gt; of C&lt;('--get')&gt;, the
following would be true:

  $opt-&gt;get == 1;

  $opt-&gt;mode eq 'get';

B&lt;Note&gt;: C&lt;get&gt; would not be set if C&lt;mode&gt; defaulted to 'get' and no arguments
were passed in.

Even though the option sub-specs for C&lt;one_of&gt; are meant to be 'first
class' specs, some options don't make sense with them, e.g. C&lt;required&gt;.

As a further shorthand, you may specify C&lt;one_of&gt; options using this form:

  [ mode =&gt; \@option_specs, \%constraints ]

=item shortcircuit

  shortcircuit =&gt; 1

If this option is present no other options will be returned.  Other
options present will be checked for proper types, but I&lt;not&gt; for
constraints.  This provides a way of specifying C&lt;--help&gt; style options.

=item Params::Validate

In addition, any constraint understood by Params::Validate may be used.

For example, to accept positive integers:

  [ 'max-iterations=i', &quot;maximum number of iterations&quot;,
    { callbacks =&gt; { positive =&gt; sub { shift() &gt; 0 } } } ],

(Internally, all constraints are translated into Params::Validate options or
callbacks.)

=back

=head3 %arg

The C&lt;%arg&gt; to C&lt;describe_options&gt; is optional.  If the last parameter is a
hashref, it contains extra arguments to modify the way C&lt;describe_options&gt;
works.  Valid arguments are:

  getopt_conf   - an arrayref of strings, passed to Getopt::Long::Configure
  show_defaults - a boolean which controls whether an option's default
                  value (if applicable) is shown as part of the usage message
                  (for backward compatibility this defaults to false)

=head2 prog_name

This routine, exported on demand, returns the basename of C&lt;$0&gt;, grabbed at
compile-time.  You can override this guess by calling C&lt;prog_name($string)&gt;
yourself.

=head1 OTHER EXPORTS

=head2 C&lt;-types&gt;

Any of the Params::Validate type constants (C&lt;SCALAR&gt;, etc.) can be imported as
well.  You can get all of them at once by importing C&lt;-types&gt;.

=head2 C&lt;-all&gt;

This import group will import C&lt;-type&gt;, C&lt;describe_options&gt;, and C&lt;prog_name&gt;.

=head1 CUSTOMIZING

Getopt::Long::Descriptive uses L&lt;Sub::Exporter|Sub::Exporter&gt; to build and
export the C&lt;describe_options&gt; routine.  By writing a new class that extends
Getopt::Long::Descriptive, the behavior of the constructed C&lt;describe_options&gt;
routine can be changed.

The following methods can be overridden:

=head2 usage_class

  my $class = Getopt::Long::Descriptive-&gt;usage_class;

This returns the class to be used for constructing a Usage object, and defaults
to Getopt::Long::Descriptive::Usage.

=head1 SEE ALSO

=over 4

=item *

L&lt;Getopt::Long&gt;

=item *

L&lt;Params::Validate&gt;

=back

=head1 AUTHORS

=over 4

=item *

Hans Dieter Pearcey &lt;hdp@cpan.org&gt;

=item *

Ricardo Signes &lt;cpan@semiotic.systems&gt;

=back

=head1 CONTRIBUTORS

=for stopwords Arthur Axel 'fREW' Schmidt Dave Rolsky Diab Jerius Hans Dieter Pearcey Harley Pig hdp@cpan.org Karen Etheridge Michael McClimon Niels Thykier Olaf Alders Ricardo Signes Roman Hubacek Smylers Thomas Neumann zhouzhen1

=over 4

=item *

Arthur Axel 'fREW' Schmidt &lt;frioux@gmail.com&gt;

=item *

Dave Rolsky &lt;autarch@urth.org&gt;

=item *

Diab Jerius &lt;djerius@cfa.harvard.edu&gt;

=item *

Hans Dieter Pearcey &lt;hdp@weftsoar.net&gt;

=item *

Harley Pig &lt;harleypig@gmail.com&gt;

=item *

hdp@cpan.org &lt;hdp@cpan.org@fc0e91e4-031c-0410-8307-be39b06d7656&gt;

=item *

Karen Etheridge &lt;ether@cpan.org&gt;

=item *

Michael McClimon &lt;michael@mcclimon.org&gt;

=item *

Niels Thykier &lt;niels@thykier.net&gt;

=item *

Olaf Alders &lt;olaf@wundersolutions.com&gt;

=item *

Ricardo Signes &lt;rjbs@semiotic.systems&gt;

=item *

Roman Hubacek &lt;roman.hubacek@centrum.cz&gt;

=item *

Smylers &lt;SMYLERS@cpan.fsck.com&gt;

=item *

Thomas Neumann &lt;blacky+perl@fluffbunny.de&gt;

=item *

zhouzhen1 &lt;zhouzhen1@gmail.com&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2005 by Hans Dieter Pearcey.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FGetopt%2FLong'>Back to Directory</a>