<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/pristine-gz</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl

=head1 NAME

pristine-gz - regenerate pristine gz files

=head1 SYNOPSIS

B&lt;pristine-gz&gt; [-vdk] gendelta I&lt;file.gz&gt; I&lt;delta&gt;

B&lt;pristine-gz&gt; [-vdk] gengz I&lt;delta&gt; I&lt;file&gt;

=head1 DESCRIPTION

This is a complement to the pristine-tar(1) command. Normally you don't
need to run it by hand, since pristine-tar calls it as necessary to handle
.tar.gz files.

pristine-gz gendelta takes the specified I&lt;gz&gt; file, and generates a
small binary I&lt;delta&gt; file that can later be used by pristine-gz gengz
to recreate the original file.

pristine-gz gengz takes the specified I&lt;delta&gt; file, and compresses
the specified input I&lt;file&gt; (which must be identical to the contents
of the original gz file). The resulting file will be identical to
the original gz file used to create the delta.

The approach used to regenerate the original gz file is to figure out how
it was produced -- what compression level was used, whether it was built
with GNU gzip(1) or with a library or BSD version, whether the --rsyncable
option was used, etc, and to reproduce this build environment when
regenerating the gz.

This approach will work for about 99.5% of cases. One example of a case it
cannot currently support is a gz file that has been produced by appending
together multiple gz files.

For the few where it doesn't work, a binary diff will be included in the
delta between the closest regneratable gz file and the original. In
the worst case, the diff will include the entire content of the original
gz file, resulting in a larger than usual delta. If the delta is much
larger than usual, pristine-gz will print a warning.

If the delta filename is &quot;-&quot;, pristine-gz reads or writes it to stdio.

=head1 OPTIONS

=over 4

=item -v

=item --verbose

Verbose mode, show each command that is run.

=item -d

=item --debug

Debug mode.

=item -k

=item --keep

Don't clean up the temporary directory on exit.

=back

=head1 ENVIRONMENT

=over 4

=item B&lt;TMPDIR&gt;

Specifies a location to place temporary files, other than the default.

=back

=head1 AUTHOR

Joey Hess &lt;joeyh@debian.org&gt;,
Faidon Liambotis &lt;paravoid@debian.org&gt;
Josh Triplett &lt;josh@joshtriplett.org&gt;

Licensed under the GPL, version 2.

=cut

use warnings;
use strict;
use Pristine::Tar;
use Pristine::Tar::Delta;
use Pristine::Tar::Formats;
use Pristine::Tar::DeltaTools;
use File::Basename qw/basename/;

delete $ENV{GZIP};

use constant {
  NODELTA =&gt; &quot;2.0&quot;,
  XDELTA  =&gt; &quot;3.0&quot;,
  XDELTA3 =&gt; &quot;4&quot;,
};

my $genversion =
  version_from_env(XDELTA3, &quot;xdelta&quot; =&gt; XDELTA, &quot;xdelta3&quot; =&gt; XDELTA3);

# consider deltas &lt; 10KB as small enough to be used immediately
my $good_enough_delta = 10 * 1024;

dispatch(
  commands =&gt; {
    usage    =&gt; [ \&amp;usage ],
    gendelta =&gt; [ \&amp;gendelta, 2 ],
    gengz    =&gt; [ \&amp;gengz, 2 ],
  },
);

sub usage {
  print STDERR &quot;Usage: pristine-gz [-vdk] gendelta file.gz delta\n&quot;;
  print STDERR &quot;       pristine-gz [-vdk] gengz delta file\n&quot;;
}

