<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/perl-reversion</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl
# vim: ts=4 sts=4 sw=4:
#
#  perl-reversion
#
# Update embedded version strings in Perl source
use utf8;
use v5.10;

use strict;
use warnings;
use Perl::Version;
use Carp qw(croak);
use Getopt::Long;
use Pod::Usage;
use File::Spec;
use File::Basename;

# Files that suggest that we have a project directory. The scores next
# to each are summed for each candidate directory. The first directory
# with a score &gt;= 1.0 is assumed to be the project home.

my %PROJECT_SIGNATURE = (
  'Makefile.PL' =&gt; 0.4,
  'Build.PL'    =&gt; 0.4,
  'dist.ini'    =&gt; 0.4,
  'MANIFEST'    =&gt; 0.4,
  't/'          =&gt; 0.4,
  'lib/'        =&gt; 0.4,
  'Changes'     =&gt; 0.4,
  'xt/'         =&gt; 0.4,
);

my $MODULE_RE = qr{ [.] pm $ }x;
my $SCRIPT_RE = qr/ \p{IsWord}+ /x;    # filenames

# Places to look for files / directories when processing a project

my %CONSIDER = (
  'lib/'     =&gt; { like =&gt; $MODULE_RE },
  'bin/'     =&gt; { like =&gt; $SCRIPT_RE },
  'script/'  =&gt; { like =&gt; $SCRIPT_RE },
  'README'   =&gt; {},
  'META.yml' =&gt; {},
);

# Maximum number of levels above current directory to search for
# project home.

my $MAX_UP = 5;

