<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/spfd</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl

#
# spfd: Simple forking SPF query service daemon
#
# (C) 2005-2012 Julian Mehnle &lt;julian@mehnle.net&gt;
#     2003-2004 Meng Weng Wong &lt;mengwong+spf@pobox.com&gt;
# $Id: spfd 148 2006-06-17 21:50:57Z Julian Mehnle $
#
##############################################################################

=head1 NAME

spfd - (Mail::SPF) - Simple forking daemon to provide SPF query services

=head1 VERSION

version 3.20250505

=head1 SYNOPSIS

B&lt;spfd&gt; B&lt;--port&gt;|B&lt;-p&gt; I&lt;port&gt; [B&lt;--set-user&gt;|B&lt;-u&gt; I&lt;uid&gt;|I&lt;username&gt;]
[B&lt;--set-group&gt;|B&lt;-g&gt; I&lt;gid&gt;|I&lt;groupname&gt;] [I&lt;OPTIONS&gt;]

B&lt;spfd&gt; B&lt;--socket&gt;|B&lt;-s&gt; I&lt;filename&gt; [B&lt;--socket-user&gt; I&lt;uid&gt;|I&lt;username&gt;]
[B&lt;--socket-group&gt; I&lt;gid&gt;|I&lt;groupname&gt;] [B&lt;--socket-perms&gt; I&lt;octal-perms&gt;]
[B&lt;--set-user&gt;|B&lt;-u&gt; I&lt;uid&gt;|I&lt;username&gt;] [B&lt;--set-group&gt;|B&lt;-g&gt; I&lt;gid&gt;|I&lt;groupname&gt;]
[I&lt;OPTIONS&gt;]

B&lt;spfd&gt; B&lt;--version|-V&gt;

B&lt;spfd&gt; B&lt;--help&gt;

=head1 DESCRIPTION

B&lt;spfd&gt; is a simple forking Sender Policy Framework (SPF) query server.  spfd
receives and answers SPF requests on a TCP/IP or UNIX domain socket.  For more
information on SPF see L&lt;https://tools.ietf.org/html/rfc7208&gt;.

The B&lt;--port&gt; form listens on a TCP/IP socket on the specified I&lt;port&gt;.  The
default port is B&lt;5970&gt;.

The B&lt;--socket&gt; form listens on a UNIX domain socket that is created with the
specified I&lt;filename&gt;.  The socket can be assigned specific user and group
ownership with the B&lt;--socket-user&gt; and B&lt;--socket-group&gt; options, and specific
filesystem permissions with the B&lt;--socket-perms&gt; option.

Generally, spfd can be instructed with the B&lt;--set-user&gt; and B&lt;--set-group&gt;
options to drop root privileges and change to another user and group before it
starts listening for requests.

The B&lt;--version&gt; form prints version information of spfd.  The B&lt;--help&gt; form
prints usage information for spfd.

=head1 OPTIONS

spfd takes any of the following I&lt;OPTIONS&gt;:

=over

=item B&lt;--default-explanation&gt; I&lt;string&gt;

=item B&lt;--def-exp&gt; I&lt;string&gt;

Use the specified I&lt;string&gt; as the default explanation if the authority domain
does not specify an explanation string of its own.

=item B&lt;--hostname&gt; I&lt;hostname&gt;

Use I&lt;hostname&gt; as the host name of the local system instead of auto-detecting
it.

=item B&lt;--debug&gt;

Print out debug information about spfd's operation, incoming requests, and the
responses sent.

=back

=head1 REQUEST

A request consists of a series of lines delimited by \x0A (LF) characters (or
whatever your system considers a newline).  Each line must be of the form
I&lt;option&gt;B&lt;=&gt;I&lt;value&gt;, where the following options are supported:

=over

=item B&lt;versions&gt;

A comma-separated list of SPF version numbers of SPF records that may be used.
B&lt;1&gt; means that C&lt;v=spf1&gt; records should be used.  B&lt;2&gt; means that C&lt;spf2.0&gt;
records should be used.  Defaults to B&lt;1,2&gt;, i.e., uses any SPF records that
are available.  Records of a higher version are preferred.

=item B&lt;scope&gt;

The authorization scope of the identity that should be checked.  Defaults to
B&lt;'mfrom'&gt;.  The following scope values are supported: B&lt;'helo'&gt;, B&lt;'mfrom'&gt;,
B&lt;'pra'&gt;.  See L&lt;Mail::SPF::Request/new&gt; for more information.

