<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Email/Sender/Role/CommonSending.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Email::Sender::Role::CommonSending 2.601;
# ABSTRACT: the common sending tasks most Email::Sender classes will need

use Moo::Role;

use Carp ();
use Email::Abstract 3.006;
use Email::Sender::Success;
use Email::Sender::Failure::Temporary;
use Email::Sender::Failure::Permanent;
use Scalar::Util ();
use Try::Tiny;

#pod =head1 DESCRIPTION
#pod
#pod Email::Sender::Role::CommonSending provides a number of features that should
#pod ease writing new classes that perform the L&lt;Email::Sender&gt; role.  Instead of
#pod writing a C&lt;send&gt; method, implementors will need to write a smaller
#pod C&lt;send_email&gt; method, which will be passed an L&lt;Email::Abstract&gt; object and
#pod envelope containing C&lt;from&gt; and C&lt;to&gt; entries.  The C&lt;to&gt; entry will be
#pod guaranteed to be an array reference.
#pod
#pod A C&lt;success&gt; method will also be provided as a shortcut for calling:
#pod
#pod   Email::Sender::Success-&gt;new(...);
#pod
#pod A few other minor details are handled by CommonSending; for more information,
#pod consult the source.
#pod
#pod The methods documented here may be overridden to alter the behavior of the
#pod CommonSending role.
#pod
#pod =cut

with 'Email::Sender';

requires 'send_email';

sub send {
  my ($self, $message, $env, @rest) = @_;
  my $email    = $self-&gt;prepare_email($message);
  my $envelope = $self-&gt;prepare_envelope($env);

  try {
    return $self-&gt;send_email($email, $envelope, @rest);
  } catch {
    Carp::confess('unknown error') unless my $err = $_;

    if (
      try { $err-&gt;isa('Email::Sender::Failure') }
      and ! (my @tmp = $err-&gt;recipients)
    ) {
      $err-&gt;_set_recipients([ @{ $envelope-&gt;{to} } ]);
    }

    die $err;
  }
}

#pod =method prepare_email
#pod
#pod This method is passed a scalar and is expected to return an Email::Abstract
#pod object.  You probably shouldn't override it in most cases.
#pod
#pod =cut

sub prepare_email {
  my ($self, $msg) = @_;

  Carp::confess(&quot;no email passed in to sender&quot;) unless defined $msg;

  # We check blessed because if someone would pass in a large message, in some
  # perls calling isa on the string would create a package with the string as
  # the name.  If the message was (say) two megs, now you'd have a two meg hash
  # key in the stash.  Oops! -- rjbs, 2008-12-04
  return $msg if Scalar::Util::blessed($msg) and eval { $msg-&gt;isa('Email::Abstract') };

  return Email::Abstract-&gt;new($msg);
}

#pod =method prepare_envelope
#pod
#pod This method is passed a hashref and returns a new hashref that should be used
#pod as the envelope passed to the C&lt;send_email&gt; method.  This method is responsible
#pod for ensuring that the F&lt;to&gt; entry is an array.
#pod
#pod =cut

sub prepare_envelope {
  my ($self, $env) = @_;

  my %new_env;
  $new_env{to}   = ref $env-&gt;{to} ? $env-&gt;{to} : [ grep {defined} $env-&gt;{to} ];
  $new_env{from} = $env-&gt;{from};

  return \%new_env;
}

#pod =method success
#pod
#pod   ...
#pod   return $self-&gt;success;
#pod
#pod This method returns a new Email::Sender::Success object.  Arguments passed to
#pod this method are passed along to the Success's constructor.  This is provided as
#pod a convenience for returning success from subclasses' C&lt;send_email&gt; methods.
#pod
#pod =cut

sub success {
  my $self = shift;
  my $success = Email::Sender::Success-&gt;new(@_);
}

no Moo::Role;
1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Email::Sender::Role::CommonSending - the common sending tasks most Email::Sender classes will need

=head1 VERSION

version 2.601

=head1 DESCRIPTION

Email::Sender::Role::CommonSending provides a number of features that should
ease writing new classes that perform the L&lt;Email::Sender&gt; role.  Instead of
writing a C&lt;send&gt; method, implementors will need to write a smaller
C&lt;send_email&gt; method, which will be passed an L&lt;Email::Abstract&gt; object and
envelope containing C&lt;from&gt; and C&lt;to&gt; entries.  The C&lt;to&gt; entry will be
guaranteed to be an array reference.

A C&lt;success&gt; method will also be provided as a shortcut for calling:

  Email::Sender::Success-&gt;new(...);

A few other minor details are handled by CommonSending; for more information,
consult the source.

The methods documented here may be overridden to alter the behavior of the
CommonSending role.

=head1 PERL VERSION

This library should run on perls released even a long time ago.  It should
work on any version of perl released in the last five years.

Although it may work on older versions of perl, no guarantee is made that the
minimum required version will not be increased.  The version may be increased
for any reason, and there is no promise that patches will be accepted to
lower the minimum required perl.

=head1 METHODS

=head2 prepare_email

This method is passed a scalar and is expected to return an Email::Abstract
object.  You probably shouldn't override it in most cases.

=head2 prepare_envelope

This method is passed a hashref and returns a new hashref that should be used
as the envelope passed to the C&lt;send_email&gt; method.  This method is responsible
for ensuring that the F&lt;to&gt; entry is an array.

=head2 success

  ...
  return $self-&gt;success;

This method returns a new Email::Sender::Success object.  Arguments passed to
this method are passed along to the Success's constructor.  This is provided as
a convenience for returning success from subclasses' C&lt;send_email&gt; methods.

=head1 AUTHOR

Ricardo Signes &lt;cpan@semiotic.systems&gt;

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2024 by Ricardo Signes.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FEmail%2FSender%2FRole'>Back to Directory</a>