<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Capture/Tiny.pm</h2><form method='post'><textarea name='content' class='file-edit'>use 5.006;
use strict;
use warnings;
package Capture::Tiny;
# ABSTRACT: Capture STDOUT and STDERR from Perl, XS or external programs
our $VERSION = '0.50';
use Carp ();
use Exporter ();
use IO::Handle ();
use File::Spec ();
use File::Temp qw/tempfile tmpnam/;
use Scalar::Util qw/reftype blessed/;
# Get PerlIO or fake it
BEGIN {
  local $@;
  eval { require PerlIO; PerlIO-&gt;can('get_layers') }
    or *PerlIO::get_layers = sub { return () };
}

#--------------------------------------------------------------------------#
# create API subroutines and export them
# [do STDOUT flag, do STDERR flag, do merge flag, do tee flag]
#--------------------------------------------------------------------------#

my %api = (
  capture         =&gt; [1,1,0,0],
  capture_stdout  =&gt; [1,0,0,0],
  capture_stderr  =&gt; [0,1,0,0],
  capture_merged  =&gt; [1,1,1,0],
  tee             =&gt; [1,1,0,1],
  tee_stdout      =&gt; [1,0,0,1],
  tee_stderr      =&gt; [0,1,0,1],
  tee_merged      =&gt; [1,1,1,1],
);

for my $sub ( keys %api ) {
  my $args = join q{, }, @{$api{$sub}};
  eval &quot;sub $sub(&amp;;@) {unshift \@_, $args; goto \\&amp;_capture_tee;}&quot;; ## no critic
}

our @ISA = qw/Exporter/;
our @EXPORT_OK = keys %api;
our %EXPORT_TAGS = ( 'all' =&gt; \@EXPORT_OK );

#--------------------------------------------------------------------------#
# constants and fixtures
#--------------------------------------------------------------------------#

my $IS_WIN32 = $^O eq 'MSWin32';

##our $DEBUG = $ENV{PERL_CAPTURE_TINY_DEBUG};
##
##my $DEBUGFH;
##open $DEBUGFH, &quot;&gt; DEBUG&quot; if $DEBUG;
##
##*_debug = $DEBUG ? sub(@) { print {$DEBUGFH} @_ } : sub(){0};

our $TIMEOUT = 30;

#--------------------------------------------------------------------------#
# command to tee output -- the argument is a filename that must
# be opened to signal that the process is ready to receive input.
# This is annoying, but seems to be the best that can be done
# as a simple, portable IPC technique
#--------------------------------------------------------------------------#
my @cmd = ($^X, '-C0', '-e', &lt;&lt;'HERE');
use Fcntl;
$SIG{HUP}=sub{exit};
if ( my $fn=shift ) {
    sysopen(my $fh, qq{$fn}, O_WRONLY|O_CREAT|O_EXCL) or die $!;
    print {$fh} $$;
    close $fh;
}
my $buf; while (sysread(STDIN, $buf, 2048)) {
    syswrite(STDOUT, $buf); syswrite(STDERR, $buf);
}
HERE

#--------------------------------------------------------------------------#
# filehandle manipulation
#--------------------------------------------------------------------------#

sub _relayer {
  my ($fh, $apply_layers) = @_;
  # _debug(&quot;# requested layers (@{$layers}) for @{[fileno $fh]}\n&quot;);

  # eliminate pseudo-layers
  binmode( $fh, &quot;:raw&quot; );
  # strip off real layers until only :unix is left
  while ( 1 &lt; ( my $layers =()= PerlIO::get_layers( $fh, output =&gt; 1 ) ) ) {
      binmode( $fh, &quot;:pop&quot; );
  }
  # apply other layers
  my @to_apply = @$apply_layers;
  shift @to_apply; # eliminate initial :unix
  # _debug(&quot;# applying layers  (unix @to_apply) to @{[fileno $fh]}\n&quot;);
  binmode($fh, &quot;:&quot; . join(&quot;:&quot;,@to_apply));
}

sub _name {
  my $glob = shift;
  no strict 'refs'; ## no critic
  return *{$glob}{NAME};
}

sub _open {
  open $_[0], $_[1] or Carp::confess &quot;Error from open(&quot; . join(q{, }, @_) . &quot;): $!&quot;;
  # _debug( &quot;# open &quot; . join( &quot;, &quot; , map { defined $_ ? _name($_) : 'undef' } @_ ) . &quot; as &quot; . fileno( $_[0] ) . &quot;\n&quot; );
}

sub _close {
  # _debug( &quot;# closing &quot; . ( defined $_[0] ? _name($_[0]) : 'undef' )  . &quot; on &quot; . fileno( $_[0] ) . &quot;\n&quot; );
  close $_[0] or Carp::confess &quot;Error from close(&quot; . join(q{, }, @_) . &quot;): $!&quot;;
}

