<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Error/TypeTiny.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Error::TypeTiny;

use 5.008001;
use strict;
use warnings;

BEGIN {
	$Error::TypeTiny::AUTHORITY = 'cpan:TOBYINK';
	$Error::TypeTiny::VERSION   = '2.008002';
}

$Error::TypeTiny::VERSION =~ tr/_//d;

require Type::Tiny;
__PACKAGE__-&gt;Type::Tiny::_install_overloads(
	q[&quot;&quot;]   =&gt; sub { local $@; $_[0]-&gt;to_string },
	q[bool] =&gt; sub { 1 },
);

require Carp;
*CarpInternal = \%Carp::CarpInternal;

our %CarpInternal;
$CarpInternal{$_}++ for @Type::Tiny::InternalPackages;

sub new {
	my $class  = shift;
	my %params = ( @_ == 1 ) ? %{ $_[0] } : @_;
	return bless \%params, $class;
}

sub throw {
	my $next = $_[0]-&gt;can( 'throw_cb' );
	splice( @_, 1, 0, undef );
	goto $next;
}

sub throw_cb {
	my $class = shift;
	my $callback = shift;
	
	my ( $level, @caller, %ctxt ) = 0;
	while (
		do {
			my $caller = caller $level;
			defined $caller and $CarpInternal{$caller};
		}
		)
	{
		$level++;
	}
	if ( ( ( caller( $level - 1 ) )[1] || &quot;&quot; ) =~
		/^(?:parameter validation for|exportable function) '(.+?)'$/ )
	{
		my ( $pkg, $func ) = ( $1 =~ m{^(.+)::(\w+)$} );
		$level++ if caller( $level ) eq ( $pkg || &quot;&quot; );
	}
	
	{
		no warnings 'uninitialized';
		# Moo's Method::Generate::Constructor puts an eval in the stack trace,
		# that is useless for debugging, so show the stack frame one above.
		$level++
			if (
			( caller( $level ) )[1] =~ /^\(eval \d+\)$/
			and ( caller( $level ) )[3] eq '(eval)'    # (caller())[3] is $subroutine
			);
		@ctxt{qw/ package file line /} = caller( $level );
	}
	
	my $stack = undef;
	if ( our $StackTrace ) {
		require Devel::StackTrace;
		$stack = &quot;Devel::StackTrace&quot;-&gt;new(
			ignore_package =&gt; [ keys %CarpInternal ],
		);
	}
	
	our $LastError = $class-&gt;new(
		context     =&gt; \%ctxt,
		stack_trace =&gt; $stack,
		@_,
	);
	
	$callback ? $callback-&gt;( $LastError ) : die( $LastError );
} #/ sub throw

sub message     { $_[0]{message} ||= $_[0]-&gt;_build_message }
sub context     { $_[0]{context} }
sub stack_trace { $_[0]{stack_trace} }

sub to_string {
	my $e = shift;
	my $c = $e-&gt;context;
	my $m = $e-&gt;message;

	$m =~ /\n\z/s
		? $m
		: $c ? sprintf(
		&quot;%s at %s line %s.\n&quot;, $m, $c-&gt;{file} || 'file?',
		$c-&gt;{line} || 'NaN'
		)
		: sprintf( &quot;%s\n&quot;, $m );
} #/ sub to_string

sub _build_message {
	return 'An exception has occurred';
}

sub croak {
	my ( $fmt, @args ) = @_;
	@_ = (
		__PACKAGE__,
		message =&gt; sprintf( $fmt, @args ),
	);
	goto \&amp;throw;
}

1;

__END__

=pod

=encoding utf-8

=head1 NAME

Error::TypeTiny - exceptions for Type::Tiny and friends

=head1 SYNOPSIS

   use feature 'try';
   use Data::Dumper;
   use Types::Standard qw( Str );
   
   try {
      Str-&gt;assert_valid( undef );
   }
   catch ( $exception ) {
      warn &quot;Encountered Error: $exception&quot;;
      warn Dumper( $exception-&gt;explain )
         if $exception-&gt;isa( &quot;Error::TypeTiny::Assertion&quot; );
   }

