<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Exception/Class/Base.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Exception::Class::Base;

use strict;
use warnings;

our $VERSION = '1.45';

use Class::Data::Inheritable 0.02;
use Devel::StackTrace 2.00;
use Scalar::Util qw( blessed );

use base qw(Class::Data::Inheritable);

BEGIN {
    __PACKAGE__-&gt;mk_classdata('Trace');
    __PACKAGE__-&gt;mk_classdata('UnsafeRefCapture');

    __PACKAGE__-&gt;mk_classdata('NoContextInfo');
    __PACKAGE__-&gt;NoContextInfo(0);

    __PACKAGE__-&gt;mk_classdata('RespectOverload');
    __PACKAGE__-&gt;RespectOverload(0);

    __PACKAGE__-&gt;mk_classdata('MaxArgLength');
    __PACKAGE__-&gt;MaxArgLength(0);

    sub NoRefs {
        my $self = shift;
        if (@_) {
            my $val = shift;
            return $self-&gt;UnsafeRefCapture( !$val );
        }
        else {
            return $self-&gt;UnsafeRefCapture;
        }
    }

    sub Fields { () }
}

use overload

    # an exception is always true
    bool =&gt; sub {1}, '&quot;&quot;' =&gt; 'as_string', fallback =&gt; 1;

# Create accessor routines
BEGIN {
    my @fields = qw( message pid uid euid gid egid time trace );

    foreach my $f (@fields) {
        my $sub = sub { my $s = shift; return $s-&gt;{$f}; };

        ## no critic (TestingAndDebugging::ProhibitNoStrict)
        no strict 'refs';
        *{$f} = $sub;
    }
    *error = \&amp;message;

    my %trace_fields = (
        package =&gt; 'package',
        file    =&gt; 'filename',
        line    =&gt; 'line',
    );

    while ( my ( $f, $m ) = each %trace_fields ) {
        my $sub = sub {
            my $s = shift;
            return $s-&gt;{$f} if exists $s-&gt;{$f};

            my $frame = $s-&gt;trace-&gt;frame(0);

            return $s-&gt;{$f} = $frame ? $frame-&gt;$m : undef;
        };

        ## no critic (TestingAndDebugging::ProhibitNoStrict)
        no strict 'refs';
        *{$f} = $sub;
    }
}

sub Classes { Exception::Class::Classes() }

sub throw {
    my $proto = shift;

    $proto-&gt;rethrow if ref $proto;

    die $proto-&gt;new(@_);
}

sub rethrow {
    my $self = shift;

    die $self;
}

sub new {
    my $proto = shift;
    my $class = ref $proto || $proto;

    my $self = bless {}, $class;

    $self-&gt;_initialize(@_);

    return $self;
}

sub _initialize {
    my $self = shift;
    my %p    = @_ == 1 ? ( error =&gt; $_[0] ) : @_;

    $self-&gt;{message} = $p{message} || $p{error} || q{};

    $self-&gt;{show_trace} = $p{show_trace} if exists $p{show_trace};

    if ( $self-&gt;NoContextInfo ) {
        $self-&gt;{show_trace} = 0;
        $self-&gt;{package}    = $self-&gt;{file} = $self-&gt;{line} = undef;
    }
    else {
        # CORE::time is important to fix an error with some versions of
        # Perl
        $self-&gt;{time} = CORE::time();
        $self-&gt;{pid}  = $$;
        $self-&gt;{uid}  = $&lt;;
        $self-&gt;{euid} = $&gt;;
        $self-&gt;{gid}  = $(;
        $self-&gt;{egid} = $);

        my @ignore_class   = (__PACKAGE__);
        my @ignore_package = 'Exception::Class';

        if ( my $i = delete $p{ignore_class} ) {
            push @ignore_class, ( ref($i) eq 'ARRAY' ? @$i : $i );
        }

        if ( my $i = delete $p{ignore_package} ) {
            push @ignore_package, ( ref($i) eq 'ARRAY' ? @$i : $i );
        }

        $self-&gt;{trace} = Devel::StackTrace-&gt;new(
            ignore_class       =&gt; \@ignore_class,
            ignore_package     =&gt; \@ignore_package,
            unsafe_ref_capture =&gt; $self-&gt;UnsafeRefCapture,
            respect_overload   =&gt; $self-&gt;RespectOverload,
            max_arg_length     =&gt; $self-&gt;MaxArgLength,
            map { $p{$_} ? ( $_ =&gt; delete $p{$_} ) : () } qw(
                frame_filter
                filter_frames_early
                skip_frames
            ),
        );
    }

    my %fields = map { $_ =&gt; 1 } $self-&gt;Fields;
    while ( my ( $key, $value ) = each %p ) {
        next if $key =~ /^(?:error|message|show_trace)$/;

        if ( $fields{$key} ) {
            $self-&gt;{$key} = $value;
        }
        else {
            Exception::Class::Base-&gt;throw(
                error =&gt; &quot;unknown field $key passed to constructor for class &quot;
                    . ref $self );
        }
    }
}

