<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Eval/TypeTiny/CodeAccumulator.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Eval::TypeTiny::CodeAccumulator;

use 5.008001;
use strict;
use warnings;

BEGIN {
	if ( $] &lt; 5.010 ) { require Devel::TypeTiny::Perl58Compat }
}

BEGIN {
	$Eval::TypeTiny::CodeAccumulator::AUTHORITY  = 'cpan:TOBYINK';
	$Eval::TypeTiny::CodeAccumulator::VERSION    = '2.008002';
}

$Eval::TypeTiny::CodeAccumulator::VERSION =~ tr/_//d;

sub new {
	my $class = shift;

	my %self  = @_ == 1 ? %{$_[0]} : @_;
	$self{env}          ||= {};
	$self{code}         ||= [];
	$self{placeholders} ||= {};
	$self{indent}       ||= '';

	bless \%self, $class;
}

sub code        { join( &quot;\n&quot;, @{ $_[0]{code} } ) }
sub description { $_[0]{description} }
sub env         { $_[0]{env} }

sub add_line {
	my $self = shift;
	my $indent = $self-&gt;{indent};

	push @{ $self-&gt;{code} }, map { $indent . $_ } map { split /\n/ } @_;

	$self;
}

sub addf {
	my $self = shift;
	my $fmt  = shift;
	$self-&gt;add_line( sprintf $fmt, @_ );
}

sub increase_indent {
	$_[0]{indent} .= &quot;\t&quot;;
	$_[0];
}

sub decrease_indent {
	$_[0]{indent} =~ s/\t$//;
	$_[0];
}

sub add_gap {
	push @{ $_[0]{code} }, '';
}

sub add_placeholder {
	my ( $self, $for ) = ( shift, @_ );
	my $indent = $self-&gt;{indent} || '';

	$self-&gt;{placeholders}{$for} = [
		scalar( @{ $self-&gt;{code} } ),
		$self-&gt;{indent},
	];
	push @{ $self-&gt;{code} }, &quot;$indent# placeholder [ $for ]&quot;;

	if ( defined wantarray ) {
		return sub { $self-&gt;fill_placeholder( $for, @_ ) };
	}
}

sub fill_placeholder {
	my ( $self, $for, @lines ) = ( shift, @_ );

	my ( $line_number, $indent ) = @{ delete $self-&gt;{placeholders}{$for} or die };
	my @indented_lines = map { $indent . $_ } map { split /\n/ } @lines;
	splice( @{ $self-&gt;{code} }, $line_number, 1, @indented_lines );

	$self;
}

sub add_variable {
	my ( $self, $suggested_name, $reference ) = ( shift, @_ );
	
	my $actual_name = $suggested_name;
	my $i = 1;
	while ( exists $self-&gt;{env}{$actual_name} ) {
		$actual_name = sprintf '%s_%d', $suggested_name, ++$i;
	}

	$self-&gt;{env}{$actual_name} = $reference;

	$actual_name;
}

sub finalize {
	my $self = shift;

	for my $p ( values %{ $self-&gt;{placeholders} } ) {
		splice( @{ $self-&gt;{code} }, $p-&gt;[0], 1 );
	}

	$self;
}

sub compile {
	my ( $self, %opts ) = ( shift, @_ );

	$self-&gt;{finalized}++ or $self-&gt;finalize();

	require Eval::TypeTiny;
	return Eval::TypeTiny::eval_closure(
		description  =&gt; $self-&gt;description,
		%opts,
		source       =&gt; $self-&gt;code,
		environment  =&gt; $self-&gt;env,
	);
}

1;

__END__

=pod

=encoding utf-8

=for stopwords pragmas coderefs

=head1 NAME

Eval::TypeTiny::CodeAccumulator - alternative API for Eval::TypeTiny

