<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/mimetype</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl

use strict;
use warnings;
our $VERSION = '0.35';
$|++;

# ########## #
# Parse ARGV #
# ########## #
use Encode::Locale;
use Encode;
@ARGV = map { decode(locale =&gt; $_, 1) } @ARGV;

my %args = ();
my %opts = (
    'help'          =&gt; ['h'],
    'usage'         =&gt; ['u'],
    'version'       =&gt; ['v'],
    'stdin'         =&gt; [''],
    'brief'         =&gt; ['b'],
    'namefile'      =&gt; ['f', 1],
    'noalign'       =&gt; ['N'],
    'describe'      =&gt; ['d'],
    'file-compat'   =&gt; [''],
    'output-format' =&gt; ['', 1],
    'language'      =&gt; ['l', 1],
    'mimetype'      =&gt; ['i'],
    'dereference'   =&gt; ['L'],
    'separator'     =&gt; ['F',1],
    'debug'         =&gt; ['D'],
    'database'      =&gt; ['', 1],
    'all'           =&gt; ['a'],
    'magic-only'    =&gt; ['M'],
);

$args{'file-compat'}++ if $0 =~ m#(^|/)file$#;

while ((@ARGV) &amp;&amp; ($ARGV[0] =~ /^-/)) {
    my $opt = shift @ARGV;
    if ($opt =~ /^--?$/) {
        $args{stdin}++ if $args{'file-compat'} &amp;&amp; $opt eq '-';
        last;
    }
    elsif ($opt =~ s/^--([\w-]+)(?:=(.*))?/$1/) {
        if (exists $opts{$opt}) {
            if ($opts{$opt}[1]) {
                my $arg = $2 || shift @ARGV;
                complain('--'.$opt, 2) unless defined $arg;
                $args{$opt} .= ( $args{$opt} ? ' ' : '' ) . $arg;
            }
            else { $args{$opt}++ }
        }
        else { complain('--'.$opt) }
    }
    elsif ($opt =~ s/^-(?!-)//) {
        foreach my $o (split //, $opt) {
            my ($key) = grep { $opts{$_}[0] eq $o } keys %opts;
            complain($o) unless $key;

            if ($opts{$key}[1]) {
                my $arg = shift @ARGV;
                complain('-'.$o, 2) unless defined $arg;
                $args{$key} .= ( $args{$key} ? ' ' : '' ).$arg; # join with whitespace
            }
            else { $args{$key}++; }
        }
    }
    else { complain($opt) }
}

if ($args{help} || $args{usage}) {
    eval 'use Pod::Usage';
    die &quot;Could not find perl module Pod::Usage\n&quot; if $@;
    pod2usage( {
        -verbose =&gt; 1,
        -exitval =&gt; 0,
    } );
}

if ($args{version}) {
    print &quot;mimetype $VERSION\n\n&quot;, &lt;&lt; 'EOV';
Copyright (c) 2003, 2012 Jaap G Karssenberg. All rights reserved.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
EOV
    exit 0;
}

complain(undef, 4) unless scalar(@ARGV) || $args{stdin} || $args{namefile};

# ############# #
# prepare stuff #
# ############# #

our %desc; # desc caching hash

# --database
{
    no warnings 'once';
    @File::MimeInfo::DIRS = split /:/, $args{database} if $args{database};
}

## Actually use our module ##
eval 'use File::MimeInfo::Magic qw/mimetype globs inodetype magic describe/;';
die $@ if $@;

*default = \&amp;File::MimeInfo::default;

# --debug
if ($args{debug}) {
    {
        no warnings 'once';
        $File::MimeInfo::DEBUG++;
        $File::MimeInfo::Magic::DEBUG++;
    }
    print '&gt; Data dirs are: ', join( ', ',
            $args{database}
                ? ( split /:/, $args{database} )
                : (
                    File::BaseDir::xdg_data_home(),
                    File::BaseDir::xdg_data_dirs()
                )
        ), &quot;\n&quot;;
}

# --file-compat
$args{describe}++ if $args{'file-compat'} &amp;&amp; !$args{mimetype};

# --namefile
if ($args{namefile}) {
    open IN, $args{namefile}
        || die &quot;Couldn't open file: $args{namefile}\n&quot;;
    unshift @ARGV, map {chomp; $_} (&lt;IN&gt;);
    close IN;
}

# --language
{
    no warnings 'once';
    $File::MimeInfo::LANG = $args{language} if $args{language};
}

# Formatting stuff
my $l = 5; # &quot;STDIN&quot;
unless ($args{brief} || $args{noalign}) {
    for (@ARGV) { $l = length($_) if $l &lt; length($_) }
}

$args{separator} = ':' unless defined $args{separator};
my $format = $args{'output-format'}
    ? parse_format($args{'output-format'})
    : $args{brief}
    ? sub { $args{describe} ? desc($_[1]) : $_[1] }
    : $args{noalign}
    ? sub { ( $_[0], $args{separator}, ' ', $args{describe} ? desc($_[1]) : $_[1] ) }
    : sub { ( $_[0], $args{separator}, ' 'x($l + 1 - length($_[0])),
        $args{describe} ? desc($_[1]) : $_[1] ) };