my %dup; # cache this so STDIN stays fd0
my %proxy_count;
sub _proxy_std {
  my %proxies;
  if ( ! defined fileno STDIN ) {
    $proxy_count{stdin}++;
    if (defined $dup{stdin}) {
      _open \*STDIN, &quot;&lt;&amp;=&quot; . fileno($dup{stdin});
      # _debug( &quot;# restored proxy STDIN as &quot; . (defined fileno STDIN ? fileno STDIN : 'undef' ) . &quot;\n&quot; );
    }
    else {
      _open \*STDIN, &quot;&lt;&quot; . File::Spec-&gt;devnull;
      # _debug( &quot;# proxied STDIN as &quot; . (defined fileno STDIN ? fileno STDIN : 'undef' ) . &quot;\n&quot; );
      _open $dup{stdin} = IO::Handle-&gt;new, &quot;&lt;&amp;=STDIN&quot;;
    }
    $proxies{stdin} = \*STDIN;
    binmode(STDIN, ':utf8') if $] &gt;= 5.008; ## no critic
  }
  if ( ! defined fileno STDOUT ) {
    $proxy_count{stdout}++;
    if (defined $dup{stdout}) {
      _open \*STDOUT, &quot;&gt;&amp;=&quot; . fileno($dup{stdout});
      # _debug( &quot;# restored proxy STDOUT as &quot; . (defined fileno STDOUT ? fileno STDOUT : 'undef' ) . &quot;\n&quot; );
    }
    else {
      _open \*STDOUT, &quot;&gt;&quot; . File::Spec-&gt;devnull;
       # _debug( &quot;# proxied STDOUT as &quot; . (defined fileno STDOUT ? fileno STDOUT : 'undef' ) . &quot;\n&quot; );
      _open $dup{stdout} = IO::Handle-&gt;new, &quot;&gt;&amp;=STDOUT&quot;;
    }
    $proxies{stdout} = \*STDOUT;
    binmode(STDOUT, ':utf8') if $] &gt;= 5.008; ## no critic
  }
  if ( ! defined fileno STDERR ) {
    $proxy_count{stderr}++;
    if (defined $dup{stderr}) {
      _open \*STDERR, &quot;&gt;&amp;=&quot; . fileno($dup{stderr});
       # _debug( &quot;# restored proxy STDERR as &quot; . (defined fileno STDERR ? fileno STDERR : 'undef' ) . &quot;\n&quot; );
    }
    else {
      _open \*STDERR, &quot;&gt;&quot; . File::Spec-&gt;devnull;
       # _debug( &quot;# proxied STDERR as &quot; . (defined fileno STDERR ? fileno STDERR : 'undef' ) . &quot;\n&quot; );
      _open $dup{stderr} = IO::Handle-&gt;new, &quot;&gt;&amp;=STDERR&quot;;
    }
    $proxies{stderr} = \*STDERR;
    binmode(STDERR, ':utf8') if $] &gt;= 5.008; ## no critic
  }
  return %proxies;
}

sub _unproxy {
  my (%proxies) = @_;
  # _debug( &quot;# unproxying: &quot; . join(&quot; &quot;, keys %proxies) . &quot;\n&quot; );
  for my $p ( keys %proxies ) {
    $proxy_count{$p}--;
    # _debug( &quot;# unproxied &quot; . uc($p) . &quot; ($proxy_count{$p} left)\n&quot; );
    if ( ! $proxy_count{$p} ) {
      _close $proxies{$p};
      _close $dup{$p} unless $] &lt; 5.008; # 5.6 will have already closed this as dup
      delete $dup{$p};
    }
  }
}

sub _copy_std {
  my %handles;
  for my $h ( qw/stdout stderr stdin/ ) {
    next if $h eq 'stdin' &amp;&amp; ! $IS_WIN32; # WIN32 hangs on tee without STDIN copied
    my $redir = $h eq 'stdin' ? &quot;&lt;&amp;&quot; : &quot;&gt;&amp;&quot;;
    _open $handles{$h} = IO::Handle-&gt;new(), $redir . uc($h); # &quot;&gt;&amp;STDOUT&quot; or &quot;&lt;&amp;STDIN&quot;
  }
  return \%handles;
}

# In some cases we open all (prior to forking) and in others we only open
# the output handles (setting up redirection)
sub _open_std {
  my ($handles) = @_;
  _open \*STDIN, &quot;&lt;&amp;&quot; . fileno $handles-&gt;{stdin} if defined $handles-&gt;{stdin};
  _open \*STDOUT, &quot;&gt;&amp;&quot; . fileno $handles-&gt;{stdout} if defined $handles-&gt;{stdout};
  _open \*STDERR, &quot;&gt;&amp;&quot; . fileno $handles-&gt;{stderr} if defined $handles-&gt;{stderr};
}