=item B&lt;identity&gt;

I&lt;Required&gt;.  The sender identity whose authorization should be checked.  This
is a domain name for the C&lt;helo&gt; scope, and an e-mail address for the C&lt;mfrom&gt;
and C&lt;pra&gt; scopes.

=item B&lt;ip_address&gt;

I&lt;Required&gt; for checks with the C&lt;helo&gt;, C&lt;mfrom&gt;, and C&lt;pra&gt; scopes.  The IP
address of the host claiming the identity that is being checked.  Can be either
an IPv4 or an IPv6 address.  An IPv4-mapped IPv6 address (e.g.
'::ffff:192.168.0.1') is treated as an IPv4 address.

=item B&lt;helo_identity&gt;

The C&lt;HELO&gt; SMTP transaction parameter in the case that the main identity is of
a scope other than C&lt;helo&gt;.  This identity is then used merely for the
expansion of C&lt;%{h}&gt; macros during the policy evaluation of the main identity.
If unspecified with a scope other than C&lt;helo&gt;, defaults to B&lt;&quot;unknown&quot;&gt;.
If the main identity is of the C&lt;helo&gt; scope, this option is unused.

=back

=head1 RESPONSE

spfd responds to SPF requests with similar series of lines of the form
I&lt;key&gt;B&lt;=&gt;I&lt;value&gt;.  The most important response keys are:

=over

=item B&lt;result&gt;

The result code of the SPF check:

=over 12

=item B&lt;pass&gt;

The specified IP address is an authorized SMTP sender for the identity.

=item B&lt;fail&gt;

The specified IP address is not an authorized SMTP sender for the identity.

=item B&lt;softfail&gt;

The specified IP address is not an authorized SMTP sender for the identity,
however the authority domain is still testing out its SPF policy.

=item B&lt;neutral&gt;

The identity's authority domain makes no assertion about the status of the IP
address.

=item B&lt;permerror&gt;

A permanent error occurred while evaluating the authority domain's policy
(e.g., a syntax error in the SPF record).  Manual intervention is required
from the authority domain.

=item B&lt;temperror&gt;

A temporary error occurred while evaluating the authority domain's policy
(e.g., a DNS error).  Try again later.

=item B&lt;none&gt;

There is no applicable SPF policy for the identity domain.

=back

=item B&lt;local_explanation&gt;

A locally generated explanation of the SPF result.

=item B&lt;authority_explanation&gt;

The authority domain's explanation for the SPF result.  Be aware that the
authority domain may be a malicious party and thus the authority explanation
should not be trusted blindly.  See RFC 4408, 10.5, for a detailed discussion
of this issue.

=item B&lt;received_spf_header&gt;

An appropriate C&lt;Received-SPF&gt; header field for the SPF result.

=item B&lt;spf_record&gt;

The authority domain's SPF record that was used for the policy evaluation.

=back

=head1 EXAMPLE

A running spfd could be tested using the C&lt;netcat&gt; utility like this (line
breaks added for clarity):

    $ echo -e &quot;identity=user@example.com\nip_address=1.2.3.4\n&quot; \
        | nc localhost 5970
    result=fail
    local_explanation=example.com: Sender is not authorized by default to use
        'user@example.com' in 'mfrom' identity (mechanism '-all' matched)
    authority_explanation=Rejected by SPF record.
    received_spf_header=Received-SPF: fail (example.com: Sender is not
        authorized by default to use 'user@example.com' in 'mfrom' identity
        (mechanism '-all' matched)) receiver=localhost; identity=mfrom;
        envelope-from=&quot;user@example.com&quot;; client-ip=1.2.3.4
    spf_record=v=spf1 mx -all

=head1 COMPATIBILITY

B&lt;spfd&gt; has undergone the following interface changes compared to earlier
versions:

=over

=item B&lt;2.000&gt;

=over

=item *

A new preferred I&lt;request&gt; style has been introduced.  Instead of the old
C&lt;sender&gt; request option, which is specific to the C&lt;MAIL FROM&gt; SMTP identity,
a generic C&lt;identity&gt; option should now be specified.  In addition, a C&lt;scope&gt;
option may be given to specify the identity's scope, otherwise a scope of
C&lt;mfrom&gt; is assumed.  The old C&lt;ip&gt; and C&lt;helo&gt; options have been replaced by
the C&lt;ip_address&gt; and C&lt;helo_identity&gt; options, respectively.