sub context_hash {
    my $self = shift;

    return {
        time =&gt; $self-&gt;{time},
        pid  =&gt; $self-&gt;{pid},
        uid  =&gt; $self-&gt;{uid},
        euid =&gt; $self-&gt;{euid},
        gid  =&gt; $self-&gt;{gid},
        egid =&gt; $self-&gt;{egid},
    };
}

sub field_hash {
    my $self = shift;

    my $hash = {};

    for my $field ( $self-&gt;Fields ) {
        $hash-&gt;{$field} = $self-&gt;$field;
    }

    return $hash;
}

sub description {
    return 'Generic exception';
}

sub show_trace {
    my $self = shift;

    return 0 unless $self-&gt;{trace};

    if (@_) {
        $self-&gt;{show_trace} = shift;
    }

    return exists $self-&gt;{show_trace} ? $self-&gt;{show_trace} : $self-&gt;Trace;
}

sub as_string {
    my $self = shift;

    my $str = $self-&gt;full_message;
    unless ( defined $str &amp;&amp; length $str ) {
        my $desc = $self-&gt;description;
        $str = defined $desc
            &amp;&amp; length $desc ? &quot;[$desc]&quot; : '[Generic exception]';
    }

    $str .= &quot;\n\n&quot; . $self-&gt;trace-&gt;as_string
        if $self-&gt;show_trace;

    return $str;
}

sub full_message { $_[0]-&gt;message }

#
# The %seen bit protects against circular inheritance.
#
## no critic (BuiltinFunctions::ProhibitStringyEval, ErrorHandling::RequireCheckingReturnValueOfEval)
eval &lt;&lt;'EOF' if $] == 5.006;
sub isa {
    my ( $inheritor, $base ) = @_;
    $inheritor = ref($inheritor) if ref($inheritor);

    my %seen;

    no strict 'refs';
    my @parents = ( $inheritor, @{&quot;$inheritor\::ISA&quot;} );
    while ( my $class = shift @parents ) {
        return 1 if $class eq $base;

        push @parents, grep { !$seen{$_}++ } @{&quot;$class\::ISA&quot;};
    }
    return 0;
}
EOF

sub caught {
    my $class = shift;

    my $e = $@;

    return unless defined $e &amp;&amp; blessed($e) &amp;&amp; $e-&gt;isa($class);
    return $e;
}

1;

# ABSTRACT: A base class for exception objects

__END__

=pod

=encoding UTF-8

=head1 NAME

Exception::Class::Base - A base class for exception objects

=head1 VERSION

version 1.45

=head1 SYNOPSIS

  use Exception::Class 'MyException';

  eval { MyException-&gt;throw( error =&gt; 'I feel funny.' ) };

  print $@-&gt;error;

=head1 DESCRIPTION

This class is the base class for all exceptions created by L&lt;Exception::Class&gt;.
It provides a number of methods for getting information about the exception.

=for Pod::Coverage     Classes
    caught
    NoRefs

=head1 METHODS

=head2 MyException-&gt;Trace($boolean)

Each C&lt;Exception::Class::Base&gt; subclass can be set individually to include a
stacktrace when the C&lt;as_string&gt; method is called. The default is to not
include a stacktrace. Calling this method with a value changes this behavior.
It always returns the current value (after any change is applied).

This value is inherited by any subclasses. However, if this value is set for a
subclass, it will thereafter be independent of the value in
C&lt;Exception::Class::Base&gt;.

Do not call this on the C&lt;Exception::Class::Base&gt; class directly or you'll
change it for all exception classes that use L&lt;Exception::Class&gt;, including
ones created in modules you don't control.

This is a class method, not an object method.

=head2 MyException-&gt;UnsafeRefCapture($boolean)