#--------------------------------------------------------------------------#
# private subs
#--------------------------------------------------------------------------#

sub _start_tee {
  my ($which, $stash) = @_; # $which is &quot;stdout&quot; or &quot;stderr&quot;
  # setup pipes
  $stash-&gt;{$_}{$which} = IO::Handle-&gt;new for qw/tee reader/;
  pipe $stash-&gt;{reader}{$which}, $stash-&gt;{tee}{$which};
  # _debug( &quot;# pipe for $which\: &quot; .  _name($stash-&gt;{tee}{$which}) . &quot; &quot; . fileno( $stash-&gt;{tee}{$which} ) . &quot; =&gt; &quot; . _name($stash-&gt;{reader}{$which}) . &quot; &quot; . fileno( $stash-&gt;{reader}{$which}) . &quot;\n&quot; );
  select((select($stash-&gt;{tee}{$which}), $|=1)[0]); # autoflush
  # setup desired redirection for parent and child
  $stash-&gt;{new}{$which} = $stash-&gt;{tee}{$which};
  $stash-&gt;{child}{$which} = {
    stdin   =&gt; $stash-&gt;{reader}{$which},
    stdout  =&gt; $stash-&gt;{old}{$which},
    stderr  =&gt; $stash-&gt;{capture}{$which},
  };
  # flag file is used to signal the child is ready
  $stash-&gt;{flag_files}{$which} = scalar( tmpnam() ) . $$;
  # execute @cmd as a separate process
  if ( $IS_WIN32 ) {
    my $old_eval_err=$@;
    undef $@;

    eval &quot;use Win32API::File qw/GetOsFHandle SetHandleInformation fileLastError HANDLE_FLAG_INHERIT INVALID_HANDLE_VALUE/ &quot;;
    # _debug( &quot;# Win32API::File loaded\n&quot;) unless $@;
    my $os_fhandle = GetOsFHandle( $stash-&gt;{tee}{$which} );
    # _debug( &quot;# Couldn't get OS handle: &quot; . fileLastError() . &quot;\n&quot;) if ! defined $os_fhandle || $os_fhandle == INVALID_HANDLE_VALUE();
    my $result = SetHandleInformation( $os_fhandle, HANDLE_FLAG_INHERIT(), 0);
    # _debug( $result ? &quot;# set no-inherit flag on $which tee\n&quot; : (&quot;# can't disable tee handle flag inherit: &quot; . fileLastError() . &quot;\n&quot;));
    _open_std( $stash-&gt;{child}{$which} );
    $stash-&gt;{pid}{$which} = system(1, @cmd, $stash-&gt;{flag_files}{$which});
    # not restoring std here as it all gets redirected again shortly anyway
    $@=$old_eval_err;
  }
  else { # use fork
    _fork_exec( $which, $stash );
  }
}

sub _fork_exec {
  my ($which, $stash) = @_; # $which is &quot;stdout&quot; or &quot;stderr&quot;
  my $pid = fork;
  if ( not defined $pid ) {
    Carp::confess &quot;Couldn't fork(): $!&quot;;
  }
  elsif ($pid == 0) { # child
    # _debug( &quot;# in child process ...\n&quot; );
    untie *STDIN; untie *STDOUT; untie *STDERR;
    _close $stash-&gt;{tee}{$which};
    # _debug( &quot;# redirecting handles in child ...\n&quot; );
    _open_std( $stash-&gt;{child}{$which} );
    # _debug( &quot;# calling exec on command ...\n&quot; );
    exec @cmd, $stash-&gt;{flag_files}{$which};
  }
  $stash-&gt;{pid}{$which} = $pid
}

sub _files_exist {
  return 1 if @_ == grep { -f } @_;
  select(undef, undef, undef, 0.001);
  return 0;
}

sub _wait_for_tees {
  my ($stash) = @_;
  my $start = time;
  my @files = values %{$stash-&gt;{flag_files}};
  my $timeout = defined $ENV{PERL_CAPTURE_TINY_TIMEOUT}
              ? $ENV{PERL_CAPTURE_TINY_TIMEOUT} : $TIMEOUT;
  1 until _files_exist(@files) || ($timeout &amp;&amp; (time - $start &gt; $timeout));
  Carp::confess &quot;Timed out waiting for subprocesses to start&quot; if ! _files_exist(@files);
  unlink $_ for @files;
}

sub _kill_tees {
  my ($stash) = @_;
  if ( $IS_WIN32 ) {
    # _debug( &quot;# closing handles\n&quot;);
    close($_) for values %{ $stash-&gt;{tee} };
    # _debug( &quot;# waiting for subprocesses to finish\n&quot;);
    my $start = time;
    1 until wait == -1 || (time - $start &gt; 30);
  }
  else {
    _close $_ for values %{ $stash-&gt;{tee} };
    waitpid $_, 0 for values %{ $stash-&gt;{pid} };
  }
}

