<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/lwp-download</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl

=head1 NAME

lwp-download - Fetch large files from the web

=head1 SYNOPSIS

 lwp-download [-a] [-s] &lt;url&gt; [&lt;local path&gt;]

 Options:

   -a   save the file in ASCII mode
   -s   use HTTP headers to guess output filename

=head1 DESCRIPTION

The B&lt;lwp-download&gt; program will save the file at I&lt;url&gt; to a local
file.

If I&lt;local path&gt; is not specified, then the current directory is
assumed.

If I&lt;local path&gt; is a directory, then the last segment of the path of the
I&lt;url&gt; is appended to form a local filename.  If the I&lt;url&gt; path ends with
slash the name &quot;index&quot; is used.  With the B&lt;-s&gt; option pick up the last segment
of the filename from server provided sources like the Content-Disposition
header or any redirect URLs.  A file extension to match the server reported
Content-Type might also be appended.  If a file with the produced filename
already exists, then B&lt;lwp-download&gt; will prompt before it overwrites and will
fail if its standard input is not a terminal.  This form of invocation will
also fail is no acceptable filename can be derived from the sources mentioned
above.

If I&lt;local path&gt; is not a directory, then it is simply used as the
path to save into.  If the file already exists it's overwritten.

The I&lt;lwp-download&gt; program is implemented using the I&lt;libwww-perl&gt;
library.  It is better suited to down load big files than the
I&lt;lwp-request&gt; program because it does not store the file in memory.
Another benefit is that it will keep you updated about its progress
and that you don't have much options to worry about.

Use the C&lt;-a&gt; option to save the file in text (ASCII) mode.  Might
make a difference on DOSish systems.

=head1 EXAMPLE

Fetch the newest and greatest perl version:

 $ lwp-download http://www.perl.com/CPAN/src/latest.tar.gz
 Saving to 'latest.tar.gz'...
 11.4 MB received in 8 seconds (1.43 MB/sec)

=head1 AUTHOR

Gisle Aas &lt;gisle@aas.no&gt;

=cut

#' get emacs out of quote mode

use strict;
use warnings;

use LWP::UserAgent ();
use LWP::MediaTypes qw(guess_media_type media_suffix);
use URI        ();
use HTTP::Date ();
use Encode;
use Encode::Locale;
use Getopt::Long qw(HelpMessage :config gnu_getopt no_ignore_case auto_help);

my $progname = $0;
$progname =~ s,.*/,,;    # only basename left in progname
$progname =~ s,.*\\,, if $^O eq &quot;MSWin32&quot;;
$progname =~ s/\.\w*$//;    # strip extension if any

my %opt;
GetOptions(
    'a' =&gt; \$opt{a},
    's' =&gt; \$opt{s}
) or HelpMessage();

my $url = URI-&gt;new(decode(locale =&gt; shift) || HelpMessage());
my $argfile = encode(locale_fs =&gt; decode(locale =&gt; shift));
HelpMessage() if defined($argfile) &amp;&amp; !length($argfile);

my $ua = LWP::UserAgent-&gt;new(
    agent      =&gt; &quot;lwp-download/$LWP::UserAgent::VERSION &quot;,
    keep_alive =&gt; 1,
    env_proxy  =&gt; 1,
);

my $file;       # name of file we download into
my $length;     # total number of bytes to download
my $flength;    # formatted length
my $size = 0;   # number of bytes received
my $start_t;    # start time of download
my $last_dur;   # time of last callback

my $shown = 0;  # have we called the show() function yet

$SIG{INT} = sub { die &quot;Interrupted\n&quot;; };

$| = 1;         # autoflush