sub readgzip {
  my $filename = shift;

  if (!is_gz($filename)) {
    error &quot;This is not a valid GZip archive.&quot;;
  }

  open(GZIP, &quot;&lt; $filename&quot;)
    or die(&quot;Could not open '$filename' for reading: $!\n&quot;);

  my $chars;
  if (read(GZIP, $chars, 10) != 10) {
    die(&quot;Unable to read 10 bytes from input\n&quot;);
  }

  my ($id1, $id2, $method, $flags, $timestamp, $level, $os, $name) =
    (unpack(&quot;CCCb8VCC&quot;, $chars), '');

  my @flags = split(//, $flags);

  if ($flags[ $fconstants{GZIP_FLAG_FNAME} ]) {
    # read a null-terminated string
    $name .= $chars while (read(GZIP, $chars, 1) == 1 &amp;&amp; ord($chars) != 0);
  }
  close(GZIP);

  return (\@flags, $timestamp, $level, $os, $name);
}

sub predictgzipargs {
  my ($flags, $timestamp, $level) = @_;
  my @flags = @$flags;

  my @args;
  unless ($flags[ $fconstants{GZIP_FLAG_FNAME} ]) {
    push @args, '-n';
    push @args, '-M' if $timestamp;
  }

  if ($level == $fconstants{GZIP_COMPRESSION_BEST}) {
    push @args, '-9';
  } elsif ($level == $fconstants{GZIP_COMPRESSION_FAST}) {
    push @args, '-1';
  }

  return @args;
}

sub reproducegz {
  my ($orig, $tempdir, $tempin) = @_;
  my $tempout = &quot;$tempdir/test.gz&quot;;
  doit_redir($orig, $tempin, &quot;gzip&quot;, &quot;-dc&quot;);

  # read fields from gzip headers
  my ($flags, $timestamp, $level, $os, $name) = readgzip($orig);
  debug(&quot;flags: [&quot;
      . join(&quot;, &quot;, @$flags)
      . &quot;] timestamp: $timestamp level: $level os: $os name: $name&quot;);

  # try to guess the gzip arguments that are needed by the header
  # information
  my @args = predictgzipargs($flags, $timestamp, $level);
  my @extraargs = (&quot;-F&quot;, $name, &quot;-T&quot;, $timestamp);

  my @try;

  push @try, [ '--gnu', @args ];
  push @try, [ '--gnu', @args, '--rsyncable' ];
  push @try, [ '--gnu', @args, '--new-rsyncable' ];
  push @try, [ '--gnu', @args, '--16-rsyncable' ];

  if ($name =~ /\//) {
    push @args, &quot;--original-name&quot;, $name;
    @extraargs = (&quot;-T&quot;, $timestamp);
    $name = basename($name);
  }

  # set the Operating System flag to the one found in the original
  # archive
  push @args, (&quot;--osflag&quot;, $os) if $os != $fconstants{GZIP_OS_UNIX};

  # many of the .gz out there are created using the BSD version of
  # gzip which is using the zlib library; try with our version of
  # bsd-gzip with added support for the undocumented GNU gzip options
  # -m and -M
  push @try, [@args];

  # Perl's Compress::Raw::Zlib interfaces directly with zlib and
  # apparently is the only implementation out there which tunes a very
  # specific parameter of zlib, memLevel, to 9, instead of 8 which is
  # the default. The module is used, among others, by Compress::Gzip
  # which in turn is used by IO::Zlib. It was found on the real world on
  # tarballs generated by Perl 5.10's Module::Build (cf. #618284)
  push @try, [ @args, '--quirk', 'perl' ];
  push @try, [ @args, '--quirk', 'perl', '-1' ];

  # apparently, there is an old version of bsd-gzip (or a similar tool
  # based on zlib) that creates gz using maximum compression (-9) but
  # does not indicate so in the headers. surprisingly, there are many
  # .gz out there.
  push @try, [ @args, '--quirk', 'buggy-bsd' ];

  # Windows' NTFS gzip implementation; quirk is really really evil
  # it should be the last test: it can result in a corrupted archive!
  if ($os == $fconstants{GZIP_OS_NTFS}) {
    pop @args;
    pop @args;    # ntfs quirk implies NTFS osflag
    push @try, [ @args, '--quirk', 'ntfs' ];
  }

  my $origsize = (stat($orig))[7];
  my ($bestvariant, $bestsize);

  foreach my $variant (@try) {
    doit_redir($tempin, $tempout, 'zgz', @$variant, @extraargs, '-c');
    if ($genversion == XDELTA &amp;&amp; !comparefiles($orig, $tempout)) {
      # TODO: Remove when xdelta is phased out.
      # only generate NODELTA files when XDELTA would be used otherwise
      return $name, $timestamp, undef, NODELTA, @$variant;
    } else {
      # generate a binary delta and see if this is the best variant so far
      my $ret;
      if ($genversion == XDELTA3) {
        $ret = try_xdelta3_diff($tempout, $orig, &quot;$tempdir/tmpdelta&quot;);
      } elsif ($genversion == XDELTA) {
        $ret = try_xdelta_diff($tempout, $orig, &quot;$tempdir/tmpdelta&quot;);
      } else {
        die &quot;Unknown delta version $genversion. Internal error.&quot;;
      }
      if ($ret == 0) {
        my $size = (stat(&quot;$tempdir/tmpdelta&quot;))[7];
        if (!defined $bestsize || $size &lt; $bestsize) {
          $bestvariant = $variant;
          $bestsize    = $size;
          rename(&quot;$tempdir/tmpdelta&quot;, &quot;$tempdir/bestdelta&quot;) || die &quot;rename: $!&quot;;
        }
        if ($size &lt;= $good_enough_delta) {
          last;
        }
      }
    }
  }

  # Nothing worked perfectly, so use the delta that was generated for
  # the best variant
  my $percentover = 100 - int(($origsize - $bestsize) / $origsize * 100);
  debug(&quot;Using delta to best variant, bloating $percentover%: @$bestvariant&quot;);
  if ($percentover &gt; 10 &amp;&amp; $bestsize &gt; $good_enough_delta) {
    print STDERR &quot;warning: pristine-gz cannot reproduce build of $orig; &quot;;
    if ($percentover &gt;= 100) {
      print STDERR &quot;storing entire file in delta!\n&quot;;
    } else {
      print STDERR
        &quot;storing $percentover% size diff in delta ($bestsize bytes)\n&quot;;
    }
    print STDERR
&quot;(Please consider filing a bug report so the delta size can be improved.)\n&quot;;
  }
  return $name, $timestamp, &quot;$tempdir/bestdelta&quot;, $genversion, @$bestvariant;
}

sub gengz {
  my $deltafile = shift;
  my $file      = shift;

  my $delta = Pristine::Tar::Delta::read(Tarball =&gt; $deltafile);
  Pristine::Tar::Delta::assert(
    $delta,
    type       =&gt; &quot;gz&quot;,
    maxversion =&gt; XDELTA3,
    fields     =&gt; [qw{params filename timestamp}]
  );

  my @params = split(' ', $delta-&gt;{params});
  while (@params) {
    $_ = shift @params;
    next if /^(--gnu|--rsyncable|--new-rsyncable|--16-rsyncable|-[nmM1-9])$/;
    if (/^(--original-name|--quirk|--osflag)$/) {
      shift @params;
      next;
    }
    die &quot;paranoia check failed on params from delta ($_)&quot;;
  }
  @params = split(' ', $delta-&gt;{params});

  my $filename = $delta-&gt;{filename};
  $filename =~ s/^.*\///;    # basename isn't strong enough

  my @zgz = (&quot;zgz&quot;, @params, &quot;-T&quot;, $delta-&gt;{timestamp});
  if (!grep { $_ eq &quot;--original-name&quot; } @params) {
    push @zgz, &quot;-F&quot;, $filename;
  }
  push @zgz, &quot;-c&quot;;

  my $version = $delta-&gt;{version};
  if (!exists $delta-&gt;{delta}) {
    die &quot;Unknown format: $version!&quot; if !($version eq NODELTA);
    doit_redir($file, &quot;$file.gz&quot;, @zgz);
  } else {
    my $tempdir = tempdir();
    my $tfile   = &quot;$tempdir/&quot; . basename($file) . &quot;.gz&quot;;
    doit_redir($file, $tfile, @zgz);
    if ($version eq XDELTA3) {
      do_xdelta3_patch($tfile, $delta-&gt;{delta}, &quot;$file.gz&quot;);
    } elsif ($version eq XDELTA) {
      do_xdelta_patch($tfile, $delta-&gt;{delta}, &quot;$file.gz&quot;);
    } else {
      die &quot;Unknown format: $version!&quot;;
    }
  }
  doit(&quot;rm&quot;, &quot;-f&quot;, $file);
}

sub gendelta {
  my $gzfile    = shift;
  my $deltafile = shift;

  my $tempdir = tempdir();
  my ($filename, $timestamp, $xdelta, $version, @params) =
    reproducegz($gzfile, $tempdir, &quot;$tempdir/test&quot;);

  Pristine::Tar::Delta::write(
    Tarball =&gt; $deltafile,
    {
      version   =&gt; $version,
      type      =&gt; 'gz',
      params    =&gt; &quot;@params&quot;,
      filename  =&gt; basename($filename),
      timestamp =&gt; $timestamp,
      (defined $xdelta ? (delta =&gt; $xdelta) : ()),
    }
  );
}
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>