sub _slurp {
  my ($name, $stash) = @_;
  my ($fh, $pos) = map { $stash-&gt;{$_}{$name} } qw/capture pos/;
  # _debug( &quot;# slurping captured $name from &quot; . fileno($fh) . &quot; at pos $pos with layers: @{[PerlIO::get_layers($fh)]}\n&quot;);
  seek( $fh, $pos, 0 ) or die &quot;Couldn't seek on capture handle for $name\n&quot;;
  my $text = do { local $/; scalar readline $fh };
  return defined($text) ? $text : &quot;&quot;;
}

#--------------------------------------------------------------------------#
# _capture_tee() -- generic main sub for capturing or teeing
#--------------------------------------------------------------------------#

sub _capture_tee {
  # _debug( &quot;# starting _capture_tee with (@_)...\n&quot; );
  my ($do_stdout, $do_stderr, $do_merge, $do_tee, $code, @opts) = @_;
  my %do = ($do_stdout ? (stdout =&gt; 1) : (),  $do_stderr ? (stderr =&gt; 1) : ());
  Carp::confess(&quot;Custom capture options must be given as key/value pairs\n&quot;)
    unless @opts % 2 == 0;
  my $stash = { capture =&gt; { @opts } };
  for ( keys %{$stash-&gt;{capture}} ) {
    my $fh = $stash-&gt;{capture}{$_};
    Carp::confess &quot;Custom handle for $_ must be seekable\n&quot;
      unless ref($fh) eq 'GLOB' || (blessed($fh) &amp;&amp; $fh-&gt;isa(&quot;IO::Seekable&quot;));
  }
  # save existing filehandles and setup captures
  local *CT_ORIG_STDIN  = *STDIN ;
  local *CT_ORIG_STDOUT = *STDOUT;
  local *CT_ORIG_STDERR = *STDERR;
  # find initial layers
  my %layers = (
    stdin   =&gt; [PerlIO::get_layers(\*STDIN) ],
    stdout  =&gt; [PerlIO::get_layers(\*STDOUT, output =&gt; 1)],
    stderr  =&gt; [PerlIO::get_layers(\*STDERR, output =&gt; 1)],
  );
  # _debug( &quot;# existing layers for $_\: @{$layers{$_}}\n&quot; ) for qw/stdin stdout stderr/;
  # get layers from underlying glob of tied filehandles if we can
  # (this only works for things that work like Tie::StdHandle)
  $layers{stdout} = [PerlIO::get_layers(tied *STDOUT)]
    if tied(*STDOUT) &amp;&amp; (reftype tied *STDOUT eq 'GLOB');
  $layers{stderr} = [PerlIO::get_layers(tied *STDERR)]
    if tied(*STDERR) &amp;&amp; (reftype tied *STDERR eq 'GLOB');
  # _debug( &quot;# tied object corrected layers for $_\: @{$layers{$_}}\n&quot; ) for qw/stdin stdout stderr/;
  # bypass scalar filehandles and tied handles
  # localize scalar STDIN to get a proxy to pick up FD0, then restore later to CT_ORIG_STDIN
  my %localize;
  $localize{stdin}++,  local(*STDIN)
    if grep { $_ eq 'scalar' } @{$layers{stdin}};
  $localize{stdout}++, local(*STDOUT)
    if $do_stdout &amp;&amp; grep { $_ eq 'scalar' } @{$layers{stdout}};
  $localize{stderr}++, local(*STDERR)
    if ($do_stderr || $do_merge) &amp;&amp; grep { $_ eq 'scalar' } @{$layers{stderr}};
  $localize{stdin}++, local(*STDIN), _open( \*STDIN, &quot;&lt;&amp;=0&quot;)
    if tied *STDIN &amp;&amp; $] &gt;= 5.008;
  $localize{stdout}++, local(*STDOUT), _open( \*STDOUT, &quot;&gt;&amp;=1&quot;)
    if $do_stdout &amp;&amp; tied *STDOUT &amp;&amp; $] &gt;= 5.008;
  $localize{stderr}++, local(*STDERR), _open( \*STDERR, &quot;&gt;&amp;=2&quot;)
    if ($do_stderr || $do_merge) &amp;&amp; tied *STDERR &amp;&amp; $] &gt;= 5.008;
  # _debug( &quot;# localized $_\n&quot; ) for keys %localize;
  # proxy any closed/localized handles so we don't use fds 0, 1 or 2
  my %proxy_std = _proxy_std();
  # _debug( &quot;# proxy std: @{ [%proxy_std] }\n&quot; );
  # update layers after any proxying
  $layers{stdout} = [PerlIO::get_layers(\*STDOUT, output =&gt; 1)] if $proxy_std{stdout};
  $layers{stderr} = [PerlIO::get_layers(\*STDERR, output =&gt; 1)] if $proxy_std{stderr};
  # _debug( &quot;# post-proxy layers for $_\: @{$layers{$_}}\n&quot; ) for qw/stdin stdout stderr/;
  # store old handles and setup handles for capture
  $stash-&gt;{old} = _copy_std();
  $stash-&gt;{new} = { %{$stash-&gt;{old}} }; # default to originals
  for ( keys %do ) {
    $stash-&gt;{new}{$_} = ($stash-&gt;{capture}{$_} ||= File::Temp-&gt;new);
    seek( $stash-&gt;{capture}{$_}, 0, 2 ) or die &quot;Could not seek on capture handle for $_\n&quot;;
    $stash-&gt;{pos}{$_} = tell $stash-&gt;{capture}{$_};
    # _debug(&quot;# will capture $_ on &quot; . fileno($stash-&gt;{capture}{$_}).&quot;\n&quot; );
    _start_tee( $_ =&gt; $stash ) if $do_tee; # tees may change $stash-&gt;{new}
  }
  _wait_for_tees( $stash ) if $do_tee;
  # finalize redirection
  $stash-&gt;{new}{stderr} = $stash-&gt;{new}{stdout} if $do_merge;
  # _debug( &quot;# redirecting in parent ...\n&quot; );
  _open_std( $stash-&gt;{new} );
  # execute user provided code
  my ($exit_code, $inner_error, $outer_error, $orig_pid, @result);
  {
    $orig_pid = $$;
    local *STDIN = *CT_ORIG_STDIN if $localize{stdin}; # get original, not proxy STDIN
    # _debug( &quot;# finalizing layers ...\n&quot; );
    _relayer(\*STDOUT, $layers{stdout}) if $do_stdout;
    _relayer(\*STDERR, $layers{stderr}) if $do_stderr;
    # _debug( &quot;# running code $code ...\n&quot; );
    my $old_eval_err=$@;
    undef $@;
    eval { @result = $code-&gt;(); $inner_error = $@ };
    $exit_code = $?; # save this for later
    $outer_error = $@; # save this for later
    STDOUT-&gt;flush if $do_stdout;
    STDERR-&gt;flush if $do_stderr;
    $@ = $old_eval_err;
  }
  # restore prior filehandles and shut down tees
  # _debug( &quot;# restoring filehandles ...\n&quot; );
  _open_std( $stash-&gt;{old} );
  _close( $_ ) for values %{$stash-&gt;{old}}; # don't leak fds
  # shouldn't need relayering originals, but see rt.perl.org #114404
  _relayer(\*STDOUT, $layers{stdout}) if $do_stdout;
  _relayer(\*STDERR, $layers{stderr}) if $do_stderr;
  _unproxy( %proxy_std );
  # _debug( &quot;# killing tee subprocesses ...\n&quot; ) if $do_tee;
  _kill_tees( $stash ) if $do_tee;
  # return captured output, but shortcut in void context
  # unless we have to echo output to tied/scalar handles;
  my %got;
  if ( $orig_pid == $$ and ( defined wantarray or ($do_tee &amp;&amp; keys %localize) ) ) {
    for ( keys %do ) {
      _relayer($stash-&gt;{capture}{$_}, $layers{$_});
      $got{$_} = _slurp($_, $stash);
      # _debug(&quot;# slurped &quot; . length($got{$_}) . &quot; bytes from $_\n&quot;);
    }
    print CT_ORIG_STDOUT $got{stdout}
      if $do_stdout &amp;&amp; $do_tee &amp;&amp; $localize{stdout};
    print CT_ORIG_STDERR $got{stderr}
      if $do_stderr &amp;&amp; $do_tee &amp;&amp; $localize{stderr};
  }
  $? = $exit_code;
  $@ = $inner_error if $inner_error;
  die $outer_error if $outer_error;
  # _debug( &quot;# ending _capture_tee with (@_)...\n&quot; );
  return unless defined wantarray;
  my @return;
  push @return, $got{stdout} if $do_stdout;
  push @return, $got{stderr} if $do_stderr &amp;&amp; ! $do_merge;
  push @return, @result;
  return wantarray ? @return : $return[0];
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Capture::Tiny - Capture STDOUT and STDERR from Perl, XS or external programs