When a C&lt;Devel::StackTrace&gt; object is created, it walks through the stack and
stores the arguments which were passed to each subroutine on the stack. If any
of these arguments are references, then that means that the
C&lt;Devel::StackTrace&gt; ends up increasing the ref count of these references,
delaying their destruction.

Since C&lt;Exception::Class::Base&gt; uses C&lt;Devel::StackTrace&gt; internally, this
method provides a way to tell C&lt;Devel::StackTrace&gt; not to store these
references. Instead, C&lt;Devel::StackTrace&gt; replaces references with their
stringified representation.

This method defaults to false. As with C&lt;Trace&gt;, it is inherited by subclasses
but setting it in a subclass makes it independent thereafter.

Do not call this on the C&lt;Exception::Class::Base&gt; class directly or you'll
change it for all exception classes that use L&lt;Exception::Class&gt;, including
ones created in modules you don't control.

=head2 MyException-&gt;RespectOverload($boolean)

When a C&lt;Devel::StackTrace&gt; object stringifies, by default it ignores
stringification overloading on any objects being dealt with.

Since C&lt;Exception::Class::Base&gt; uses C&lt;Devel::StackTrace&gt; internally, this
method provides a way to tell C&lt;Devel::StackTrace&gt; to respect overloading.

This method defaults to false. As with C&lt;Trace&gt;, it is inherited by subclasses
but setting it in a subclass makes it independent thereafter.

Do not call this on the C&lt;Exception::Class::Base&gt; class directly or you'll
change it for all exception classes that use L&lt;Exception::Class&gt;, including
ones created in modules you don't control.

=head2 MyException-&gt;MaxArgLength($boolean)

When a C&lt;Devel::StackTrace&gt; object stringifies, by default it displays the full
argument for each function. This parameter can be used to limit the maximum
length of each argument.

Since C&lt;Exception::Class::Base&gt; uses C&lt;Devel::StackTrace&gt; internally, this
method provides a way to tell C&lt;Devel::StackTrace&gt; to limit the length of
arguments.

This method defaults to 0. As with C&lt;Trace&gt;, it is inherited by subclasses but
setting it in a subclass makes it independent thereafter.

Do not call this on the C&lt;Exception::Class::Base&gt; class directly or you'll
change it for all exception classes that use L&lt;Exception::Class&gt;, including
ones created in modules you don't control.

=head2 MyException-&gt;Fields

This method returns the extra fields defined for the given class, as a list.

Do not call this on the C&lt;Exception::Class::Base&gt; class directly or you'll
change it for all exception classes that use L&lt;Exception::Class&gt;, including
ones created in modules you don't control.

=head2 MyException-&gt;throw( $message )

=head2 MyException-&gt;throw( message =&gt; $message )

=head2 MyException-&gt;throw( error =&gt; $error )

This method creates a new object with the given error message. If no error
message is given, this will be an empty string. It then dies with this object
as its argument.

This method also takes a C&lt;show_trace&gt; parameter which indicates whether or not
the particular exception object being created should show a stacktrace when its
C&lt;as_string&gt; method is called. This overrides the value of C&lt;Trace&gt; for this
class if it is given.

The frames included in the trace can be controlled by the C&lt;ignore_class&gt; and
C&lt;ignore_package&gt; parameters. These are passed directly to Devel::Stacktrace's
constructor. See C&lt;Devel::Stacktrace&gt; for more details. This class B&lt;always&gt;
passes C&lt;__PACKAGE__&gt; for C&lt;ignore_class&gt; and C&lt;'Exception::Class'&gt; for
C&lt;ignore_package&gt;, in addition to any arguments you provide.

If only a single value is given to the constructor it is assumed to be the
message parameter.

Additional keys corresponding to the fields defined for the particular
exception subclass will also be accepted.

=head2 MyException-&gt;new(...)

This method takes the same parameters as C&lt;throw&gt;, but instead of dying simply
returns a new exception object.

This method is always called when constructing a new exception object via the
C&lt;throw&gt; method.

=head2 MyException-&gt;description

Returns the description for the given C&lt;Exception::Class::Base&gt; subclass. The
C&lt;Exception::Class::Base&gt; class's description is &quot;Generic exception&quot; (this may
change in the future). This is also an object method.

=head2 $exception-&gt;rethrow

Simply dies with the object as its sole argument. It's just syntactic sugar.
This does not change any of the object's attribute values.  However, it will
cause C&lt;caller&gt; to report the die as coming from within the
C&lt;Exception::Class::Base&gt; class rather than where rethrow was called.

