<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/cpanel-lib/Authen/SASL/Perl/LOGIN.pm</h2><form method='post'><textarea name='content' class='file-edit'># Copyright (c) 2002 Graham Barr &lt;gbarr@pobox.com&gt;. All rights reserved.
# This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.

package Authen::SASL::Perl::LOGIN;
$Authen::SASL::Perl::LOGIN::VERSION = '2.1800';
use strict;
use warnings;
use vars qw(@ISA);

@ISA	 = qw(Authen::SASL::Perl);

my %secflags = (
	noanonymous =&gt; 1,
);

sub _order { 1 }
sub _secflags {
  shift;
  scalar grep { $secflags{$_} } @_;
}

sub mechanism { 'LOGIN' }

sub client_start {
  my $self = shift;
  $self-&gt;{stage} = 0;
  '';
}

sub client_step {
  my ($self, $string) = @_;

  # XXX technically this is wrong. I might want to change that.
  # spec say it's &quot;staged&quot; and that the content of the challenge doesn't
  # matter
  # actually, let's try
  my $stage = ++$self-&gt;{stage};
  if ($stage == 1) {
      return $self-&gt;_call('user');
  }
  elsif ($stage == 2) {
      return $self-&gt;_call('pass');
  }
  elsif ($stage == 3) {
      $self-&gt;set_success;
      return;
  }
  else {
      return $self-&gt;set_error(&quot;Invalid sequence&quot;);
  }
}

sub server_start {
  my $self      = shift;
  my $response  = shift;
  my $user_cb   = shift || sub {};

  $self-&gt;{answer}    = {};
  $self-&gt;{stage}     = 0;
  $self-&gt;{need_step} = 1;
  $self-&gt;{error}     = undef;
  $user_cb-&gt;('Username:');
  return;
}

sub server_step {
  my $self      = shift;
  my $response  = shift;
  my $user_cb   = shift || sub {};

  my $stage = ++$self-&gt;{stage};

  if ($stage == 1) {
    unless (defined $response) {
        $self-&gt;set_error(&quot;Invalid sequence (empty username)&quot;);
        return $user_cb-&gt;();
    }
    $self-&gt;{answer}{user} = $response;
    return $user_cb-&gt;(&quot;Password:&quot;);
  }
  elsif ($stage == 2) {
    unless (defined $response) {
        $self-&gt;set_error(&quot;Invalid sequence (empty pass)&quot;);
        return $user_cb-&gt;();
    }
    $self-&gt;{answer}{pass} = $response;
  }
  else {
    $self-&gt;set_error(&quot;Invalid sequence (end)&quot;);
    return $user_cb-&gt;();
  }
  my $error = &quot;Credentials don't match&quot;;
  my $answers = { user =&gt; $self-&gt;{answer}{user}, pass =&gt; $self-&gt;{answer}{pass} };
  if (my $checkpass = $self-&gt;{callback}{checkpass}) {
    my $cb = sub {
      my $result = shift;
      unless ($result) {
        $self-&gt;set_error($error);
      }
      else {
        $self-&gt;set_success;
      }
      $user_cb-&gt;();
    };
    $checkpass-&gt;($self =&gt; $answers =&gt; $cb );
    return;
  }
  elsif (my $getsecret = $self-&gt;{callback}{getsecret}) {
    my $cb = sub {
      my $good_pass = shift;
      if ($good_pass &amp;&amp; $good_pass eq ($self-&gt;{answer}{pass} || &quot;&quot;)) {
        $self-&gt;set_success;
      }
      else {
        $self-&gt;set_error($error);
      }
      $user_cb-&gt;();
    };
    $getsecret-&gt;($self =&gt; $answers =&gt; $cb );
    return;
  }
  else {
    $self-&gt;set_error($error);
    $user_cb-&gt;();
  }
  return;
}

1;

__END__

=head1 NAME

Authen::SASL::Perl::LOGIN - Login Authentication class

=head1 VERSION

version 2.1800

=head1 SYNOPSIS

  use Authen::SASL qw(Perl);

  $sasl = Authen::SASL-&gt;new(
    mechanism =&gt; 'LOGIN',
    callback  =&gt; {
      user =&gt; $user,
      pass =&gt; $pass
    },
  );

=head1 DESCRIPTION

This method implements the client and server part of the LOGIN SASL algorithm,
as described in IETF Draft draft-murchison-sasl-login-XX.txt.

=head2 CALLBACK

The callbacks used are:

=head3 Client

=over 4

=item user

The username to be used for authentication

=item pass

The user's password to be used for authentication

=back

=head3 Server

=over 4

=item getsecret(username)

returns the password associated with C&lt;username&gt;

=item checkpass(username, password)

returns true and false depending on the validity of the credentials passed
in arguments.

=back

=head1 SEE ALSO

L&lt;Authen::SASL&gt;,
L&lt;Authen::SASL::Perl&gt;

=head1 AUTHORS

Software written by Graham Barr &lt;gbarr@pobox.com&gt;,
documentation written by Peter Marschall &lt;peter@adpm.de&gt;.
Server support by Yann Kerherve &lt;yannk@cpan.org&gt;

Please report any bugs, or post any suggestions, to the perl-ldap mailing list
&lt;perl-ldap@perl.org&gt;

=head1 COPYRIGHT 

Copyright (c) 2002-2004 Graham Barr.
All rights reserved. This program is free software; you can redistribute 
it and/or modify it under the same terms as Perl itself.

Documentation Copyright (c) 2004 Peter Marschall.
All rights reserved.  This documentation is distributed,
and may be redistributed, under the same terms as Perl itself. 

Server support Copyright (c) 2009 Yann Kerherve.
All rights reserved. This program is free software; you can redistribute 
it and/or modify it under the same terms as Perl itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fcpanel-lib%2FAuthen%2FSASL%2FPerl'>Back to Directory</a>