=head1 VERSION

version 0.50

=head1 SYNOPSIS

  use Capture::Tiny ':all';

  # capture from external command

  ($stdout, $stderr, $exit) = capture {
    system( $cmd, @args );
  };

  # capture from arbitrary code (Perl or external)

  ($stdout, $stderr, @result) = capture {
    # your code here
  };

  # capture partial or merged output

  $stdout = capture_stdout { ... };
  $stderr = capture_stderr { ... };
  $merged = capture_merged { ... };

  # tee output

  ($stdout, $stderr) = tee {
    # your code here
  };

  $stdout = tee_stdout { ... };
  $stderr = tee_stderr { ... };
  $merged = tee_merged { ... };

=head1 DESCRIPTION

Capture::Tiny provides a simple, portable way to capture almost anything sent
to STDOUT or STDERR, regardless of whether it comes from Perl, from XS code or
from an external program.  Optionally, output can be teed so that it is
captured while being passed through to the original filehandles.  Yes, it even
works on Windows (usually).  Stop guessing which of a dozen capturing modules
to use in any particular situation and just use this one.

=head1 USAGE

The following functions are available.  None are exported by default.

=head2 capture

  ($stdout, $stderr, @result) = capture \&amp;code;
  $stdout = capture \&amp;code;

The C&lt;capture&gt; function takes a code reference and returns what is sent to
STDOUT and STDERR as well as any return values from the code reference.  In
scalar context, it returns only STDOUT.  If no output was received for a
filehandle, it returns an empty string for that filehandle.  Regardless of calling
context, all output is captured -- nothing is passed to the existing filehandles.

