<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Email/Sender/Transport/SMTP.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Email::Sender::Transport::SMTP 2.601;
# ABSTRACT: send email over SMTP

use Moo;

use Email::Sender::Failure::Multi;
use Email::Sender::Success::Partial;
use Email::Sender::Role::HasMessage ();
use Email::Sender::Util;
use MooX::Types::MooseLike::Base qw(Bool InstanceOf Int Str HashRef);
use Net::SMTP 3.05; #XXX upstream requires 3.07, but it appears to not matter

use utf8 (); # See below. -- rjbs, 2015-05-14

#pod =head1 DESCRIPTION
#pod
#pod This transport is used to send email over SMTP, either with or without secure
#pod sockets (SSL/TLS).  It is one of the most complex transports available, capable
#pod of partial success.
#pod
#pod For a potentially more efficient version of this transport, see
#pod L&lt;Email::Sender::Transport::SMTP::Persistent&gt;.
#pod
#pod =head1 ATTRIBUTES
#pod
#pod The following attributes may be passed to the constructor:
#pod
#pod =over 4
#pod
#pod =item C&lt;hosts&gt;: an arrayref of names of the host to try, in order; defaults to a single element array containing C&lt;localhost&gt;
#pod
#pod The attribute C&lt;host&gt; may be given, instead, which contains a single hostname.
#pod
#pod =item C&lt;ssl&gt;: if 'starttls', use STARTTLS; if 'ssl' (or 1), connect securely;
#pod if 'maybestarttls', use STARTTLS if available; otherwise, no security
#pod
#pod =item C&lt;ssl_options&gt;: passed to Net::SMTP constructor for 'ssl' connections or
#pod to starttls for 'starttls' or 'maybestarttls' connections; should contain extra
#pod options for IO::Socket::SSL
#pod
#pod =item C&lt;port&gt;: port to connect to; defaults to 25 for non-SSL, 465 for 'ssl',
#pod 587 for 'starttls'
#pod
#pod =item C&lt;timeout&gt;: maximum time in secs to wait for server; default is 120
#pod
#pod =cut

sub BUILD {
  my ($self) = @_;
  Carp::croak(&quot;do not pass port number to SMTP transport in host, use port parameter&quot;)
    if grep {; /:/ } $self-&gt;hosts;

  if ($self-&gt;sasl_username and not defined $self-&gt;sasl_password) {
    $self-&gt;_throw(&quot;sasl_username but no sasl_password&quot;);
  }
}