# Subroutines to identify file types
my @MAGIC = (
  {
    name =&gt; 'perl',
    test =&gt; sub {
      my ( $name, $info ) = @_;
      return 1 if $name =~ m{ [.] (?i: pl | pm | t | xs ) $ }x;
      my $lines = $info-&gt;{lines};
      return 1 if @$lines &amp;&amp; $lines-&gt;[0] =~ m{ ^ \#\! .* perl }ix;
      return;
    },
  },
  {
    name =&gt; 'meta',
    test =&gt; sub {
      my ( $name, $info ) = @_;
      return basename( $name ) eq 'META.yml';
    },
  },
  {
    name =&gt; 'plain',
    test =&gt; sub {
      my ( $name, $info ) = @_;
      return -T $name;
    },
  }
);

my $man      = 0;
my $help     = 0;
my $quiet    = 0;
my $bump     = undef;
my $current  = undef;
my $set      = undef;
my $dryrun   = undef;
my $force_to = undef;
my @dir_skip    = ();

my %BUMP = (
  bump              =&gt; 'auto',    # original -bump behavior
  'bump-revision'   =&gt; 0,
  'bump-version'    =&gt; 1,
  'bump-subversion' =&gt; 2,
  'bump-alpha'      =&gt; 3,
);

GetOptions(
  'help|?'    =&gt; \$help,
  'man'       =&gt; \$man,
  'current=s' =&gt; \$current,
  'set=s'     =&gt; \$set,
  'dirskip=s' =&gt; \@dir_skip,
  (
    map {
      my $opt = $_;
      $_ =&gt; sub {
        if ( defined $bump ) {
          die &quot;Please specify only one -bump option\n&quot;;
        }
        $bump = $BUMP{$opt};
       }
     } keys %BUMP
  ),
  (
    map {
      my $opt = $_;
      $_ =&gt; sub {
        if ( defined $force_to ) {
          die
           &quot;Please specify only one of -normal, -numify, or -stringify\n&quot;;
        }
        $force_to = $opt;
       }
     } qw(normal numify stringify)
  ),
  'dryrun' =&gt; \$dryrun,
  'quiet'  =&gt; \$quiet,
) or pod2usage( 2 );

pod2usage( 1 ) if $help;
pod2usage( -exitstatus =&gt; 0, -verbose =&gt; 2 ) if $man;

die &quot;Please specify either -set or -bump, not both\n&quot;
 if $set &amp;&amp; $bump;

# Directories to skip during expansion
my @skip = ( qw( .svn .git .github blib CVS .DS_Store ), @dir_skip );

# this slightly changes the way it was done before. It's still a
# regex, but I fixed the regex for precedence with anchors, and
# quotemeta everything.
my $SKIP = '^( ' . join( ' | ', map { quotemeta($_) } @skip ) . ' )$';
#note( &quot;Regex is $SKIP\n&quot; );
$SKIP = qr/$SKIP/x;

my @files = @ARGV ? expand_dirs( @ARGV ) : find_proj_files();

die &quot;Can't find any files to process. Try naming some\n&quot;,
 &quot;directories and/or files on the command line.\n&quot;
 unless @files;

if ( my @missing = grep { !-e $_ } @files ) {
  die &quot;Can't find &quot;, conjunction_list( 'or', @missing ), &quot;\n&quot;;
}

my %documents = map { $_ =&gt; {} } @files;
load_all( \%documents );

if ( my @bad_type
  = grep { !defined $documents{$_}{type} } keys %documents ) {
  die &quot;Can't process &quot;, conjunction_list( 'or', @bad_type ), &quot;\n&quot;,
   &quot;I can only process text files\n&quot;;
}

my $versions = find_versions( \%documents, $current );
my @got = sort keys %$versions;

if ( @got == 0 ) {
  die &quot;Can't find &quot;, defined $current
   ? &quot;version string $current\n&quot;
   : &quot;any version strings\n&quot;;
}
elsif ( @got &gt; 1 ) {
  die &quot;Found versions &quot;,
   conjunction_list( 'and', map { &quot;$versions-&gt;{$_}[0]{ver}&quot; } @got ),
   &quot;. Please use\n&quot;,
   &quot;the --current option to specify the current version\n&quot;;
}

my $new_ver;
if ( $set ) {
  $new_ver = Perl::Version-&gt;new( $set );
}
elsif ( defined $bump ) {
  $new_ver = $versions-&gt;{ $got[0] }[0]{ver};
  if ( $bump eq 'auto' ) {
    if ( $new_ver-&gt;is_alpha ) {
      $new_ver-&gt;inc_alpha;
    }
    else {
      my $pos = $new_ver-&gt;components - 1;
      $new_ver-&gt;increment( $pos );
    }
  }
  else {
    my $pos = $new_ver-&gt;components - 1;
    if ( $bump &gt; $pos ) {
      my %NAME = (
        0 =&gt; 'revision',
        1 =&gt; 'version',
        2 =&gt; 'subversion',
        3 =&gt; 'alpha',
      );
      my $name = $NAME{$bump};
      die &quot;Cannot -bump-$name -- version $new_ver does not have &quot;
       . &quot;'$name' component.\n&quot;
       . &quot;Use -set if you intended to add it.\n&quot;;
    }
    $new_ver-&gt;increment( $bump );
  }
}
else {
  my $current_ver = $versions-&gt;{ $got[0] }[0]{ver};
  $current_ver = $current_ver-&gt;$force_to if $force_to;
  note( &quot;Current project version is $current_ver\n&quot; );
}

if ( defined $new_ver ) {
  set_versions( \%documents, $versions, $new_ver, $force_to );
  save_all( \%documents );
}

sub version_re_perl_pack {
  my $ver_re = shift;

  return
   qr{ ^(\s* package \s+ (?: \w+ (?: (?: :: | ' ) \w+ )* \s+ ))
                 $ver_re
                 ( .* \s* ) \z }x;
}


sub version_re_perl {
  my $ver_re = shift;

  return
   qr{ ^ ( .*?  [\$\*] (?: \w+ (?: :: | ' ) )* VERSION \s* = \D*? )
                 $ver_re
                 ( .* \s*) \z }x;
}

sub version_re_test {
  my $ver_re = shift;
  return qr{ ^ ( .*? use_ok .*? ) $ver_re ( .* \s*) \z }x;
}


sub version_re_pod {
  my $ver_re = shift;

  return qr{ ^ ( .*? (?i: version ) .*? ) $ver_re ( .* \s*) \z }x;
}

sub version_re_plain {
  my $ver_re = shift;
  return qr{ ^ ( .*? ) $ver_re ( .* \s* ) \z }x;
}

sub version_re_meta {
  my ( $indent, $ver_re ) = @_;
  return qr{ ^ ( $indent version: \s* ) $ver_re ( \s* ) }x;
}

sub set_versions {
  my $docs        = shift;
  my $versions    = shift;
  my $new_version = shift
   or die &quot;Internal: no version specified&quot;;
  my $force_to = shift;

  if ( $force_to ) {
    # the forced formats set their own formats, so override the deatils
    # in the string we want
    # https://github.com/briandfoy/perl-version/issues/10
    my $alpha_format = $new_version-&gt;{format}{alpha};
    $new_version = Perl::Version-&gt;new( $new_version-&gt;$force_to );
    $new_version-&gt;{format}{alpha} = $alpha_format;
  }

  note( &quot;Setting version to $new_version\n&quot; );

  # Edit the documents
  for my $edits ( values %$versions ) {
    for my $edit ( @$edits ) {
      my $info = $edit-&gt;{info};

      if ( $force_to ) {
        $edit-&gt;{ver} = $new_version;
      }
      else {
        $edit-&gt;{ver}-&gt;set( $new_version );
      }

      $info-&gt;{lines}[ $edit-&gt;{line} ]
       = $edit-&gt;{pre} . $edit-&gt;{ver} . $edit-&gt;{post};
      $info-&gt;{dirty}++;
    }
  }
}

sub find_version_for_doc {
  my ( $ver_found, $version, $name, $info, $machine ) = @_;

  note( &quot;Scanning $name\n&quot; );

  my $state = $machine-&gt;{init};
  my $lines = $info-&gt;{lines};

  LINE:
  for my $ln ( 0 .. @$lines - 1 ) {
    my $line = $lines-&gt;[$ln];

    # Bail out when we're in a state with no possible actions.
    last LINE unless @$state;

    STATE: {
      for my $trans ( @$state ) {
        if ( my @match = $line =~ $trans-&gt;{re} ) {
          if ( $trans-&gt;{mark} ) {
            my $ver = Perl::Version-&gt;new( $2 . $3 . $4 );
            next if defined $version and &quot;$version&quot; ne &quot;$ver&quot;;
            push @{ $ver_found-&gt;{ $ver-&gt;normal } },
             {
              file =&gt; $name,
              info =&gt; $info,
              line =&gt; $ln,
              pre  =&gt; $1,
              ver  =&gt; $ver,
              post =&gt; $5
             };
            note( &quot; $ver&quot; );
          }

          if ( my $code = $trans-&gt;{exec} ) {
            $code-&gt;( $machine, \@match, $line );
          }

          if ( my $goto = $trans-&gt;{goto} ) {
            $state = $machine-&gt;{$goto};
            redo STATE;
          }
        }
      }
    }
  }
  note( &quot;\n&quot; );
}

sub find_versions {
  my $docs    = shift;
  my $version = shift;

  my $ver_re = Perl::Version::REGEX;

  # Filetypes that don't have much to say about what the version
  # might be.
  my %uncertain = map { $_ =&gt; 1 } qw( plain );

  my %machines = (

    # State machine for Perl source
    perl =&gt; {
      init =&gt; [
        {
          re   =&gt; qr{ ^ = (?! cut ) }x,
          goto =&gt; 'pod',
        },
        {
          re   =&gt; version_re_perl_pack( $ver_re ),
          mark =&gt; 1,
        },
        {
          re   =&gt; version_re_perl( $ver_re ),
          mark =&gt; 1,
        },
      ],

      # pod within perl
      pod =&gt; [
        {
          re   =&gt; qr{ ^ =head\d\s+VERSION\b }x,
          goto =&gt; 'version',
        },
        {
          re   =&gt; qr{ ^ =cut }x,
          goto =&gt; 'init',
        },
      ],

      # version section within pod
      version =&gt; [
        {
          re   =&gt; qr{ ^ = (?! head\d\s+VERSION\b ) }x,
          goto =&gt; 'pod',
        },
        {
          re   =&gt; version_re_test( $ver_re ),
          mark =&gt; 1,
        },
        {
          re   =&gt; version_re_perl_pack( $ver_re ),
          mark =&gt; 1,
        },
        {
          re   =&gt; version_re_pod( $ver_re ),
          mark =&gt; 1,
        },

      ],
    },

    # State machine for plain text. Matches once then loops
    plain =&gt; {
      init =&gt; [
        {
          re   =&gt; version_re_plain( $ver_re ),
          mark =&gt; 1,
          goto =&gt; 'done',
        }
      ],
      done =&gt; [],
    },

    # State machine for META.yml.
    meta =&gt; {
      init =&gt; [
        {
          re   =&gt; qr{^ (\s*) (?! ---) }x,
          goto =&gt; 'version',
          exec =&gt; sub {
            my ( $machine, $matches, $line ) = @_;
            $machine-&gt;{version} = [
              {
                re =&gt; version_re_meta(
                  '\s{' . length( $matches-&gt;[0] ) . '}', $ver_re
                ),
                mark =&gt; 1,
              },
            ];
          },
        },
      ],
    },
  );

  my $ver_found = {};

  my $scan_like = sub {
    my ( $version, $filter ) = @_;
    while ( my ( $name, $info ) = each %$docs ) {
      next unless $filter-&gt;( $info-&gt;{type} );
      my $machine = $machines{ $info-&gt;{type} }
       or die &quot;Internal: can't find state machine for type &quot;,
       $info-&gt;{type};
      find_version_for_doc( $ver_found, $version, $name, $info,
        $machine );
    }
  };

  $scan_like-&gt;( $version, sub { !$uncertain{ $_[0] } } );

  # Can we guess what the version is now?
  unless ( defined $version ) {
    my @found = keys %$ver_found;
    $version = $ver_found-&gt;{ $found[0] }[0]{ver}
     if @found == 1;
  }

  $scan_like-&gt;( $version, sub { $uncertain{ $_[0] } } );

  return $ver_found;
}

sub guess_type {
  my ( $name, $info ) = @_;
  for my $try ( @MAGIC ) {
    return $try-&gt;{name}
     if $try-&gt;{test}-&gt;( $name, $info );
  }

  return;
}

sub load_all {
  my $docs = shift;

  for my $doc ( keys %$docs ) {

    #note( &quot;Loading $doc\n&quot; );
    $docs-&gt;{$doc} = {
      lines =&gt; read_lines( $doc, ':raw', array_ref =&gt; 1 ),
      dirty =&gt; 0,
    };
    $docs-&gt;{$doc}{type} = guess_type( $doc, $docs-&gt;{$doc} );

    #note( &quot;Type is &quot;, $docs-&gt;{$doc}{type}, &quot;\n&quot; );
  }
}

sub read_lines {
	my( $file, $mode, %args ) = @_;

	my @lines;

	if( open my $fh, &quot;&lt;$mode&quot;, 	$file ) {
		@lines = &lt;$fh&gt;;
		close $fh;
		}

	return \@lines if $args{array_ref};
	return @lines;
	}

sub save_all {
  my $docs = shift;

  for my $doc ( grep { $docs-&gt;{$_}{dirty} } keys %$docs ) {
    if ( $dryrun ) {
      note( &quot;Would save $doc\n&quot; );
    }
    else {
      note( &quot;Saving $doc\n&quot; );
      my $mode = eval { (stat $doc)[2] &amp; 07777 };
      open my $fh, '&gt;:raw', $doc or croak &quot;Could not open file $doc: $!\n&quot;;
      $fh-&gt;autoflush(1);
      print $fh @{ $docs-&gt;{$doc}{lines} };
      close $fh;
      chmod $mode, $doc if defined $mode;
    }
  }
}

sub note {
  print join( '', @_ ) unless $quiet;
}

sub find_proj_files {
  if ( my $dir = find_project( File::Spec-&gt;curdir ) ) {
    my @files = ();
    while ( my ( $obj, $spec ) = each %CONSIDER ) {
      if ( my $got = exists_in( $dir, $obj ) ) {
        push @files,
         expand_dirs_matching( $spec-&gt;{like} || qr{}, $got );
      }
    }
    unless ( @files ) {
      die &quot;I looked at &quot;,
       conjunction_list( 'and', sort keys %CONSIDER ),
       &quot; but found no files to process\n&quot;;
    }
    return @files;
  }
  else {
    die &quot;No files / directories specified and I can't\n&quot;,
     &quot;find a directory that looks like a project home.\n&quot;;
  }
}

sub conjunction_list {
  my $conj = shift;
  my @list = @_;
  my $last = pop @list;
  return $last unless @list;
  return join( &quot; $conj &quot;, join( ', ', @list ), $last );
}

sub expand_dirs {
  return expand_dirs_matching( qr{}, @_ );
}

sub expand_dirs_matching {
  my $match = shift;
  my @work  = @_;
  my @out   = ();
  while ( my $obj = shift @work ) {
    if ( -d $obj ) {
      opendir my $dh, $obj
       or die &quot;Can't read directory $obj ($!)\n&quot;;
      push @work, map { File::Spec-&gt;catdir( $obj, $_ ) }
       grep { $_ !~ $SKIP }
       grep { $_ !~ /^[.][.]?$/ } readdir $dh;
      closedir $dh;
    }
    elsif ( $obj =~ $match ) {
      push @out, $obj;
    }
  }

  return @out;
}

sub exists_in {
  my ( $base, $name ) = @_;

  my $try;

  if ( $name =~ m{^(.+)/$} ) {
    $try = File::Spec-&gt;catdir( $base, $1 );
    return unless -d $try;
  }
  else {
    $try = File::Spec-&gt;catfile( $base, $name );
    return unless -f $try;
  }

  return File::Spec-&gt;canonpath( $try );
}

sub find_dir_like {
  my $start     = shift;
  my $max_up    = shift;
  my $signature = shift;

  for ( 1 .. $max_up ) {
    my $score = 0;
    while ( my ( $file, $weight ) = each %$signature ) {
      $score += $weight if exists_in( $start, $file );
    }
    return File::Spec-&gt;canonpath( $start ) if $score &gt;= 1.0;
    $start = File::Spec-&gt;catdir( $start, File::Spec-&gt;updir );
  }

  return;
}

# Find the project directory
sub find_project {
  return find_dir_like( shift, $MAX_UP, \%PROJECT_SIGNATURE );
}

__END__

=head1 NAME

perl-reversion - Manipulate project version numbers

=head1 SYNOPSIS

perl-reversion [options] [file ...]

 Options:

    -help               see this summary
    -man                view man page for perl-reversion
    -bump               make the smallest possible increment

    -bump-revision      increment the specified version component
    -bump-version
    -bump-subversion
    -bump-alpha

    -set &lt;version&gt;      set the project version number
    -current &lt;version&gt;  specify the current version

    -dskip              specify a directory not to searched
                        you can specify this multiple times

    -normal             print current version in a specific format OR
    -numify             force versions to be a specific format,
    -stringify          with -set or -bump

    -dryrun             just go through the motions, but don't
                        actually save files

=head1 DESCRIPTION

A typical distribution of a Perl module has embedded version numbers is
a number of places. Typically the version will be mentioned in the
README file and in each module's source. For a module the version may
appear twice: once in the code and once in the pod.

This script makes it possible to update all of these version numbers
with a simple command.

To update the version numbers of specific files name them on the command
line. Any directories will be recursively expanded.

If used with no filename arguments perl-reversion will attempt to update
README and any files below lib/ in the current project.

=head1 OPTIONS

=over

=item C&lt;&lt; -bump &gt;&gt;

Attempt to make the smallest possible increment to the version. The
least significant part of the version string is incremented.

    1       =&gt;  2
    1.1     =&gt;  1.2
    1.1.1   =&gt;  1.1.2
    1.1.1_1 =&gt;  1.1.1_2

=item C&lt;&lt; -bump-revision &gt;&gt;

=item C&lt;&lt; -bump-version &gt;&gt;

=item C&lt;&lt; -bump-subversion &gt;&gt;

=item C&lt;&lt; -bump-alpha &gt;&gt;

Increment the specified version component.  Like the C&lt;inc_*&gt; methods of
L&lt;Perl::Version&gt;, incrementing a component sets all components to the right of
it to zero.

=item C&lt;&lt; -set &lt;version&gt; &gt;&gt;

Set the version to the specified value. Unless the C&lt;-normal&gt; option is
also specified the format of each individual version string will be
preserved.

=item C&lt;&lt; -current &lt;version&gt; &gt;&gt;

Specify the current version. Only matching version strings will
be updated.

=item C&lt;&lt; -dskip &lt;dir&gt; &gt;&gt;

Specify the directory dir not to search. This option can be selected
multiple times.

=item C&lt;&lt; -normal &gt;&gt;

=item C&lt;&lt; -numify &gt;&gt;

=item C&lt;&lt; -stringify &gt;&gt;

Use a specific formatting, as in L&lt;Perl::Version/Formatting&gt;.

Alone, these options control how the current (found) version is displayed.

With C&lt;-bump&gt; or C&lt;-set&gt;, also update version strings to have the given
formatting, regardless of the version format passed to C&lt;-set&gt; or the current
version (for C&lt;-bump&gt;).

If none of these options are specified, perl-reversion will preserve the
formatting of each individual version string (the same as C&lt;-stringify&gt;).

=item C&lt;&lt; -dryrun &gt;&gt;

If set, perl-reversion will not save files. Use this to see
what gets changed before it actually happens.

=back

=head1 SOURCE

The source is available at:

	https://github.com/briandfoy/perl-version

=head1 AUTHOR

Andy Armstrong  C&lt;&lt; &lt;andy@hexten.net&gt; &gt;&gt;

Currently maintained by brian d foy.

=head1 LICENCE AND COPYRIGHT

Copyright (c) 2007, Andy Armstrong C&lt;&lt; &lt;andy@hexten.net&gt; &gt;&gt;. All rights reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself. See L&lt;perlartistic&gt;.

=head1 DISCLAIMER OF WARRANTY

BECAUSE THIS SOFTWARE IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
FOR THE SOFTWARE, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
PROVIDE THE SOFTWARE &quot;AS IS&quot; WITHOUT WARRANTY OF ANY KIND, EITHER
EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE
ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE SOFTWARE IS WITH
YOU. SHOULD THE SOFTWARE PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL
NECESSARY SERVICING, REPAIR, OR CORRECTION.

IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
REDISTRIBUTE THE SOFTWARE AS PERMITTED BY THE ABOVE LICENCE, BE
LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL,
OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE
THE SOFTWARE (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING
RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A
FAILURE OF THE SOFTWARE TO OPERATE WITH ANY OTHER SOFTWARE), EVEN IF
SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF
SUCH DAMAGES.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>