This is how legacy requests with the C&lt;mfrom&gt; scope would translate to the new
preferred request style:

  Legacy request style       | New request style
 ----------------------------+---------------------------------------
                             | scope=mfrom
  sender=&lt;mfrom-identity&gt;    | identity=&lt;mfrom-identity&gt;
  ip=&lt;ip-address&gt;            | ip_address=&lt;ip-address&gt;
  helo=&lt;helo-identity&gt;       | helo_identity=&lt;helo-identity&gt;

A new I&lt;response&gt; style featuring new response values has also been introduced:

  Legacy response style      | New response style
 ----------------------------+---------------------------------------
  result=&lt;result-code&gt;       | result=&lt;result-code&gt;
  header_comment=&lt;local-exp&gt; | local_explanation=&lt;local-exp&gt;
  smtp_comment=&lt;local-exp    | authority_explanation=&lt;authority-exp&gt;
    or authority-exp&gt;        | 
  spf_record=&lt;spf-record&gt;    | spf_record=&lt;spf-record&gt;
                             | received_spf_header=&lt;header&gt;

The legacy request style is deprecated but still supported for backwards
compatibility.  The legacy response values are still returned for backwards
compatibility in addition to the new response values, but may be removed in the
future.  Adjust your code to use the new request and response styles.

=item *

The former C&lt;unknown&gt; and C&lt;error&gt; result codes have been renamed to C&lt;permerror&gt;
and C&lt;temperror&gt;, respectively, in order to comply with RFC 4408 terminology.

=item *

In the case of an empty C&lt;MAIL FROM&gt; SMTP transaction parameter (C&lt;&lt;
MAIL FROM:&lt;&gt; &gt;&gt;), the identity checked will be postmaster@helo name as specified
in RFC 7208.

=back

=back

=head1 SEE ALSO

L&lt;Mail::SPF&gt;, L&lt;spfquery(1)&gt;

L&lt;http://tools.ietf.org/html/rfc4408&gt;

=head1 AUTHORS

This version of B&lt;spfd&gt; is a complete rewrite by Julian Mehnle &lt;julian@mehnle.net&gt;,
based on an earlier version written by Meng Weng Wong &lt;mengwong+spf@pobox.com&gt;.

=cut

our $VERSION = '2.000';

use warnings;
use strict;

use Error ':try';
use IO::Handle;
use Getopt::Long qw(:config gnu_compat);
use Socket;
use Mail::SPF;

use constant TRUE   =&gt; (0 == 0);
use constant FALSE  =&gt; not TRUE;

use constant default_port   =&gt; 5970;

use constant deprecated_request_keys =&gt; {
    sender      =&gt; 'identity',
    ip          =&gt; 'ip_address',
    helo        =&gt; 'helo_identity'
};

# Helper Functions
##############################################################################

sub usage {
    STDERR-&gt;print(&lt;&lt;'EOT');
Usage:
    spfd --port|-p &lt;port&gt;
        [--set-user|-u &lt;uid&gt;|&lt;username&gt;] [--set-group|-g &lt;gid&gt;|&lt;groupname&gt;]
    spfd --socket|-s &lt;filename&gt; [--socket-user &lt;uid&gt;|&lt;username&gt;]
        [--socket-group &lt;gid&gt;|&lt;groupname&gt;] [--socket-perms &lt;octal-perms&gt;]
        [--set-user|-u &lt;uid&gt;|&lt;username&gt;] [--set-group|-g &lt;gid&gt;|&lt;groupname&gt;]
EOT
    return;
}

sub deprecated_option {
    my ($old_option, $new_option, $options) = @_;
    return FALSE if not exists($options-&gt;{$old_option});
    STDERR-&gt;print(
        &quot;Warning: '$old_option' option is deprecated&quot; .
        ($new_option ? &quot;; use '$new_option' instead&quot; : '') .
        &quot;.\n&quot;
    );
    $options-&gt;{$new_option} = delete($options-&gt;{$old_option});
    return TRUE;
}

# Command-line Option Handling
##############################################################################