sub BUILDARGS {
  my ($self, @rest) = @_;
  my $arg = $self-&gt;SUPER::BUILDARGS(@rest);

  if (exists $arg-&gt;{host}) {
    Carp::croak(&quot;can't pass both host and hosts to constructor&quot;)
      if exists $arg-&gt;{hosts};

    $arg-&gt;{hosts} = [ delete $arg-&gt;{host} ];
  }

  if (exists $arg-&gt;{sasl_authenticator} and exists $arg-&gt;{sasl_username}) {
    Carp::croak(&quot;can't pass both sasl_authenticator and sasl_username to constructor&quot;);
  }

  return $arg;
}

has ssl  =&gt; (is =&gt; 'ro', isa =&gt; Str, default =&gt; sub { 0 });

has _hosts =&gt; (
  is  =&gt; 'ro',
  isa =&gt; sub {
    die &quot;invalid hosts in Email::Sender::Transport::SMTP constructor&quot;
      unless defined $_[0]
          &amp;&amp; (ref $_[0] eq 'ARRAY')
          &amp;&amp; (grep {; length } @{ $_[0] }) &gt; 0;
  },
  default  =&gt; sub {  [ 'localhost' ]  },
  init_arg =&gt; 'hosts',
);

sub hosts { @{ $_[0]-&gt;_hosts } }

sub host  { $_[0]-&gt;_hosts-&gt;[0] }

has _security =&gt; (
  is   =&gt; 'ro',
  lazy =&gt; 1,
  init_arg =&gt; undef,
  default  =&gt; sub {
    my $ssl = $_[0]-&gt;ssl;
    return '' unless $ssl;
    $ssl = lc $ssl;
    return 'starttls' if 'starttls' eq $ssl;
    return 'maybestarttls' if 'maybestarttls' eq $ssl;
    return 'ssl' if $ssl eq 1 or $ssl eq 'ssl';

    Carp::cluck(qq{&quot;ssl&quot; argument to Email::Sender::Transport::SMTP was &quot;$ssl&quot; rather than one of the permitted values: maybestarttls, starttls, ssl});

    return 1;
  },
);

has ssl_options =&gt; (is =&gt; 'ro', isa =&gt; HashRef, default =&gt; sub {  {}  });

has port =&gt; (
  is  =&gt; 'ro',
  isa =&gt; Int,
  lazy    =&gt; 1,
  default =&gt; sub {
    return $_[0]-&gt;_security eq 'starttls' ? 587
         : $_[0]-&gt;_security eq 'ssl'      ? 465
         :                                   25
  },
);

has timeout =&gt; (is =&gt; 'ro', isa =&gt; Int, default =&gt; sub { 120 });

#pod =item C&lt;sasl_username&gt;: the username to use for auth; optional
#pod
#pod =item C&lt;sasl_password&gt;: the password to use for auth; required if C&lt;sasl_username&gt; is provided
#pod
#pod =cut

has sasl_username =&gt; (is =&gt; 'ro', isa =&gt; Str);
has sasl_password =&gt; (is =&gt; 'ro', isa =&gt; Str);

#pod =item C&lt;sasl_authenticator&gt;: An C&lt;Authen::SASL&gt; instance to use for auth; optional
#pod
#pod The C&lt;sasl_authenticator&gt; and C&lt;sasl_username&gt; attributes are mutually exclusive.
#pod
#pod =cut

has sasl_authenticator =&gt; (is =&gt; 'ro', isa =&gt; InstanceOf['Authen::SASL']);

#pod =item C&lt;allow_partial_success&gt;: if true, will send data even if some recipients were rejected; defaults to false
#pod
#pod =cut

has allow_partial_success =&gt; (is =&gt; 'ro', isa =&gt; Bool, default =&gt; sub { 0 });

#pod =item C&lt;helo&gt;: what to say when saying HELO; no default
#pod
#pod =item C&lt;localaddr&gt;: local address from which to connect
#pod
#pod =item C&lt;localport&gt;: local port from which to connect
#pod
#pod =cut

has helo      =&gt; (is =&gt; 'ro', isa =&gt; Str);
has localaddr =&gt; (is =&gt; 'ro');
has localport =&gt; (is =&gt; 'ro', isa =&gt; Int);

#pod =item C&lt;debug&gt;: if true, put the L&lt;Net::SMTP&gt; object in debug mode
#pod
#pod =back
#pod
#pod =cut

has debug =&gt; (is =&gt; 'ro', isa =&gt; Bool, default =&gt; sub { 0 });

# I am basically -sure- that this is wrong, but sending hundreds of millions of
# messages has shown that it is right enough.  I will try to make it textbook
# later. -- rjbs, 2008-12-05
sub _quoteaddr {
  my $addr       = shift;
  my @localparts = split /\@/, $addr;
  my $domain     = pop @localparts;
  my $localpart  = join q{@}, @localparts;

  return $addr # The first regex here is RFC 821 &quot;specials&quot; excepting dot.
    unless $localpart =~ /[\x00-\x1F\x7F&lt;&gt;\(\)\[\]\\,;:@&quot;]/
    or     $localpart =~ /^\./
    or     $localpart =~ /\.$/;
  return join q{@}, qq(&quot;$localpart&quot;), $domain;
}

sub _maybe_auth {
  my ($self, $smtp) = @_;

  if ($self-&gt;sasl_username) {
    return $smtp-&gt;auth($self-&gt;sasl_username, $self-&gt;sasl_password);
  }

  if ($self-&gt;sasl_authenticator) {
    return $smtp-&gt;auth($self-&gt;sasl_authenticator);
  }

  return 1;
}

sub _smtp_client {
  my ($self) = @_;

  my $class = &quot;Net::SMTP&quot;;

  my $smtp = $class-&gt;new( $self-&gt;_net_smtp_args );

  unless ($smtp) {
    $self-&gt;_throw(
      sprintf &quot;unable to establish SMTP connection to (%s) port %s&quot;,
        (join q{, }, $self-&gt;hosts),
        $self-&gt;port,
    );
  }

  if ($self-&gt;_security eq 'starttls') {
    $self-&gt;_throw(&quot;can't STARTTLS: &quot; . $smtp-&gt;message)
      unless $smtp-&gt;starttls(%{ $self-&gt;ssl_options });
  }

  if ($self-&gt;_security eq 'maybestarttls') {
    if ( $smtp-&gt;supports('STARTTLS', 500, [&quot;Command unknown: 'STARTTLS'&quot;]) ) {
      $self-&gt;_throw(&quot;can't STARTTLS: &quot; . $smtp-&gt;message)
        unless $smtp-&gt;starttls(%{ $self-&gt;ssl_options });
    }
  }

  unless ($self-&gt;_maybe_auth($smtp)) {
    if ($smtp-&gt;message =~ /MIME::Base64|Authen::SASL/) {
      Carp::confess(&quot;SMTP auth requires MIME::Base64 and Authen::SASL&quot;);
    }

    $self-&gt;_throw('failed AUTH', $smtp);
  }

  return $smtp;
}

sub _net_smtp_args {
  my ($self) = @_;

  return (
    [ $self-&gt;hosts ],
    Port    =&gt; $self-&gt;port,
    Timeout =&gt; $self-&gt;timeout,
    Debug   =&gt; $self-&gt;debug,

    (($self-&gt;_security eq 'ssl')
      ? (SSL =&gt; 1, %{ $self-&gt;ssl_options })
      : ()),

    defined $self-&gt;helo      ? (Hello     =&gt; $self-&gt;helo)      : (),
    defined $self-&gt;localaddr ? (LocalAddr =&gt; $self-&gt;localaddr) : (),
    defined $self-&gt;localport ? (LocalPort =&gt; $self-&gt;localport) : (),
  );
}

sub _throw {
  my ($self, @rest) = @_;
  Email::Sender::Util-&gt;_failure(@rest)-&gt;throw;
}

sub send_email {
  my ($self, $email, $env) = @_;

  Email::Sender::Failure-&gt;throw(&quot;no valid addresses in recipient list&quot;)
    unless my @to = grep { defined and length } @{ $env-&gt;{to} };

  my $smtp = $self-&gt;_smtp_client;

  my $FAULT = sub { $self-&gt;_throw($_[0], $smtp); };

  $smtp-&gt;mail(_quoteaddr($env-&gt;{from}))
    or $FAULT-&gt;(&quot;$env-&gt;{from} failed after MAIL FROM&quot;);

  my @failures;
  my @ok_rcpts;

  for my $addr (@to) {
    if ($smtp-&gt;to(_quoteaddr($addr))) {
      push @ok_rcpts, $addr;
    } else {
      # my ($self, $error, $smtp, $error_class, @rest) = @_;
      push @failures, Email::Sender::Util-&gt;_failure(
        undef,
        $smtp,
        recipients =&gt; [ $addr ],
      );
    }
  }

  # This logic used to include: or (@ok_rcpts == 1 and $ok_rcpts[0] eq '0')
  # because if called without SkipBad, $smtp-&gt;to can return 1 or 0.  This
  # should not happen because we now always pass SkipBad and do the counting
  # ourselves.  Still, I've put this comment here (a) in memory of the
  # suffering it caused to have to find that problem and (b) in case the
  # original problem is more insidious than I thought! -- rjbs, 2008-12-05

  if (
    @failures
    and ((@ok_rcpts == 0) or (! $self-&gt;allow_partial_success))
  ) {
    $failures[0]-&gt;throw if @failures == 1;

    my $message = sprintf '%s recipients were rejected during RCPT',
      @ok_rcpts ? 'some' : 'all';

    Email::Sender::Failure::Multi-&gt;throw(
      message  =&gt; $message,
      failures =&gt; \@failures,
    );
  }

  # restore Pobox's support for streaming, code-based messages, and arrays here
  # -- rjbs, 2008-12-04

  $smtp-&gt;data                        or $FAULT-&gt;(&quot;error at DATA start&quot;);

  my $msg_string = $email-&gt;as_string;
  my $hunk_size  = $self-&gt;_hunk_size;

  while (length $msg_string) {
    my $next_hunk = substr $msg_string, 0, $hunk_size, '';

    $smtp-&gt;datasend($next_hunk) or $FAULT-&gt;(&quot;error at during DATA&quot;);
  }

  $smtp-&gt;dataend                     or $FAULT-&gt;(&quot;error at after DATA&quot;);

  my $message = $smtp-&gt;message;

  $self-&gt;_message_complete($smtp);

  # We must report partial success (failures) if applicable.
  return $self-&gt;success({ message =&gt; $message }) unless @failures;
  return $self-&gt;partial_success({
    message =&gt; $message,
    failure =&gt; Email::Sender::Failure::Multi-&gt;new({
      message  =&gt; 'some recipients were rejected during RCPT',
      failures =&gt; \@failures
    }),
  });
}

sub _hunk_size { 2**20 } # send messages to DATA in hunks of 1 mebibyte

sub success {
  my $self = shift;
  my $success = Moo::Role-&gt;create_class_with_roles('Email::Sender::Success', 'Email::Sender::Role::HasMessage')-&gt;new(@_);
}

sub partial_success {
  my $self = shift;
  my $partial_success = Moo::Role-&gt;create_class_with_roles('Email::Sender::Success::Partial', 'Email::Sender::Role::HasMessage')-&gt;new(@_);
}

sub _message_complete { $_[1]-&gt;quit; }

#pod =head1 PARTIAL SUCCESS
#pod
#pod If C&lt;allow_partial_success&gt; was set when creating the transport, the transport
#pod may return L&lt;Email::Sender::Success::Partial&gt; objects.  Consult that module's
#pod documentation.
#pod
#pod =cut

with 'Email::Sender::Transport';
no Moo;
1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Email::Sender::Transport::SMTP - send email over SMTP

=head1 VERSION

version 2.601

=head1 DESCRIPTION

This transport is used to send email over SMTP, either with or without secure
sockets (SSL/TLS).  It is one of the most complex transports available, capable
of partial success.

For a potentially more efficient version of this transport, see
L&lt;Email::Sender::Transport::SMTP::Persistent&gt;.

=head1 PERL VERSION

This library should run on perls released even a long time ago.  It should
work on any version of perl released in the last five years.

Although it may work on older versions of perl, no guarantee is made that the
minimum required version will not be increased.  The version may be increased
for any reason, and there is no promise that patches will be accepted to
lower the minimum required perl.

=head1 ATTRIBUTES

The following attributes may be passed to the constructor:

=over 4

=item C&lt;hosts&gt;: an arrayref of names of the host to try, in order; defaults to a single element array containing C&lt;localhost&gt;

The attribute C&lt;host&gt; may be given, instead, which contains a single hostname.

=item C&lt;ssl&gt;: if 'starttls', use STARTTLS; if 'ssl' (or 1), connect securely;
if 'maybestarttls', use STARTTLS if available; otherwise, no security

=item C&lt;ssl_options&gt;: passed to Net::SMTP constructor for 'ssl' connections or
to starttls for 'starttls' or 'maybestarttls' connections; should contain extra
options for IO::Socket::SSL

=item C&lt;port&gt;: port to connect to; defaults to 25 for non-SSL, 465 for 'ssl',
587 for 'starttls'

=item C&lt;timeout&gt;: maximum time in secs to wait for server; default is 120

=item C&lt;sasl_username&gt;: the username to use for auth; optional

=item C&lt;sasl_password&gt;: the password to use for auth; required if C&lt;sasl_username&gt; is provided

=item C&lt;sasl_authenticator&gt;: An C&lt;Authen::SASL&gt; instance to use for auth; optional

The C&lt;sasl_authenticator&gt; and C&lt;sasl_username&gt; attributes are mutually exclusive.

=item C&lt;allow_partial_success&gt;: if true, will send data even if some recipients were rejected; defaults to false

=item C&lt;helo&gt;: what to say when saying HELO; no default

=item C&lt;localaddr&gt;: local address from which to connect

=item C&lt;localport&gt;: local port from which to connect

=item C&lt;debug&gt;: if true, put the L&lt;Net::SMTP&gt; object in debug mode

=back

=head1 PARTIAL SUCCESS

If C&lt;allow_partial_success&gt; was set when creating the transport, the transport
may return L&lt;Email::Sender::Success::Partial&gt; objects.  Consult that module's
documentation.

=head1 AUTHOR

Ricardo Signes &lt;cpan@semiotic.systems&gt;

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2024 by Ricardo Signes.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FEmail%2FSender%2FTransport'>Back to Directory</a>