<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/json_xs</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl

=head1 NAME

json_xs - JSON::XS commandline utility

=head1 SYNOPSIS

   json_xs [-v] [-f inputformat] [-t outputformat]

=head1 DESCRIPTION

F&lt;json_xs&gt; converts between some input and output formats (one of them is
JSON).

The default input format is C&lt;json&gt; and the default output format is
C&lt;json-pretty&gt;.

=head1 OPTIONS

=over 4

=item -v

Be slightly more verbose.

=item -f fromformat

Read a file in the given format from STDIN.

C&lt;fromformat&gt; can be one of:

=over 4

=item json - a json text encoded, either utf-8, utf16-be/le, utf32-be/le

=item cbor - CBOR (RFC 7049, L&lt;CBOR::XS&gt;), a kind of binary JSON

=item storable - a L&lt;Storable&gt; frozen value

=item storable-file - a L&lt;Storable&gt; file (Storable has two incompatible formats)

=item bencode - use L&lt;Convert::Bencode&gt;, if available (used by torrent files, among others)

=item clzf - L&lt;Compress::LZF&gt; format (requires that module to be installed)

=item eval - evaluate the given code as (non-utf-8) Perl, basically the reverse of &quot;-t dump&quot;

=item yaml - L&lt;YAML&gt; format (requires that module to be installed)

=item string - do not attempt to decode the file data

=item none - nothing is read, creates an C&lt;undef&gt; scalar - mainly useful with C&lt;-e&gt;

=back

=item -t toformat

Write the file in the given format to STDOUT.

C&lt;toformat&gt; can be one of:

=over 4

=item json, json-utf-8 - json, utf-8 encoded

=item json-pretty - as above, but pretty-printed

=item json-utf-16le, json-utf-16be - little endian/big endian utf-16

=item json-utf-32le, json-utf-32be - little endian/big endian utf-32

=item cbor - CBOR (RFC 7049, L&lt;CBOR::XS&gt;), a kind of binary JSON

=item cbor-packed - CBOR using extensions to make it smaller

=item storable - a L&lt;Storable&gt; frozen value in network format

=item storable-file - a L&lt;Storable&gt; file in network format (Storable has two incompatible formats)

=item bencode - use L&lt;Convert::Bencode&gt;, if available (used by torrent files, among others)

=item clzf - L&lt;Compress::LZF&gt; format

=item yaml - L&lt;YAML::XS&gt; format

=item dump - L&lt;Data::Dump&gt;

=item dumper - L&lt;Data::Dumper&gt;

=item string - writes the data out as if it were a string

=item none - nothing gets written, mainly useful together with C&lt;-e&gt;

Note that Data::Dumper doesn't handle self-referential data structures
correctly - use &quot;dump&quot; instead.

=back

=item -e code

Evaluate perl code after reading the data and before writing it out again
- can be used to filter, create or extract data. The data that has been
written is in C&lt;$_&gt;, and whatever is in there is written out afterwards.

=back

=head1 EXAMPLES

   json_xs -t none &lt;isitreally.json

&quot;JSON Lint&quot; - tries to parse the file F&lt;isitreally.json&gt; as JSON - if it
is valid JSON, the command outputs nothing, otherwise it will print an
error message and exit with non-zero exit status.

   &lt;src.json json_xs &gt;pretty.json

Prettify the JSON file F&lt;src.json&gt; to F&lt;dst.json&gt;.

   json_xs -f storable-file &lt;file

Read the serialised Storable file F&lt;file&gt; and print a human-readable JSON
version of it to STDOUT.

   json_xs -f storable-file -t yaml &lt;file

Same as above, but write YAML instead (not using JSON at all :)

   json_xs -f none -e '$_ = [1, 2, 3]'

Dump the perl array as UTF-8 encoded JSON text.

   &lt;torrentfile json_xs -f bencode -e '$_ = join &quot;\n&quot;, map @$_, @{$_-&gt;{&quot;announce-list&quot;}}' -t string

Print the tracker list inside a torrent file.

   lwp-request http://cpantesters.perl.org/show/JSON-XS.json | json_xs

Fetch the cpan-testers result summary C&lt;JSON::XS&gt; and pretty-print it.

=head1 AUTHOR

Copyright (C) 2008 Marc Lehmann &lt;json@schmorp.de&gt;

=cut

use strict;

use Getopt::Long;
use Storable ();
use Encode;

use JSON::XS;

my $opt_verbose;
my $opt_from = &quot;json&quot;;
my $opt_to   = &quot;json-pretty&quot;;
my $opt_eval;

Getopt::Long::Configure (&quot;bundling&quot;, &quot;no_ignore_case&quot;, &quot;require_order&quot;);

GetOptions(
   &quot;v&quot;   =&gt; \$opt_verbose,
   &quot;f=s&quot; =&gt; \$opt_from,
   &quot;t=s&quot; =&gt; \$opt_to,
   &quot;e=s&quot; =&gt; \$opt_eval,
) or die &quot;Usage: $0 [-v] -f fromformat [-e code] [-t toformat]\n&quot;;

