<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/enc2xs</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl
    eval 'exec /usr/local/cpanel/3rdparty/perl/542/bin/perl -S $0 ${1+&quot;$@&quot;}'
	if 0; # ^ Run only under a shell
#!./perl
BEGIN {
    # @INC poking  no longer needed w/ new MakeMaker and Makefile.PL's
    # with $ENV{PERL_CORE} set
    # In case we need it in future...
    require Config; Config-&gt;import();
    pop @INC if $INC[-1] eq '.';
}
use strict;
use warnings;
use Getopt::Std;
use Config;
my @orig_ARGV = @ARGV;
our $VERSION  = do { my @r = (q$Revision: 2.25 $ =~ /\d+/g); sprintf &quot;%d.&quot;.&quot;%02d&quot; x $#r, @r };

# These may get re-ordered.
# RAW is a do_now as inserted by &amp;enter
# AGG is an aggregated do_now, as built up by &amp;process

use constant {
  RAW_NEXT =&gt; 0,
  RAW_IN_LEN =&gt; 1,
  RAW_OUT_BYTES =&gt; 2,
  RAW_FALLBACK =&gt; 3,

  AGG_MIN_IN =&gt; 0,
  AGG_MAX_IN =&gt; 1,
  AGG_OUT_BYTES =&gt; 2,
  AGG_NEXT =&gt; 3,
  AGG_IN_LEN =&gt; 4,
  AGG_OUT_LEN =&gt; 5,
  AGG_FALLBACK =&gt; 6,
};

# (See the algorithm in encengine.c - we're building structures for it)

# There are two sorts of structures.
# &quot;do_now&quot; (an array, two variants of what needs storing) is whatever we need
# to do now we've read an input byte.
# It's housed in a &quot;do_next&quot; (which is how we got to it), and in turn points
# to a &quot;do_next&quot; which contains all the &quot;do_now&quot;s for the next input byte.

# There will be a &quot;do_next&quot; which is the start state.
# For a single byte encoding it's the only &quot;do_next&quot; - each &quot;do_now&quot; points
# back to it, and each &quot;do_now&quot; will cause bytes. There is no state.

# For a multi-byte encoding where all characters in the input are the same
# length, then there will be a tree of &quot;do_now&quot;-&gt;&quot;do_next&quot;-&gt;&quot;do_now&quot;
# branching out from the start state, one step for each input byte.
# The leaf &quot;do_now&quot;s will all be at the same distance from the start state,
# only the leaf &quot;do_now&quot;s cause output bytes, and they in turn point back to
# the start state.

# For an encoding where there are variable length input byte sequences, you
# will encounter a leaf &quot;do_now&quot; sooner for the shorter input sequences, but
# as before the leaves will point back to the start state.

# The system will cope with escape encodings (imagine them as a mostly
# self-contained tree for each escape state, and cross links between trees
# at the state-switching characters) but so far no input format defines these.

# The system will also cope with having output &quot;leaves&quot; in the middle of
# the bifurcating branches, not just at the extremities, but again no
# input format does this yet.

# There are two variants of the &quot;do_now&quot; structure. The first, smaller variant
# is generated by &amp;enter as the input file is read. There is one structure
# for each input byte. Say we are mapping a single byte encoding to a
# single byte encoding, with  &quot;ABCD&quot; going &quot;abcd&quot;. There will be
# 4 &quot;do_now&quot;s, {&quot;A&quot; =&gt; [...,&quot;a&quot;,...], &quot;B&quot; =&gt; [...,&quot;b&quot;,...], &quot;C&quot;=&gt;..., &quot;D&quot;=&gt;...}

# &amp;process then walks the tree, building aggregate &quot;do_now&quot; structures for
# adjacent bytes where possible. The aggregate is for a contiguous range of
# bytes which each produce the same length of output, each move to the
# same next state, and each have the same fallback flag.
# So our 4 RAW &quot;do_now&quot;s above become replaced by a single structure
# containing:
# [&quot;A&quot;, &quot;D&quot;, &quot;abcd&quot;, 1, ...]
# ie, for an input byte $_ in &quot;A&quot;..&quot;D&quot;, output 1 byte, found as
# substr (&quot;abcd&quot;, (ord $_ - ord &quot;A&quot;) * 1, 1)
# which maps very nicely into pointer arithmetic in C for encengine.c

sub encode_U
{
 # UTF-8 encode long hand - only covers part of perl's range
 ## my $uv = shift;
 # chr() works in native space so convert value from table
 # into that space before using chr().
 my $ch = chr(utf8::unicode_to_native($_[0]));
 # Now get core perl to encode that the way it likes.
 utf8::encode($ch);
 return $ch;
}

sub encode_S
{
 # encode single byte
 ## my ($ch,$page) = @_; return chr($ch);
 return chr $_[0];
}

sub encode_D
{
 # encode double byte MS byte first
 ## my ($ch,$page) = @_; return chr($page).chr($ch);
 return chr ($_[1]) . chr $_[0];
}

sub encode_M
{
 # encode Multi-byte - single for 0..255 otherwise double
 ## my ($ch,$page) = @_;
 ## return &amp;encode_D if $page;
 ## return &amp;encode_S;
 return chr ($_[1]) . chr $_[0] if $_[1];
 return chr $_[0];
}

my %encode_types = (U =&gt; \&amp;encode_U,
                    S =&gt; \&amp;encode_S,
                    D =&gt; \&amp;encode_D,
                    M =&gt; \&amp;encode_M,
                   );

# Win32 does not expand globs on command line
if ($^O eq 'MSWin32' and !$ENV{PERL_CORE}) {
    eval &quot;\@ARGV = map(glob(\$_),\@ARGV)&quot;;
    @ARGV = @orig_ARGV unless @ARGV;
}

my %opt;
# I think these are:
# -Q to disable the duplicate codepoint test
# -S make mapping errors fatal
# -q to remove comments written to output files
# -O to enable the (brute force) substring optimiser
# -o &lt;output&gt; to specify the output file name (else it's the first arg)
# -f &lt;inlist&gt; to give a file with a list of input files (else use the args)
# -n &lt;name&gt; to name the encoding (else use the basename of the input file.
#Getopt::Long::Configure(&quot;bundling&quot;);
#GetOptions(\%opt, qw(C M=s S Q q O o=s f=s n=s v));
getopts('CM:SQqOo:f:n:v',\%opt);

$opt{M} and make_makefile_pl($opt{M}, @ARGV);
$opt{C} and make_configlocal_pm($opt{C}, @ARGV);
$opt{v} ||= $ENV{ENC2XS_VERBOSE};
$opt{q} ||= $ENV{ENC2XS_NO_COMMENTS};

sub verbose {
    print STDERR @_ if $opt{v};
}
sub verbosef {
    printf STDERR @_ if $opt{v};
}


# ($cpp, $static, $sized) = compiler_info($declaration)
#
# return some information about the compiler and compile options we're using:
#
#   $declaration - true if we're doing a declaration rather than a definition.
#
#   $cpp    - we're using C++
#   $static - ok to declare the arrays as static
#   $sized  - the array declarations should be sized

sub compiler_info {
    my ($declaration) = @_;

    my $ccflags = $Config{ccflags};
    if (defined $Config{ccwarnflags}) {
        $ccflags .= &quot; &quot; . $Config{ccwarnflags};
    }
    my $compat   = $ccflags =~ /\Q-Wc++-compat/;
    my $pedantic = $ccflags =~ /-pedantic/;

    my $cpp      = ($Config{d_cplusplus} || '') eq 'define';

    # The encpage_t tables contain recursive and mutually recursive
    # references. To allow them to compile under C++ and some restrictive
    # cc options, it may be necessary to make the tables non-static/const
    # (thus moving them from the text to the data segment) and/or not
    # include the size in the declaration.

    my $static = !(
                        $cpp
                     || ($compat &amp;&amp; $pedantic)
                     || ($^O eq 'MacOS' &amp;&amp; $declaration)
                  );

    # -Wc++-compat on its own warns if the array declaration is sized.
    # The easiest way to avoid this warning is simply not to include
    # the size in the declaration.
    # With -pedantic as well, the issue doesn't arise because $static
    # above becomes false.
    my $sized  = $declaration &amp;&amp; !($compat &amp;&amp; !$pedantic);

    return ($cpp, $static, $sized);
}


# This really should go first, else the die here causes empty (non-erroneous)
# output files to be written.
my @encfiles;
if (exists $opt{f}) {
    # -F is followed by name of file containing list of filenames
    my $flist = $opt{f};
    open(FLIST,$flist) || die &quot;Cannot open $flist:$!&quot;;
    chomp(@encfiles = &lt;FLIST&gt;);
    close(FLIST);
} else {
    @encfiles = @ARGV;
}

my $cname = $opt{o} ? $opt{o} : shift(@ARGV);
unless ($cname) { # Debugging a Win32 nmake error-only; works via cmdline.
    print &quot;\nARGV:&quot;;
    print &quot;$_ &quot; for @ARGV;
    print &quot;\nopt:&quot;;
    print &quot;  $_ =&gt; &quot;,defined $opt{$_}?$opt{$_}:&quot;undef&quot;,&quot;\n&quot; for keys %opt;
}
chmod(0666,$cname) if -f $cname &amp;&amp; !-w $cname;
open(C,&quot;&gt;&quot;, $cname) || die &quot;Cannot open $cname:$!&quot;;

my $dname = $cname;
my $hname = $cname;

my ($doC,$doEnc,$doUcm,$doPet);

if ($cname =~ /\.(c|xs)$/i) # VMS may have upcased filenames with DECC$ARGV_PARSE_STYLE defined
 {
  $doC = 1;
  $dname =~ s/(\.[^\.]*)?$/.exh/;
  chmod(0666,$dname) if -f $cname &amp;&amp; !-w $dname;
  open(D,&quot;&gt;&quot;, $dname) || die &quot;Cannot open $dname:$!&quot;;
  $hname =~ s/(\.[^\.]*)?$/.h/;
  chmod(0666,$hname) if -f $cname &amp;&amp; !-w $hname;
  open(H,&quot;&gt;&quot;, $hname) || die &quot;Cannot open $hname:$!&quot;;

  foreach my $fh (\*C,\*D,\*H)
  {
   print $fh &lt;&lt;&quot;END&quot; unless $opt{'q'};
/*
 !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
 This file was autogenerated by:
 $^X $0 @orig_ARGV
 enc2xs VERSION $VERSION
*/
END
  }

  if ($cname =~ /\.c$/i &amp;&amp; $Config{ccname} eq &quot;gcc&quot;)
   {
    print C qq(#pragma GCC diagnostic ignored &quot;-Wc++-compat&quot;\n);
   }

  if ($cname =~ /\.xs$/i)
   {
    print C &quot;#define PERL_NO_GET_CONTEXT\n&quot;;
    print C &quot;#include &lt;EXTERN.h&gt;\n&quot;;
    print C &quot;#include &lt;perl.h&gt;\n&quot;;
    print C &quot;#include &lt;XSUB.h&gt;\n&quot;;
   }
  print C &quot;#include \&quot;encode.h\&quot;\n\n&quot;;

 }
elsif ($cname =~ /\.enc$/i)
 {
  $doEnc = 1;
 }
elsif ($cname =~ /\.ucm$/i)
 {
  $doUcm = 1;
 }
elsif ($cname =~ /\.pet$/i)
 {
  $doPet = 1;
 }

my %encoding;
my %strings;
my $string_acc;
my %strings_in_acc;

my $saved = 0;
my $subsave = 0;
my $strings = 0;

sub cmp_name
{
 if ($a =~ /^.*-(\d+)/)
  {
   my $an = $1;
   if ($b =~ /^.*-(\d+)/)
    {
     my $r = $an &lt;=&gt; $1;
     return $r if $r;
    }
  }
 return $a cmp $b;
}


foreach my $enc (sort cmp_name @encfiles)
 {
  my ($name,$sfx) = $enc =~ /^.*?([\w-]+)\.(enc|ucm)$/;
  $name = $opt{'n'} if exists $opt{'n'};
  if (open(E,$enc))
   {
    if ($sfx eq 'enc')
     {
      compile_enc(\*E,lc($name));
     }
    else
     {
      compile_ucm(\*E,lc($name));
     }
   }
  else
   {
    warn &quot;Cannot open $enc for $name:$!&quot;;
   }
 }

if ($doC)
 {
  verbose &quot;Writing compiled form\n&quot;;
  foreach my $name (sort cmp_name keys %encoding)
   {
    my ($e2u,$u2e,$erep,$min_el,$max_el) = @{$encoding{$name}};
    process($name.'_utf8',$e2u);
    addstrings(\*C,$e2u);

    process('utf8_'.$name,$u2e);
    addstrings(\*C,$u2e);
   }
  outbigstring(\*C,&quot;enctable&quot;);
  foreach my $name (sort cmp_name keys %encoding)
   {
    my ($e2u,$u2e,$erep,$min_el,$max_el) = @{$encoding{$name}};
    outtable(\*C,$e2u, &quot;enctable&quot;);
    outtable(\*C,$u2e, &quot;enctable&quot;);

    # push(@{$encoding{$name}},outstring(\*C,$e2u-&gt;{Cname}.'_def',$erep));
   }
  my ($cpp) = compiler_info(0);
  my $ext  = $cpp ? 'extern &quot;C&quot;' : &quot;extern&quot;;
  my $exta = $cpp ? 'extern &quot;C&quot;' : &quot;static&quot;;
  my $extb = $cpp ? 'extern &quot;C&quot;' : &quot;&quot;;
  foreach my $enc (sort cmp_name keys %encoding)
   {
    # my ($e2u,$u2e,$rep,$min_el,$max_el,$rsym) = @{$encoding{$enc}};
    my ($e2u,$u2e,$rep,$min_el,$max_el) = @{$encoding{$enc}};
    #my @info = ($e2u-&gt;{Cname},$u2e-&gt;{Cname},$rsym,length($rep),$min_el,$max_el);
    my $replen = 0; 
    $replen++ while($rep =~ /\G\\x[0-9A-Fa-f]/g);
    my $sym = &quot;${enc}_encoding&quot;;
    $sym =~ s/\W+/_/g;
    my @info = ($e2u-&gt;{Cname},$u2e-&gt;{Cname},&quot;${sym}_rep_character&quot;,$replen,
        $min_el,$max_el);
    print C &quot;${exta} const U8 ${sym}_rep_character[] = \&quot;$rep\&quot;;\n&quot;;
    print C &quot;${exta} const char ${sym}_enc_name[] = \&quot;$enc\&quot;;\n\n&quot;;
    print C &quot;${extb} const encode_t $sym = \n&quot;;
    # This is to make null encoding work -- dankogai
    for (my $i = (scalar @info) - 1;  $i &gt;= 0; --$i){
    $info[$i] ||= 1;
    }
    # end of null tweak -- dankogai
    print C &quot; {&quot;,join(',',@info,&quot;{${sym}_enc_name,(const char *)0}&quot;),&quot;};\n\n&quot;;
   }

  foreach my $enc (sort cmp_name keys %encoding)
   {
    my $sym = &quot;${enc}_encoding&quot;;
    $sym =~ s/\W+/_/g;
    print H &quot;${ext} encode_t $sym;\n&quot;;
    print D &quot; Encode_XSEncoding(aTHX_ &amp;$sym);\n&quot;;
   }

  if ($cname =~ /(\w+)\.xs$/)
   {
    my $mod = $1;
    print C &lt;&lt;'END';

static void
Encode_XSEncoding(pTHX_ encode_t *enc)
{
 dSP;
 HV *stash = gv_stashpv(&quot;Encode::XS&quot;, TRUE);
 SV *iv    = newSViv(PTR2IV(enc));
 SV *sv    = sv_bless(newRV_noinc(iv),stash);
 int i = 0;
 /* with the SvLEN() == 0 hack, PVX won't be freed. We cast away name's
 constness, in the hope that perl won't mess with it. */
 assert(SvTYPE(iv) &gt;= SVt_PV); assert(SvLEN(iv) == 0);
 SvFLAGS(iv) |= SVp_POK;
 SvPVX(iv) = (char*) enc-&gt;name[0];
 PUSHMARK(sp);
 XPUSHs(sv);
 while (enc-&gt;name[i])
  {
   const char *name = enc-&gt;name[i++];
   XPUSHs(sv_2mortal(newSVpvn(name,strlen(name))));
  }
 PUTBACK;
 call_pv(&quot;Encode::define_encoding&quot;,G_DISCARD);
 SvREFCNT_dec(sv);
}

END

    print C &quot;\nMODULE = Encode::$mod\tPACKAGE = Encode::$mod\n\n&quot;;
    print C &quot;BOOT:\n{\n&quot;;
    print C &quot;#include \&quot;$dname\&quot;\n&quot;;
    print C &quot;}\n&quot;;
   }
  # Close in void context is bad, m'kay
  close(D) or warn &quot;Error closing '$dname': $!&quot;;
  close(H) or warn &quot;Error closing '$hname': $!&quot;;

  my $perc_saved    = $saved/($strings + $saved) * 100;
  my $perc_subsaved = $subsave/($strings + $subsave) * 100;
  verbosef &quot;%d bytes in string tables\n&quot;,$strings;
  verbosef &quot;%d bytes (%.3g%%) saved spotting duplicates\n&quot;,
    $saved, $perc_saved              if $saved;
  verbosef &quot;%d bytes (%.3g%%) saved using substrings\n&quot;,
    $subsave, $perc_subsaved         if $subsave;
 }
elsif ($doEnc)
 {
  foreach my $name (sort cmp_name keys %encoding)
   {
    my ($e2u,$u2e,$erep,$min_el,$max_el) = @{$encoding{$name}};
    output_enc(\*C,$name,$e2u);
   }
 }
elsif ($doUcm)
 {
  foreach my $name (sort cmp_name keys %encoding)
   {
    my ($e2u,$u2e,$erep,$min_el,$max_el) = @{$encoding{$name}};
    output_ucm(\*C,$name,$u2e,$erep,$min_el,$max_el);
   }
 }

# writing half meg files and then not checking to see if you just filled the
# disk is bad, m'kay
close(C) or die &quot;Error closing '$cname': $!&quot;;

# End of the main program.

sub compile_ucm
{
 my ($fh,$name) = @_;
 my $e2u = {};
 my $u2e = {};
 my $cs;
 my %attr;
 while (&lt;$fh&gt;)
  {
   s/#.*$//;
   last if /^\s*CHARMAP\s*$/i;
   if (/^\s*&lt;(\w+)&gt;\s+&quot;?([^&quot;]*)&quot;?\s*$/i) # &quot; # Grrr
    {
     $attr{$1} = $2;
    }
  }
 if (!defined($cs =  $attr{'code_set_name'}))
  {
   warn &quot;No &lt;code_set_name&gt; in $name\n&quot;;
  }
 else
  {
   $name = $cs unless exists $opt{'n'};
  }
 my $erep;
 my $urep;
 my $max_el;
 my $min_el;
 if (exists $attr{'subchar'})
  {
   #my @byte;
   #$attr{'subchar'} =~ /^\s*/cg;
   #push(@byte,$1) while $attr{'subchar'} =~ /\G\\x([0-9a-f]+)/icg;
   #$erep = join('',map(chr(hex($_)),@byte));
   $erep = $attr{'subchar'}; 
   $erep =~ s/^\s+//; $erep =~ s/\s+$//;
  }
 print &quot;Reading $name ($cs)\n&quot;
   unless defined $ENV{MAKEFLAGS}
      and $ENV{MAKEFLAGS} =~ /\b(s|silent|quiet)\b/;
 my $nfb = 0;
 my $hfb = 0;
 while (&lt;$fh&gt;)
  {
   s/#.*$//;
   last if /^\s*END\s+CHARMAP\s*$/i;
   next if /^\s*$/;
   my (@uni, @byte) = ();
   my ($uni, $byte, $fb) = m/^(\S+)\s+(\S+)\s+(\S+)\s+/o
       or die &quot;Bad line: $_&quot;;
   while ($uni =~  m/\G&lt;([U0-9a-fA-F\+]+)&gt;/g){
       push @uni, map { substr($_, 1) } split(/\+/, $1);
   }
   while ($byte =~ m/\G\\x([0-9a-fA-F]+)/g){
       push @byte, $1;
   }
   if (@uni)
    {
     my $uch =  join('', map { encode_U(hex($_)) } @uni );
     my $ech = join('',map(chr(hex($_)),@byte));
     my $el  = length($ech);
     $max_el = $el if (!defined($max_el) || $el &gt; $max_el);
     $min_el = $el if (!defined($min_el) || $el &lt; $min_el);
     if (length($fb))
      {
       $fb = substr($fb,1);
       $hfb++;
      }
     else
      {
       $nfb++;
       $fb = '0';
      }
     # $fb is fallback flag
     # 0 - round trip safe
     # 1 - fallback for unicode -&gt; enc
     # 2 - skip sub-char mapping
     # 3 - fallback enc -&gt; unicode
     enter($u2e,$uch,$ech,$u2e,$fb+0) if ($fb =~ /[01]/);
     enter($e2u,$ech,$uch,$e2u,$fb+0) if ($fb =~ /[03]/);
    }
   else
    {
     warn $_;
    }
  }
 if ($nfb &amp;&amp; $hfb)
  {
   die &quot;$nfb entries without fallback, $hfb entries with\n&quot;;
  }
 $encoding{$name} = [$e2u,$u2e,$erep,$min_el,$max_el];
}


sub compile_enc
{
 my ($fh,$name) = @_;
 my $e2u = {};
 my $u2e = {};

 my $type;
 while ($type = &lt;$fh&gt;)
  {
   last if $type !~ /^\s*#/;
  }
 chomp($type);
 return if $type eq 'E';
 # Do the hash lookup once, rather than once per function call. 4% speedup.
 my $type_func = $encode_types{$type};
 my ($def,$sym,$pages) = split(/\s+/,scalar(&lt;$fh&gt;));
 warn &quot;$type encoded $name\n&quot;;
 my $rep = '';
 # Save a defined test by setting these to defined values.
 my $min_el = ~0; # A very big integer
 my $max_el = 0;  # Anything must be longer than 0
 {
  my $v = hex($def);
  $rep = &amp;$type_func($v &amp; 0xFF, ($v &gt;&gt; 8) &amp; 0xffe);
 }
 my $errors;
 my $seen;
 # use -Q to silence the seen test. Makefile.PL uses this by default.
 $seen = {} unless $opt{Q};
 do
  {
   my $line = &lt;$fh&gt;;
   chomp($line);
   my $page = hex($line);
   my $ch = 0;
   my $i = 16;
   do
    {
     # So why is it 1% faster to leave the my here?
     my $line = &lt;$fh&gt;;
     $line =~ s/\r\n$/\n/;
     die &quot;$.:${line}Line should be exactly 65 characters long including
     newline (&quot;.length($line).&quot;)&quot; unless length ($line) == 65;
     # Split line into groups of 4 hex digits, convert groups to ints
     # This takes 65.35		
     # map {hex $_} $line =~ /(....)/g
     # This takes 63.75 (2.5% less time)
     # unpack &quot;n*&quot;, pack &quot;H*&quot;, $line
     # There's an implicit loop in map. Loops are bad, m'kay. Ops are bad, m'kay
     # Doing it as while ($line =~ /(....)/g) took 74.63
     foreach my $val (unpack &quot;n*&quot;, pack &quot;H*&quot;, $line)
      {
       next if $val == 0xFFFD;
       my $ech = &amp;$type_func($ch,$page);
       if ($val || (!$ch &amp;&amp; !$page))
        {
         my $el  = length($ech);
         $max_el = $el if $el &gt; $max_el;
         $min_el = $el if $el &lt; $min_el;
         my $uch = encode_U($val);
         if ($seen) {
           # We're doing the test.
           # We don't need to read this quickly, so storing it as a scalar,
           # rather than 3 (anon array, plus the 2 scalars it holds) saves
           # RAM and may make us faster on low RAM systems. [see __END__]
           if (exists $seen-&gt;{$uch})
             {
               warn sprintf(&quot;U%04X is %02X%02X and %04X\n&quot;,
                            $val,$page,$ch,$seen-&gt;{$uch});
               $errors++;
             }
           else
             {
               $seen-&gt;{$uch} = $page &lt;&lt; 8 | $ch;
             }
         }
         # Passing 2 extra args each time is 3.6% slower!
         # Even with having to add $fallback ||= 0 later
         enter_fb0($e2u,$ech,$uch);
         enter_fb0($u2e,$uch,$ech);
        }
       else
        {
         # No character at this position
         # enter($e2u,$ech,undef,$e2u);
        }
       $ch++;
      }
    } while --$i;
  } while --$pages;
 die &quot;\$min_el=$min_el, \$max_el=$max_el - seems we read no lines&quot;
   if $min_el &gt; $max_el;
 die &quot;$errors mapping conflicts\n&quot; if ($errors &amp;&amp; $opt{'S'});
 $encoding{$name} = [$e2u,$u2e,$rep,$min_el,$max_el];
}

# my ($a,$s,$d,$t,$fb) = @_;
sub enter {
  my ($current,$inbytes,$outbytes,$next,$fallback) = @_;
  # state we shift to after this (multibyte) input character defaults to same
  # as current state.
  $next ||= $current;
  # Making sure it is defined seems to be faster than {no warnings;} in
  # &amp;process, or passing it in as 0 explicitly.
  # XXX $fallback ||= 0;

  # Start at the beginning and work forwards through the string to zero.
  # effectively we are removing 1 character from the front each time
  # but we don't actually edit the string. [this alone seems to be 14% speedup]
  # Hence -$pos is the length of the remaining string.
  my $pos = -length $inbytes;
  while (1) {
    my $byte = substr $inbytes, $pos, 1;
    #  RAW_NEXT =&gt; 0,
    #  RAW_IN_LEN =&gt; 1,
    #  RAW_OUT_BYTES =&gt; 2,
    #  RAW_FALLBACK =&gt; 3,
    # to unicode an array would seem to be better, because the pages are dense.
    # from unicode can be very sparse, favouring a hash.
    # hash using the bytes (all length 1) as keys rather than ord value,
    # as it's easier to sort these in &amp;process.

    # It's faster to always add $fallback even if it's undef, rather than
    # choosing between 3 and 4 element array. (hence why we set it defined
    # above)
    my $do_now = $current-&gt;{Raw}{$byte} ||= [{},-$pos,'',$fallback];
    # When $pos was -1 we were at the last input character.
    unless (++$pos) {
      $do_now-&gt;[RAW_OUT_BYTES] = $outbytes;
      $do_now-&gt;[RAW_NEXT] = $next;
      return;
    }
    # Tail recursion. The intermediate state may not have a name yet.
    $current = $do_now-&gt;[RAW_NEXT];
  }
}

# This is purely for optimisation. It's just &amp;enter hard coded for $fallback
# of 0, using only a 3 entry array ref to save memory for every entry.
sub enter_fb0 {
  my ($current,$inbytes,$outbytes,$next) = @_;
  $next ||= $current;

  my $pos = -length $inbytes;
  while (1) {
    my $byte = substr $inbytes, $pos, 1;
    my $do_now = $current-&gt;{Raw}{$byte} ||= [{},-$pos,''];
    unless (++$pos) {
      $do_now-&gt;[RAW_OUT_BYTES] = $outbytes;
      $do_now-&gt;[RAW_NEXT] = $next;
      return;
    }
    $current = $do_now-&gt;[RAW_NEXT];
  }
}

sub process
{
  my ($name,$a) = @_;
  $name =~ s/\W+/_/g;
  $a-&gt;{Cname} = $name;
  my $raw = $a-&gt;{Raw};
  my ($l, $agg_max_in, $agg_next, $agg_in_len, $agg_out_len, $agg_fallback);
  my @ent;
  $agg_max_in = 0;
  foreach my $key (sort keys %$raw) {
    #  RAW_NEXT =&gt; 0,
    #  RAW_IN_LEN =&gt; 1,
    #  RAW_OUT_BYTES =&gt; 2,
    #  RAW_FALLBACK =&gt; 3,
    my ($next, $in_len, $out_bytes, $fallback) = @{$raw-&gt;{$key}};
    # Now we are converting from raw to aggregate, switch from 1 byte strings
    # to numbers
    my $b = ord $key;
    $fallback ||= 0;
    if ($l &amp;&amp;
        # If this == fails, we're going to reset $agg_max_in below anyway.
        $b == ++$agg_max_in &amp;&amp;
        # References in numeric context give the pointer as an int.
        $agg_next == $next &amp;&amp;
        $agg_in_len == $in_len &amp;&amp;
        $agg_out_len == length $out_bytes &amp;&amp;
        $agg_fallback == $fallback
        # &amp;&amp; length($l-&gt;[AGG_OUT_BYTES]) &lt; 16
       ) {
      #     my $i = ord($b)-ord($l-&gt;[AGG_MIN_IN]);
      # we can aggregate this byte onto the end.
      $l-&gt;[AGG_MAX_IN] = $b;
      $l-&gt;[AGG_OUT_BYTES] .= $out_bytes;
    } else {
      # AGG_MIN_IN =&gt; 0,
      # AGG_MAX_IN =&gt; 1,
      # AGG_OUT_BYTES =&gt; 2,
      # AGG_NEXT =&gt; 3,
      # AGG_IN_LEN =&gt; 4,
      # AGG_OUT_LEN =&gt; 5,
      # AGG_FALLBACK =&gt; 6,
      # Reset the last thing we saw, plus set 5 lexicals to save some derefs.
      # (only gains .6% on euc-jp  -- is it worth it?)
      push @ent, $l = [$b, $agg_max_in = $b, $out_bytes, $agg_next = $next,
                       $agg_in_len = $in_len, $agg_out_len = length $out_bytes,
                       $agg_fallback = $fallback];
    }
    if (exists $next-&gt;{Cname}) {
      $next-&gt;{'Forward'} = 1 if $next != $a;
    } else {
      process(sprintf(&quot;%s_%02x&quot;,$name,$b),$next);
    }
  }
  # encengine.c rules say that last entry must be for 255
  if ($agg_max_in &lt; 255) {
    push @ent, [1+$agg_max_in, 255,undef,$a,0,0];
  }
  $a-&gt;{'Entries'} = \@ent;
}


sub addstrings
{
 my ($fh,$a) = @_;
 my $name = $a-&gt;{'Cname'};
 # String tables
 foreach my $b (@{$a-&gt;{'Entries'}})
  {
   next unless $b-&gt;[AGG_OUT_LEN];
   $strings{$b-&gt;[AGG_OUT_BYTES]} = undef;
  }
 if ($a-&gt;{'Forward'})
  {
   my ($cpp, $static, $sized) = compiler_info(1);
   my $count = $sized ? scalar(@{$a-&gt;{'Entries'}}) : '';
   if ($static) {
     # we cannot ask Config for d_plusplus since we can override CC=g++-6 on the cmdline
     print $fh &quot;#ifdef __cplusplus\n&quot;; # -fpermissive since g++-6
     print $fh &quot;extern encpage_t $name\[$count];\n&quot;;
     print $fh &quot;#else\n&quot;;
     print $fh &quot;static const encpage_t $name\[$count];\n&quot;;
     print $fh &quot;#endif\n&quot;;
   } else {
     print $fh &quot;extern encpage_t $name\[$count];\n&quot;;
   }
  }
 $a-&gt;{'DoneStrings'} = 1;
 foreach my $b (@{$a-&gt;{'Entries'}})
  {
   my ($s,$e,$out,$t,$end,$l) = @$b;
   addstrings($fh,$t) unless $t-&gt;{'DoneStrings'};
  }
}

sub outbigstring
{
  my ($fh,$name) = @_;

  $string_acc = '';

  # Make the big string in the string accumulator. Longest first, on the hope
  # that this makes it more likely that we find the short strings later on.
  # Not sure if it helps sorting strings of the same length lexically.
  foreach my $s (sort {length $b &lt;=&gt; length $a || $a cmp $b} keys %strings) {
    my $index = index $string_acc, $s;
    if ($index &gt;= 0) {
      $saved += length($s);
      $strings_in_acc{$s} = $index;
    } else {
    OPTIMISER: {
    if ($opt{'O'}) {
      my $sublength = length $s;
      while (--$sublength &gt; 0) {
        # progressively lop characters off the end, to see if the start of
        # the new string overlaps the end of the accumulator.
        if (substr ($string_acc, -$sublength)
        eq substr ($s, 0, $sublength)) {
          $subsave += $sublength;
          $strings_in_acc{$s} = length ($string_acc) - $sublength;
          # append the last bit on the end.
          $string_acc .= substr ($s, $sublength);
          last OPTIMISER;
        }
        # or if the end of the new string overlaps the start of the
        # accumulator
        next unless substr ($string_acc, 0, $sublength)
          eq substr ($s, -$sublength);
        # well, the last $sublength characters of the accumulator match.
        # so as we're prepending to the accumulator, need to shift all our
        # existing offsets forwards
        $_ += $sublength foreach values %strings_in_acc;
        $subsave += $sublength;
        $strings_in_acc{$s} = 0;
        # append the first bit on the start.
        $string_acc = substr ($s, 0, -$sublength) . $string_acc;
        last OPTIMISER;
      }
    }
    # Optimiser (if it ran) found nothing, so just going have to tack the
    # whole thing on the end.
    $strings_in_acc{$s} = length $string_acc;
    $string_acc .= $s;
      };
    }
  }

  $strings = length $string_acc;
  my ($cpp) = compiler_info(0);
  my $var = $cpp ? '' : 'static';
  my $definition = &quot;\n$var const U8 $name\[$strings] = { &quot; .
    join(',',unpack &quot;C*&quot;,$string_acc);
  # We have a single long line. Split it at convenient commas.
  print $fh $1, &quot;\n&quot; while $definition =~ /\G(.{74,77},)/gcs;
  print $fh substr ($definition, pos $definition), &quot; };\n&quot;;
}

sub findstring {
  my ($name,$s) = @_;
  my $offset = $strings_in_acc{$s};
  die &quot;Can't find string &quot; . join (',',unpack &quot;C*&quot;,$s) . &quot; in accumulator&quot;
    unless defined $offset;
  &quot;$name + $offset&quot;;
}

sub outtable
{
 my ($fh,$a,$bigname) = @_;
 my $name = $a-&gt;{'Cname'};
 $a-&gt;{'Done'} = 1;
 foreach my $b (@{$a-&gt;{'Entries'}})
  {
   my ($s,$e,$out,$t,$end,$l) = @$b;
   outtable($fh,$t,$bigname) unless $t-&gt;{'Done'};
  }
 my ($cpp, $static) = compiler_info(0);
 my $count = scalar(@{$a-&gt;{'Entries'}});
 if ($static) {
     print $fh &quot;#ifdef __cplusplus\n&quot;; # -fpermissive since g++-6
     print $fh &quot;encpage_t $name\[$count] = {\n&quot;;
     print $fh &quot;#else\n&quot;;
     print $fh &quot;static const encpage_t $name\[$count] = {\n&quot;;
     print $fh &quot;#endif\n&quot;;
 } else {
   print $fh &quot;\nencpage_t $name\[$count] = {\n&quot;;
 }
 foreach my $b (@{$a-&gt;{'Entries'}})
  {
   my ($sc,$ec,$out,$t,$end,$l,$fb) = @$b;
   # $end |= 0x80 if $fb; # what the heck was on your mind, Nick?  -- Dan
   print  $fh &quot;{&quot;;
   if ($l)
    {
     printf $fh findstring($bigname,$out);
    }
   else
    {
     print  $fh &quot;0&quot;;
    }
   print  $fh &quot;,&quot;,$t-&gt;{Cname};
   printf $fh &quot;,0x%02x,0x%02x,$l,$end},\n&quot;,$sc,$ec;
  }
 print $fh &quot;};\n&quot;;
}

sub output_enc
{
 my ($fh,$name,$a) = @_;
 die &quot;Changed - fix me for new structure&quot;;
 foreach my $b (sort keys %$a)
  {
   my ($s,$e,$out,$t,$end,$l,$fb) = @{$a-&gt;{$b}};
  }
}

sub decode_U
{
 my $s = shift;
}

my @uname;
sub char_names{} # cf. https://rt.cpan.org/Ticket/Display.html?id=132471

sub output_ucm_page
{
  my ($cmap,$a,$t,$pre) = @_;
  # warn sprintf(&quot;Page %x\n&quot;,$pre);
  my $raw = $t-&gt;{Raw};
  foreach my $key (sort keys %$raw) {
    #  RAW_NEXT =&gt; 0,
    #  RAW_IN_LEN =&gt; 1,
    #  RAW_OUT_BYTES =&gt; 2,
    #  RAW_FALLBACK =&gt; 3,
    my ($next, $in_len, $out_bytes, $fallback) = @{$raw-&gt;{$key}};
    my $u = ord $key;
    $fallback ||= 0;

    if ($next != $a &amp;&amp; $next != $t) {
      output_ucm_page($cmap,$a,$next,(($pre|($u &amp;0x3F)) &lt;&lt; 6)&amp;0xFFFF);
    } elsif (length $out_bytes) {
      if ($pre) {
        $u = $pre|($u &amp;0x3f);
      }
      my $s = sprintf &quot;&lt;U%04X&gt; &quot;,$u;
      #foreach my $c (split(//,$out_bytes)) {
      #  $s .= sprintf &quot;\\x%02X&quot;,ord($c);
      #}
      # 9.5% faster changing that loop to this:
      $s .= sprintf +(&quot;\\x%02X&quot; x length $out_bytes), unpack &quot;C*&quot;, $out_bytes;
      $s .= sprintf &quot; |%d # %s\n&quot;,($fallback ? 1 : 0),$uname[$u];
      push(@$cmap,$s);
    } else {
      warn join(',',$u, @{$raw-&gt;{$key}},$a,$t);
    }
  }
}

sub output_ucm
{
 my ($fh,$name,$h,$rep,$min_el,$max_el) = @_;
 print $fh &quot;# $0 @orig_ARGV\n&quot; unless $opt{'q'};
 print $fh &quot;&lt;code_set_name&gt; \&quot;$name\&quot;\n&quot;;
 char_names();
 if (defined $min_el)
  {
   print $fh &quot;&lt;mb_cur_min&gt; $min_el\n&quot;;
  }
 if (defined $max_el)
  {
   print $fh &quot;&lt;mb_cur_max&gt; $max_el\n&quot;;
  }
 if (defined $rep)
  {
   print $fh &quot;&lt;subchar&gt; &quot;;
   foreach my $c (split(//,$rep))
    {
     printf $fh &quot;\\x%02X&quot;,ord($c);
    }
   print $fh &quot;\n&quot;;
  }
 my @cmap;
 output_ucm_page(\@cmap,$h,$h,0);
 print $fh &quot;#\nCHARMAP\n&quot;;
 foreach my $line (sort { substr($a,8) cmp substr($b,8) } @cmap)
  {
   print $fh $line;
  }
 print $fh &quot;END CHARMAP\n&quot;;
}

use vars qw(
    $_Enc2xs
    $_Version
    $_Inc
    $_E2X 
    $_Name
    $_TableFiles
    $_Now
);

sub find_e2x{
    eval { require File::Find; };
    my (@inc, %e2x_dir);
    for my $inc (@INC){
    push @inc, $inc unless $inc eq '.'; #skip current dir
    }
    File::Find::find(
         sub {
         my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
             $atime,$mtime,$ctime,$blksize,$blocks)
             = lstat($_) or return;
         -f _ or return;
         if (/^.*\.e2x$/o){
             no warnings 'once';
             $e2x_dir{$File::Find::dir} ||= $mtime;
         }
         return;
         }, @inc);
    warn join(&quot;\n&quot;, keys %e2x_dir), &quot;\n&quot;;
    for my $d (sort {$e2x_dir{$a} &lt;=&gt; $e2x_dir{$b}} keys %e2x_dir){
    $_E2X = $d;
    # warn &quot;$_E2X =&gt; &quot;, scalar localtime($e2x_dir{$d});
    return $_E2X;
    }
}

sub make_makefile_pl
{
    eval { require Encode } or die &quot;You need to install Encode to use enc2xs -M\nerror: $@\n&quot;;
    # our used for variable expansion
    $_Enc2xs = $0;
    $_Version = $VERSION;
    $_E2X = find_e2x();
    $_Name = shift;
    $_TableFiles = join(&quot;,&quot;, map {qq('$_')} @_);
    $_Now = scalar localtime();

    eval { require File::Spec; };
    _print_expand(File::Spec-&gt;catfile($_E2X,&quot;Makefile_PL.e2x&quot;),&quot;Makefile.PL&quot;);
    _print_expand(File::Spec-&gt;catfile($_E2X,&quot;_PM.e2x&quot;),        &quot;$_Name.pm&quot;);
    _print_expand(File::Spec-&gt;catfile($_E2X,&quot;_T.e2x&quot;),         &quot;t/$_Name.t&quot;);
    _print_expand(File::Spec-&gt;catfile($_E2X,&quot;README.e2x&quot;),     &quot;README&quot;);
    _print_expand(File::Spec-&gt;catfile($_E2X,&quot;Changes.e2x&quot;),    &quot;Changes&quot;);
    exit;
}

use vars qw(
        $_ModLines
        $_LocalVer
        );

sub make_configlocal_pm {
    eval { require Encode } or die &quot;Unable to require Encode: $@\n&quot;;
    eval { require File::Spec; };

    # our used for variable expantion
    my %in_core = map { $_ =&gt; 1 } (
        'ascii',      'iso-8859-1', 'utf8',
        'ascii-ctrl', 'null',       'utf-8-strict'
    );
    my %LocalMod = ();
    # check @enc;
    use File::Find ();
    my $wanted = sub{
	-f $_ or return;
	$File::Find::name =~ /\A\./        and return;
	$File::Find::name =~ /\.pm\z/      or  return;
	$File::Find::name =~ m/\bEncode\b/ or  return;
	my $mod = $File::Find::name;
	$mod =~ s/.*\bEncode\b/Encode/o;
	$mod =~ s/\.pm\z//o;
	$mod =~ s,/,::,og;
	eval qq{ require $mod; } or return;
        warn qq{ require $mod;\n};
	for my $enc ( Encode-&gt;encodings() ) {
	    no warnings;
	    $in_core{$enc}                   and next;
	    $Encode::Config::ExtModule{$enc} and next;
	    $LocalMod{$enc} ||= $mod;
	}
    };
    File::Find::find({wanted =&gt; $wanted}, @INC);
    $_ModLines = &quot;&quot;;
    for my $enc ( sort keys %LocalMod ) {
        $_ModLines .=
          qq(\$Encode::ExtModule{'$enc'} = &quot;$LocalMod{$enc}&quot;;\n);
    }
    warn $_ModLines if $_ModLines;
    $_LocalVer = _mkversion();
    $_E2X      = find_e2x();
    $_Inc      = $INC{&quot;Encode.pm&quot;};
    $_Inc =~ s/\.pm$//o;
    _print_expand( File::Spec-&gt;catfile( $_E2X, &quot;ConfigLocal_PM.e2x&quot; ),
        File::Spec-&gt;catfile( $_Inc, &quot;ConfigLocal.pm&quot; ), 1 );
    exit;
}

sub _mkversion{
    # v-string is now depreciated; use time() instead;
    #my ($ss,$mm,$hh,$dd,$mo,$yyyy) = localtime();
    #$yyyy += 1900, $mo +=1;
    #return sprintf(&quot;v%04d.%04d.%04d&quot;, $yyyy, $mo*100+$dd, $hh*100+$mm);
    return time();
}

sub _print_expand{
    eval { require File::Basename } or die &quot;File::Basename needed.  Are you on miniperl?;\nerror: $@\n&quot;;
    File::Basename-&gt;import();
    my ($src, $dst, $clobber) = @_;
    if (!$clobber and -e $dst){
    warn &quot;$dst exists. skipping\n&quot;;
    return;
    }
    warn &quot;Generating $dst...\n&quot;;
    open my $in, $src or die &quot;$src : $!&quot;;
    if ((my $d = dirname($dst)) ne '.'){
    -d $d or mkdir $d, 0755 or die  &quot;mkdir $d : $!&quot;;
    }	   
    open my $out, &quot;&gt;&quot;, $dst or die &quot;$!&quot;;
    my $asis = 0;
    while (&lt;$in&gt;){ 
    if (/^#### END_OF_HEADER/){
        $asis = 1; next;
    }	  
    s/(\$_[A-Z][A-Za-z0-9]+)_/$1/gee unless $asis;
    print $out $_;
    }
}
__END__

=head1 NAME

enc2xs -- Perl Encode Module Generator

=head1 SYNOPSIS

  enc2xs -[options]
  enc2xs -M ModName mapfiles...
  enc2xs -C

=head1 DESCRIPTION

F&lt;enc2xs&gt; builds a Perl extension for use by Encode from either
Unicode Character Mapping files (.ucm) or Tcl Encoding Files (.enc).
Besides being used internally during the build process of the Encode
module, you can use F&lt;enc2xs&gt; to add your own encoding to perl.
No knowledge of XS is necessary.

=head1 Quick Guide

If you want to know as little about Perl as possible but need to
add a new encoding, just read this chapter and forget the rest.

=over 4

=item 0.Z&lt;&gt;

Have a .ucm file ready.  You can get it from somewhere or you can write
your own from scratch or you can grab one from the Encode distribution
and customize it.  For the UCM format, see the next Chapter.  In the
example below, I'll call my theoretical encoding myascii, defined
in I&lt;my.ucm&gt;.  C&lt;$&gt; is a shell prompt.

  $ ls -F
  my.ucm

=item 1.Z&lt;&gt;

Issue a command as follows;

  $ enc2xs -M My my.ucm
  generating Makefile.PL
  generating My.pm
  generating README
  generating Changes

Now take a look at your current directory.  It should look like this.

  $ ls -F
  Makefile.PL   My.pm         my.ucm        t/

The following files were created.

  Makefile.PL - MakeMaker script
  My.pm       - Encode submodule
  t/My.t      - test file

=over 4

=item 1.1.Z&lt;&gt;

If you want *.ucm installed together with the modules, do as follows;

  $ mkdir Encode
  $ mv *.ucm Encode
  $ enc2xs -M My Encode/*ucm

=back

=item 2.Z&lt;&gt;

Edit the files generated.  You don't have to if you have no time AND no
intention to give it to someone else.  But it is a good idea to edit
the pod and to add more tests.

=item 3.Z&lt;&gt;

Now issue a command all Perl Mongers love:

  $ perl Makefile.PL
  Writing Makefile for Encode::My

=item 4.Z&lt;&gt;

Now all you have to do is make.

  $ make
  cp My.pm blib/lib/Encode/My.pm
  /usr/local/bin/perl /usr/local/bin/enc2xs -Q -O \
    -o encode_t.c -f encode_t.fnm
  Reading myascii (myascii)
  Writing compiled form
  128 bytes in string tables
  384 bytes (75%) saved spotting duplicates
  1 bytes (0.775%) saved using substrings
  ....
  chmod 644 blib/arch/auto/Encode/My/My.bs
  $

The time it takes varies depending on how fast your machine is and
how large your encoding is.  Unless you are working on something big
like euc-tw, it won't take too long.

=item 5.Z&lt;&gt;

You can &quot;make install&quot; already but you should test first.

  $ make test
  PERL_DL_NONLAZY=1 /usr/local/bin/perl -Iblib/arch -Iblib/lib \
    -e 'use Test::Harness  qw(&amp;runtests $verbose); \
    $verbose=0; runtests @ARGV;' t/*.t
  t/My....ok
  All tests successful.
  Files=1, Tests=2,  0 wallclock secs
   ( 0.09 cusr + 0.01 csys = 0.09 CPU)

=item 6.Z&lt;&gt;

If you are content with the test result, just &quot;make install&quot;

=item 7.Z&lt;&gt;

If you want to add your encoding to Encode's demand-loading list
(so you don't have to &quot;use Encode::YourEncoding&quot;), run

  enc2xs -C

to update Encode::ConfigLocal, a module that controls local settings.
After that, &quot;use Encode;&quot; is enough to load your encodings on demand.

=back

=head1 The Unicode Character Map

Encode uses the Unicode Character Map (UCM) format for source character
mappings.  This format is used by IBM's ICU package and was adopted
by Nick Ing-Simmons for use with the Encode module.  Since UCM is
more flexible than Tcl's Encoding Map and far more user-friendly,
this is the recommended format for Encode now.

A UCM file looks like this.

  #
  # Comments
  #
  &lt;code_set_name&gt; &quot;US-ascii&quot; # Required
  &lt;code_set_alias&gt; &quot;ascii&quot;   # Optional
  &lt;mb_cur_min&gt; 1             # Required; usually 1
  &lt;mb_cur_max&gt; 1             # Max. # of bytes/char
  &lt;subchar&gt; \x3F             # Substitution char
  #
  CHARMAP
  &lt;U0000&gt; \x00 |0 # &lt;control&gt;
  &lt;U0001&gt; \x01 |0 # &lt;control&gt;
  &lt;U0002&gt; \x02 |0 # &lt;control&gt;
  ....
  &lt;U007C&gt; \x7C |0 # VERTICAL LINE
  &lt;U007D&gt; \x7D |0 # RIGHT CURLY BRACKET
  &lt;U007E&gt; \x7E |0 # TILDE
  &lt;U007F&gt; \x7F |0 # &lt;control&gt;
  END CHARMAP

=over 4

=item *

Anything that follows C&lt;#&gt; is treated as a comment.

=item *

The header section continues until a line containing the word
CHARMAP. This section has a form of I&lt;E&lt;lt&gt;keywordE&lt;gt&gt; value&gt;, one
pair per line.  Strings used as values must be quoted. Barewords are
treated as numbers.  I&lt;\xXX&gt; represents a byte.

Most of the keywords are self-explanatory. I&lt;subchar&gt; means
substitution character, not subcharacter.  When you decode a Unicode
sequence to this encoding but no matching character is found, the byte
sequence defined here will be used.  For most cases, the value here is
\x3F; in ASCII, this is a question mark.

=item *

CHARMAP starts the character map section.  Each line has a form as
follows:

  &lt;UXXXX&gt; \xXX.. |0 # comment
    ^     ^      ^
    |     |      +- Fallback flag
    |     +-------- Encoded byte sequence
    +-------------- Unicode Character ID in hex

The format is roughly the same as a header section except for the
fallback flag: | followed by 0..3.   The meaning of the possible
values is as follows:

=over 4

=item |0 

Round trip safe.  A character decoded to Unicode encodes back to the
same byte sequence.  Most characters have this flag.

=item |1

Fallback for unicode -&gt; encoding.  When seen, enc2xs adds this
character for the encode map only.

=item |2 

Skip sub-char mapping should there be no code point.

=item |3 

Fallback for encoding -&gt; unicode.  When seen, enc2xs adds this
character for the decode map only.

=back

=item *

And finally, END OF CHARMAP ends the section.

=back

When you are manually creating a UCM file, you should copy ascii.ucm
or an existing encoding which is close to yours, rather than write
your own from scratch.

When you do so, make sure you leave at least B&lt;U0000&gt; to B&lt;U0020&gt; as
is, unless your environment is EBCDIC.

B&lt;CAVEAT&gt;: not all features in UCM are implemented.  For example,
icu:state is not used.  Because of that, you need to write a perl
module if you want to support algorithmical encodings, notably
the ISO-2022 series.  Such modules include L&lt;Encode::JP::2022_JP&gt;,
L&lt;Encode::KR::2022_KR&gt;, and L&lt;Encode::TW::HZ&gt;.

=head2 Coping with duplicate mappings

When you create a map, you SHOULD make your mappings round-trip safe.
That is, C&lt;encode('your-encoding', decode('your-encoding', $data)) eq
$data&gt; stands for all characters that are marked as C&lt;|0&gt;.  Here is
how to make sure:

=over 4

=item * 

Sort your map in Unicode order.

=item *

When you have a duplicate entry, mark either one with '|1' or '|3'.
  
=item * 

And make sure the '|1' or '|3' entry FOLLOWS the '|0' entry.

=back

Here is an example from big5-eten.

  &lt;U2550&gt; \xF9\xF9 |0
  &lt;U2550&gt; \xA2\xA4 |3

Internally Encoding -&gt; Unicode and Unicode -&gt; Encoding Map looks like
this;

  E to U               U to E
  --------------------------------------
  \xF9\xF9 =&gt; U2550    U2550 =&gt; \xF9\xF9
  \xA2\xA4 =&gt; U2550
 
So it is round-trip safe for \xF9\xF9.  But if the line above is upside
down, here is what happens.

  E to U               U to E
  --------------------------------------
  \xA2\xA4 =&gt; U2550    U2550 =&gt; \xF9\xF9
  (\xF9\xF9 =&gt; U2550 is now overwritten!)

The Encode package comes with F&lt;ucmlint&gt;, a crude but sufficient
utility to check the integrity of a UCM file.  Check under the
Encode/bin directory for this.

When in doubt, you can use F&lt;ucmsort&gt;, yet another utility under
Encode/bin directory.

=head1 Bookmarks

=over 4

=item *

ICU Home Page 
L&lt;http://www.icu-project.org/&gt;

=item *

ICU Character Mapping Tables
L&lt;http://site.icu-project.org/charts/charset&gt;

=item *

ICU:Conversion Data
L&lt;http://www.icu-project.org/userguide/conversion-data.html&gt;

=back

=head1 SEE ALSO

L&lt;Encode&gt;,
L&lt;perlmod&gt;,
L&lt;perlpod&gt;

=cut

# -Q to disable the duplicate codepoint test
# -S make mapping errors fatal
# -q to remove comments written to output files
# -O to enable the (brute force) substring optimiser
# -o &lt;output&gt; to specify the output file name (else it's the first arg)
# -f &lt;inlist&gt; to give a file with a list of input files (else use the args)
# -n &lt;name&gt; to name the encoding (else use the basename of the input file.

With %seen holding array refs:

      865.66 real        28.80 user         8.79 sys
      7904  maximum resident set size
      1356  average shared memory size
     18566  average unshared data size
       229  average unshared stack size
     46080  page reclaims
     33373  page faults

With %seen holding simple scalars:

      342.16 real        27.11 user         3.54 sys
      8388  maximum resident set size
      1394  average shared memory size
     14969  average unshared data size
       236  average unshared stack size
     28159  page reclaims
      9839  page faults

Yes, 5 minutes is faster than 15. Above is for CP936 in CN. Only difference is
how %seen is storing things its seen. So it is pathalogically bad on a 16M
RAM machine, but it's going to help even on modern machines.
Swapping is bad, m'kay :-)
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>