my $options = {};
my $getopt_result = GetOptions(
    $options,

    'port|p=i',
    'socket|s=s',
    'socket-user=s',
    'socket-group=s',
    'socket-perms=s',
    'set-user|u=s',
    'set-group=s',

    'default-explanation|def-exp=s',
    'hostname=s',

    'debug!',

    # Black Magic options:
    'enable-black-magic!',

    # Meta actions:
    'version|V!',
    'help!',

    # Deprecated options:
    'path=s',       # Now 'socket'
    'pathuser=s',   # Now 'socket-user'
    'pathgroup=s',  # Now 'socket-group'
    'pathmode=s',   # Now 'socket-perms'
    'setuser=s',    # Now 'set-user'
    'setgroup=s'    # Now 'set-group'
);

if (not $getopt_result) {
    usage();
    exit(255);
}

if ($options-&gt;{help}) {
    usage();
    exit(0);
}

if ($options-&gt;{version}) {
    print(&quot;spfd version $VERSION (using Mail::SPF)\n&quot;);
    exit(0);
}

my $enable_black_magic = $options-&gt;{'enable-black-magic'};

if (
    $enable_black_magic and
    not defined(eval('require Mail::SPF::BlackMagic'))
) {
    STDERR-&gt;print(&quot;Error: Cannot enable black magic. Unable to load Mail::SPF::BlackMagic.\n&quot;);
    exit(255);
}
elsif ($enable_black_magic) {
    STDERR-&gt;print(&quot;Black magic enabled.\n&quot;);
}

deprecated_option('path',       'socket',       $options);
deprecated_option('pathuser',   'socket-user',  $options);
deprecated_option('pathgroup',  'socket-group', $options);
deprecated_option('pathmode',   'socket-perms', $options);
deprecated_option('setuser',    'set-user',     $options);
deprecated_option('setgroup',   'set-group',    $options);

my $port                = $options-&gt;{port};
my $socket_path         = $options-&gt;{socket};
my $socket_user         = $options-&gt;{'socket-user'};
my $socket_group        = $options-&gt;{'socket-group'};
my $socket_perms        = $options-&gt;{'socket-perms'};
my $set_user            = $options-&gt;{'set-user'};
my $set_group           = $options-&gt;{'set-group'};

my $default_explanation = $options-&gt;{'default-explanation'};
my $hostname            = $options-&gt;{hostname};

my $debug               = defined($options-&gt;{debug}) ? $options-&gt;{debug} : $ENV{DEBUG};

if (defined($port) and defined($socket_path)) {
    usage();
    exit(255);
}

if (not defined($port) and not defined($socket_path)) {
    $port = default_port;
    STDERR-&gt;print(&quot;Using default TCP/IP port ($port).  Run `spfd --help` for supported options.\n&quot;);
}

# Main Program
##############################################################################

STDOUT-&gt;autoflush(TRUE);

my $listen_socket;

if (defined($port)) {
    require IO::Socket::INET;
    $listen_socket = IO::Socket::INET-&gt;new(
        Listen      =&gt; TRUE,
        LocalAddr   =&gt; '127.0.0.1',
        LocalPort   =&gt; $port,
        ReuseAddr   =&gt; TRUE
    );
    print(&quot;spfd (PID $$): Listening on TCP/IP port $port.\n&quot;);
    #$0 = &quot;spfd listening on TCP port $port&quot;;
}
elsif (defined($socket_path)) {
    require IO::Socket::UNIX;
    unlink $socket_path
        if -S $socket_path;
    $listen_socket = IO::Socket::UNIX-&gt;new(
        Listen      =&gt; TRUE,
        Local       =&gt; $socket_path
    );
    print(&quot;spfd (PID $$): Listening on UNIX socket '$socket_path'.\n&quot;);
    #$0 = &quot;spfd listening on UNIX socket $socket_path&quot;;

    $socket_user  = normalize_uid($socket_user);
    $socket_group = normalize_gid($socket_group);
    chown($socket_user, $socket_group, $socket_path)
        or die(&quot;Unable to chown($socket_user, $socket_group) socket '$socket_path'&quot;)
        if $socket_user != -1 or $socket_path != -1;

    chmod(oct($socket_perms), $socket_path)
        or die(&quot;Unable to chmod($socket_perms) socket '$socket_path': $!&quot;)
        if defined($socket_perms);
}

if (defined($set_group)) {
    $set_group = normalize_gid($set_group);
    $( = $) = $set_group;
    $( == $set_group and $) == $set_group
        or die(&quot;Unable to setgid($set_group): $!&quot;);
}