# --dereference
if ($args{dereference}) {
    eval 'use File::Spec';
    die &quot;Could not find perl module File::Spec\n&quot; if $@;
}
# --stdin
if ($args{stdin}) {
    eval 'use IO::Scalar';
    die &quot;Could not find perl module IO::Scalar\n&quot; if $@;
}

if (!File::MimeInfo::has_mimeinfo_database()) {
    die &quot;No mimeinfo database found\n&quot;;
}

# ######## #
# do stuff #
# ######## #

# --stdin
if ($args{stdin}) {
    my $data;
    {
        no warnings 'once';
        read(STDIN, $data, $File::MimeInfo::Magic::max_buffer);
    }
    my $scalar = new IO::Scalar \$data;
    print $format-&gt;('STDIN', mimetype($scalar)), &quot;\n&quot;;
    exit;
}

foreach my $file (@ARGV) {
    # --dereference
    my $f = ($args{dereference} &amp;&amp; -l $file) ? resolvelink($file) : $file;
    # --magic-only
    if ($args{'magic-only'}) {
        print $format-&gt;($file, magic($f) || default($f)), &quot;\n&quot;;
    }
    # --all
    elsif ($args{all}) {
        for (qw#inodetype globs magic default#) {
            my $m = eval &quot;$_(\$f)&quot;;
            print $format-&gt;($file, $m), &quot;\n&quot; if $m;
        }
    }
    else {
        print $format-&gt;($file, mimetype($f)), &quot;\n&quot;
    }
}

exit;

# ########### #
# Subroutines #
# ########### #

sub complain { # Error messages
    my $opt = shift;
    my $m = shift || 1;

    my $bn = $0;
    $bn =~ s|^(.*/)*||;
    if ($m == 1) { print STDERR &quot;$bn: unrecognized option '$opt'&quot; }
    elsif ($m == 2) { print STDERR &quot;$bn: option '$opt' requires an argument&quot; }
    elsif ($m == 3) { print STDERR &quot;$bn: $opt: No such file or directory\n&quot; }
    elsif ($m == 4) { print STDERR &quot;usage: $bn [options] files&quot; }

    print &quot;\nTry '$bn --help' for more information.\n&quot; unless $m == 3;
    exit $m;
}

sub parse_format { # Advanced formatting
    my $form = shift;
    my $code = &quot;sub { '$form' }&quot;;
    # code will get @_ = qw/file type/
    $code =~ s/(?&lt;!\\)%f/'.\$_[0].'/g;
    $code =~ s/(?&lt;!\\)%m/'.\$_[1].'/g;
    $code =~ s/(?&lt;!\\)%d/'.desc(\$_[1]).'/g;
    return eval $code;
}

sub resolvelink { # --dereference
    my $file = shift;
    my $link = readlink($file) || return $file;
    my (undef, $dir, undef) = File::Spec-&gt;splitpath($file);
    $link = File::Spec-&gt;rel2abs($link, $dir);
    $link = resolvelink($link) if -l $link; # recurs
    return $link;
}

sub desc { # Cache description
    my $mt = shift;
    return undef unless $mt;
    $desc{$mt} ||= describe($mt) || describe($mt, ''); # second form overrules the language settings to default
}

__END__

=head1 NAME

mimetype - Determine file type

=head1 SYNOPSIS

mimetype [options] [-] files

=head1 DESCRIPTION

This script tries to determine the mime type of a file using the
Shared MIME-info database. It is intended as a kind of I&lt;file(1)&gt; work-alike,
but uses mimetypes instead of descriptions.

If one symlinks the I&lt;file&gt; command to I&lt;mimetype&gt; it will behave
a little more compatible, see L&lt;/--file-compat&gt;.
Commandline options to specify alternative magic files are not
implemented the same because of the conflicting data formats.
Also the wording of the descriptions will differ.

For naming switches I followed the manpage of file(1) version 4.02
when possible. They seem to differ completely from the spec in the
'utilities' chapter of IEEE Std 1003.1-2001 (POSIX).

=head1 OPTIONS

=over 4

=item B&lt;-a&gt;, B&lt;--all&gt;

Show output of all rules that match the file.

TODO: this method now just returns one match for each
method (globs, magic, etc.).

=item B&lt;-b&gt;, B&lt;--brief&gt;

Do not prepend filenames to output lines (brief mode).

=item B&lt;--database&gt;=I&lt;mimedir&gt;:I&lt;mimedir&gt;:...

Force the program to look in these directories for the shared mime-info
database. The directories specified by the basedir specification
are ignored.

=item B&lt;-d&gt;, B&lt;--describe&gt;

Print file descriptions instead of mime types, this is the
default when using L&lt;/--file-compat&gt;.

=item B&lt;-D&gt;, B&lt;--debug&gt;

Print debug information about how the mimetype was determined.

=item B&lt;-f&gt; I&lt;namefile&gt;, B&lt;--namefile&gt;=I&lt;namefile&gt;