Of course, you always have access to the original stacktrace for the exception
object.

=head2 $exception-&gt;message

=head2 $exception-&gt;error

Returns the error/message associated with the exception.

=head2 $exception-&gt;pid

Returns the pid at the time the exception was thrown.

=head2 $exception-&gt;uid

Returns the real user id at the time the exception was thrown.

=head2 $exception-&gt;gid

Returns the real group id at the time the exception was thrown.

=head2 $exception-&gt;euid

Returns the effective user id at the time the exception was thrown.

=head2 $exception-&gt;egid

Returns the effective group id at the time the exception was thrown.

=head2 $exception-&gt;time

Returns the time in seconds since the epoch at the time the exception was
thrown.

=head2 $exception-&gt;package

Returns the package from which the exception was thrown.

=head2 $exception-&gt;file

Returns the file within which the exception was thrown.

=head2 $exception-&gt;line

Returns the line where the exception was thrown.

=head2 $exception-&gt;context_hash

Returns a hash reference with the following keys:

=over 4

=item * time

=item * pid

=item * uid

=item * euid

=item * gid

=item * egid

=back

=head2 $exception-&gt;field_hash

Returns a hash reference where the keys are any fields defined for the
exception class and the values are the values associated with the field in the
given object.

=head2 $exception-&gt;trace

Returns the trace object associated with the object.

=head2 $exception-&gt;show_trace($boolean)

This method can be used to set whether or not a stack trace is included when
the as_string method is called or the object is stringified.

=head2 $exception-&gt;as_string

Returns a string form of the error message (something like what you'd expect
from die). If the class or object is set to show traces then then the full
trace is also included. The result looks like C&lt;Carp::confess&gt;.

=head2 $exception-&gt;full_message

Called by the C&lt;as_string&gt; method to get the message. By default, this is the
same as calling the C&lt;message&gt; method, but may be overridden by a subclass. See
below for details.

=head1 LIGHTWEIGHT EXCEPTIONS

A lightweight exception is one which records no information about its context
when it is created. This can be achieved by setting C&lt;&lt; $class-&gt;NoContextInfo
&gt;&gt; to a true value.

You can make this the default for a class of exceptions by setting it after
creating the class:

  use Exception::Class (
      'LightWeight',
      'HeavyWeight',
  );

  LightWeight-&gt;NoContextInfo(1);

A lightweight exception does have a stack trace object, nor does it record the
time, pid, uid, euid, gid, or egid. It only has a message.

=head1 OVERLOADING

C&lt;Exception::Class::Base&gt; objects are overloaded so that stringification
produces a normal error message. This just calls the C&lt;&lt; $exception-&gt;as_string
&gt;&gt; method described above. This means that you can just C&lt;print $@&gt; after an
C&lt;eval&gt; and not worry about whether or not its an actual object. It also means
an application or module could do this:

  $SIG{__DIE__} = sub { Exception::Class::Base-&gt;throw( error =&gt; join '', @_ ); };

and this would probably not break anything (unless someone was expecting a
different type of exception object from C&lt;die&gt;).

=head1 OVERRIDING THE as_string METHOD

By default, the C&lt;as_string&gt; method simply returns the value C&lt;message&gt; or
C&lt;error&gt; param plus a stack trace, if the class's C&lt;Trace&gt; method returns a
true value or C&lt;show_trace&gt; was set when creating the exception.

However, once you add new fields to a subclass, you may want to include those
fields in the stringified error.

Inside the C&lt;as_string&gt; method, the message (non-stack trace) portion of the
error is generated by calling the C&lt;full_message&gt; method. This can be easily
overridden. For example:

  sub full_message {
      my $self = shift;

      my $msg = $self-&gt;message;

      $msg .= &quot; and foo was &quot; . $self-&gt;foo;

      return $msg;
  }

=head1 SUPPORT

Bugs may be submitted at L&lt;https://github.com/houseabsolute/Exception-Class/issues&gt;.

I am also usually active on IRC as 'autarch' on C&lt;irc://irc.perl.org&gt;.

=head1 SOURCE

The source code repository for Exception-Class can be found at L&lt;https://github.com/houseabsolute/Exception-Class&gt;.

=head1 AUTHOR

Dave Rolsky &lt;autarch@urth.org&gt;

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2021 by Dave Rolsky.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

The full text of the license can be found in the
F&lt;LICENSE&gt; file included with this distribution.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FException%2FClass'>Back to Directory</a>