It is prototyped to take a subroutine reference as an argument. Thus, it
can be called in block form:

  ($stdout, $stderr) = capture {
    # your code here ...
  };

Note that the coderef is evaluated in list context.  If you wish to force
scalar context on the return value, you must use the C&lt;scalar&gt; keyword.

  ($stdout, $stderr, $count) = capture {
    my @list = qw/one two three/;
    return scalar @list; # $count will be 3
  };

Also note that within the coderef, the C&lt;@_&gt; variable will be empty.  So don't
use arguments from a surrounding subroutine without copying them to an array
first:

  sub wont_work {
    my ($stdout, $stderr) = capture { do_stuff( @_ ) };    # WRONG
    ...
  }

  sub will_work {
    my @args = @_;
    my ($stdout, $stderr) = capture { do_stuff( @args ) }; # RIGHT
    ...
  }

Captures are normally done to an anonymous temporary filehandle.  To
capture via a named file (e.g. to externally monitor a long-running capture),
provide custom filehandles as a trailing list of option pairs:

  my $out_fh = IO::File-&gt;new(&quot;out.txt&quot;, &quot;w+&quot;);
  my $err_fh = IO::File-&gt;new(&quot;err.txt&quot;, &quot;w+&quot;);
  capture { ... } stdout =&gt; $out_fh, stderr =&gt; $err_fh;

The filehandles must be read/write and seekable.  Modifying the files or
filehandles during a capture operation will give unpredictable results.
Existing IO layers on them may be changed by the capture.

When called in void context, C&lt;capture&gt; saves memory and time by
not reading back from the capture handles.

=head2 capture_stdout

  ($stdout, @result) = capture_stdout \&amp;code;
  $stdout = capture_stdout \&amp;code;

The C&lt;capture_stdout&gt; function works just like C&lt;capture&gt; except only
STDOUT is captured.  STDERR is not captured.

=head2 capture_stderr

  ($stderr, @result) = capture_stderr \&amp;code;
  $stderr = capture_stderr \&amp;code;

The C&lt;capture_stderr&gt; function works just like C&lt;capture&gt; except only
STDERR is captured.  STDOUT is not captured.

=head2 capture_merged

  ($merged, @result) = capture_merged \&amp;code;
  $merged = capture_merged \&amp;code;

The C&lt;capture_merged&gt; function works just like C&lt;capture&gt; except STDOUT and
STDERR are merged. (Technically, STDERR is redirected to the same capturing
handle as STDOUT before executing the function.)

Caution: STDOUT and STDERR output in the merged result are not guaranteed to be
properly ordered due to buffering.

=head2 tee

  ($stdout, $stderr, @result) = tee \&amp;code;
  $stdout = tee \&amp;code;

The C&lt;tee&gt; function works just like C&lt;capture&gt;, except that output is captured
as well as passed on to the original STDOUT and STDERR.

When called in void context, C&lt;tee&gt; saves memory and time by
not reading back from the capture handles, except when the
original STDOUT or STDERR were tied or opened to a scalar
handle.

=head2 tee_stdout

  ($stdout, @result) = tee_stdout \&amp;code;
  $stdout = tee_stdout \&amp;code;

The C&lt;tee_stdout&gt; function works just like C&lt;tee&gt; except only
STDOUT is teed.  STDERR is not teed (output goes to STDERR as usual).

=head2 tee_stderr

  ($stderr, @result) = tee_stderr \&amp;code;
  $stderr = tee_stderr \&amp;code;

The C&lt;tee_stderr&gt; function works just like C&lt;tee&gt; except only
STDERR is teed.  STDOUT is not teed (output goes to STDOUT as usual).