Read the names of the files to be examined from the file 'namefile'
(one per line) before the argument list.

=item B&lt;--file-compat&gt;

Make mimetype behave a little more L&lt;file(1)&gt; compatible. This
is turned on automatically when you call mimetype by a link
called 'file'.

A single '-' won't be considered a separator
between options and filenames anymore, but becomes identical to L&lt;/--stdin&gt;.
( You can still use '--' as separator, but
that is not backward compatible with the original file command. )
Also the default becomes to print descriptions instead of mimetypes.

=item B&lt;-F&gt; I&lt;string&gt;, B&lt;--separator&gt;=I&lt;string&gt;

Use string as custom separator between the file name and its mimetype
or description, defaults to ':' .

=item B&lt;-h&gt;, B&lt;--help&gt;

=item B&lt;-u&gt;, B&lt;--usage&gt;

Print a help message and exits.

=item B&lt;-i&gt;, B&lt;--mimetype&gt;

Use mime types, opposite to L&lt;/--describe&gt;,
this is the default when _not_ using L&lt;/--file-compat&gt;.

=item B&lt;-L&gt;, B&lt;--dereference&gt;

Follow symbolic links.

=item B&lt;-l&gt; I&lt;code&gt;, B&lt;--language&gt;=I&lt;code&gt;

The language attribute specifies a two letter language code, this makes
descriptions being outputted in the specified language.

=item B&lt;-M&gt;, B&lt;--magic-only&gt;

Do not check for extensions, globs or inode type, only look at the content
of the file. This is particularly useful if for some reason you don't trust
the name or the extension a file has.

=item B&lt;-N&gt;, B&lt;--noalign&gt;

Do not align output fields.

=item B&lt;--output-format&gt;

If you want an alternative output format, you can specify a format string
containing the following escapes:

    %f for the filename
    %d description
    %m mime type

Alignment is not available when using this,
you need to post-process the output to do that.

=item B&lt;--stdin&gt;

Determine type of content from STDIN, less powerful then normal file checking
because it only uses magic typing. This will happen also if the STDIN filehandle
is a pipe.

To use this option L&lt;IO::Scalar&gt; needs to be installed.

=item B&lt;-v&gt;, B&lt;--version&gt;

Print the version of the program and exit.

=back

=head1 ENVIRONMENT

=over 4

=item XDG_DATA_HOME

=item XDG_DATA_DIRS

These variables can list base directories to search for data files. The shared
mime-info will be expected in the &quot;mime&quot; sub directory of one of these
directories. If these are not set, there will be searched for the
following directories:

    $HOME/.local/share/mime
    /usr/local/share/mime
    /usr/share/mime

See also the &quot;XDG Base Directory Specification&quot;
L&lt;http://freedesktop.org/Standards/basedir-spec&gt;

=back

=head1 FILES

The base dir for all data files is determined by two environment variables,
see L&lt;/ENVIRONMENT&gt;.

=over 4

=item F&lt;BASE/mime/packages/SOURCE.xml&gt;

All other files are compiled from these source files. To re-compile them
use B&lt;update-mime-database(1)&gt;.

=item F&lt;BASE/mime/globs&gt;

Compiled information about globs.

=item F&lt;BASE/mime/magic&gt;

Compiled information about magic numbers.

=item F&lt;BASE/mime/MEDIA/SUBTYPE.xml&gt;

Descriptions of a mimetype in multiple languages, used for the
L&lt;/--describe&gt; switch.

=back

=head1 DIAGNOSTICS

If a file has an empty mimetype or an empty description,
most probably the file doesn't exist and the given name
doesn't match any globs. An empty description can also mean that
there is no description available in the language you specified.

The program exits with a non-zero exit value if either the commandline
arguments failed, a module it depends on wasn't found or the shared
mime-info database wasn't accessible. See L&lt;File::MimeInfo&gt; for more details.

=head1 TODO

The '--all' switch doesn't really show all matches, but only one per
mime-typing method. This needs to be implemented in the modules first.

=head1 BUGS

If you find bugs, please file them in our Github
issue tracker at L&lt;https://github.com/mbeijen/File-MimeInfo/issues&gt;.

B&lt;mimetype&gt; doesn't provide a switch for looking inside compressed files
because it seems to me that this can only be done by un-compressing the file,
something that defeats the purpose. On the other hand the option should
exist for strict compatibility with file(1). Possibly a subclass should be
made for this one day.

=head1 AUTHOR

Jaap Karssenberg E&lt;lt&gt;pardus@cpan.orgE&lt;gt&gt;
Maintained by Michiel Beijen E&lt;lt&gt;mb@x14.nlE&lt;gt&gt;

=head1 COPYRIGHT

Copyright (c) 2003, 2012 Jaap G Karssenberg. All rights reserved.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

=head1 SEE ALSO

L&lt;file(1)&gt;,
L&lt;update-mime-database(1)&gt;,
L&lt;File::MimeInfo(3)&gt;,
L&lt;http://freedesktop.org/Software/shared-mime-info&gt;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>