my %F = (
   &quot;none&quot;          =&gt; sub { undef },
   &quot;string&quot;        =&gt; sub { $_ },
   &quot;json&quot;          =&gt; sub {
      my $enc =
         /^\x00\x00\x00/s  ? &quot;utf-32be&quot;
       : /^\x00.\x00/s     ? &quot;utf-16be&quot;
       : /^.\x00\x00\x00/s ? &quot;utf-32le&quot;
       : /^.\x00.\x00/s    ? &quot;utf-16le&quot;
       :                     &quot;utf-8&quot;;
      warn &quot;input text encoding is $enc\n&quot; if $opt_verbose;
      JSON::XS-&gt;new-&gt;decode (decode $enc, $_)
   },
   &quot;cbor&quot;          =&gt; sub { require CBOR::XS; CBOR::XS-&gt;new-&gt;allow_cycles-&gt;decode ($_) },
   &quot;storable&quot;      =&gt; sub { Storable::thaw $_ },
   &quot;storable-file&quot; =&gt; sub { open my $fh, &quot;&lt;&quot;, \$_; Storable::fd_retrieve $fh },
   &quot;bencode&quot;       =&gt; sub { require Convert::Bencode; Convert::Bencode::bdecode ($_) },
   &quot;clzf&quot;          =&gt; sub { require Compress::LZF; Compress::LZF::sthaw ($_) },
   &quot;yaml&quot;          =&gt; sub { require YAML::XS; YAML::XS::Load ($_) },
   &quot;eval&quot;          =&gt; sub { my $v = eval &quot;no strict; no warnings; no utf8;\n#line 1 \&quot;input\&quot;\n$_&quot;; die &quot;$@&quot; if $@; $v },
);

my %T = (
   &quot;none&quot;          =&gt; sub { &quot;&quot; },
   &quot;string&quot;        =&gt; sub { $_ },
   &quot;json&quot;          =&gt; sub { encode_json $_ },
   &quot;json-utf-8&quot;    =&gt; sub { encode_json $_ },
   &quot;json-pretty&quot;   =&gt; sub { JSON::XS-&gt;new-&gt;utf8-&gt;pretty-&gt;canonical-&gt;encode ($_) },
   &quot;json-utf-16le&quot; =&gt; sub { encode &quot;utf-16le&quot;, JSON::XS-&gt;new-&gt;encode ($_) },
   &quot;json-utf-16be&quot; =&gt; sub { encode &quot;utf-16be&quot;, JSON::XS-&gt;new-&gt;encode ($_) },
   &quot;json-utf-32le&quot; =&gt; sub { encode &quot;utf-32le&quot;, JSON::XS-&gt;new-&gt;encode ($_) },
   &quot;json-utf-32be&quot; =&gt; sub { encode &quot;utf-32be&quot;, JSON::XS-&gt;new-&gt;encode ($_) },
   &quot;cbor&quot;          =&gt; sub { require CBOR::XS; CBOR::XS::encode_cbor ($_) },
   &quot;cbor-packed&quot;   =&gt; sub { require CBOR::XS; CBOR::XS-&gt;new-&gt;pack_strings-&gt;encode ($_) },
   &quot;storable&quot;      =&gt; sub { Storable::nfreeze $_ },
   &quot;storable-file&quot; =&gt; sub { open my $fh, &quot;&gt;&quot;, \my $buf; Storable::nstore_fd $_, $fh; $buf },
   &quot;bencode&quot;       =&gt; sub { require Convert::Bencode; Convert::Bencode::bencode ($_) },
   &quot;clzf&quot;          =&gt; sub { require Compress::LZF; Compress::LZF::sfreeze_cr ($_) },
   &quot;yaml&quot;          =&gt; sub { require YAML::XS; YAML::XS::Dump ($_) },
   &quot;dumper&quot;        =&gt; sub {
      require Data::Dumper;
      #local $Data::Dumper::Purity    = 1; # hopeless case
      local $Data::Dumper::Terse     = 1;
      local $Data::Dumper::Indent    = 1;
      local $Data::Dumper::Useqq     = 1;
      local $Data::Dumper::Quotekeys = 0;
      local $Data::Dumper::Sortkeys  = 1;
      Data::Dumper::Dumper($_)
   },
   &quot;dump&quot;          =&gt; sub {
      require Data::Dump;
      local $Data::Dump::TRY_BASE64 = 0;
      Data::Dump::dump ($_) . &quot;\n&quot;
   },
);

$F{$opt_from}
   or die &quot;$opt_from: not a valid fromformat\n&quot;;

$T{$opt_to}
   or die &quot;$opt_to: not a valid toformat\n&quot;;

if ($opt_from ne &quot;none&quot;) {
   local $/;
   binmode STDIN; # stupid perl sometimes thinks its funny
   $_ = &lt;STDIN&gt;;
}

$_ = $F{$opt_from}-&gt;();

eval $opt_eval;
die $@ if $@;

$_ = $T{$opt_to}-&gt;();

binmode STDOUT;
syswrite STDOUT, $_;


</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>