=head2 tee_merged

  ($merged, @result) = tee_merged \&amp;code;
  $merged = tee_merged \&amp;code;

The C&lt;tee_merged&gt; function works just like C&lt;capture_merged&gt; except that output
is captured as well as passed on to STDOUT.

Caution: STDOUT and STDERR output in the merged result are not guaranteed to be
properly ordered due to buffering.

=head1 LIMITATIONS

=head2 Portability

Portability is a goal, not a guarantee.  C&lt;tee&gt; requires fork, except on
Windows where C&lt;system(1, @cmd)&gt; is used instead.  Not tested on any
particularly esoteric platforms yet.  See the
L&lt;CPAN Testers Matrix|http://matrix.cpantesters.org/?dist=Capture-Tiny&gt;
for test result by platform.

=head2 PerlIO layers

Capture::Tiny does its best to preserve PerlIO layers such as ':utf8' or
':crlf' when capturing (only for Perl 5.8.1+) .  Layers should be applied to
STDOUT or STDERR I&lt;before&gt; the call to C&lt;capture&gt; or C&lt;tee&gt;.  This may not work
for tied filehandles (see below).

=head2 Modifying filehandles before capturing

Generally speaking, you should do little or no manipulation of the standard IO
filehandles prior to using Capture::Tiny.  In particular, closing, reopening,
localizing or tying standard filehandles prior to capture may cause a variety of
unexpected, undesirable and/or unreliable behaviors, as described below.
Capture::Tiny does its best to compensate for these situations, but the
results may not be what you desire.

=head3 Closed filehandles

Capture::Tiny will work even if STDIN, STDOUT or STDERR have been previously
closed.  However, since they will be reopened to capture or tee output, any
code within the captured block that depends on finding them closed will, of
course, not find them to be closed.  If they started closed, Capture::Tiny will
close them again when the capture block finishes.

Note that this reopening will happen even for STDIN or a filehandle not being
captured to ensure that the filehandle used for capture is not opened to file
descriptor 0, as this causes problems on various platforms.

Prior to Perl 5.12, closed STDIN combined with PERL_UNICODE=D leaks filehandles
and also breaks tee() for undiagnosed reasons.  So don't do that.

=head3 Localized filehandles

If code localizes any of Perl's standard filehandles before capturing, the capture
will affect the localized filehandles and not the original ones.  External system
calls are not affected by localizing a filehandle in Perl and will continue
to send output to the original filehandles (which will thus not be captured).

=head3 Scalar filehandles

If STDOUT or STDERR are reopened to scalar filehandles prior to the call to
C&lt;capture&gt; or C&lt;tee&gt;, then Capture::Tiny will override the output filehandle for
the duration of the C&lt;capture&gt; or C&lt;tee&gt; call and then, for C&lt;tee&gt;, send captured
output to the output filehandle after the capture is complete.  (Requires Perl
5.8)

Capture::Tiny attempts to preserve the semantics of STDIN opened to a scalar
reference, but note that external processes will not be able to read from such
a handle.  Capture::Tiny tries to ensure that external processes will read from
the null device instead, but this is not guaranteed.

=head3 Tied output filehandles

If STDOUT or STDERR are tied prior to the call to C&lt;capture&gt; or C&lt;tee&gt;, then
Capture::Tiny will attempt to override the tie for the duration of the
C&lt;capture&gt; or C&lt;tee&gt; call and then send captured output to the tied filehandle after
the capture is complete.  (Requires Perl 5.8)

Capture::Tiny may not succeed resending UTF-8 encoded data to a tied
STDOUT or STDERR filehandle.  Characters may appear as bytes.  If the tied filehandle
is based on L&lt;Tie::StdHandle&gt;, then Capture::Tiny will attempt to determine
appropriate layers like C&lt;:utf8&gt; from the underlying filehandle and do the right
thing.

=head3 Tied input filehandle

Capture::Tiny attempts to preserve the semantics of tied STDIN, but this
requires Perl 5.8 and is not entirely predictable.  External processes
will not be able to read from such a handle.

Unless having STDIN tied is crucial, it may be safest to localize STDIN when
capturing:

  my ($out, $err) = do { local *STDIN; capture { ... } };

=head2 Modifying filehandles during a capture

Attempting to modify STDIN, STDOUT or STDERR I&lt;during&gt; C&lt;capture&gt; or C&lt;tee&gt; is
almost certainly going to cause problems.  Don't do that.

=head3 Forking inside a capture

Forks aren't portable.  The behavior of filehandles during a fork is even
less so.  If Capture::Tiny detects that a fork has occurred within a
capture, it will shortcut in the child process and return empty strings for
captures.  Other problems may occur in the child or parent, as well.
Forking in a capture block is not recommended.

=head3 Using threads

Filehandles are global.  Mixing up I/O and captures in different threads
without coordination is going to cause problems.  Besides, threads are
officially discouraged.

