<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Error/TypeTiny/Assertion.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Error::TypeTiny::Assertion;

use 5.008001;
use strict;
use warnings;

BEGIN {
	$Error::TypeTiny::Assertion::AUTHORITY = 'cpan:TOBYINK';
	$Error::TypeTiny::Assertion::VERSION   = '2.008002';
}

$Error::TypeTiny::Assertion::VERSION =~ tr/_//d;

require Error::TypeTiny;
our @ISA = 'Error::TypeTiny';

sub type           { $_[0]{type} }
sub value          { $_[0]{value} }
sub varname        { $_[0]{varname} ||= '$_' }
sub attribute_step { $_[0]{attribute_step} }
sub attribute_name { $_[0]{attribute_name} }

sub has_type           { defined $_[0]{type} };           # sic
sub has_attribute_step { exists $_[0]{attribute_step} }
sub has_attribute_name { exists $_[0]{attribute_name} }

sub new {
	my $class = shift;
	my $self  = $class-&gt;SUPER::new( @_ );
	
	# Supported but undocumented parameter is `mgaca`.
	# This indicates whether Error::TypeTiny::Assertion
	# should attempt to figure out which attribute caused
	# the error from Method::Generate::Accessor's info.
	# Can be set to true/false or not set. If not set,
	# the current behaviour is true, but this may change
	# in the future. If set to false, will ignore the
	# $Method::Generate::Accessor::CurrentAttribute hashref.
	#
	
	if ( ref $Method::Generate::Accessor::CurrentAttribute
		and $self-&gt;{mgaca} || !exists $self-&gt;{mgaca} )
	{
		require B;
		my %d = %{$Method::Generate::Accessor::CurrentAttribute};
		$self-&gt;{attribute_name} = $d{name} if defined $d{name};
		$self-&gt;{attribute_step} = $d{step} if defined $d{step};
		
		if ( defined $d{init_arg} ) {
			$self-&gt;{varname} = sprintf( '$args-&gt;{%s}', B::perlstring( $d{init_arg} ) );
		}
		elsif ( defined $d{name} ) {
			$self-&gt;{varname} = sprintf( '$self-&gt;{%s}', B::perlstring( $d{name} ) );
		}
	} #/ if ( ref $Method::Generate::Accessor::CurrentAttribute...)
	
	return $self;
} #/ sub new

sub message {
	my $e = shift;
	$e-&gt;varname eq '$_'
		? $e-&gt;SUPER::message
		: sprintf( '%s (in %s)', $e-&gt;SUPER::message, $e-&gt;varname );
}

sub _build_message {
	my $e = shift;
	$e-&gt;has_type
		? sprintf(
		'%s did not pass type constraint &quot;%s&quot;',
		Type::Tiny::_dd( $e-&gt;value ), $e-&gt;type
		)
		: sprintf(
		'%s did not pass type constraint',
		Type::Tiny::_dd( $e-&gt;value )
		);
} #/ sub _build_message

*to_string = sub {
	my $e   = shift;
	my $msg = $e-&gt;message;
	
	my $c = $e-&gt;context;
	$msg .= sprintf( &quot; at %s line %s&quot;, $c-&gt;{file} || 'file?', $c-&gt;{line} || 'NaN' )
		if $c;
		
	my $explain = $e-&gt;explain;
	return &quot;$msg\n&quot; unless @{ $explain || [] };
	
	$msg .= &quot;\n&quot;;
	for my $line ( @$explain ) {
		$msg .= &quot;    $line\n&quot;;
	}
	
	return $msg;
	}
	if $] &gt;= 5.008;
	
sub explain {
	my $e = shift;
	return undef unless $e-&gt;has_type;
	$e-&gt;type-&gt;validate_explain( $e-&gt;value, $e-&gt;varname );
}

1;

__END__

=pod

=encoding utf-8

=head1 NAME

Error::TypeTiny::Assertion - exception when a value fails a type constraint

=head1 STATUS

This module is covered by the
L&lt;Type-Tiny stability policy|Type::Tiny::Manual::Policies/&quot;STABILITY&quot;&gt;.

=head1 DESCRIPTION

This exception is thrown when a value fails a type constraint assertion.

This package inherits from L&lt;Error::TypeTiny&gt;; see that for most
documentation. Major differences are listed below:

=head2 Attributes

=over

=item C&lt;type&gt;

The type constraint that was checked against. Weakened links are involved,
so this may end up being C&lt;undef&gt;.

=item C&lt;value&gt;

The value that was tested.

=item C&lt;varname&gt;

The name of the variable that was checked, if known. Defaults to C&lt;&lt; '$_' &gt;&gt;.

=item C&lt;attribute_name&gt;

If this exception was thrown as the result of an isa check or a failed
coercion for a Moo attribute, then this will tell you which attribute (if
your Moo is new enough).

(Hopefully one day this will support other OO frameworks.)

=item C&lt;attribute_step&gt;

If this exception was thrown as the result of an isa check or a failed
coercion for a Moo attribute, then this will contain either C&lt;&lt; &quot;isa check&quot; &gt;&gt;
or C&lt;&lt; &quot;coercion&quot; &gt;&gt; to indicate which went wrong (if your Moo is new enough).

(Hopefully one day this will support other OO frameworks.)

=back

=head2 Methods

=over

=item C&lt;has_type&gt;, C&lt;has_attribute_name&gt;, C&lt;has_attribute_step&gt;

Predicate methods.

=item C&lt;message&gt;

Overridden to add C&lt;varname&gt; to the message if defined.

=item C&lt;explain&gt;

Attempts to explain why the value did not pass the type constraint. Returns
an arrayref of strings providing step-by-step reasoning; or returns undef if
no explanation is possible.

=back

=head1 BUGS

Please report any bugs to
L&lt;https://github.com/tobyink/p5-type-tiny/issues&gt;.

=head1 SEE ALSO

L&lt;Error::TypeTiny&gt;.

=head1 AUTHOR

Toby Inkster E&lt;lt&gt;tobyink@cpan.orgE&lt;gt&gt;.

=head1 COPYRIGHT AND LICENCE

This software is copyright (c) 2013-2014, 2017-2025 by Toby Inkster.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=head1 DISCLAIMER OF WARRANTIES

THIS PACKAGE IS PROVIDED &quot;AS IS&quot; AND WITHOUT ANY EXPRESS OR IMPLIED
WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
MERCHANTIBILITY AND FITNESS FOR A PARTICULAR PURPOSE.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FError%2FTypeTiny'>Back to Directory</a>