my $res = $ua-&gt;request(
    HTTP::Request-&gt;new(GET =&gt; $url),
    sub {
        unless (defined $file) {
            my $res = $_[1];

            my $directory;
            if (defined $argfile &amp;&amp; -d $argfile) {
                ($directory, $argfile) = ($argfile, undef);
            }

            unless (defined $argfile) {

                # find a suitable name to use
                $file = $opt{s} &amp;&amp; $res-&gt;filename;

                # if this fails we try to make something from the URL
                unless ($file) {
                    $file = ($url-&gt;path_segments)[-1];
                    if (!defined($file) || !length($file)) {
                        $file = &quot;index&quot;;
                        my $suffix = media_suffix($res-&gt;content_type);
                        $file .= &quot;.$suffix&quot; if $suffix;
                    }
                    elsif ($url-&gt;scheme eq 'ftp'
                        || $file =~ /\.t[bg]z$/
                        || $file =~ /\.tar(\.(Z|gz|bz2?))?$/)
                    {
                        # leave the filename as it was
                    }
                    else {
                        my $ct = guess_media_type($file);
                        unless ($ct eq $res-&gt;content_type) {

                            # need a better suffix for this type
                            my $suffix = media_suffix($res-&gt;content_type);
                            $file .= &quot;.$suffix&quot; if $suffix;
                        }
                    }
                }

               # validate that we don't have a harmful filename now.  The server
               # might try to trick us into doing something bad.
                if (!length($file)
                    || $file
                    =~ s/([^a-zA-Z0-9_\.\-\+\~])/sprintf &quot;\\x%02x&quot;, ord($1)/ge
                    || $file =~ /^\./)
                {
                    die
                        &quot;Will not save &lt;$url&gt; as \&quot;$file\&quot;.\nPlease override file name on the command line.\n&quot;;
                }

                if (defined $directory) {
                    require File::Spec;
                    $file = File::Spec-&gt;catfile($directory, $file);
                }

                # Check if the file is already present
                if (-l $file) {
                    die
                        &quot;Will not save &lt;$url&gt; to link \&quot;$file\&quot;.\nPlease override file name on the command line.\n&quot;;
                }
                elsif (-f _) {
                    die
                        &quot;Will not save &lt;$url&gt; as \&quot;$file\&quot; without verification.\nEither run from terminal or override file name on the command line.\n&quot;
                        unless -t;
                    $shown = 1;
                    print &quot;Overwrite $file? [y] &quot;;
                    my $ans = &lt;STDIN&gt;;
                    unless (defined($ans) &amp;&amp; $ans =~ /^y?\n/) {
                        if (defined $ans) {
                            print &quot;Ok, aborting.\n&quot;;
                        }
                        else {
                            print &quot;\nAborting.\n&quot;;
                        }
                        exit 1;
                    }
                    $shown = 0;
                }
                elsif (-e _) {
                    die &quot;Will not save &lt;$url&gt; as \&quot;$file\&quot;.  Path exists.\n&quot;;
                }
                else {
                    print &quot;Saving to '$file'...\n&quot;;
                    use Fcntl qw(O_WRONLY O_EXCL O_CREAT);
                    sysopen(FILE, $file, O_WRONLY | O_EXCL | O_CREAT)
                        || die &quot;Can't open $file: $!&quot;;
                }
            }
            else {
                $file = $argfile;
            }
            unless (fileno(FILE)) {
                open(FILE, &quot;&gt;&quot;, $file) || die &quot;Can't open $file: $!\n&quot;;
            }
            binmode FILE unless $opt{a};
            $length   = $res-&gt;content_length;
            $flength  = fbytes($length) if defined $length;
            $start_t  = time;
            $last_dur = 0;
        }

        print FILE $_[0] or die &quot;Can't write to $file: $!\n&quot;;
        $size += length($_[0]);

        if (defined $length) {
            my $dur = time - $start_t;
            if ($dur != $last_dur) {    # don't update too often
                $last_dur = $dur;
                my $perc = $size / $length;
                my $speed;
                $speed = fbytes($size / $dur) . &quot;/sec&quot; if $dur &gt; 3;
                my $secs_left = fduration($dur / $perc - $dur);
                $perc = int($perc * 100);
                my $show = &quot;$perc% of $flength&quot;;
                $show .= &quot; (at $speed, $secs_left remaining)&quot; if $speed;
                show($show, 1);
            }
        }
        else {
            show(fbytes($size) . &quot; received&quot;);
        }
    }
);

if (fileno(FILE)) {
    close(FILE) || die &quot;Can't write to $file: $!\n&quot;;

    show(&quot;&quot;);    # clear text
    print &quot;\r&quot;;
    print fbytes($size);
    print &quot; of &quot;, fbytes($length) if defined($length) &amp;&amp; $length != $size;
    print &quot; received&quot;;
    my $dur = time - $start_t;
    if ($dur) {
        my $speed = fbytes($size / $dur) . &quot;/sec&quot;;
        print &quot; in &quot;, fduration($dur), &quot; ($speed)&quot;;
    }
    print &quot;\n&quot;;

    if (my $mtime = $res-&gt;last_modified) {
        utime time, $mtime, $file;
    }

    if ($res-&gt;header(&quot;X-Died&quot;) || !$res-&gt;is_success) {
        if (my $died = $res-&gt;header(&quot;X-Died&quot;)) {
            print &quot;$died\n&quot;;
        }
        if (-t) {
            print &quot;Transfer aborted.  Delete $file? [n] &quot;;
            my $ans = &lt;STDIN&gt;;
            if (defined($ans) &amp;&amp; $ans =~ /^y\n/) {
                unlink($file) &amp;&amp; print &quot;Deleted.\n&quot;;
            }
            elsif ($length &gt; $size) {
                print &quot;Truncated file kept: &quot;, fbytes($length - $size),
                    &quot; missing\n&quot;;
            }
            else {
                print &quot;File kept.\n&quot;;
            }
            exit 1;
        }
        else {
            print &quot;Transfer aborted, $file kept\n&quot;;
        }
    }
    exit 0;
}

# Did not manage to create any file
print &quot;\n&quot; if $shown;
if (my $xdied = $res-&gt;header(&quot;X-Died&quot;)) {
    print &quot;$progname: Aborted\n$xdied\n&quot;;
}
else {
    print &quot;$progname: &quot;, $res-&gt;status_line, &quot;\n&quot;;
}
exit 1;


sub fbytes {
    my $n = int(shift);
    if ($n &gt;= 1024 * 1024) {
        return sprintf &quot;%.3g MB&quot;, $n / (1024.0 * 1024);
    }
    elsif ($n &gt;= 1024) {
        return sprintf &quot;%.3g KB&quot;, $n / 1024.0;
    }
    else {
        return &quot;$n bytes&quot;;
    }
}

sub fduration {
    use integer;
    my $secs = int(shift);
    my $hours = $secs / (60 * 60);
    $secs -= $hours * 60 * 60;
    my $mins = $secs / 60;
    $secs %= 60;
    if ($hours) {
        return &quot;$hours hours $mins minutes&quot;;
    }
    elsif ($mins &gt;= 2) {
        return &quot;$mins minutes&quot;;
    }
    else {
        $secs += $mins * 60;
        return &quot;$secs seconds&quot;;
    }
}


BEGIN {
    my @ani = qw(- \ | /);
    my $ani = 0;

    sub show {
        my ($mess, $show_ani) = @_;
        print &quot;\r$mess&quot; . (&quot; &quot; x (75 - length $mess));
        my $msg = $show_ani ? $ani[$ani++]. &quot;\b&quot; : ' ';
        print $msg;
        $ani %= @ani;
        $shown++;
    }
}
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>