=head3 Dropping privileges during a capture

If you drop privileges during a capture, temporary files created to
facilitate the capture may not be cleaned up afterwards.

=head2 No support for Perl 5.8.0

It's just too buggy when it comes to layers and UTF-8.  Perl 5.8.1 or later
is recommended.

=head2 Limited support for Perl 5.6

Perl 5.6 predates PerlIO.  UTF-8 data may not be captured correctly.

=head1 ENVIRONMENT

=head2 PERL_CAPTURE_TINY_TIMEOUT

Capture::Tiny uses subprocesses internally for C&lt;tee&gt;.  By default,
Capture::Tiny will timeout with an error if such subprocesses are not ready to
receive data within 30 seconds (or whatever is the value of
C&lt;$Capture::Tiny::TIMEOUT&gt;).  An alternate timeout may be specified by setting
the C&lt;PERL_CAPTURE_TINY_TIMEOUT&gt; environment variable.  Setting it to zero will
disable timeouts.  B&lt;NOTE&gt;, this does not timeout the code reference being
captured -- this only prevents Capture::Tiny itself from hanging your process
waiting for its child processes to be ready to proceed.

=head1 SEE ALSO

This module was inspired by L&lt;IO::CaptureOutput&gt;, which provides
similar functionality without the ability to tee output and with more
complicated code and API.  L&lt;IO::CaptureOutput&gt; does not handle layers
or most of the unusual cases described in the L&lt;/LIMITATIONS&gt; section and
I no longer recommend it.

There are many other CPAN modules that provide some sort of output capture,
albeit with various limitations that make them appropriate only in particular
circumstances.  I'm probably missing some.  The long list is provided to show
why I felt Capture::Tiny was necessary.

=over 4

=item *

L&lt;IO::Capture&gt;

=item *

L&lt;IO::Capture::Extended&gt;

=item *

L&lt;IO::CaptureOutput&gt;

=item *

L&lt;IPC::Capture&gt;

=item *

L&lt;IPC::Cmd&gt;

=item *

L&lt;IPC::Open2&gt;

=item *

L&lt;IPC::Open3&gt;

=item *

L&lt;IPC::Open3::Simple&gt;

=item *

L&lt;IPC::Open3::Utils&gt;

=item *

L&lt;IPC::Run&gt;

=item *

L&lt;IPC::Run::SafeHandles&gt;

=item *

L&lt;IPC::Run::Simple&gt;

=item *

L&lt;IPC::Run3&gt;

=item *

L&lt;IPC::System::Simple&gt;

=item *

L&lt;Tee&gt;

=item *

L&lt;IO::Tee&gt;

=item *

L&lt;File::Tee&gt;

=item *

L&lt;Filter::Handle&gt;

=item *

L&lt;Tie::STDERR&gt;

=item *

L&lt;Tie::STDOUT&gt;

=item *

L&lt;Test::Output&gt;

=back

=for :stopwords cpan testmatrix url bugtracker rt cpants kwalitee diff irc mailto metadata placeholders metacpan

=head1 SUPPORT

=head2 Bugs / Feature Requests

Please report any bugs or feature requests through the issue tracker
at L&lt;https://github.com/dagolden/Capture-Tiny/issues&gt;.
You will be notified automatically of any progress on your issue.

=head2 Source Code

This is open source software.  The code repository is available for
public review and contribution under the terms of the license.

L&lt;https://github.com/dagolden/Capture-Tiny&gt;

  git clone https://github.com/dagolden/Capture-Tiny.git

=head1 AUTHOR

David Golden &lt;dagolden@cpan.org&gt;

=head1 CONTRIBUTORS

=for stopwords Dagfinn Ilmari Mannsåker David E. Wheeler Ed Sabol fecundf Graham Knop Karen Etheridge Mohammad S Anwar Peter Rabbitson Sven Kirmess

=over 4

=item *

Dagfinn Ilmari Mannsåker &lt;ilmari@ilmari.org&gt;

=item *

David E. Wheeler &lt;david@justatheory.com&gt;

=item *

Ed Sabol &lt;esabol@users.noreply.github.com&gt;

=item *

fecundf &lt;not.com+github@gmail.com&gt;

=item *

Graham Knop &lt;haarg@haarg.org&gt;

=item *

Karen Etheridge &lt;ether@cpan.org&gt;

=item *

Mohammad S Anwar &lt;mohammad.anwar@yahoo.com&gt;

=item *

Peter Rabbitson &lt;ribasushi@cpan.org&gt;

=item *

Sven Kirmess &lt;sven.kirmess@kzone.ch&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is Copyright (c) 2009 by David Golden.

This is free software, licensed under:

  The Apache License, Version 2.0, January 2004

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FCapture'>Back to Directory</a>