=head1 SYNOPSIS

  my $make_adder = 'Eval::TypeTiny::CodeAccumulator'-&gt;new(
    description =&gt; 'adder',
  );
  
  my $n = 40;
  my $varname = $make_adder-&gt;add_variable( '$addend' =&gt; \$n );
  
  $make_adder-&gt;add_line( 'sub {' );
  $make_adder-&gt;increase_indent;
  $make_adder-&gt;add_line( 'my $other_addend = shift;' );
  $make_adder-&gt;add_gap;
  $make_adder-&gt;add_line( 'return ' . $varname . ' + $other_addend;' );
  $make_adder-&gt;decrease_indent;
  $make_adder-&gt;add_line( '}' );
  
  my $adder = $make_adder-&gt;compile;
  
  say $adder-&gt;( 2 );  ## ==&gt; 42

=head1 STATUS
 
This module is covered by the
L&lt;Type-Tiny stability policy|Type::Tiny::Manual::Policies/&quot;STABILITY&quot;&gt;.

=head1 DESCRIPTION

=head2 Constructor

=over

=item C&lt;&lt; new( %attrs ) &gt;&gt;

The only currently supported attribute is C&lt;description&gt;.

=back

=head2 Methods

=over

=item C&lt;&lt; env() &gt;&gt;

Returns the current compilation environment, a hashref of variables to close
over.

=item C&lt;&lt; code() &gt;&gt;

Returns the source code so far.

=item C&lt;&lt; description() &gt;&gt;

Returns the same description given to the constructor, if any.

=item C&lt;&lt; add_line( @lines_of_code ) &gt;&gt;

Adds the next line of code.

=item C&lt;&lt; addf( $fmt, @args ) &gt;&gt;

Shortcut for C&lt;&lt; add_line( sprintf $fmt, @args ) &gt;&gt;.

=item C&lt;&lt; add_gap() &gt;&gt;

Adds a blank line of code.

=item C&lt;&lt; increase_indent() &gt;&gt;

Increases the indentation level for subsequent lines of code.

=item C&lt;&lt; decrease_indent() &gt;&gt;

Decreases the indentation level for subsequent lines of code.

=item C&lt;&lt; add_variable( $varname, $reference_to_value ) &gt;&gt;

Adds a variable to the compilation environment so that the coderef being
generated can close over it.

If a variable already exists in the environment with that name, will instead
add a variable with a different name and return that name. You should always
continue to refer to the variable with that returned name, just in case.

=item C&lt;&lt; add_placeholder( $placeholder_name ) &gt;&gt;

Adds a line of code which is just a comment, but remembers its line number.

=item C&lt;&lt; fill_placeholder( $placeholder_name, @lines_of_code ) &gt;&gt;

Goes back to a previously inserted placeholder and replaces it with code.

As an alternative, C&lt;add_placeholder&gt; returns a coderef, which you can call
like C&lt;&lt; $callback-&gt;( @lines_of_code ) &gt;&gt;.

=item C&lt;&lt; compile( %opts ) &gt;&gt;

Compiles the code and returns it as a coderef.

Options are passed on to C&lt;&lt; eval_closure &gt;&gt; from L&lt;Eval::TypeTiny&gt;,
but cannot include C&lt;code&gt; or C&lt;environment&gt;. C&lt;&lt; alias =&gt; 1 &gt;&gt;
is probably the option most likely to be useful, but in general
you won't need to provide any options.

=item C&lt;&lt; finalize() &gt;&gt;

This method is called by C&lt;compile&gt; just before compiling the code. All it
does is remove unfilled placeholder comments. It is not intended for end
users to call, but is documented as it may be a useful hook if you are
subclassing this class.

=back

=head1 BUGS

Please report any bugs to
L&lt;https://github.com/tobyink/p5-type-tiny/issues&gt;.

=head1 SEE ALSO

L&lt;Eval::TypeTiny&gt;.

=head1 AUTHOR

Toby Inkster E&lt;lt&gt;tobyink@cpan.orgE&lt;gt&gt;.

=head1 COPYRIGHT AND LICENCE

This software is copyright (c) 2022-2025 by Toby Inkster.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=head1 DISCLAIMER OF WARRANTIES

THIS PACKAGE IS PROVIDED &quot;AS IS&quot; AND WITHOUT ANY EXPRESS OR IMPLIED
WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FEval%2FTypeTiny'>Back to Directory</a>