if (defined($set_user)) {
    $set_user = normalize_uid($set_user);
    $&lt; = $&gt; = $set_user;
    $&lt; == $set_user and $&gt; == $set_user
        or die(&quot;Unable to setuid($set_user): $!&quot;);
}

my $spf_server = Mail::SPF::Server-&gt;new(
    default_authority_explanation
                    =&gt; $default_explanation,
    hostname        =&gt; $hostname,

    # Black Magic:
    # TODO
    # max-dns-interactive-terms
    # max-name-lookups-per-term
    # more?
);

# Handle Client Connections
##############################################################################

while (my $socket = $listen_socket-&gt;accept()) {
    if (fork) {
        # Parent process.
        close($socket);
        wait;  # Reap our immediate child (the grand-child will run on its own).
        next;
    }
    elsif (fork) {
        # Child process, parent of grand-child process.
        # The child exits immediately in order to avoid zombies:
        exit;
    }

    # Grand-child process.

    my $time = gmtime;
    if ($debug) {
        my $peerinfo =
            $listen_socket-&gt;isa('IO::Socket::INET') ?
                sprintf(&quot; from %s [%s]&quot;, scalar(gethostbyaddr($socket-&gt;peeraddr, AF_INET)), $socket-&gt;peerhost)
            :   '';
        print(&quot;\n&quot;);
        print(&quot;[$time] Incoming connection&quot; . $peerinfo . &quot;\n&quot;);
    }

    try {
        $socket-&gt;autoflush(TRUE);

        my $request_values = {};
        while (&lt;$socket&gt;) {
            s/\s+$//;
            last if /^$/;
            my ($key, $value) = split(/=/, $_, 2);
            $key = lc($key);
            $key = deprecated_request_keys-&gt;{$key}
                if defined(deprecated_request_keys-&gt;{$key});
            $request_values-&gt;{$key} = $value;

            print(&quot;[$time] R: $key=$value\n&quot;)
                if $debug;
        }

        my @versions = split(',', $request_values-&gt;{versions} || '');

        my $request = Mail::SPF::Request-&gt;new(
            versions        =&gt; @versions ? [@versions] : undef,
            scope           =&gt; $request_values-&gt;{scope},
            identity        =&gt; $request_values-&gt;{identity},
            ip_address      =&gt; $request_values-&gt;{ip_address},
            helo_identity   =&gt; $request_values-&gt;{helo_identity}
        );

        my $result = $spf_server-&gt;process($request);

        my $response_values = {};
        $response_values-&gt;{result}                  = $result-&gt;code;
        $response_values-&gt;{local_explanation}       = $result-&gt;local_explanation;
        $response_values-&gt;{authority_explanation}   = $result-&gt;authority_explanation
            if $result-&gt;can('authority_explanation');
        $response_values-&gt;{received_spf_header}     = $result-&gt;received_spf_header;
        $response_values-&gt;{spf_record}              = $result-&gt;request-&gt;root_request-&gt;record
            if defined($result-&gt;request-&gt;root_request-&gt;record);

        # Legacy response values:
        $response_values-&gt;{smtp_comment}            =
            defined($response_values-&gt;{authority_explanation}) ?
                $response_values-&gt;{authority_explanation}
            :   $response_values-&gt;{local_explanation};
        $response_values-&gt;{header_comment}          = $response_values-&gt;{local_explanation};

        foreach my $key (qw(
            result local_explanation authority_explanation received_spf_header spf_record
            smtp_comment header_comment
        )) {
            defined($response_values-&gt;{$key}) or next;
            $socket-&gt;print(&quot;$key=$response_values-&gt;{$key}\n&quot;);
            print(&quot;[$time] W: $key=$response_values-&gt;{$key}\n&quot;)
                if $debug;
        }
    }
    catch Mail::SPF::Exception with {
        my ($e) = @_;
        printf(&quot;[$time] An error occurred: %s\n&quot;, $e-&gt;text);
    };

    $socket-&gt;close();

    exit;
}

# Helper Functions
##############################################################################

sub normalize_uid {
    my ($uid) = @_;
    return -1 if not defined($uid);
    return getpwnam($uid)
        or die(&quot;Unknown user '$uid'&quot;)
        if $uid =~ /\D/;
    return $uid;
}

sub normalize_gid {
    my ($gid) = @_;
    return -1 if not defined($gid);
    return getgrnam($gid)
        or die(&quot;Unknown group '$gid'&quot;)
        if $gid =~ /\D/;
    return $gid;
}
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>