=head1 STATUS

This module is covered by the
L&lt;Type-Tiny stability policy|Type::Tiny::Manual::Policies/&quot;STABILITY&quot;&gt;.

=head1 DESCRIPTION

When Type::Tiny and its related modules encounter an error, they throw an
exception object. These exception objects inherit from Error::TypeTiny.

=head2 Constructors

=over

=item C&lt;&lt; new(%attributes) &gt;&gt;

Moose-style constructor function.

=item C&lt;&lt; throw(%attributes) &gt;&gt;

Constructs an exception and passes it to C&lt;die&gt;.

Automatically populates C&lt;context&gt; and C&lt;stack_trace&gt; if appropriate.

=item C&lt;&lt; throw_cb($callback, %attributes) &gt;&gt;

Constructs an exception and passes it to C&lt;&lt; $callback &gt;&gt; which should
be a coderef; if undef, uses C&lt;die&gt;.

Automatically populates C&lt;context&gt; and C&lt;stack_trace&gt; if appropriate.

=back

=head2 Attributes

=over

=item C&lt;message&gt;

The error message.

=item C&lt;context&gt;

Hashref containing the package, file and line that generated the error.

=item C&lt;stack_trace&gt;

A more complete stack trace. This feature requires L&lt;Devel::StackTrace&gt;;
use the C&lt;&lt; $StackTrace &gt;&gt; package variable to switch it on.

=back

=head2 Methods

=over

=item C&lt;to_string&gt;

Returns the message, followed by the context if it is set.

=back

=head2 Functions

=over

=item C&lt;&lt; Error::TypeTiny::croak($format, @args) &gt;&gt;

Functional-style shortcut to C&lt;throw&gt; method. Takes an C&lt;sprintf&gt;-style
format string and optional arguments to construct the C&lt;message&gt;.

=back

=head2 Overloading

=over

=item *

Stringification is overloaded to call C&lt;to_string&gt;.

=back

=head2 Package Variables

=over

=item C&lt;&lt; %Carp::CarpInternal &gt;&gt;

Error::TypeTiny honours this package variable from L&lt;Carp&gt;.
(C&lt; %Error::TypeTiny::CarpInternal&gt; is an alias for it.)

=item C&lt;&lt; $Error::TypeTiny::StackTrace &gt;&gt;

Boolean to toggle stack trace generation.

=item C&lt;&lt; $Error::TypeTiny::LastError &gt;&gt;

A reference to the last exception object thrown.

=back

=head1 CAVEATS

Although Error::TypeTiny objects are thrown for errors produced by
Type::Tiny, that doesn't mean every time you use Type::Tiny you'll get
Error::TypeTinys whenever you want.

For example, if you use a Type::Tiny type constraint in a Moose attribute,
Moose will not call the constraint's C&lt;assert_valid&gt; method (which throws
an exception). Instead it will call C&lt;check&gt; and C&lt;get_message&gt; (which do
not), and will C&lt;confess&gt; an error message of its own. (The C&lt;&lt; $LastError &gt;&gt;
package variable may save your bacon.)

=head1 BUGS

Please report any bugs to
L&lt;https://github.com/tobyink/p5-type-tiny/issues&gt;.

=head1 SEE ALSO

L&lt;Error::TypeTiny::Assertion&gt;,
L&lt;Error::TypeTiny::WrongNumberOfParameters&gt;.

L&lt;Try::Tiny&gt;, L&lt;Try::Tiny::ByClass&gt;.

=head1 AUTHOR

Toby Inkster E&lt;lt&gt;tobyink@cpan.orgE&lt;gt&gt;.

=head1 COPYRIGHT AND LICENCE

This software is copyright (c) 2013-2014, 2017-2025 by Toby Inkster.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=head1 DISCLAIMER OF WARRANTIES

THIS PACKAGE IS PROVIDED &quot;AS IS&quot; AND WITHOUT ANY EXPRESS OR IMPLIED
WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FError'>Back to Directory</a>