<h2>Editing File: /usr/local/cpanel/3rdparty/perl/542/bin/spamd</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/local/cpanel/3rdparty/perl/542/bin/perl -T -w
# &lt;@LICENSE&gt;
# Licensed to the Apache Software Foundation (ASF) under one or more
# contributor license agreements.  See the NOTICE file distributed with
# this work for additional information regarding copyright ownership.
# The ASF licenses this file to you under the Apache License, Version 2.0
# (the &quot;License&quot;); you may not use this file except in compliance with
# the License.  You may obtain a copy of the License at:
# 
#     http://www.apache.org/licenses/LICENSE-2.0
# 
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an &quot;AS IS&quot; BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
# &lt;/@LICENSE&gt;

#IMPORTANT: The order of -T -w above is important for spamd_hup.t on Solaris 10 - changed per bug 6883

use strict;
use warnings;
use re 'taint';

my @ORIG_INC_OPTS;
BEGIN {
  # bug 8030 - Save what is in @INC to capture any -I arguments passed in to use at SIGHUP restart
  # This is done before any use lib statements add anything else to @INC
  my %orig_inc;
  for (my $i = $#INC; $i &gt;=0; $i--) {
    my $path = $INC[$i];
    if (!$orig_inc{$path}) { # more stringent checking will done later after more modules are loaded
       $orig_inc{$path} = 1;
       unshift(@ORIG_INC_OPTS, $path);
    }
  }
}

my $PREFIX          = '/usr/local/cpanel/3rdparty/perl/542/lib';             # substituted at 'make' time
my $DEF_RULES_DIR   = '/usr/share/spamassassin';      # substituted at 'make' time
my $LOCAL_RULES_DIR = '/etc/mail/spamassassin';    # substituted at 'make' time
my $LOCAL_STATE_DIR = '/var/lib/spamassassin';    # substituted at 'make' time
use lib '/usr/local/cpanel/3rdparty/perl/542/cpanel-lib';                   # substituted at 'make' time

# added by jm for use inside the distro
# This is disabled during the &quot;make install&quot; process.
BEGIN {
}

our ($have_getaddrinfo_in_core, $have_getaddrinfo_legacy, $io_socket_module_name,
     $have_inet4, $have_inet6, $ai_addrconfig_flag);

BEGIN {
    eval q/require IO::Socket::INET6/; # enforce IO::Socket::INET6 to be compiled in when available
}
# don't force requirement on IO::Socket::IP or IO::Socket::INET6
BEGIN {
  require Socket;
  $have_getaddrinfo_in_core = eval {
    # The Socket module (1.94) bundled with Perl 5.14.* provides
    # new affordances for IPv6, including implementations of the
    # Socket::getaddrinfo() and Socket::getnameinfo() functions,
    # along with related constants and a handful of new functions.
    # Perl 5.16.0 upgrades the core Socket module to version 2.001.
  # Socket-&gt;VERSION(1.94);  # provides getaddrinfo() and getnameinfo()
  # Socket-&gt;VERSION(1.95);  # provides AI_ADDRCONFIG
    Socket-&gt;VERSION(1.96);  # provides NIx_NOSERV, and Exporter tag :addrinfo
  # Socket-&gt;VERSION(1.97);  # IO::Socket::IP depends on Socket 1.97
    Socket-&gt;import(qw(/^(?:AI|NI|NIx|EAI)_/));

    # AUTOLOADing 'constants' here enables inlining - see Exporter man page
    &amp;AI_ADDRCONFIG; &amp;AI_PASSIVE;
    &amp;NI_NUMERICHOST, &amp;NI_NUMERICSERV; &amp;NIx_NOSERV; 1;
  };

  $have_getaddrinfo_legacy = !$have_getaddrinfo_in_core &amp;&amp; eval {
    require Socket6;
  # Socket6-&gt;VERSION(0.13);  # provides NI_NAMEREQD
    Socket6-&gt;VERSION(0.18);  # provides AI_NUMERICSERV
    Socket6-&gt;import(qw(/^(?:AI|NI|NIx|EAI)_/));
    &amp;AI_ADDRCONFIG; &amp;AI_PASSIVE;  # enable inlining
    &amp;NI_NUMERICHOST; &amp;NI_NUMERICSERV; &amp;NI_NAMEREQD; 1;
  };

  Socket-&gt;import(qw(:DEFAULT IPPROTO_TCP));

  &amp;SOCK_STREAM; &amp;IPPROTO_TCP; &amp;SOMAXCONN; # enable inlining

  &amp;AF_UNSPEC; &amp;AF_INET; &amp;AF_INET6;  # enable inlining

  $ai_addrconfig_flag = 0;

  if ($have_getaddrinfo_in_core) {
    # using a modern Socket module

    eval {  # does the operating system recognize an AI_ADDRCONFIG flag?
      if (&amp;AI_ADDRCONFIG &amp;&amp; &amp;EAI_BADFLAGS) {
        my($err, @res) = Socket::getaddrinfo(&quot;localhost&quot;, 0,
                           { family =&gt; &amp;AF_UNSPEC, flags =&gt; &amp;AI_ADDRCONFIG });
        $ai_addrconfig_flag = &amp;AI_ADDRCONFIG if !$err || $err != &amp;EAI_BADFLAGS;
      }
    };

    *ip_or_name_to_ip_addresses = sub {
      my($addr, $ai_family) = @_;
      # Socket::getaddrinfo returns a list of hashrefs
      my($error, @res) =
        Socket::getaddrinfo($addr, 0,
          { family =&gt; $ai_family, flags =&gt; $ai_addrconfig_flag | &amp;AI_PASSIVE, 
            socktype =&gt; &amp;SOCK_STREAM, protocol =&gt; &amp;IPPROTO_TCP });
      my(@ip_addrs);
      if (!$error) {
        for my $a (@res) {
          my($err, $ip_addr) =
            Socket::getnameinfo($a-&gt;{addr},
                                &amp;NI_NUMERICHOST | &amp;NI_NUMERICSERV, &amp;NIx_NOSERV);
          if (!$err) { push(@ip_addrs, $ip_addr) }
          elsif (!$error) { $error = $err }
        }
      }
      return ($error, @ip_addrs);
    };

    *peer_info_from_socket = sub {
      my $sock = shift;
      my $peer_addr = $sock-&gt;peerhost;  # textual representation of an IP addr
      $peer_addr or return;
      my $peer_hostname;
      if ($sock-&gt;UNIVERSAL::can('peerhostname')) {
        $peer_hostname = $sock-&gt;peerhostname;  # provided by IO::Socket::IP
      } else {
        my($err, $host) = Socket::getnameinfo($sock-&gt;peername,
                                              &amp;NI_NAMEREQD, &amp;NIx_NOSERV);
        $peer_hostname = $host  if !$err;
      }
      return ($sock-&gt;peerport, $peer_addr, $peer_hostname||$peer_addr,
              $sock-&gt;sockport);
    };

  } elsif ($have_getaddrinfo_legacy) {
    # using a legacy Socket6 module; somewhat different API on getaddrinfo()
    # and getnameinfo() compared to these functions in a module Socket

    eval {  # does the operating system recognize an AI_ADDRCONFIG flag?
      if (&amp;AI_ADDRCONFIG &amp;&amp; &amp;EAI_BADFLAGS) {
        my @res = Socket6::getaddrinfo(&quot;localhost&quot;, &quot;&quot;, 0, &amp;SOCK_STREAM,
                                       &amp;IPPROTO_TCP, &amp;AI_ADDRCONFIG);
        my $err = @res &gt;= 5 ? 0 : $res[0];
        $ai_addrconfig_flag = &amp;AI_ADDRCONFIG if !$err || $err != &amp;EAI_BADFLAGS;
      }
    };

    *ip_or_name_to_ip_addresses = sub {
      my($addr, $ai_family) = @_;
      # Socket6::getaddrinfo returns a list of quintuples
      my @res = Socket6::getaddrinfo($addr, '',
                                     $ai_family, &amp;SOCK_STREAM, &amp;IPPROTO_TCP,
                                     $ai_addrconfig_flag | &amp;AI_PASSIVE);
      my($error, @ip_addrs);
      if (@res &lt; 5) {
        $error = $res[0];
      } else {
        my($family, $socktype, $proto, $saddr, $canonname);
        while (@res &gt;= 5) {
          ($family, $socktype, $proto, $saddr, $canonname, @res) = @res;
          my(@resinfo) =
            Socket6::getnameinfo($saddr, &amp;NI_NUMERICHOST | &amp;NI_NUMERICSERV);
          if (@resinfo &gt;= 2) { push(@ip_addrs, $resinfo[0]) }
          elsif (!$error) { $error = $resinfo[0] }
        }
      }
      return ($error, @ip_addrs);
    };

    *peer_info_from_socket = sub {
      my $sock = shift;
      my $peer_addr = $sock-&gt;peerhost;
      $peer_addr or return;
      my @resinfo = (Socket6::getnameinfo($sock-&gt;peername, &amp;NI_NAMEREQD))[0];
      my $peer_hostname = @resinfo &gt; 1 ? $resinfo[0] : undef;
      return ($sock-&gt;peerport, $peer_addr, $peer_hostname||$peer_addr,
              $sock-&gt;sockport);
    };

  } else {  # IPv4 only, no getaddrinfo() available

    *ip_or_name_to_ip_addresses = sub {
      my($addr, $ai_family) = @_;
      $ai_family == &amp;AF_UNSPEC || $ai_family == &amp;AF_INET
        or die &quot;Protocol family $ai_family not supported on this platform&quot;;
      my($error, @ip_addrs, @binaddr);
      $! = 0; my @res = gethostbyname($addr);
      if (!@res) {
        $error = &quot;no results from gethostbyname $!&quot;;
      } else {
        my($name,$aliases,$addrtype,$length);
        ($name,$aliases,$addrtype,$length,@binaddr) = @res;
      }
      if (!@binaddr) {
        $error = &quot;no such host&quot;;
      } else {
        for (@binaddr) {
          my $ip_addr = Socket::inet_ntoa($_);
          push(@ip_addrs, $ip_addr)  if $ip_addr;
        }
      }
      return ($error, @ip_addrs);
    };

    *peer_info_from_socket = sub {
      my $sock = shift;
      my ($peer_port, $in_addr) = Socket::sockaddr_in($sock-&gt;peername)
        or return;
      my $peer_addr = Socket::inet_ntoa($in_addr) or return;
      my $peer_hostname = gethostbyaddr($in_addr, &amp;AF_INET);
      return ($peer_port, $peer_addr, $peer_hostname||$peer_addr,
              $sock-&gt;sockport);
    };

  }

  if (eval { require IO::Socket::IP }) {  # handles IPv6 and IPv4
    IO::Socket::IP-&gt;VERSION(0.09);  # implements IPV6_V6ONLY
    $io_socket_module_name = 'IO::Socket::IP';

  } elsif (eval { require IO::Socket::INET6 }) {  # handles IPv6 and IPv4
    $io_socket_module_name = 'IO::Socket::INET6';

  } elsif (eval { require IO::Socket::INET }) {  # IPv4 only
    $io_socket_module_name = 'IO::Socket::INET';
  }

  $have_inet4 =  # can we create a PF_INET socket?
    defined $io_socket_module_name &amp;&amp; eval {  
      my $sock =
        $io_socket_module_name-&gt;new(LocalAddr =&gt; '0.0.0.0', Proto =&gt; 'tcp');
      $sock-&gt;close or die &quot;error closing socket: $!&quot;  if $sock;
      $sock ? 1 : undef;
    };

  $have_inet6 =  # can we create a PF_INET6 socket?
    defined $io_socket_module_name &amp;&amp;
    $io_socket_module_name ne 'IO::Socket::INET' &amp;&amp;
    eval {
      my $sock =
        $io_socket_module_name-&gt;new(LocalAddr =&gt; '::', Proto =&gt; 'tcp');
      $sock-&gt;close or die &quot;error closing socket: $!&quot;  if $sock;
      $sock ? 1 : undef;
    };

}

use IO::Handle;
use IO::Pipe;
use IO::File ();

use Mail::SpamAssassin;
use Mail::SpamAssassin::NetSet;
use Mail::SpamAssassin::SubProcBackChannel;
use Mail::SpamAssassin::SpamdForkScaling qw(:pfstates);
use Mail::SpamAssassin::Logger qw(:DEFAULT log_message);
use Mail::SpamAssassin::Util qw(untaint_var untaint_file_path secure_tmpdir
                                exit_status_str am_running_on_windows
                                get_user_groups force_die);
use Mail::SpamAssassin::Timeout;

use Getopt::Long;
use POSIX qw(:sys_wait_h);
use POSIX qw(locale_h setsid sigprocmask);
use Errno;
use Fcntl qw(:flock);

use Cwd ();
use File::Spec 0.8;
use File::Path;
use Carp ();
use Time::HiRes qw(time);

use constant RUNNING_ON_MACOS =&gt; ($^O =~ /^darwin/oi);

# Check to make sure the script version and the module version matches.
# If not, die here!  Also, deal with unchanged VERSION macro.
if ($Mail::SpamAssassin::VERSION ne '4.000001' &amp;&amp; '4.000001' ne &quot;\@\@VERSION\@\@&quot;) {
  die 'spamd: spamd script is v4.000001, but using modules v'.$Mail::SpamAssassin::VERSION.&quot;\n&quot;;
}

# Bug 3062: SpamAssassin should be &quot;locale safe&quot;
POSIX::setlocale(LC_TIME,'C');

my %resphash = (
  EX_OK          =&gt; 0,     # no problems
  EX_USAGE       =&gt; 64,    # command line usage error
  EX_DATAERR     =&gt; 65,    # data format error
  EX_NOINPUT     =&gt; 66,    # cannot open input
  EX_NOUSER      =&gt; 67,    # addressee unknown
  EX_NOHOST      =&gt; 68,    # host name unknown
  EX_UNAVAILABLE =&gt; 69,    # service unavailable
  EX_SOFTWARE    =&gt; 70,    # internal software error
  EX_OSERR       =&gt; 71,    # system error (e.g., can't fork)
  EX_OSFILE      =&gt; 72,    # critical OS file missing
  EX_CANTCREAT   =&gt; 73,    # can't create (user) output file
  EX_IOERR       =&gt; 74,    # input/output error
  EX_TEMPFAIL    =&gt; 75,    # temp failure; user is invited to retry
  EX_PROTOCOL    =&gt; 76,    # remote error in protocol
  EX_NOPERM      =&gt; 77,    # permission denied
  EX_CONFIG      =&gt; 78,    # configuration error
  EX_TIMEOUT     =&gt; 79,    # read timeout
);

sub print_version {
  printf(&quot;SpamAssassin Server version %s\n&quot;, Mail::SpamAssassin::Version());
  printf(&quot;  running on Perl %s\n&quot;,
         join(&quot;.&quot;, map( 0+($_||0), ($] =~ /(\d)\.(\d{3})(\d{3})?/) )));
  eval { require IO::Socket::SSL; };
  printf(&quot;  with SSL support (%s %s)\n&quot;, &quot;IO::Socket::SSL&quot;, $IO::Socket::SSL::VERSION) unless ($@);
  eval { require Compress::Zlib; };
  printf(&quot;  with zlib support (%s %s)\n&quot;, &quot;Compress::Zlib&quot;, $Compress::Zlib::VERSION) unless ($@);
}

sub print_usage_and_exit {
  my ( $message, $respnam ) = (@_);
  $respnam ||= 'EX_USAGE';

  if ($respnam eq 'EX_OK' ) {
    print_version();
    print(&quot;\n&quot;);
  }

  require Pod::Usage;
  Pod::Usage-&gt;import;
  pod2usage(
    -verbose =&gt; 0,
    -message =&gt; $message,
    -exitval =&gt; $resphash{$respnam},
  );
}

# defaults
my %opt = (
  'user-config'   =&gt; 1,
  # scaling settings; some of these aren't actually settable via cmdline
  'server-scale-period' =&gt; 2,   # how often to scale the # of kids, secs
  'min-children'  =&gt; 1,         # min kids to have running
  'min-spare'     =&gt; 1,         # min kids that must be spare
  'max-spare'     =&gt; 2,         # max kids that should be spare
  'pre'           =&gt; [],        # extra .pre lines
  'cf'            =&gt; [],        # extra config lines
);


# bug 1725, 2192:
# Untaint all command-line options and ENV vars, since spamd is launched
# as a daemon from a known-safe environment. Also store away some of the
# vars we need for a SIGHUP later on.

# Testing for taintedness only works before detainting %ENV
Mail::SpamAssassin::Util::am_running_in_taint_mode();

# First clean PATH and untaint the environment -- need to do this before
# Cwd::cwd(), else it will croak.
Mail::SpamAssassin::Util::clean_path_in_taint_mode();
untaint_var( \%ENV );

# The zeroth argument will be replaced in daemonize().
my $ORIG_ARG0 = untaint_var($0);

# Getopt::Long clears all arguments it processed (untaint both @ARGVs here!)
my @ORIG_ARGV = untaint_var( \@ARGV );

# daemonize() switches to the root later on and we need to come back here
# somehow -- untaint the dir to be on the safe side.
my $ORIG_CWD = untaint_var( Cwd::cwd() );

prepare_for_sighup_restart();

# Parse the command line
Getopt::Long::Configure(&quot;bundling&quot;);
GetOptions(
  'allow-tell'               =&gt; \$opt{'tell'},
  'allowed-ips|A=s'          =&gt; \@{ $opt{'allowed-ip'} },
  'configpath|C=s'           =&gt; \$opt{'configpath'},
  'c'                        =&gt; \$opt{'create-prefs'},
  'create-prefs!'            =&gt; \$opt{'create-prefs'},
  'daemonize!'               =&gt; \$opt{'daemonize'},
  'debug|D:s'                =&gt; \$opt{'debug'},
  'default-user|U=s'         =&gt; \$opt{'default-user'},
  'd'                        =&gt; \$opt{'daemonize'},
  'groupname|g=s'            =&gt; \$opt{'groupname'},
  'helper-home-dir|H:s'      =&gt; \$opt{'home_dir_for_helpers'},
  'help|h'                   =&gt; \$opt{'help'},
  '4|ipv4only|ipv4-only|ipv4'=&gt; sub { $opt{'force_ipv4'} = 1;
                                      $opt{'force_ipv6'} = 0; },
  '6'                        =&gt; sub { $opt{'force_ipv6'} = 1;
                                      $opt{'force_ipv4'} = 0; },
  'ldap-config!'             =&gt; \$opt{'ldap-config'},
  'listen|listen-ip|ip-address|i:s' =&gt; \@{ $opt{'listen-sockets'} },
  'local!'                   =&gt; \$opt{'local'},
  'L'                        =&gt; \$opt{'local'},
  'l'                        =&gt; \$opt{'tell'},
  'round-robin!'             =&gt; \$opt{'round-robin'},
  'min-children=i'           =&gt; \$opt{'min-children'},
  'max-children|m=i'         =&gt; \$opt{'max-children'},
  'min-spare=i'              =&gt; \$opt{'min-spare'},
  'max-spare=i'              =&gt; \$opt{'max-spare'},
  'max-conn-per-child=i'     =&gt; \$opt{'max-conn-per-child'},
  'nouser-config|x'          =&gt; sub { $opt{'user-config'} = 0 },
  'paranoid!'                =&gt; \$opt{'paranoid'},
  'P'                        =&gt; \$opt{'paranoid'},
  'pidfile|r=s'              =&gt; \$opt{'pidfile'},
  'port|p=s'                 =&gt; \$opt{'port'},
  'Q'                        =&gt; \$opt{'setuid-with-sql'},
  'q'                        =&gt; \$opt{'sql-config'},
  'server-cert=s'            =&gt; \$opt{'server-cert'},
  'server-key=s'             =&gt; \$opt{'server-key'},
  'setuid-with-ldap'         =&gt; \$opt{'setuid-with-ldap'},
  'setuid-with-sql'          =&gt; \$opt{'setuid-with-sql'},
  'siteconfigpath=s'         =&gt; \$opt{'siteconfigpath'},
  'pre=s'                    =&gt; \@{$opt{'pre'}},
  'cf=s'                     =&gt; \@{$opt{'cf'}},
  'socketgroup=s'            =&gt; \$opt{'socketgroup'},
  'socketmode=s'             =&gt; \$opt{'socketmode'},
  'socketowner=s'            =&gt; \$opt{'socketowner'},
  'socketpath=s'             =&gt; \$opt{'socketpath'},
  'sql-config!'              =&gt; \$opt{'sql-config'},
  'ssl'                      =&gt; \$opt{'ssl'},
  'ssl-verify'               =&gt; \$opt{'ssl-verify'},
  'ssl-ca-file=s'            =&gt; \$opt{'ssl-ca-file'},
  'ssl-ca-path=s'            =&gt; \$opt{'ssl-ca-path'},
  'ssl-port=s'               =&gt; \$opt{'ssl-port'},
  'syslog-socket=s'          =&gt; \$opt{'syslog-socket'},
  'syslog|s=s'               =&gt; \$opt{'syslog'},
  'log-timestamp-fmt:s'      =&gt; \$opt{'log-timestamp-fmt'},
  'timeout-tcp|T=i'          =&gt; \$opt{'timeout-tcp'},
  'timeout-child|t=i'        =&gt; \$opt{'timeout-child'},
  'timing'                   =&gt; \$opt{'timing'},
  'user-config'              =&gt; \$opt{'user-config'},
  'username|u=s'             =&gt; \$opt{'username'},
  'version|V'                =&gt; \$opt{'version'},
  'virtual-config-dir=s'     =&gt; \$opt{'virtual-config-dir'},
  'v'                        =&gt; \$opt{'vpopmail'},
  'vpopmail!'                =&gt; \$opt{'vpopmail'},

  # cPanel options
  'start-dormant'            =&gt; \$opt{'start-dormant'}, # used to switch faster to dormant mode

  #
  # NOTE: These are old options.  We should ignore (but warn about)
  # the ones that are now defaults.  Everything else gets a die (see note2)
  # so the user doesn't get us doing something they didn't expect.
  #
  # NOTE2: 'die' doesn't actually stop the process, GetOptions() catches
  # it, then passes the error on, so we'll end up doing a Usage statement.
  # You can avoid that by doing an explicit exit in the sub.
  #
  
  # last in 2.3
  'F:i'                   =&gt; sub { warn &quot;spamd: the -F option has been removed from spamd, please remove from your commandline and re-run\n&quot;; exit 2; },
  'add-from!'             =&gt; sub { warn &quot;spamd: the --add-from option has been removed from spamd, please remove from your commandline and re-run\n&quot;; exit 2; },

  # last in 2.4
  'stop-at-threshold|S' =&gt; sub { warn &quot;spamd: the -S option has been deprecated and is no longer supported, ignoring\n&quot; },

) or print_usage_and_exit();

if ($opt{'help'}) {
  print_usage_and_exit(qq{For more details, use &quot;man spamd&quot;.\n}, 'EX_OK');
}
if ($opt{'version'}) {
  print_version();
  exit($resphash{'EX_OK'});
}

if (!defined $opt{'default-user'}) {
  $opt{'default-user'} = 'nobody';
}

my $log_timestamp_fmt = $opt{'log-timestamp-fmt'};
if (defined $log_timestamp_fmt &amp;&amp; lc($log_timestamp_fmt) eq 'default') {
  undef $log_timestamp_fmt;  # undefined implies per-logger's default
}
if (defined $log_timestamp_fmt) {
  # a nondefault timestamp format was specified, need to reopen stderr logger
  Mail::SpamAssassin::Logger::remove('stderr');
  Mail::SpamAssassin::Logger::add(method =&gt; 'stderr',
				  timestamp_fmt =&gt; $log_timestamp_fmt,
				  escape =&gt; 1);
}

# Enable debugging, if any areas were specified.  We do this already here,
# accessing some non-public API so we can use the convenient dbg() routine.
# Don't do this at home (aka any 3rd party tools), kids!
if (defined $opt{'debug'}) {
  $opt{'debug'} ||= 'all';
}
# always turn on at least info-level debugging for spamd
$opt{'debug'} ||= 'info';
# turn on debugging facilities as soon as possible
Mail::SpamAssassin::Logger::add_facilities($opt{'debug'});

# bug 2228: make the values of (almost) all parameters which accept file paths
# absolute, so they are still valid after daemonize()
foreach my $opt (
  qw(
  configpath
  siteconfigpath
  socketpath
  pidfile
  home_dir_for_helpers
  )
  )
{
  # rel2abs taints the new value!
  $opt{$opt} =
    untaint_file_path(File::Spec-&gt;rel2abs( $opt{$opt} )) if $opt{$opt};
}

# These can be changed on command line with -A flag
my $allowed_nets = Mail::SpamAssassin::NetSet-&gt;new();
if ( @{ $opt{'allowed-ip'} } ) {
  set_allowed_ip( grep length, map { split /,/ } @{ $opt{'allowed-ip'} } );
} else {
  set_allowed_ip('127.0.0.1', '::1');
}

### Begin initialization of logging ########################

# The syslog facility can be changed on the command line with the
# --syslog flag. Special cases are:
# * A log facility of 'stderr' will log to STDERR
# * &quot; &quot;   &quot;        &quot;  'null' disables all logging
# * &quot; &quot;   &quot;        &quot;  'file' logs to the file &quot;spamd.log&quot;
# * Any facility containing non-word characters is interpreted as the name
#   of a specific logfile
my $log_facility = $opt{'syslog'} || 'mail';

# The --syslog-socket option specifies one of the possible socket types or
# logging mechanisms as accepted by the Sys::Syslog::setlogsock() subroutine.
# Depending on a version of Sys::Syslog and on the underlying operating system,
# one of the following values (or their subset) can be used: native, eventlog,
# tcp, udp, inet, unix, stream, pipe, console. The value 'eventlog' is
# specific to Win32 events logger and requires a perl module Win32::EventLog.
#
# In addition to values acceptable by Sys::Syslog::setlogsock(),
# a --syslog-socket=none is mapped to --syslog=stderr and $log_socket='file'.
#
# A value 'file' in variable $log_socket implies logging to any file handler
# (either a specific log file or STDERR), A value 'none' in $log_socket
# represents no logging, equivalent to --syslog=null.
#
# (old text: The socket to log over can be changed on the command line with
#  the --syslog-socket flag. Logging to any file handler (either a specific log
#  file or STDERR) is internally represented by a socket 'file', no logging
#  at all is 'none'. The latter is different from --syslog-socket=none which
#  gets mapped to --syslog=stderr and such --syslog-socket=file. An internal
#  socket of 'none' means as much as --syslog=null. Sounds complicated? It is.
#  But it works.
# )

my $log_socket = $opt{'syslog-socket'};

if (!defined $log_socket || $log_socket eq '') {
  $log_socket = am_running_on_windows() ? 'none' : 'unix';
} else {
  $log_socket = lc $log_socket;
}

# This is the default log file; it can be changed on the command line
# via a --syslog flag containing non-word characters.
my $log_file = &quot;spamd.log&quot;;

# A specific log file was given (--syslog=/path/to/file).
if ($log_facility =~ /[^a-z0-9]/) {
  $log_file = $log_facility;
  $log_socket = 'file';
}
# The generic log file was requested (--syslog=file).
elsif (lc($log_facility) eq 'file') {
  $log_socket = 'file';
}
# The casing is kept only if the facility specified a file.
else {
  $log_facility = lc($log_facility);
}

# Either above or at the command line the socket was set
# to 'file' (--syslog-socket=file).
if ($log_socket eq 'file') {
  $log_facility = 'file';
}
# The socket 'none' (--syslog-socket=none) historically
# represents logging to STDERR.
elsif ($log_socket eq 'none') {
  $log_facility = 'stderr';
}

# Either above or at the command line the facility was set
# to 'stderr' (--syslog=stderr).
if ($log_facility eq 'stderr') {
  $log_socket = 'file';
}

# The --log-timestamp-fmt option can provide a POSIX strftime(3) format for
# timestamps included in each logged message. Each logger (stderr, file,
# syslog) has its own default value for a timestamp format, which applies when
# --log-timestamp-fmt option is not given, or with --log-timestamp-fmt=default 	
# Timestamps can be turned off by specifying an empty string with this
# option, e.g. --log-timestamp-fmt='' or just --log-timestamp-fmt=
# Typical use: --log-timestamp-fmt='%a %b %e %H:%M:%S %Y' .

# Logging via syslog is requested.
if ($log_socket ne 'file' &amp;&amp; $log_facility ne 'null') {
  if (!Mail::SpamAssassin::Logger::add(method =&gt; 'syslog',
				       socket =&gt; $log_socket,
				       facility =&gt; $log_facility,
				       ident =&gt; 'spamd',
				       timestamp_fmt =&gt; $log_timestamp_fmt,
				       escape =&gt; 1))
  {
    # syslog method failed 
    $log_facility = 'stderr';
  }
}
# Otherwise, the user wants to log to some file.
elsif ($log_facility eq 'file') {
  if (!Mail::SpamAssassin::Logger::add(method =&gt; 'file',
				       filename =&gt; $log_file,
				       timestamp_fmt =&gt; $log_timestamp_fmt,
				       escape =&gt; 1))
  {
    # file method failed
    $log_facility = 'stderr';
  }
}

### End initialization of logging ##########################

# REIMPLEMENT: if $log_socket is none, fall back to log_facility 'stderr'.
# If log_fac is stderr and defined $opt{'debug'}, set log_fac to 'null' to
# avoid duplicating log messages.
# TVD: isn't this already done up above?

# support setuid() to user unless:
# run with -u
# we're not root
# doing --vpopmail or --virtual-config-dir
# using --sql-config or --ldap-config
# (unless we're also using --setuid-with-sql or --setuid-with-ldap)
my $setuid_to_user = (
        $opt{'username'} ||
        $&gt; != 0 ||
        $opt{'vpopmail'} ||
        $opt{'virtual-config-dir'} ||
        ($opt{'sql-config'} &amp;&amp; !$opt{'setuid-with-sql'}) ||
        ($opt{'ldap-config'} &amp;&amp; !$opt{'setuid-with-ldap'})
      ) ? 0 : 1;

dbg(&quot;spamd: will perform setuids? $setuid_to_user&quot;);

if ( $opt{'vpopmail'} ) {
  if ( !$opt{'username'} ) {
    die &quot;spamd: cannot use --vpopmail without -u\n&quot;;
  }
}

if ( $opt{'virtual-config-dir'} ) {
  if ( !$opt{'username'} ) {
    die &quot;spamd: cannot use --virtual-config-dir without -u\n&quot;;
  }
}

if ($opt{'sql-config'} &amp;&amp; !$opt{'setuid-with-sql'}) {
  if ( !$opt{'username'} ) {
    die &quot;spamd: cannot use --sql-config without -u\n&quot;;
  }
}

if ($opt{'ldap-config'} &amp;&amp; !$opt{'setuid-with-ldap'}) {
  if ( !$opt{'username'} ) {
    die &quot;spamd: cannot use --ldap-config without -u\n&quot;;
  }
}

# always copy the config, later code may disable
my $copy_config_p = 1;

my $current_user;

my $client;               # used for the client connection ...
my $childlimit;           # max number of kids allowed
my $timeout_tcp;          # socket timeout (connect-&gt;headers), 0=no timeout
my $timeout_child;        # processing timeout (headers-&gt;finish), 0=no timeout
my $clients_per_child;    # number of clients each child should process
my %children;             # current children
my @children_exited;

if ( defined $opt{'max-children'} ) {
  $childlimit = $opt{'max-children'};

  # Make sure that the values are at least 1
  $childlimit = undef if ( $childlimit &lt; 1 );
}

if ( defined $opt{'max-conn-per-child'} ) {
  $clients_per_child = $opt{'max-conn-per-child'};

  # Make sure that the values are at least 1
  $clients_per_child = undef if ( $clients_per_child &lt; 1 );
}

# Set some &quot;sane&quot; limits for defaults
$childlimit        ||= 5;
$clients_per_child ||= 200;

if (defined $opt{'timeout-tcp'} &amp;&amp; $opt{'timeout-tcp'} &gt;= 0) {
  $timeout_tcp = $opt{'timeout-tcp'};
  $timeout_tcp = undef if ($timeout_tcp == 0);
}
else {
  $timeout_tcp = 30;
}

if (defined $opt{'timeout-child'} &amp;&amp; $opt{'timeout-child'} &gt;= 0) {
  $timeout_child = $opt{'timeout-child'};
  $timeout_child = undef if ($timeout_child == 0);
}
else {
  $timeout_child = 300;
}

# ensure scaling parameters are logical
if ($opt{'min-children'} &lt; 1) {
  $opt{'min-children'} = 1;
}
if ($opt{'min-spare'} &lt; 0) {
  $opt{'min-spare'} = 0;
}
if ($opt{'min-spare'} &gt; $childlimit) {
  $opt{'min-spare'} = $childlimit-1;
}
if ($opt{'max-spare'} &lt; $opt{'min-spare'}) {
  # emulate Apache behaviour:
  # http://httpd.apache.org/docs-2.0/mod/prefork.html#maxspareservers
  $opt{'max-spare'} = $opt{'min-spare'}+1;
}

my $dontcopy = 1;
if ( $opt{'create-prefs'} ) { $dontcopy = 0; }

my $orighome;
if ( defined $ENV{'HOME'} ) {
  if ( defined $opt{'username'} )
  {    # spamd is going to run as another user, so reset $HOME
    if ( my $nh = ( getpwnam( $opt{'username'} ) )[7] ) {
      $ENV{'HOME'} = $nh;
    }
    else {
      die &quot;spamd: unable to determine home directory for user '&quot;
        . $opt{'username'} . &quot;'\n&quot;;
    }
  }

  $orighome = $ENV{'HOME'};    # keep a copy for use by Razor, Pyzor etc.
  delete $ENV{'HOME'};         # we do not want to use this when running spamd
}

# Do welcomelist later in tmp dir. Side effect: this will be done as -u user.

# Initialize SSL options

$opt{'server-key'}  ||= &quot;$LOCAL_RULES_DIR/certs/server-key.pem&quot;;
$opt{'server-cert'} ||= &quot;$LOCAL_RULES_DIR/certs/server-cert.pem&quot;;

$opt{'ssl-verify'} = 1  if $opt{'ssl-ca-file'} || $opt{'ssl-ca-path'};
$opt{'ssl'} ||= $opt{'ssl-verify'};
if ($opt{'ssl-ca-file'} &amp;&amp; !-e $opt{'ssl-ca-file'}) {
  die &quot;spamd: ssl-ca-file $opt{'ssl-ca-file'} does not exist\n&quot;;
}
if ($opt{'ssl-ca-path'} &amp;&amp; !-e $opt{'ssl-ca-path'}) {
  die &quot;spamd: ssl-ca-path $opt{'ssl-ca-path'} does not exist\n&quot;;
}

# ---------------------------------------------------------------------------
# Server (listening) socket setup for the various supported types

dbg(&quot;spamd: socket module of choice: %s %s, Socket %s&quot;.
    &quot;, %s PF_INET, %s PF_INET6, %s, AI_ADDRCONFIG %s&quot;,
    $io_socket_module_name,
    $io_socket_module_name-&gt;VERSION,
    Socket-&gt;VERSION,
    $have_inet4 ? 'have' : 'no',
    $have_inet6 ? 'have' : 'no',
    $have_getaddrinfo_in_core ? 'using Socket::getaddrinfo'
    : $have_getaddrinfo_legacy ? 'using legacy Socket6::getaddrinfo'
    : 'no getaddrinfo, using gethostbyname, IPv4-only',
    $ai_addrconfig_flag ? &quot;is supported&quot; : &quot;not supported&quot;,
);

my $have_ssl_module;
my @listen_sockets;  # list of hashrefs, contains info on all listen sockets
my $server_select_mask;

my @listen_socket_specs = @{$opt{'listen-sockets'}};

{ # merge legacy option --socketpath into @listen_socket_specs
  my $socketpath = $opt{'socketpath'};
  if (defined $socketpath &amp;&amp; $socketpath ne '') {
    $socketpath =~ m{^/}
      or die &quot;socketpath option should specify an absolute path: $socketpath&quot;;
    push(@listen_socket_specs, $socketpath);
  }
}

# supply a default socket (loopback IP address) if none specified
push(@listen_socket_specs, 'localhost')  if !@listen_socket_specs;

for (@listen_socket_specs) {
  my $socket_specs = $_;

  $socket_specs = '*'  if $socket_specs eq '';  # empty implies all interfaces

  local($1,$2,$3,$4,$5,$6);
  if ($socket_specs =~
           m{^ (?: (ssl) : )?
               ( / .* ) \z }xsi) {  # unix socket - absolute path
    my($proto,$path) = ($1, $2);
  # $proto = 'ssl'  if defined $opt{'ssl'} || defined $opt{'ssl-port'};
    $proto = !defined($proto) ? '' : lc($proto);
    # abstracted out the setup-retry code
    dbg(&quot;spamd: unix socket: %s&quot;, $path);
    server_sock_setup(\&amp;server_sock_setup_unix, $socket_specs, $path);
  } elsif ($socket_specs =~
           m{^ (?: (ssl) : )?
               ( [0-9]+ ) \z }xsi) {  # unix socket - absolute path
    my ($proto, $fd) = ($1, $2);
    $proto = 'ssl'  if defined $opt{'ssl'} || defined $opt{'ssl-port'};
    $proto = !defined($proto) ? '' : lc($proto);
    # abstracted out the setup-retry code
    dbg(&quot;spamd: fd socket: %s&quot;, $socket_specs);
    server_sock_setup_fd($socket_specs, $fd, $proto eq 'ssl' ? 1 : 0);
  } elsif ($socket_specs =~
           m{^ (?: (ssl) : )?
               (?: \[ ( [^\]]* ) \]
                 | ( [a-z0-9._-]* )
                 | ( [a-f0-9]* : [a-f0-9]* : [a-f0-9:]*
                     (?: % [a-z0-9._~-]* )? \z )
                 | ( \* )
               )?
               (?: : ( [a-z0-9-]* ) )? \z }xsi) {
    my($proto,$addr,$port) = ($1, $2||$3||$4||$5, $6);
    $addr = 'localhost'  if !defined $addr;
    $proto = 'ssl'  if defined $opt{'ssl'} || defined $opt{'ssl-port'};
    $proto = !defined($proto) ? '' : lc($proto);
    $port = $opt{'ssl-port'}  if !defined $port &amp;&amp; $proto eq 'ssl';
    $port = $opt{'port'}      if !defined $port || $port eq '';
    $port = '783'             if !defined $port || $port eq '';
    if ($port ne '' &amp;&amp; $port !~ /^(\d+)\z/) {
      $port = ( getservbyname($port,'tcp') )[2];
      $port or die &quot;spamd: invalid port: $port, socket: $socket_specs\n&quot;;
    }
    # abstracted out the setup-retry code
    dbg('spamd: %s socket specification: &quot;%s&quot;, IP address: %s, port: %s',
        $proto, $socket_specs, $addr, $port);
    server_sock_setup(\&amp;server_sock_setup_inet,
                      $socket_specs, $addr, $port, $proto eq 'ssl' ? 1 : 0);
  } else {
    die &quot;Invalid socket specification syntax: $socket_specs\n&quot;;
  }
}

@listen_sockets  or die &quot;No listen sockets specified, aborting\n&quot;;

# ---------------------------------------------------------------------------

# Check for server certs
if ( $have_ssl_module ) {
  if ( !-e $opt{'server-key'} ) {
    die &quot;spamd: server key file $opt{'server-key'} does not exist\n&quot;;
  }
  if ( !-e $opt{'server-cert'} ) {
    die &quot;spamd: server certificate file $opt{'server-cert'} does not exist\n&quot;;
  }
}

# ---------------------------------------------------------------------------

my $sockets_access_lock_tempfile;  # a File::Temp object, if locking is needed
my $sockets_access_lock_fh;  # per-child file handle on a lock file

my $backchannel = Mail::SpamAssassin::SubProcBackChannel-&gt;new();
my $scaling;

if (!$opt{'round-robin'})
{
  my $max_children = $childlimit;

  # change $childlimit to avoid churn when we startup and create loads
  # of spare servers; when we're using scaling, it's not as important
  # as it was with the old algorithm.
  if ($childlimit &gt; $opt{'max-spare'}) {
    $childlimit = $opt{'max-spare'};
  }
  if ($childlimit &lt; $opt{'min-children'}) {
    $childlimit = $opt{'min-children'};
  }

  $scaling = Mail::SpamAssassin::SpamdForkScaling-&gt;new({
        backchannel =&gt; $backchannel,
        min_children =&gt; $opt{'min-children'},
        max_children =&gt; $max_children,
        min_idle =&gt; $opt{'min-spare'},
        max_idle =&gt; $opt{'max-spare'},
        cur_children_ref =&gt; \$childlimit
      });
}

# ---------------------------------------------------------------------------

sub compose_listen_info_string {
  my @listeninfo;

  for my $socket_info (@listen_sockets) {
    next if !$socket_info;
    my $socket = $socket_info-&gt;{socket};
    next if !$socket;
    my $socket_specs = $socket_info-&gt;{specs};

    if ($socket-&gt;isa('IO::Socket::UNIX')) {
      push(@listeninfo, &quot;UNIX domain socket &quot; . $socket_info-&gt;{path});

    } elsif ( $socket-&gt;isa('IO::Socket::INET')  ||
              $socket-&gt;isa('IO::Socket::INET6') ||
              $socket-&gt;isa('IO::Socket::IP') ) {
      push(@listeninfo, sprintf(&quot;%s [%s]:%s&quot;, ref $socket,
                      $socket_info-&gt;{ip_addr}, $socket_info-&gt;{port}));

    } elsif ($socket-&gt;isa('IO::Socket::SSL')) {
      push(@listeninfo, sprintf(&quot;SSL [%r]:%s&quot;, $socket_info-&gt;{ip_addr},
                      $socket_info-&gt;{port}));
    }
  }

  # just for reporting at startup
  return join(', ', @listeninfo);
}

sub server_sock_setup {
  my($sub, @args) = @_;

  # retry 3 times to bind to the listening socket; 3 seconds delay,
  # max, but should allow a little time for any existing shutting-down
  # server to complete shutdown
  my $lastretry = 10;
  for my $retry (1 .. $lastretry) {
    if ($retry &gt; 1) { sleep 1; }

    eval { &amp;$sub(@args) } and last;  # success =&gt; break

    if ($retry == $lastretry) {
      die $@;               # this is fatal
    } else {
      warn &quot;server socket setup failed, retry $retry: $@&quot;;
      # but retry
    }
  }
}

# ---------------------------------------------------------------------------

sub server_sock_setup_fd {
    my ( $socket_specs, $fd, $ssl ) = @_;

    my $srvsocket;
    open( $srvsocket, '+&lt;&amp;=' . $fd ) || die &quot;Could not open fd $fd: $!&quot;;
    my $sockname = getsockname($srvsocket);
    my ( $sock_type, $sock_port ) = unpack( 'Sn10', $sockname );
    if ( $sock_type == &amp;AF_INET6 ) {
        bless $srvsocket, 'IO::Socket::INET6';
    }
    elsif ( $sock_type == &amp;AF_INET ) {
        bless $srvsocket, 'IO::Socket::INET';
    }
    else {
        bless $srvsocket, 'IO::Socket::UNIX';
    }

    # TODO : SSL
    if ( $srvsocket-&gt;isa('IO::Socket::UNIX') ) {
        push(
            @listen_sockets,
            {
                specs  =&gt; $socket_specs,
                path   =&gt; $srvsocket-&gt;hostpath(),
                socket =&gt; $srvsocket,
                fd     =&gt; $fd
            }
        );

    }
    else {
        push(
            @listen_sockets,
            {
                specs   =&gt; $socket_specs,
                ip_addr =&gt; $srvsocket-&gt;sockaddr(),
                port    =&gt; $sock_port,
                socket  =&gt; $srvsocket,
                fd      =&gt; $fd
            }
        );
    }
    1;
}

# Create the sockets
sub server_sock_setup_unix {
  my($socket_specs, $path) = @_;

  # see if the socket is in use: if we connect to the current socket, it
  # means that spamd is already running, so we have to bail on our own.
  # Yes, there is a window here: best we can do for now. There is almost
  # certainly a better way, but we don't know it. Yet.

  if (-e $path) {
    unless (-S $path) {
      die &quot;spamd: file $path exists but is no socket, exiting\n&quot;;
    }
  
    if ( IO::Socket::UNIX-&gt;new( Peer =&gt; $path, Type =&gt; &amp;SOCK_STREAM ) ) {
      # socket bind successful: must already be running

      # make sure not to enter this socket into @listen_sockets,
      # otherwise exit handlers would unlink it!
      die &quot;spamd: already running on $path, exiting\n&quot;;
    }
    else {
      dbg(&quot;spamd: removing stale socket file $path&quot;);
      unlink $path;
    }
  }
  if (not -d (File::Spec-&gt;splitpath($path))[1]) {
    die &quot;spamd: directory for $path does not exist, exiting\n&quot;;
  }

  my %socket = (
    Local  =&gt; $path,
    Type   =&gt; &amp;SOCK_STREAM,
    Listen =&gt; &amp;SOMAXCONN,
  );
  dbg(&quot;spamd: creating UNIX socket:\n&quot; . join(&quot;\n&quot;, map { &quot; $_: &quot; . (defined $socket{$_} ? $socket{$_} : &quot;(undef)&quot;) } sort keys %socket));
  my $server_unix = IO::Socket::UNIX-&gt;new(%socket);
  
  # sanity check!  cf. bug 3490
  if (not $server_unix or not -S $path) {
    unless ($server_unix) {
      dbg &quot;spamd: socket path might have been truncated due to system limits\n&quot;;
      die &quot;spamd: could not create UNIX socket on $path: $!\n&quot;;
    }
    my $hostpath = $server_unix-&gt;hostpath();
    if ($hostpath ne $path) {
      warn &quot;spamd: socket path was truncated at position &quot; . length($hostpath) . &quot;\n&quot;;
      warn &quot;spamd: leaving stale socket at $hostpath\n&quot; if -S $hostpath;
      die &quot;spamd: path length for UNIX socket on $path exceeds system limit, exiting\n&quot;;
    }
    else {
      die &quot;spamd: could not find newly-created UNIX socket on $path: $!\n&quot;;
    }
  }

  my $mode = $opt{socketmode};
  if ($mode) {
    $mode = oct $mode;
  } else {
    $mode = 0666;        # default
  }

  my $owner = $opt{socketowner};
  my $group = $opt{socketgroup};
  if ($owner || $group) {
    my $uid = -1;
    my $gid = -1;
    if ($owner) {
      my ($login,$pass,$puid,$pgid) = getpwnam($owner)
                           or die &quot;spamd: $owner not in passwd database\n&quot;;
      $uid = $puid;
    }
    if ($group) {
      my ($name,$pass,$ggid,$members) = getgrnam($group)
                           or die &quot;spamd: $group not in group database\n&quot;;
      $gid = $ggid;
    }
    if (!chown $uid, $gid, $path) {
      die &quot;spamd: could not chown $path to $uid/$gid: $!&quot;;
    }
  }

  if (!chmod $mode, $path) {    # make sure everybody can talk to it
    die &quot;spamd: could not chmod $path to $mode: $!&quot;;
  }

  push(@listen_sockets, { specs =&gt; $socket_specs,
                          path =&gt; $path,
                          socket =&gt; $server_unix,
                          fd =&gt; $server_unix-&gt;fileno })  if $server_unix;
  1;
}

sub server_sock_setup_inet {
  my($socket_specs, $addr, $port, $ssl) = @_;

  $have_inet4 || $have_inet6
    or warn &quot;spamd: neither the PF_INET (IPv4) nor the PF_INET6 (IPv6) &quot;.
            &quot;protocol families seem to be available, pushing our luck anyway\n&quot;;

  my $ai_family = &amp;AF_UNSPEC;  # defaults to any address family (i.e. both)
  if      ($have_inet6 &amp;&amp; (!$have_inet4 || $opt{'force_ipv6'})) {
    $ai_family = &amp;AF_INET6;
  } elsif ($have_inet4 &amp;&amp; (!$have_inet6 || $opt{'force_ipv4'})) {
    $ai_family = &amp;AF_INET;
  }
  my($error, @addresses);
  if (!defined $addr || lc $addr eq 'localhost') {  # loopback interface
    push(@addresses, '::1')
      if $ai_family == &amp;AF_UNSPEC || $ai_family == &amp;AF_INET6;
    push(@addresses, '127.0.0.1')
      if $ai_family == &amp;AF_UNSPEC || $ai_family == &amp;AF_INET;
  } elsif ($addr eq '*' || $addr eq '') {  # any address
    push(@addresses, '::')
      if $ai_family == &amp;AF_UNSPEC || $ai_family == &amp;AF_INET6;
    push(@addresses, '0.0.0.0')
      if $ai_family == &amp;AF_UNSPEC || $ai_family == &amp;AF_INET;
  } else {
    ($error, @addresses) = ip_or_name_to_ip_addresses($addr, $ai_family);
  }
  die &quot;spamd: invalid address for a listen socket: \&quot;$socket_specs\&quot;: $error\n&quot;
    if $error;
  die &quot;spamd: no valid address for a listen socket: \&quot;$socket_specs\&quot;\n&quot;
    if !@addresses;

  dbg(&quot;spamd: attempting to listen on IP addresses: %s, port %d&quot;,
      join(', ',@addresses), $port);
  my(@diag_succ, @diag_fail);
  for my $adr (@addresses) {
    my %sockopt = (
      LocalAddr =&gt; $adr,
      LocalPort =&gt; $port,
      Type      =&gt; &amp;SOCK_STREAM,
      Proto     =&gt; 'tcp',
      ReuseAddr =&gt; 1,
      Listen    =&gt; &amp;SOMAXCONN,
    );
    $sockopt{V6Only} = 1  if $io_socket_module_name eq 'IO::Socket::IP'
                             &amp;&amp; IO::Socket::IP-&gt;VERSION &gt;= 0.09;
    if ($ssl) {
      if (!$have_ssl_module) {
	eval { require IO::Socket::SSL; }
	or die &quot;spamd: SSL encryption requested, &quot;.
	    &quot;but IO::Socket::SSL is unavailable ($@)\n&quot;;
	$have_ssl_module = 1;
      }
      %sockopt = (%sockopt, (
        SSL_server      =&gt; 1,
        SSL_key_file    =&gt; $opt{'server-key'},
        SSL_cert_file   =&gt; $opt{'server-cert'},
      ));
      my $ssl_mode;
      if ($opt{'ssl-verify'}) {
	$ssl_mode = Net::SSLeay::VERIFY_PEER()
	    | Net::SSLeay::VERIFY_FAIL_IF_NO_PEER_CERT();
	if ($opt{'ssl-ca-file'}) {
	  $sockopt{SSL_ca_file} = $opt{'ssl-ca-file'};
	}
	if ($opt{'ssl-ca-path'}) {
	  $sockopt{SSL_ca_path} = $opt{'ssl-ca-path'};
	}
	$sockopt{SSL_check_crl} = 0;
	$sockopt{SSL_verifycn_scheme} = 'none';
	$sockopt{SSL_verifycn_publicsuffix} = '';
      } else {
	$ssl_mode = Net::SSLeay::VERIFY_NONE()
	    | Net::SSLeay::VERIFY_FAIL_IF_NO_PEER_CERT();
      }
      $sockopt{SSL_verify_mode} = $ssl_mode;
    }
    dbg(&quot;spamd: creating %s socket: %s&quot;,
        $ssl ? 'IO::Socket::SSL' : $io_socket_module_name,
        join(', ', map(&quot;$_: &quot;.(defined $sockopt{$_} ? $sockopt{$_} : &quot;(undef)&quot;),
                       sort keys %sockopt)));
    my $server_inet = $ssl ? IO::Socket::SSL-&gt;new(%sockopt)
                           : $io_socket_module_name-&gt;new(%sockopt);
    my $diag;
    if (!$server_inet) {
      $diag = sprintf(&quot;could not create %s socket on [%s]:%s: %s&quot;,
                      $ssl ? 'IO::Socket::SSL' : $io_socket_module_name,
                      $adr, $port, $ssl &amp;&amp; $IO::Socket::SSL::SSL_ERROR ?
                      &quot;$!,$IO::Socket::SSL::SSL_ERROR&quot; : $!);
      push(@diag_fail, $diag);
    } else {
      $diag = sprintf(&quot;created %s socket on [%s]:%s&quot;,
                      $ssl ? 'IO::Socket::SSL' : $io_socket_module_name,
                      $adr, $port);
      push(@diag_succ, $diag);
      push(@listen_sockets, { specs =&gt; $socket_specs,
                              ip_addr =&gt; $adr, port =&gt; $port,
                              socket =&gt; $server_inet,
                              fd =&gt; $server_inet-&gt;fileno });
    }
    dbg(&quot;spamd: %s&quot;, $diag);
  }
  if (!@diag_fail) {
    # no failures, nothing to report
  } elsif (@diag_succ) {  # some failures and some success
    # just warn of all attempts, successful and failed
    warn &quot;spamd: $_\n&quot;  for @diag_succ;
    warn &quot;spamd: $_\n&quot;  for @diag_fail;
  } else {  # all failed, no success
    warn &quot;spamd: $_\n&quot;  for @diag_fail[0 .. $#diag_fail-1];
    die  &quot;spamd: $_\n&quot;  for $diag_fail[-1];
  }

  1;
}

# ---------------------------------------------------------------------------

# for select() purposes: make a map of the server socket FDs
map_server_sockets();

if (!$scaling &amp;&amp; @listen_sockets &gt; 1) {
  require File::Temp;

  # Have multiple sockets and autonomous child processes (--round-robin),
  # prepare an anonymous lock file to protect access to select+accept.

  # using the same choice of a tmp dir as in Util::secure_tmpfile()
  my $tmpdir = untaint_file_path($ENV{'TMPDIR'} || File::Spec-&gt;tmpdir);

  # the file will be automatically removed by DESTROY on program exit
  $sockets_access_lock_tempfile =
    File::Temp-&gt;new(DIR =&gt; $tmpdir, SUFFIX =&gt; '.lck', EXLOCK =&gt; 0);

  dbg(&quot;spamd: created a lock file %s to protect select+accept&quot;,
      $sockets_access_lock_tempfile-&gt;filename);
}

if ( defined $opt{'pidfile'} ) {
  $opt{'pidfile'} = untaint_file_path( $opt{'pidfile'} );
}


my $spamtest = Mail::SpamAssassin-&gt;new(
  {
    dont_copy_prefs      =&gt; $dontcopy,
    rules_filename       =&gt; ( $opt{'configpath'} || 0 ),
    site_rules_filename  =&gt; ( $opt{'siteconfigpath'} || 0 ),
    pre_config_text      =&gt; join(&quot;\n&quot;, @{$opt{'pre'}}).&quot;\n&quot;,
    post_config_text     =&gt; join(&quot;\n&quot;, @{$opt{'cf'}}).&quot;\n&quot;,
    force_ipv4           =&gt; ( $opt{'force_ipv4'} || 0 ),
    local_tests_only     =&gt; ( $opt{'local'} || 0 ),
    debug                =&gt; ( $opt{'debug'} || 0 ),
    paranoid             =&gt; ( $opt{'paranoid'} || 0 ),
    require_rules        =&gt; 1,
    skip_prng_reseeding  =&gt; 1,  # let us do the reseeding by ourselves
    home_dir_for_helpers =&gt; (
      defined $opt{'home_dir_for_helpers'}
      ? $opt{'home_dir_for_helpers'}
      : $orighome
    ),
    PREFIX          =&gt; $PREFIX,
    DEF_RULES_DIR   =&gt; $DEF_RULES_DIR,
    LOCAL_RULES_DIR =&gt; $LOCAL_RULES_DIR,
    LOCAL_STATE_DIR =&gt; $LOCAL_STATE_DIR
  }
);

#Enable Timing?
if ($opt{'timing'}) {
  $spamtest-&gt;timer_enable();
}

# if $clients_per_child == 1, there's no point in copying configs around
unless ($clients_per_child &gt; 1) {
  # unset $copy_config_p so we don't bother trying to copy things back
  # after closing the connection
  $copy_config_p = 0;
}

# See Bug 6837: establishing a __DIE__ handler should be done after
# most modules have been loaded, as the $^S cannot distinguish
# true failures from eval attempt failures within a 'require'-d module.
# If the problem persists in some late-lodaded modules, we may need
# to tighten the condition to something like 'if defined $^S &amp;&amp; !$^S'.
#
# redirect __WARN__ and __DIE__
# do not trap warnings here based on eval scope; evals are very
# common throughout.  die()s can be trapped though.
$SIG{__WARN__} = sub {
  log_message(&quot;warn&quot;, $_[0]);
};
$SIG{__DIE__} = sub {
  # see http://use.perl.org/comments.pl?mode=flat&amp;sid=33872 for $^S
  log_message(&quot;error&quot;, $_[0]) unless $^S;
};

## DAEMONIZE! ##

my $originalparent = $$;
$opt{'daemonize'} and daemonize();

# bug 3443: setup signal handlers before the kids since we may have to
# kill them...  make sure this happens before setting up the pidfile to
# avoid a race condition.
my $got_sighup;
setup_parent_sig_handlers();

# should be done post-daemonize such that any files created by this
# process are written with the right ownership and everything.
seteuid_to_user();
preload_modules_with_tmp_homedir();
restore_euid();

# this must be after preload_modules_with_tmp_homedir(), for bug 5606
$spamtest-&gt;init_learner({
  opportunistic_expire_check_only =&gt; 1,
});

# bayes DBs may still be tied() at this point, so untie them and such.
$spamtest-&gt;finish_learner();

# If we're going to be switching users in check(), let's backup the
# fresh configuration now for later restoring ...  MUST be placed after
# the M::SA creation.
my %conf_backup;
my %msa_backup;

if ($copy_config_p) {
  foreach( 'username', 'user_dir', 'userstate_dir', 'learn_to_journal' ) {
    $msa_backup{$_} = $spamtest-&gt;{$_} if (exists $spamtest-&gt;{$_});
  }

  $spamtest-&gt;copy_config(undef, \%conf_backup) ||
    die &quot;spamd: error returned from copy_config\n&quot;;
}

# bonus: SIGUSR2 to dump a stack trace.  this is never reset
my $current_msgid = &quot;(none)&quot;;
$SIG{USR2} = \&amp;backtrace_handler  if !am_running_on_windows();

# log server started, but processes watching the log to wait for connect
# should wait until they see the pid, after signal handlers are in place
# FIXME: two calls are one too much
info(&quot;spamd: server started on %s (running version %s)&quot;,
     compose_listen_info_string(), Mail::SpamAssassin::Version());

my $remote_port;

# Make the pidfile ...
if (defined $opt{'pidfile'}) {
  if (open PIDF, &quot;&gt;$opt{'pidfile'}&quot;) {
    print PIDF &quot;$$\n&quot;;
    close PIDF;
  }
  else {
    warn &quot;spamd: cannot write to PID file: $!\n&quot;;
  }
}

# The &quot;prefork_init&quot; plugin callback is called in the parent process shortly
# before forking off child processes. It allows plugins which were activated
# by the master spamd process to prepare for a fork, e.g. by closing or
# dropping some resources which won't be of any use by a child process.
#
$spamtest-&gt;call_plugins(&quot;prefork_init&quot;);  # since SA 3.4.0

# now allow waiting processes to connect, if they're watching the log.
# The test suite does this!
info(&quot;spamd: server pid: $$&quot;);
kill(&quot;USR1&quot;,$originalparent) if ($opt{'daemonize'});

# Fork off our children.
for ( 1 .. $childlimit ) {
  spawn();
}

if ($scaling) {
  $scaling-&gt;set_server_fh(map($_-&gt;{socket},@listen_sockets));
}

my $dormant_mode;
if ( eval q{require Cpanel::Services::Dormant; 1} ) {
  $dormant_mode = 'Cpanel::Services::Dormant'-&gt;new( service =&gt; 'spamd' );
}

while (1) {
  if (!$scaling) {
    # wait for a signal (ie: child's death)
    # bug 4190: use a time-limited sleep, and call child_handler() even
    # if haven't received a SIGCHLD, due to inherent race condition
    sleep 10;
  } else {
    my $go_dormant = should_go_dormant( $scaling );
    $scaling-&gt;main_server_poll($opt{'server-scale-period'}, $go_dormant);
  }

  # bug 6377: on win32 the parent never receives SIGCHLD
# child_handler()  if !$scaling || am_running_on_windows();
  child_handler();  # it doesn't hurt to call child_handler unconditionally

  child_cleaner();

  do_sighup_restart()  if defined $got_sighup;

  for (my $i = keys %children; $i &lt; $childlimit; $i++) {
    spawn();
    $dormant_mode-&gt;got_an_active_connection(); # reset dormant timeout when spawning a new child
  }
}

sub should_go_dormant {
    my ( $scaling ) = ( @_ );
    die unless ref $scaling;

    return unless ref $dormant_mode &amp;&amp; $dormant_mode-&gt;is_enabled();

    my @kids      = keys %{$scaling-&gt;{kids}};
    my @idle_kids = grep { $scaling-&gt;{kids}-&gt;{$_} == PFSTATE_IDLE } @kids;

    if ( scalar @idle_kids != scalar @kids ) {
      $dormant_mode-&gt;got_an_active_connection();
      return;
    }

    # only used after startup if no activity, then discard it
    #   need to happen after the previous kids check to wait for them to be properly initialized
    my $start_dormant = $opt{'start-dormant'};
    $opt{'start-dormant'} = undef if $start_dormant;

    if ( $dormant_mode-&gt;should_go_dormant() || $start_dormant ) {
      # time to go in dormant mode
      return sub {
        my $self = shift;

        # not really needed
        child_handler(); # it doesn't hurt to call child_handler unconditionally
        child_cleaner();

        my %current_flags;
        # Remove CLOEXEC
        foreach ( my $i = 0; $i &lt;= $#{ $self-&gt;{server_fh} }; $i++ ) {
          my $fileno = $self-&gt;{server_fileno}-&gt;[$i];
          my $fh     = $self-&gt;{server_fh}-&gt;[$i];
          $current_flags{$fileno} = fcntl( $fh, Fcntl::F_GETFD(), 0 ) or warn &quot;Failed to get flags on fileno: $fileno&quot;;
          my $new_flags = $current_flags{$fileno} &amp; ~&amp;Fcntl::FD_CLOEXEC;
          fcntl( $fh, Fcntl::F_SETFD(), $new_flags ) or warn &quot;Failed to set flags on fileno: $fileno&quot;;
       }

        my $ls = join(',', map { $_-&gt;{fd} } @listen_sockets );
        # remove start-dormant which is only used for the first startup
        my @args = grep { $_ ne '--start-dormant' &amp;&amp; $_ !~ qr{^--listen=} } @ORIG_ARGV;
        exec('/usr/local/cpanel/libexec/spamd-dormant', @args, '--listen=' . $ls );
        # no die here as we want to continue if it fails go dormant
        warn(&quot;Fail to switch to dormant mode '/usr/local/cpanel/libexec/spamd-dormant': $!&quot;);
      };
    }
    return;
}

# Kicks off a kid ...
sub spawn {
  my $pid;

  $backchannel-&gt;setup_backchannel_parent_pre_fork();

  # block signal for fork
  my $sigset;
  if (!am_running_on_windows()) {
    $sigset = POSIX::SigSet-&gt;new( POSIX::SIGINT(), POSIX::SIGCHLD() );
    sigprocmask( POSIX::SIG_BLOCK(), $sigset )
      or die &quot;spamd: cannot block SIGINT/SIGCHLD for fork: $!\n&quot;;
  }    

  $pid = fork();
  die &quot;spamd: fork: $!&quot; unless defined $pid;

  if ($pid) {
    ## PARENT

    $children{$pid} = 1;
    info(&quot;spamd: server successfully spawned child process, pid $pid&quot;);
    $backchannel-&gt;setup_backchannel_parent_post_fork($pid);
    if ($scaling) {
      $scaling-&gt;add_child($pid);
    }
    if (!am_running_on_windows()) {
      sigprocmask( POSIX::SIG_UNBLOCK(), $sigset )
        or die &quot;spamd: cannot unblock SIGINT/SIGCHLD for fork: $!\n&quot;;
    }
    #Changing to return the process id to improve communications for bug 6304
    return $pid;
  }
  else {
    ## CHILD

    # Reset signal handling to default settings, and unblock.
    # These lines must be as soon as possible after the fork (bug 4304)
    setup_child_sig_handlers();
    if (!am_running_on_windows()) {
      sigprocmask( POSIX::SIG_UNBLOCK(), $sigset )
        or die &quot;spamd: cannot unblock SIGINT/SIGCHLD for fork: $!\n&quot;;
    }

    srand;  # reseed pseudorandom number generator soon for each child process
    if ($sockets_access_lock_tempfile) {
      # A lock will be required across select+accept in a child processes,
      # Bug 6996. Need to have a per-child filehandle on the same lock file
      # for flock to work, let's dup(2) the parent's file handle.
      my $fname = $sockets_access_lock_tempfile-&gt;filename;
      $sockets_access_lock_fh = IO::File-&gt;new($fname, &quot;+&gt;&quot;);
      $sockets_access_lock_fh or die &quot;Can't open a lock file $fname: $!&quot;;
    }

    # support non-root use
    if ( $opt{'username'} ) {
      my ( $uuid, $ugid ) = ( getpwnam( $opt{'username'} ) )[ 2, 3 ];
      if ( !defined $uuid || $uuid == 0 ) {
        die &quot;spamd: cannot run as nonexistent user or root with -u option\n&quot;;
      }

      if ( $opt{'groupname'} ) {
        $ugid = getgrnam( $opt{'groupname'} ) || $ugid;
      }

      # bug 5518: assignments to $) and $( don't always work on all platforms
      # bug 3900: assignments to $&gt; and $&lt; problems with BSD perl bug
      # use the POSIX functions to hide the platform specific workarounds 
      dbg(&quot;spamd: Privilege de-escalation from user $&lt; and groups $(\n&quot;);
      my $togids = &quot;$ugid &quot;.get_user_groups($uuid);
      if ($( ne $togids || $) ne $togids) {
        $! = 0; POSIX::setgid($ugid);  # set effective and real gid
        if ($!) { warn(&quot;spamd: POSIX::setgid $ugid failed: $!\n&quot;); }
        $! = 0; $( = $ugid;
        if ($!) { warn(&quot;spamd: failed to set gid $ugid: $!\n&quot;); }
        # set effective and real gid/grouplist another way because we lack initgroups in Perl
        $! = 0; $) = $togids;
        if ($!) {
          # could be perl 5.30 bug #134169, let's be safe
          if (grep { $_ eq '0' } split(/ /, ${)})) {
            die(&quot;spamd: failed to set effective gid $togids: $!\n&quot;);
          } else {
            warn(&quot;spamd: failed to set effective gid $togids: $!\n&quot;);
          }
        }
      } else {
        dbg(&quot;spamd: Group already set to $(&quot;);
      }
      if ($&lt; != $uuid || $&gt; != $uuid) {
        $! = 0; POSIX::setuid($uuid);  # set effective and real UID
        if ($!) { warn(&quot;spamd: POSIX::setuid $uuid failed: $!\n&quot;); }
        $! = 0; $&lt; = $uuid; $&gt; = $uuid;   # bug 5574
        if ($!) { warn(&quot;spamd: setuid $uuid failed: $!\n&quot;); }
        dbg(&quot;spamd: now running as: ruid=$&lt; euid=$&gt; rgid=$( egid=$)&quot;);

        # keep the sanity check to catch problems like bug 3900 just in case
        if ( $&gt; != $uuid and $&gt; != ( $uuid - 2**32 ) ) {
          sleep(1); # prevent spamd fork flooding
          die &quot;spamd: setuid to uid $uuid failed (ruid=$&lt;, euid=$&gt;), not started as root?\n&quot;;
        }
      } else {
        dbg(&quot;spamd: Uid already set to $&lt;&quot;);
      }
    }

    # set process name where supported
    # this will help make it clear via process listing which is child/parent
    $0 = 'spamd child';

    # Let's call spamd_child_init only after root privs are dropped
    # Mail::SpamAssassin::main() will also run this to set global_state_dir
    $spamtest-&gt;call_plugins(&quot;spamd_child_init&quot;);

    $backchannel-&gt;setup_backchannel_child_post_fork();
    if ($scaling) {     # only do this once, for efficiency; $$ is a syscall
      $scaling-&gt;set_my_pid($$);
    }

    # handle $clients_per_child connections, then die in &quot;old&quot; age...
    my $orders;
    for ( my $i = 0 ; $i &lt; $clients_per_child ; $i++ ) {
      if ($scaling) {
        $scaling-&gt;update_child_status_idle();
        $orders = $scaling-&gt;wait_for_orders(); # and sleep...

        if ($orders != PFORDER_ACCEPT) {
          info(&quot;spamd: unknown order: $orders&quot;);
        }
      }

      # use a large eval scope to catch die()s and ensure they
      # don't kill the server.
      my $evalret = eval { accept_a_conn($scaling ? 0.5 : undef); };

      if (!defined $evalret) {
        warn(&quot;spamd: error: $@, continuing\n&quot;);
        if ($client) { $client-&gt;close(); }  # avoid fd leaks
      }
      elsif ($evalret == -1) {
        # serious error; used for accept() failure
        die(&quot;spamd: respawning server\n&quot;);
      }

      $spamtest-&gt;call_plugins(&quot;spamd_child_post_connection_close&quot;);

      # if we changed UID during processing, change back!
      if ($setuid_to_user &amp;&amp; ($&gt; != $&lt;) &amp;&amp; ($&gt; != ($&lt; - 2**32))) {
        $) = &quot;$( $(&quot;;    # change eGID
        $&gt; = $&lt;;         # change eUID

        # check again; ensure the change happened
        if ($&gt; != $&lt; &amp;&amp; ($&gt; != ( $&lt; - 2**32))) {
          # make it fatal to avoid security breaches
          die(&quot;spamd: return setuid failed&quot;);
        }
      }

      if ($copy_config_p) {
        # use a timeout!  There are bugs in Storable on certain platforms
        # that can cause spamd to hang -- see bug 3828 comment 154.
        # we don't use Storable any more, but leave this in -- just
        # in case.
	# bug 4699: this is the alarm that often ends up with an empty $@

	my $timer = Mail::SpamAssassin::Timeout-&gt;new({ secs =&gt; 20 });
	my $err = $timer-&gt;run(sub {	

          while(my($k,$v) = each %msa_backup) {
            $spamtest-&gt;{$k} = $v;
          }

          # if we changed user, we would have also loaded up new configs
          # (potentially), so let's restore back the saved version we
          # had before.
          $spamtest-&gt;copy_config(\%conf_backup, undef) ||
            die &quot;spamd: error returned from copy_config\n&quot;;
        });

	if ($timer-&gt;timed_out()) {
	  warn(&quot;spamd: copy_config timeout, respawning child process after &quot;.
		($i+1).&quot; messages&quot;);
	  exit;		# so that the master spamd can respawn
	}
      }
      undef $current_user;

      #LOG TIMING
      if ($opt{'timing'}) {
        info(&quot;timing: &quot; . $spamtest-&gt;timer_report());
      } else {
        dbg(&quot;timing: &quot; . $spamtest-&gt;timer_report()) if would_log('dbg', 'timing');
      }
    }

    # If the child lives to get here, it will die ...  Muhaha.
    exit;
  }
}

sub accept_from_any_server_socket {
  my($timeout) = @_;
  my($client, $selected_socket_info, $socket, $locked);

  eval {
    if (!@listen_sockets) {
      # nothing?
      die &quot;no sockets?&quot;;

    } elsif (@listen_sockets == 1) {
      $selected_socket_info = $listen_sockets[0];

    } else {
      # determine which of our server FDs is ready using select().
      # We only need to do this if we have more than one server
      # socket supported, since otherwise there can only be one socket
      # with a client waiting.
      # (TODO: we could extend the prefork protocol to pass this data)

      if ($sockets_access_lock_fh) {
        dbg(&quot;spamd: acquiring a lock over select+accept&quot;);
        # with multiple sockets a lock across select+accept is needed, Bug 6996
        flock($sockets_access_lock_fh, LOCK_EX)
          or die &quot;Can't acquire lock access to sockets: $!&quot;;
        $locked = 1;
      }

      my $sel_mask_str = unpack('b*', $server_select_mask);
      dbg(&quot;spamd: select() on fd bit field %s, %s, %s&quot;,
          $sel_mask_str, defined $timeout ? &quot;timeout $timeout&quot; : &quot;no timeout&quot;,
          $locked ? &quot;locked&quot; : &quot;not locked&quot;);

      my $fdvec = $server_select_mask;
      my $nfound = select($fdvec, undef, undef, $timeout);

      if (!defined $nfound || $nfound &lt; 0) {
        die &quot;select failed on fd bit field $sel_mask_str: $!&quot;;
      } elsif (!$nfound) {
        die &quot;no fd ready, fd bit field $sel_mask_str&quot;;
      }

      my(@ready_fd) =  # list of file descriptors ready for read
        grep(defined $_-&gt;{fd} &amp;&amp; vec($fdvec, $_-&gt;{fd}, 1), @listen_sockets);
      if (!@ready_fd) {
        die &quot;no file descriptors matching a bit field &quot; . unpack('b*',$fdvec);
      } elsif (@ready_fd == 1) {  # easy, just one is ready
        $selected_socket_info = $ready_fd[0];
      } else {  # give equal opportunity to each ready socket
        my $j = int rand(@ready_fd);
        $selected_socket_info = $ready_fd[$j];
        dbg(&quot;spamd: requests ready on multiple sockets, picking #%d out of %d&quot;,
            $j+1, scalar @ready_fd);
      }

    } # end multiple sockets case

    if ($selected_socket_info) {
      my $socket = $selected_socket_info-&gt;{socket};
      $socket or die &quot;no socket???, impossible&quot;;
      dbg(&quot;spamd: accept() on fd %d&quot;, $selected_socket_info-&gt;{fd});
      $client = $socket-&gt;accept;
      if (!defined $client) {
        if (defined $socket) {
          die sprintf(&quot;%s accept failed: %s\n&quot;, ref $socket,
                       $socket-&gt;isa('IO::Socket::SSL') ?
                         $socket-&gt;errstr : $@);
        } else {
          die &quot;accept failed: no socket available: $!\n&quot;;
        }
      }
    }
    1;  # end eval with success

  } or do {
    my $err = $@ ne '' ? $@ : &quot;errno=$!&quot;;  chomp $err;
    info(&quot;spamd: accept_a_conn: $err&quot;);
  };

  if ($locked) {
    dbg(&quot;spamd: releasing a lock over select+accept&quot;);
    flock($sockets_access_lock_fh, LOCK_UN)
      or die &quot;Can't release sockets-access lock: $!&quot;;
  }

  return ($client, $selected_socket_info);
}

sub accept_a_conn {
  my ($timeout) = @_;

  my $socket_info;
  # $client is a global variable
  ($client, $socket_info) = accept_from_any_server_socket($timeout);

  if ($scaling) {
    $scaling-&gt;update_child_status_busy();
  }

  # Bah!
  if ( !$client  || !defined $client-&gt;connected() ) {

    # this can happen when interrupted by SIGCHLD on Solaris,
    # perl 5.8.0, and some other platforms with -m.
    if ( $! == &amp;Errno::EINTR ) {
      return 0;
    }
    elsif ( $@ =~ /ssl3_get_record:wrong version number/ ||
            $@ =~ /peer did not return a certificate/ ) {
      # Handshake error, not speaking SSL? No need to respawn
      return 0;
    }
    else {
      return -1;
    }
  }

  $client-&gt;autoflush(1);

  # keep track of start time
  $spamtest-&gt;timer_reset;
  my $start = time;

  my ($remote_hostname, $remote_hostaddr, $local_port);

  if ($client-&gt;isa('IO::Socket::UNIX')) {
    $remote_hostname = 'localhost';
    $remote_hostaddr = '127.0.0.1';
    $remote_port = $socket_info-&gt;{path};
    info(&quot;spamd: got connection over %s&quot;, $socket_info-&gt;{path});
  }
  else {
    ($remote_port, $remote_hostaddr, $remote_hostname, $local_port) =
      peer_info_from_socket($client);
    $remote_hostaddr or die 'failed to obtain port and ip from socket';

    my $ssl_info = '';
    if ($client-&gt;isa('IO::Socket::SSL')) {
      $ssl_info = ', ';
      my $ssl_version = $client-&gt;get_sslversion();
      if (defined $ssl_version) {
        $ssl_info .= $ssl_version.'/';
      } else {
        $ssl_version = $client-&gt;get_sslversion_int();
        if    ($ssl_version == 0x0304) { $ssl_info .= 'TLSv1.3/'; }
        elsif ($ssl_version == 0x0303) { $ssl_info .= 'TLSv1.2/'; }
        elsif ($ssl_version == 0x0302) { $ssl_info .= 'TLSv1.1/'; }
        elsif ($ssl_version == 0x0301) { $ssl_info .= 'TLSv1.0/'; }
        elsif ($ssl_version == 0x0300) { $ssl_info .= 'SSLv3/'; }
        elsif ($ssl_version == 0x0002) { $ssl_info .= 'SSLv2/'; }
      }
      $ssl_info .= $client-&gt;get_cipher();
    }

    my $msg = sprintf(&quot;connection from %s [%s]:%s to port %d, fd %d%s&quot;,
                      $remote_hostname, $remote_hostaddr, $remote_port,
                      $local_port, $socket_info-&gt;{fd}, $ssl_info);
    if (ip_is_allowed($remote_hostaddr)) {
      info(&quot;spamd: $msg&quot;);
    }
    else {
      warn(&quot;spamd: unauthorized $msg&quot;);
      $client-&gt;close;
      return 0;
    }
  }

  local ($_);
  eval {
    Mail::SpamAssassin::Util::trap_sigalrm_fully(sub {
                          die &quot;tcp timeout&quot;;
                        });
    alarm $timeout_tcp if ($timeout_tcp);
    # send the request to the child process
    $_ = $client-&gt;getline;
  };
  alarm 0;

  if ($@) {
    if ($@ =~ /tcp timeout/) {
      service_timeout(&quot;($timeout_tcp second socket timeout reading input from client)&quot;);
    } else {
      warn &quot;spamd: $@&quot;;
    }
    $client-&gt;close;
    return 0;
  }

  if ( !defined $_ ) {
    protocol_error(&quot;(closed before headers)&quot;);
    $client-&gt;close;
    return 0;
  }

  s/\r?\n//;

  # It might be a CHECK message, meaning that we should just check
  # if it's spam or not, then return the appropriate response.
  # If we get the PROCESS command, the client is going to send a
  # message that we need to filter.

  if (/(PROCESS|CHECK|SYMBOLS|REPORT|HEADERS|REPORT_IFSPAM) SPAMC\/(.*)/) {
    my $method = $1;
    my $version = $2;
    eval {
      Mail::SpamAssassin::Util::trap_sigalrm_fully(sub {
                          die &quot;child processing timeout&quot;;
                        });
      alarm $timeout_child if ($timeout_child);
      check($method, $version, $start, $remote_hostname, $remote_hostaddr);
    };
    alarm 0;

    if ($@) {
      if ($@ =~ /child processing timeout/) {
        service_timeout(&quot;($timeout_child second timeout while trying to $method)&quot;);
      } else {
	warn &quot;spamd: $@&quot;;
      }
      $client-&gt;close();
      return 0;
    }
  }

  elsif (/(TELL) SPAMC\/(.*)/) {
    my $method = $1;
    my $version = $2;
    eval {
      Mail::SpamAssassin::Util::trap_sigalrm_fully(sub {
						     die &quot;child processing timeout&quot;;
						   });
      alarm $timeout_child if ($timeout_child);
      dotell($method, $version, $start, $remote_hostname, $remote_hostaddr);
    };
    alarm 0;

    if ($@) {
      if ($@ =~ /child processing timeout/) {
        service_timeout(&quot;($timeout_child second timeout while trying to $method)&quot;);
      } else {
	warn &quot;spamd: $@&quot;;
      }
      $client-&gt;close();
      return 0;
    }
  }

  # Looks like a client is just seeing if we're alive or changed its mind

  elsif (/(SKIP|PING) SPAMC\/(.*)/) {
    my $method = $1;
    my $version = $2;

    if ($method eq 'SKIP') {
      # It may be a SKIP message, meaning that the client (spamc)
      # thinks it is too big to check.  So we don't do any real work
      # in that case.
      info(&quot;spamd: skipped large message in %3.1f seconds&quot;, time - $start);
    }
    doskip_or_ping($method, $version,
                   $start, $remote_hostname, $remote_hostaddr);
  }

  # If it was none of the above, then we don't know what it was.

  else {
    protocol_error($_);
  }

  # Close out our connection to the client ...
  $client-&gt;close();
  return 1;
}

sub handle_setuid_to_user {
  if ($spamtest-&gt;{paranoid}) {
    die(&quot;spamd: in paranoid mode, still running as root: closing connection&quot;);
  }
  if (!am_running_on_windows()) {
    warn(&quot;spamd: still running as root: user not specified with -u, &quot;
         . &quot;not found, or set to root, falling back to $opt{'default-user'}\n&quot;);

    my ($name, $pwd, $uid, $gid, $quota, $comment, $gcos, $dir, $etc) =
        getpwnam($opt{'default-user'});
  
    $) = (get_user_groups($uid));       # eGID
    $&gt; = $uid;                          # eUID
    if (!defined($uid) || ($&gt; != $uid and $&gt; != ($uid - 2**32))) {
      die(&quot;spamd: setuid to $opt{'default-user'} failed&quot;);
  }

  $spamtest-&gt;signal_user_changed(
    {
      username =&gt; $name,
      user_dir =&gt; $dir
    }
  );
  }
}

sub parse_body {
  my ($client, $expected_length, $compress_zlib, $start_time) = @_;

  my @msglines;
  my $actual_length;

  if ($compress_zlib &amp;&amp; !defined($expected_length)) {
    service_unavailable_error(&quot;Compress requires Content-length header&quot;);
    return;
  }

  if ($compress_zlib) {
    $actual_length = zlib_inflate_read($client, $expected_length, \@msglines);
    if ($actual_length &lt; 0) { return; }
    $expected_length = $actual_length;
  }
  else {
    @msglines = ();
    $actual_length = 0;
    while (defined($_ = $client-&gt;getline())) {
      $actual_length += length($_);
      push(@msglines, $_);    
      last if (defined $expected_length &amp;&amp; $actual_length &gt;= $expected_length);
    }
  }
  
  # Now parse *only* the message headers; the MIME tree won't be generated 
  # yet, it will be done on demand later on.
  my $mail = $spamtest-&gt;parse(\@msglines, 0,
                       !$timeout_child || !$start_time ? ()
                       : { master_deadline =&gt; $start_time + $timeout_child } );

  return ($mail, $actual_length);
}

sub zlib_inflate_read {
  my ($client, $expected_length, $msglinesref) = @_;
  my $out;
  my $actual_length;

  eval {
    require Compress::Zlib;
    my ($zlib, $status) = Compress::Zlib::inflateInit();
    if (!$zlib) { die &quot;inflateInit failed: $status&quot;; }

    my $red = 0;
    my $buf;

    # TODO: inflate in smaller buffers instead of at EOF
    while (1) {
      my $numbytes = $client-&gt;read($buf, (1024 * 64), $red);
      if (!defined $numbytes) {
        die &quot;read of zlib data failed: $!&quot;;
        return -1;
      }
      last if $numbytes == 0;
      $red += $numbytes;
    }

    if ($red &gt; $expected_length) {
      warn &quot;spamd: zlib read $red &gt; expected_length $expected_length\n&quot;;
      substr ($buf, $expected_length) = '';
    }

    ($out, $status) = $zlib-&gt;inflate($buf);
    if ($status != Compress::Zlib::Z_STREAM_END()) {
      die &quot;failed to find end of zlib stream\n&quot;;
    }
  };

  if ($@) { 
    service_unavailable_error(&quot;zlib: $@&quot;);
    return -1;
  }

  $actual_length = length($out);

  # TODO: split during inflate, too
  # note that this preserves line endings
  @{$msglinesref} = map { my $s=$_; $s=~s/$/\n/gs; $s } split(/\n/, $out);
  return $actual_length;
}

sub parse_msgids {
  my ($mail) = @_;

  # Extract the Message-Id(s) for logging purposes.
  my $msgid  = $mail-&gt;get_pristine_header(&quot;Message-Id&quot;);
  my $rmsgid = $mail-&gt;get_pristine_header(&quot;Resent-Message-Id&quot;);
  foreach my $id ((\$msgid, \$rmsgid)) {
    if ( $$id ) {
      # no re &quot;strict&quot;;  # since perl 5.21.8: Ranges of ASCII printables...
      while ( $$id =~ s/\([^\(\)]*\)// )
         { }                           # remove comments and
      $$id =~ s/^\s+|\s+$//g;          # leading and trailing spaces
      $$id =~ s/\s+/ /g;               # collapse whitespaces
      $$id =~ s/^.*?&lt;(.*?)&gt;.*$/$1/;    # keep only the id itself
      $$id =~ s/[^\x21-\x7e]/?/g;      # replace all weird chars
      $$id =~ s/[&lt;&gt;]/?/g;              # plus all dangling angle brackets
      $$id =~ s/^(.+)$/&lt;$1&gt;/;          # re-bracket the id (if not empty)
    }
  }
  return ($msgid, $rmsgid);
}

sub check {
  my ( $method, $version, $start_time, $remote_hostname, $remote_hostaddr ) = @_;
  local ($_);
  my $expected_length;
  my $compress_zlib;

  # used to ensure we don't accidentally fork (bug 4370)
  my $starting_self_pid = $$;

  # Protocol version 1.0 and greater may have &quot;User:&quot; and
  # &quot;Content-length:&quot; headers.  But they're not required.

  if ( $version &gt; 1.0 ) {
    my $hdrs = {};

    return 0 unless (parse_headers($hdrs, $client));

    $expected_length = $hdrs-&gt;{expected_length};
    $compress_zlib = $hdrs-&gt;{compress_zlib};
  }

  return 0 unless do_user_handling();
  if ($&gt; == 0 &amp;&amp; !am_running_on_windows()) {
	die &quot;spamd: still running as root! dying&quot;;
  }

  my $resp = &quot;EX_OK&quot;;

  # generate mail object from input
  my ($mail, $actual_length) = parse_body($client, $expected_length,
                                          $compress_zlib, $start_time);
  return 0 unless defined($mail);       # error

  if ($compress_zlib) {
    $expected_length = $actual_length;  # previously it was the gzipped length
  }

  # attempt to fetch the message ids
  my ($msgid, $rmsgid) = parse_msgids($mail);

  $msgid        ||= &quot;(unknown)&quot;;
  $current_user ||= &quot;(unknown)&quot;;
  $current_msgid = $msgid;      # for the SIGUSR2 backtrace
  info(&quot;spamd: &quot; . ($method eq 'PROCESS' ? &quot;processing&quot; : &quot;checking&quot;)
       . &quot; message $msgid&quot;
       . ( $rmsgid ? &quot; aka $rmsgid&quot; : &quot;&quot; )
       . &quot; for ${current_user}:$&gt;&quot;);

  # Check length if we're supposed to.
  if (defined $expected_length &amp;&amp; $actual_length != $expected_length) {
    protocol_error(
      &quot;(Content-Length mismatch: Expected $expected_length bytes, got $actual_length bytes)&quot;
    );
    $mail-&gt;finish();
    return 0;
  }

  # Go ahead and check the message
  $spamtest-&gt;init(1);
  my $status = Mail::SpamAssassin::PerMsgStatus-&gt;new($spamtest, $mail);
  $status-&gt;check();

  my $msg_score     =  &amp;Mail::SpamAssassin::Util::get_tag_value_for_score($status-&gt;get_score, $status-&gt;get_required_score, $status-&gt;is_spam);
  my $msg_threshold = sprintf( &quot;%2.1f&quot;, $status-&gt;get_required_score );

  my $response_spam_status = &quot;&quot;;
  my $was_it_spam;
  if ( $status-&gt;is_spam ) {
    $response_spam_status = $method eq &quot;REPORT_IFSPAM&quot; ? &quot;Yes&quot; : &quot;True&quot;;
    $was_it_spam = 'identified spam';
  }
  else {
    $response_spam_status = $method eq &quot;REPORT_IFSPAM&quot; ? &quot;No&quot; : &quot;False&quot;;
    $was_it_spam = 'clean message';
  }

  my $spamhdr = &quot;Spam: $response_spam_status ; $msg_score / $msg_threshold&quot;;

  if ( $method eq 'PROCESS' || $method eq 'HEADERS' ) {

    $status-&gt;set_tag('REMOTEHOSTNAME', $remote_hostname);
    $status-&gt;set_tag('REMOTEHOSTADDR', $remote_hostaddr);

    # Build the message to send back and measure it
    my $msg_resp        = $status-&gt;rewrite_mail();

    if ($method eq 'HEADERS') {
      # just the headers; delete everything after first \015\012\015\012
      $msg_resp =~ s/(\015?\012\015?\012).*$/$1/gs;
    }

    my $msg_resp_length = length($msg_resp);

    if ( $version &gt;= 1.3 )    # Spamc protocol 1.3 means multi hdrs are OK
    {
      syswrite_full_buffer( $client, &quot;SPAMD/1.1 $resphash{$resp} $resp\r\n&quot; .
        &quot;Content-length: $msg_resp_length\r\n&quot; . $spamhdr . &quot;\r\n\r\n&quot; .
        $msg_resp );
    }
    elsif (
      $version &gt;= 1.2 )    # Spamc protocol 1.2 means it accepts content-length
    {
      syswrite_full_buffer( $client, &quot;SPAMD/1.1 $resphash{$resp} $resp\r\n&quot; .
        &quot;Content-length: $msg_resp_length\r\n\r\n&quot; . $msg_resp );
    }
    else                   # Earlier than 1.2 didn't accept content-length
    {
      syswrite_full_buffer( $client, &quot;SPAMD/1.0 $resphash{$resp} $resp\r\n&quot; . $msg_resp );
    }
  }
  else                     # $method eq 'CHECK' et al
  {
    syswrite_full_buffer( $client, &quot;SPAMD/1.1 $resphash{$resp} $resp\r\n&quot; );

    if ( $method eq &quot;CHECK&quot; ) {
      syswrite( $client, &quot;$spamhdr\r\n\r\n&quot; );
    }
    else {
      my $msg_resp = '';

      if ( $method eq &quot;REPORT&quot;
        or ( $method eq &quot;REPORT_IFSPAM&quot; and $status-&gt;is_spam ) )
      {
        $msg_resp = $status-&gt;get_report;
      }
      elsif ( $method eq &quot;REPORT_IFSPAM&quot; ) {

        # message is ham, $msg_resp remains empty
      }
      elsif ( $method eq &quot;SYMBOLS&quot; ) {
        $msg_resp = $status-&gt;get_names_of_tests_hit;
        $msg_resp .= &quot;\r\n&quot; if ( $version &lt; 1.3 );
      }
      else {
        die &quot;spamd: unknown method $method&quot;;
      }

      if ( $version &gt;= 1.3 )    # Spamc protocol &gt; 1.2 means multi hdrs are OK
      {
        my $msg_resp_length = length($msg_resp);
        syswrite_full_buffer( $client,
                  &quot;Content-length: $msg_resp_length\r\n&quot; . 
                  $spamhdr . &quot;\r\n\r\n&quot; . $msg_resp );
      }
      else {
        syswrite_full_buffer( $client, $spamhdr . &quot;\r\n\r\n&quot; . $msg_resp );
      }
    }
  }

  my $scantime = sprintf( &quot;%.1f&quot;, time - $start_time );

  info(&quot;spamd: $was_it_spam ($msg_score/$msg_threshold) for $current_user:$&gt; in&quot;
       . &quot; $scantime seconds, $actual_length bytes.&quot; );

  # add a summary &quot;result:&quot; line, based on mass-check format
  my @extra;
  push(@extra, &quot;scantime=&quot;.$scantime, &quot;size=$actual_length&quot;,
            &quot;user=&quot;.$current_user, &quot;uid=&quot;.$&gt;,
            &quot;required_score=&quot;.$msg_threshold,
            &quot;rhost=&quot;.$remote_hostname, &quot;raddr=&quot;.$remote_hostaddr,
            &quot;rport=&quot;.$remote_port);

  {
    # no re &quot;strict&quot;;  # since perl 5.21.8: Ranges of ASCII printables...
    my $safe = $msgid; $safe =~ s/[\x00-\x20\s,]/_/gs; push(@extra, &quot;mid=$safe&quot;);
  }
  if ($rmsgid) {
    # no re &quot;strict&quot;;  # since perl 5.21.8: Ranges of ASCII printables...
    my $safe = $rmsgid; $safe =~ s/[\x00-\x20\s,]/_/gs; push(@extra, &quot;rmid=$safe&quot;);
  }
  if (defined $status-&gt;{bayes_score}) {
    push(@extra, &quot;bayes=&quot;.sprintf(&quot;%06f&quot;, $status-&gt;{bayes_score}));
  }
  push(@extra, &quot;autolearn=&quot;.$status-&gt;get_autolearn_status());
  push(@extra, $status-&gt;get_spamd_result_log_items());

  my $yorn = $status-&gt;is_spam() ? 'Y' : '.';
  my $score = $status-&gt;get_score();
  my $tests = join(&quot;,&quot;, sort(grep(length,$status-&gt;get_names_of_tests_hit())));

  my $log = sprintf(&quot;spamd: result: %s %2d - %s %s&quot;, $yorn, $score,
	       $tests, join(&quot;,&quot;, @extra));
  info($log);

  # bug 3808: log scan results to any listening plugins, too
  $spamtest-&gt;call_plugins(&quot;log_scan_result&quot;, { result =&gt; $log });

  # bug 3466: handle the bayes expiry bits after the results were returned to
  # the client.  keeps clients from timing out.  if bayes_expiry_due is set,
  # then the opportunistic check has already checked.  go ahead and do another
  # sync/expire run.
  if ($status-&gt;{'bayes_expiry_due'}) {
    dbg(&quot;spamd: bayes expiry was marked as due, running post-check&quot;);
    $spamtest-&gt;rebuild_learner_caches();
    $spamtest-&gt;finish_learner();
  }

  $status-&gt;finish();    # added by jm to allow GC'ing
  $mail-&gt;finish();

  # ensure we didn't accidentally fork (bug 4370)
  if ($starting_self_pid != $$) {
    eval { warn(&quot;spamd: accidental fork: $$ != $starting_self_pid&quot;); };
    force_die(0);        # avoid END and dtor processing
  }

  return 1;
}

sub dotell {
  my ($method, $version, $start_time, $remote_hostname, $remote_hostaddr) = @_;
  local ($_);

  my $hdrs = {};

  return 0 unless (parse_headers($hdrs, $client));

  my $expected_length = $hdrs-&gt;{expected_length};
  my $compress_zlib = $hdrs-&gt;{compress_zlib};

  return 0 unless do_user_handling();
  if ($&gt; == 0 &amp;&amp; !am_running_on_windows()) {
	die &quot;spamd: still running as root! dying&quot;;
  }

  if (!$opt{tell}) {
    service_unavailable_error(&quot;TELL commands are not enabled, set the --allow-tell switch.&quot;);
    return 0;
  }

  if ($hdrs-&gt;{set_local} &amp;&amp; $hdrs-&gt;{remove_local}) {
    protocol_error(&quot;Unable to set local and remove local in the same operation.&quot;);
    return 0;
  }

  if ($hdrs-&gt;{set_remote} &amp;&amp; $hdrs-&gt;{remove_remote}) {
    protocol_error(&quot;Unable to set remote and remove remote in the same operation.&quot;);
    return 0;
  }

  if ($opt{'sql-config'} &amp;&amp; !defined($current_user)) {
    unless (handle_user_sql('nobody')) {
      service_unavailable_error(&quot;Error fetching user preferences via SQL&quot;);
      return 0;
    }
  }

  if ($opt{'ldap-config'} &amp;&amp; !defined($current_user)) {
    handle_user_ldap('nobody');
  }

  my $resp = &quot;EX_OK&quot;;

  # generate mail object from input
  my($mail, $actual_length) =
    parse_body($client, $expected_length, $compress_zlib, $start_time);

  return 0 unless defined($mail);       # error

  if ($compress_zlib) {
    $expected_length = $actual_length;  # previously it was the gzipped length
  }

  if ( $mail-&gt;get_header(&quot;X-Spam-Checker-Version&quot;) ) {
    my $new_mail = $spamtest-&gt;parse($spamtest-&gt;remove_spamassassin_markup($mail), 1);
    $mail-&gt;finish();
    $mail = $new_mail;
  }

  # attempt to fetch the message ids
  my ($msgid, $rmsgid) = parse_msgids($mail);

  $msgid        ||= &quot;(unknown)&quot;;
  $current_user ||= &quot;(unknown)&quot;;

  # Check length if we're supposed to.
  if (defined $expected_length &amp;&amp; $actual_length != $expected_length) {
    protocol_error(&quot;(Content-Length mismatch: Expected $expected_length bytes, got $actual_length bytes)&quot;);
    $mail-&gt;finish();
    return 0;
  }

  my @did_set;
  my @did_remove;

  # bug 5740 Don't bayes learn if global configs disabkle bayes,
  #  also give user some control with userprefs bayes_learn_during_report option

  if (defined $spamtest-&gt;{bayes_scanner} &amp;&amp; $spamtest-&gt;{conf}-&gt;{bayes_learn_during_report}) {
    if ($hdrs-&gt;{set_local}) {
      my $status = $spamtest-&gt;learn($mail, undef, ($hdrs-&gt;{message_class} eq 'spam' ? 1 : 0), 0);

      push(@did_set, 'local') if ($status-&gt;did_learn());
      $status-&gt;finish();
    }

    if ($hdrs-&gt;{remove_local}) {
      my $status = $spamtest-&gt;learn($mail, undef, undef, 1);

      push(@did_remove, 'local') if ($status-&gt;did_learn());
      $status-&gt;finish();
    }
  }

  if ($hdrs-&gt;{set_remote}) {
    require Mail::SpamAssassin::Reporter;
    my $msgrpt = Mail::SpamAssassin::Reporter-&gt;new($spamtest, $mail);

    push(@did_set, 'remote') if ($msgrpt-&gt;report());
  }

  if ($hdrs-&gt;{remove_remote}) {
    require Mail::SpamAssassin::Reporter;
    my $msgrpt = Mail::SpamAssassin::Reporter-&gt;new($spamtest, $mail);

    push(@did_remove, 'remote') if ($msgrpt-&gt;revoke());
  }

  my $hdr = &quot;&quot;;
  my $info_str;

  if (scalar(@did_set)) {
    $hdr .= &quot;DidSet: &quot; . join(',', @did_set) . &quot;\r\n&quot;;
    $info_str .= &quot; Setting &quot; . join(',', @did_set) . &quot; &quot;;
  }

  if (scalar(@did_remove)) {
    $hdr .= &quot;DidRemove: &quot; . join(',', @did_remove) . &quot;\r\n&quot;;
    $info_str .= &quot; Removing &quot; . join(',', @did_remove) . &quot; &quot;;
  }

  if (!$info_str) {
    $info_str = &quot; Did nothing &quot;;
  }

  print $client &quot;SPAMD/1.1 $resphash{$resp} $resp\r\n&quot;,
    $hdr . &quot;\r\n\r\n&quot;;

  my $scantime = sprintf( &quot;%.1f&quot;, time - $start_time );

  info(&quot;spamd: Tell:${info_str}for $current_user:$&gt; in&quot;
       . &quot; $scantime seconds, $actual_length bytes&quot;);

  $mail-&gt;finish();
  return 1;
}

sub doskip_or_ping {
  my ($method, $version, $start_time, $remote_hostname, $remote_hostaddr) = @_;

  if ( $version &gt;= 1.5 ) {
    # Spamc protocol 1.5 means client is expected to send a protocol header
    # (usually just a null header), followed by an empty line
    # Fixes Bug 6187.

    my $hdrs = {};
    return 0 unless (parse_headers($hdrs, $client));
  }

  if ($method eq 'PING') {
    print $client &quot;SPAMD/1.5 $resphash{EX_OK} PONG\r\n&quot;;
  }

  return 1;
}

###########################################################################

sub do_user_handling {
  if ($setuid_to_user &amp;&amp; $&gt; == 0) {
    handle_setuid_to_user();
  }

  if ( $opt{'sql-config'} &amp;&amp; !defined($current_user) ) {
    unless ( handle_user_sql('nobody') ) {
      service_unavailable_error(&quot;Error fetching user preferences via SQL&quot;);
      return 0;
    }
  }

  if ( $opt{'ldap-config'} &amp;&amp; !defined($current_user) ) {
    handle_user_ldap('nobody');
  }

  dbg (&quot;spamd: running as uid $&gt;&quot;);
  return 1;
}

# generalised header parser.  
sub parse_headers {
  my ($hdrs, $client) = @_;

  my $got_user_header;

  # max 255 headers
  for my $hcount ( 0 .. 255 ) {
    my $line = $client-&gt;getline;

    unless (defined $line) {
      protocol_error(&quot;(EOF during headers)&quot;);
      return 0;
    }
    $line =~ s/\r\n$//;

    if (!length $line) {    # end of headers
      return 1;
    }

    my ($header, $value) = split (/:\s*/, $line, 2);
    unless (defined $value) {
      protocol_error(&quot;(header not in 'Name: value' format)&quot;);
      return 0;
    }

    if ($header eq 'Content-length') {
      return 0 unless got_clen_header($hdrs, $header, $value);
    }
    elsif ($header eq 'User') {
      return 0 unless got_user_header($hdrs, $header, $value);
      $got_user_header++;
    }
    elsif ($header eq 'Message-class') {
      return 0 unless got_message_class_header($hdrs, $header, $value);
    }
    elsif ($header eq 'Set') {
      return 0 unless got_set_header($hdrs, $header, $value);
    }
    elsif ($header eq 'Remove') {
      return 0 unless got_remove_header($hdrs, $header, $value);
    }
    elsif ($header eq 'Compress') {
      return 0 unless got_compress_header($hdrs, $header, $value);
    }
  }

  # avoid too-many-headers DOS attack
  protocol_error(&quot;(too many headers)&quot;);
  return 0;
}

# We'll run handle user unless we've been told not
# to process per-user config files.  Otherwise
# we'll check and see if we need to try SQL
# lookups.  If $opt{'user-config'} is true, we need to try
# their config file and then do the SQL lookup.
# If $opt{'user-config'} IS NOT true, we skip the conf file and
# only need to do the SQL lookup if $opt{'sql-config'} IS
# true.  (I got that wrong the first time.)
#
sub got_user_header {
  my ( $client, $header, $value ) = @_;

  { # no re &quot;strict&quot;;  # since perl 5.21.8: Ranges of ASCII printables...
    local $1;
    if ( $value !~ /^([\x20-\xFF]*)$/ ) {
      protocol_error(&quot;(User header contains control chars)&quot;);
      return 0;
    }
    $current_user = $1;
  }

  if ( !$opt{'user-config'} ) {
    if ( $opt{'sql-config'} ) {
      unless ( handle_user_sql($current_user) ) {
        service_unavailable_error(&quot;Error fetching user preferences via SQL&quot;);
	return 0;
      }
    }
    elsif ( $opt{'ldap-config'} ) {
      handle_user_ldap($current_user);
    }
    elsif ( $opt{'virtual-config-dir'} ) {
      handle_virtual_config_dir($current_user);
    }
    elsif ( $opt{'setuid-with-sql'} ) {
      unless ( handle_user_setuid_with_sql($current_user) ) {
        service_unavailable_error(&quot;Error fetching user preferences via SQL&quot;);
	return 0;
      }
      $setuid_to_user = 1;    #to benefit from any paranoia.
    }
    elsif ( $opt{'setuid-with-ldap'} ) {
      handle_user_setuid_with_ldap($current_user);
      $setuid_to_user = 1;    # as above
    }
    else {
      handle_user_setuid_basic($current_user);
    }
  }
  else {
    handle_user_setuid_basic($current_user);
    if ( $opt{'sql-config'} ) {
      unless ( handle_user_sql($current_user) ) {
        service_unavailable_error(&quot;Error fetching user preferences via SQL&quot;);
	return 0;
      }
    }
  }
  return 1;
}

sub got_clen_header {
  my ( $hdrs, $header, $value ) = @_;
  if ( $value !~ /^(\d*)$/ ) {
    protocol_error(&quot;(Content-Length contains non-numeric bytes)&quot;);
    return 0;
  }
  $hdrs-&gt;{expected_length} = $1;
  return 1;
}

sub got_message_class_header {
  my ($hdrs, $header, $value) = @_;

  unless (lc($value) ne 'spam' || lc($value) ne 'ham') {
    protocol_error(&quot;(Message-class header contains invalid class)&quot;);
    return 0;
  }
  $hdrs-&gt;{message_class} = $value;

  return 1;
}

sub got_set_header {
  my ($hdrs, $header, $value) = @_;

  $hdrs-&gt;{set_local} = 0;
  $hdrs-&gt;{set_remote} = 0;

  if ($value =~ /local/i) {
    $hdrs-&gt;{set_local} = 1;
  }

  if ($value =~ /remote/i) {
    $hdrs-&gt;{set_remote} = 1;
  }

  return 1;
}

sub got_remove_header {
  my ($hdrs, $header, $value) = @_;

  $hdrs-&gt;{remove_local} = 0;
  $hdrs-&gt;{remove_remote} = 0;

  if ($value =~ /local/i) {
    $hdrs-&gt;{remove_local} = 1;
  }

  if ($value =~ /remote/i) {
    $hdrs-&gt;{remove_remote} = 1;
  }

  return 1;
}

sub got_compress_header {
  my ($hdrs, $header, $value) = @_;

  if ($value =~ /zlib/i) {
    eval { require Compress::Zlib; };
    if ($@) {
      protocol_error(&quot;(compression not supported, Compress::Zlib not installed: $@)&quot;);
      return 0;
    }
    $hdrs-&gt;{compress_zlib} = 1;
    dbg(&quot;spamd: compress header received: $value&quot;);
  }
  else {
    protocol_error(&quot;(compression type not supported: $value)&quot;);
    return 0;
  }

  return 1;
}

sub protocol_error {
  my ($err) = @_;
  my $resp = &quot;EX_PROTOCOL&quot;;
  syswrite($client, &quot;SPAMD/1.0 $resphash{$resp} Bad header line: $err\r\n&quot;);
  warn(&quot;spamd: bad protocol: header error: $err\n&quot;);
}

sub service_unavailable_error {
  my ($err) = @_;
  my $resp = &quot;EX_UNAVAILABLE&quot;;
  syswrite($client,
	   &quot;SPAMD/1.0 $resphash{$resp} Service Unavailable: $err\r\n&quot;);
  warn(&quot;spamd: service unavailable: $err\n&quot;);
}

sub service_timeout {
  my ($err) = @_;
  my $resp = &quot;EX_TIMEOUT&quot;;
  print $client &quot;SPAMD/1.0 $resphash{$resp} Timeout: $err\r\n&quot;;
  warn(&quot;spamd: timeout: $err\n&quot;);
}

###########################################################################

sub seteuid_to_user {
  return if (am_running_on_windows() || $&gt; != 0);
  
  my $suidto = $opt{'username'} || $opt{'default-user'};
  my ($name, $pwd, $uid, $gid, $quota, $comment, $gcos, $suiddir, $etc) = getpwnam($suidto);

  if (!defined $uid) {
      die &quot;spamd: seteuid_to_user (getpwnam) unable to find user: '$suidto'\n&quot;;
  }

  $) = (get_user_groups($uid));     # change eGID
  $&gt; = $uid;                        # change eUID
  if ( !defined($uid) || ( $&gt; != $uid and $&gt; != ( $uid - 2**32 ) ) ) {
    # make it fatal to avoid security breaches
    die(&quot;spamd: fatal error: setuid to $suidto failed&quot;);
  }
}

sub restore_euid {
  return if (am_running_on_windows());
  
  if (($&gt; != $&lt;) &amp;&amp; ($&gt; != ($&lt; - 2**32))) {
    $) = &quot;$( $(&quot;;    # change eGID
    $&gt; = $&lt;;         # change eUID
    # check again; ensure the change happened
    if ($&gt; != $&lt; &amp;&amp; ($&gt; != ( $&lt; - 2**32))) {
      # make it fatal to avoid security breaches
      die(&quot;spamd: return setuid failed&quot;);
    }
  }
}

sub handle_user_setuid_basic {
  my $username = shift;

  # If $opt{'username'} in use, then look up userinfo for that uid;
  # otherwise use what was passed via $username
  #
  my $suidto = $username;
  if ( $opt{'username'} ) {
    $suidto = $opt{'username'};
  }
  my ($name, $pwd, $uid, $gid, $quota, $comment, $gcos, $suiddir, $etc) =
      am_running_on_windows() ? ('nobody') : getpwnam($suidto);

  if (!defined $uid) {
      my $errmsg =
        &quot;spamd: handle_user (getpwnam) unable to find user: '$suidto'&quot;;
      die &quot;$errmsg\n&quot; if $spamtest-&gt;{'paranoid'};
      # if we are given a username, but can't look it up, maybe name
      # services are down?  let's break out here to allow them to get
      # 'defaults' when we are not running paranoid
      info($errmsg);
      return 0;
  }

  if ($setuid_to_user) {
    $) = (get_user_groups($uid));     # change eGID
    $&gt; = $uid;                        # change eUID
    if ( !defined($uid) || ( $&gt; != $uid and $&gt; != ( $uid - 2**32 ) ) ) {
      # make it fatal to avoid security breaches
      die(&quot;spamd: fatal error: setuid to $suidto failed&quot;);
    }
    else {
      info(&quot;spamd: setuid to $suidto succeeded&quot;);
    }
  }

  my $userdir;

  # if $opt{'user-config'} is in use, read user prefs from the remote
  # username's home dir (if it exists): bug 5611
  if ( $opt{'user-config'} ) {
    my $prefsfrom = $username;  # the one passed, NOT $opt{username}

    if ($prefsfrom eq $suidto) {
      $userdir = $suiddir;  # reuse the already-looked-up info, tainted
    } elsif ( $opt{'vpopmail'} ) {
      #
      # If vpopmail config enabled then set $userdir to virtual homedir
      #
      my $username_untainted;
      $username_untainted =
        untaint_var($username)  if $username =~ /^[-:,.=+A-Za-z0-9_\@~]+\z/;
      my $vpopdir = $suiddir; # This should work with common vpopmail setups
      $userdir = `$vpopdir/bin/vuserinfo -d \Q$username_untainted\E`;
      if ($? == 0) {
        chomp($userdir);
      } else {
        $userdir = handle_user_vpopmail($username_untainted,$vpopdir);
      }
    } else {
      $userdir = (getpwnam($prefsfrom))[7];
    }

    # we *still* die if this can't be found
    if (!defined $userdir) {
        my $errmsg =
          &quot;spamd: handle_user (userdir) unable to find user: '$prefsfrom'\n&quot;;
        die $errmsg if $spamtest-&gt;{'paranoid'};
        # if we are given a username, but can't look it up, maybe name
        # services are down?  let's break out here to allow them to get
        # 'defaults' when we are not running paranoid
        info($errmsg);
        return 0;
    }
  }

  # call this anyway, regardless of --user-config, so that
  # signal_user_changed() is called
  handle_user_set_user_prefs(untaint_var($userdir), $username);
}

sub handle_user_vpopmail {
  #
  # If vuserinfo failed $username could be an alias
  # As the alias could be an alias itself we'll try to resolve it recursively
  # Because we're mistrusting vpopmail we'll set off an alarm
  #
  my $username = shift;
  my $vpopdir = shift;
  my $userdir;
  my $vpoptimeout = 5;
  my $vptimer = Mail::SpamAssassin::Timeout-&gt;new({ secs =&gt; $vpoptimeout });

  $vptimer-&gt;run(sub {
    my $vpopusername = $username;
    my @aliases = split(/\n/, `$vpopdir/bin/valias \Q$vpopusername\E`);
    while (@aliases) {
      my $vpopusername_tainted = shift(@aliases);
      local $1;
      if ($vpopusername_tainted =~ /-&gt; &amp;?(.+)$/) {
        $vpopusername = untaint_var($1);
        if ($vpopusername =~ s{^(/.+)/Maildir/$}{$1}) {
          # this is the path to a real mailbox
          $userdir = $vpopusername;
        } elsif ($vpopusername !~ /^[#| \t]/ &amp;&amp;
                 $vpopusername =~ /^[^@ \t]+\@[^@ \t]+\s*$/) {
          # this is a forward to another e-mail address
          $vpopusername =~ s{^.+ -&gt; (.+)}{$1};
          $vpopusername_tainted = `$vpopdir/bin/vuserinfo -d \Q$vpopusername\E`;
          if ($? == 0 &amp;&amp; $vpopusername_tainted ne '') {
            $userdir = untaint_var($vpopusername_tainted);
          } else {
            unshift(@aliases,
                    split(/\n/, `$vpopdir/bin/valias \Q$vpopusername\E`));
          }
        }
        last if defined $userdir;
      }
    }
  });

  if ($vptimer-&gt;timed_out()) {
    dbg(&quot;spamd: timed out resolving vpopmail user/alias '%s'&quot;, $username);
    undef $userdir;
  } elsif (!defined($userdir)) {
    dbg(&quot;spamd: failed to resolve vpopmail user/alias '%s'&quot;, $username);
  } else {
    chomp($userdir);
  }
  return $userdir;
}

sub handle_user_set_user_prefs {
  my ($dir, $username) = @_;

  # don't do this if we weren't passed a directory
  if ($dir) {
    my $cf_file = $dir . &quot;/.spamassassin/user_prefs&quot;;
    create_default_cf_if_needed( $cf_file, $username, $dir );
    $spamtest-&gt;read_scoreonly_config($cf_file);
  }

  # signal_user_changed will ignore undef user_dirs, so this is ok
  $spamtest-&gt;signal_user_changed(
    {
      username =&gt; $username,
      user_dir =&gt; $dir
    }
  );

  return 1;
}

# Handle user configs without the necessity of having individual users or a
# SQL/LDAP database.
sub handle_virtual_config_dir {
  my ($username) = @_;

  my $dir = $opt{'virtual-config-dir'};
  my $userdir;
  my $prefsfile;

  if ( defined $dir ) {
    my $safename = $username;
    $safename =~ s/[^-A-Za-z0-9\+_\.\,\@\=]/_/gs;
    my $localpart = '';
    my $domain    = '';
    if ( $safename =~ /^(.*)\@(.*)$/ ) { $localpart = $1; $domain = $2; }

    # Do userdir lookup exim-style. 
    # If a config for the full address exists, use that one
    # else look for a domain default
    if ($dir=~/%x/) {
      ($userdir=$dir)=~s/%x/${safename}/g;

      $prefsfile=$userdir.'/user_prefs';
      if (-f $prefsfile) {
        $dir = $userdir;

      } else {
        $dir =~ s/%x/${domain}/g;

        $prefsfile = $dir.'/user_prefs';
        $userdir   = $dir;
      }

    # Use the normal escaping
    } else { 
      $dir =~ s/\%u/${safename}/g;
      $dir =~ s/\%l/${localpart}/g;
      $dir =~ s/\%d/${domain}/g;
      $dir =~ s/\%\%/\%/g;

      $userdir   = $dir;
      $prefsfile = $dir . '/user_prefs';
    }

    # Log that the default configuration is being used for a user.
    info(&quot;spamd: using default config for $username: $prefsfile&quot;);
  }

  if ( -f $prefsfile ) {

    # Found a config, load it.
    $spamtest-&gt;read_scoreonly_config($prefsfile);
  }

  # assume that $userdir will be a writable directory we can
  # use for Bayes dbs etc.
  $spamtest-&gt;signal_user_changed(
    {
      username =&gt; $username,
      userstate_dir =&gt; $userdir,
      user_dir =&gt; $userdir
    }
  );
  return 1;
}

sub handle_user_sql {
  my ($username) = @_;

  unless ( $spamtest-&gt;load_scoreonly_sql($username) ) {
    return 0;
  }
  $spamtest-&gt;signal_user_changed(
    {
      username =&gt; $username,
      user_dir =&gt; undef
    }
  );
  return 1;
}

sub handle_user_ldap {
  my $username = shift;
  dbg(&quot;ldap: entering handle_user_ldap($username)&quot;);
  $spamtest-&gt;load_scoreonly_ldap($username);
  $spamtest-&gt;signal_user_changed(
    {
      username =&gt; $username,
      user_dir =&gt; undef
    }
  );
  return 1;
}

sub handle_user_setuid_with_sql {
  my $username = shift;

  # Bug 6313: interestingly, if $username is not tainted than $pwd, $gcos and
  # $etc end up tainted but other fields not;  if $username _is_ tainted,
  # getpwnam does not complain, but all returned fields are tainted (which
  # makes sense, but is worth remembering)
  #
  my ($name, $pwd, $uid, $gid, $quota, $comment, $gcos, $dir, $etc) =
      getpwnam(untaint_var($username));

  if (!$spamtest-&gt;{'paranoid'} &amp;&amp; !defined($uid)) {
    # if we are given a username, but can't look it up, maybe name
    # services are down?  let's break out here to allow them to get
    # 'defaults' when we are not running paranoid
    info(&quot;spamd: handle_user (sql) unable to find user: $username&quot;);
    return 0;
  }

  if ($setuid_to_user) {
    $) = (get_user_groups($uid));     # change eGID
    $&gt; = $uid;                        # change eUID
    if (!defined($uid) || ($&gt; != $uid and $&gt; != ($uid - 2**32))) {
      # make it fatal to avoid security breaches
      die(&quot;spamd: fatal error: setuid to $username failed&quot;);
    }
    else {
      info(&quot;spamd: setuid to $username succeeded, reading scores from SQL&quot;);
    }
  }

  my $spam_conf_dir = $dir . '/.spamassassin'; # needed for Bayes, etc.

  if ( ($opt{'user-config'} || defined $opt{'home_dir_for_helpers'})
       &amp;&amp; ! -d $spam_conf_dir ) {
    if (mkdir $spam_conf_dir, 0700) {
      info(&quot;spamd: created $spam_conf_dir for $username&quot;);
    }
    else {
      info(&quot;spamd: failed to create $spam_conf_dir for $username&quot;);
    }
  }

  unless ($spamtest-&gt;load_scoreonly_sql($username)) {
    return 0;
  }

  $spamtest-&gt;signal_user_changed( { username =&gt; $username } );
  return 1;
}

sub handle_user_setuid_with_ldap {
  my $username = shift;
  my ($name, $pwd, $uid, $gid, $quota, $comment, $gcos, $dir, $etc) =
      getpwnam($username);

  if (!$spamtest-&gt;{'paranoid'} &amp;&amp; !defined($uid)) {
    # if we are given a username, but can't look it up, maybe name
    # services are down?  let's break out here to allow them to get
    # 'defaults' when we are not running paranoid
    info(&quot;spamd: handle_user (ldap) unable to find user: $username&quot;);
    return 0;
  }

  if ($setuid_to_user) {
    $) = (get_user_groups($uid));    # change eGID
    $&gt; = $uid;           # change eUID
    if (!defined($uid) || ($&gt; != $uid and $&gt; != ($uid - 2**32))) {
      # make it fatal to avoid security breaches
      die(&quot;spamd: fatal error: setuid to $username failed&quot;);
    }
    else {
      info(&quot;spamd: setuid to $username succeeded, reading scores from LDAP&quot;);
    }
  }

  my $spam_conf_dir = $dir . '/.spamassassin'; # needed for Bayes, etc.
  if (! -d $spam_conf_dir) {
    if (mkdir $spam_conf_dir, 0700) {
      info(&quot;spamd: created $spam_conf_dir for $username&quot;);
    }
    else {
      info(&quot;spamd: failed to create $spam_conf_dir for $username&quot;);
    }
  }

  $spamtest-&gt;load_scoreonly_ldap($username);

  $spamtest-&gt;signal_user_changed( { username =&gt; $username } );
  return 1;
}

sub create_default_cf_if_needed {
  my ( $cf_file, $username, $userdir ) = @_;

  # Parse user scores, creating default .cf if needed:
  if ( !-r $cf_file &amp;&amp; !$spamtest-&gt;{'dont_copy_prefs'} ) {
    info(&quot;spamd: creating default_prefs: $cf_file&quot;);

    # If vpopmail config enabled then pass virtual homedir onto
    # create_default_prefs via $userdir
    $spamtest-&gt;create_default_prefs( $cf_file, $username, $userdir );

    if (! -r $cf_file) {
      info(&quot;spamd: failed to create readable default_prefs: $cf_file&quot;);
    }
  }
}

# sig handlers: parent process
sub setup_parent_sig_handlers {
  $SIG{HUP}  = \&amp;restart_handler;
  $SIG{CHLD} = \&amp;child_handler;
  $SIG{INT}  = \&amp;kill_handler;
  $SIG{TERM} = \&amp;kill_handler;
  $SIG{PIPE} = 'IGNORE';
}

# sig handlers: child processes
sub setup_child_sig_handlers {
  # note: all the signals changed in setup_parent_sig_handlers() must
  # be reset to appropriate values here!
  my $h = 'DEFAULT';
  if (am_running_on_windows()) {
    # on win32 the parent never receives SIGCHLD
    $h = sub { my($sig) = @_;
               info(&quot;spamd: child got SIG$sig, exiting&quot;);
               kill QUIT =&gt; 0;
               exit 0;
             };
  }
  $SIG{$_} = $h  foreach qw(HUP INT TERM CHLD);
  $SIG{PIPE} = 'IGNORE';
}

sub kill_handler {
  my ($sig) = @_;
  info(&quot;spamd: server killed by SIG$sig, shutting down&quot;);

  for my $socket_info (@listen_sockets) {
    next if !$socket_info;

    my $socket = $socket_info-&gt;{socket};
    $socket-&gt;close  if $socket;  # ignoring status

    my $path = $socket_info-&gt;{path};
    if (defined $path) {  # unlink a UNIX domain socket
      unlink($path) or warn &quot;spamd: cannot unlink $path: $!\n&quot;;
    }
  }

  if (defined($opt{'pidfile'})) {
    unlink($opt{'pidfile'})
      or warn &quot;spamd: cannot unlink $opt{'pidfile'}: $!\n&quot;;
  }

  $SIG{CHLD} = 'DEFAULT';    # we're going to kill our children
  if ($scaling) {
    $scaling-&gt;set_exiting_flag(); # don't start new ones
  }
  my $killsig = am_running_on_windows() ? 'KILL' : 'INT';
  foreach my $pid (keys %children) {
    kill($killsig, $pid)
      or info(&quot;spamd: cannot send SIG$killsig to child process [$pid]: $!&quot;);
  }
  exit 0;
}

# takes care of dead children
sub child_handler {
  my ($sig) = @_;

  # do NOT call syslog here unless the child's pid is in our list of known
  # children.  This is due to syslog-ng brokenness -- bugs 3625, 4237;
  # see also bug 6745.

  # clean up any children which have exited
  for (;;) {
    # waitpid returns a pid of the deceased process, or -1 if there is no
    # such child process. On some systems, a value of 0 indicates that there
    # are processes still running. Note that Windows uses negative pids for
    # child processes - bug 6376, bug 6356.
    #
    my $pid = waitpid(-1, WNOHANG);
    last if !$pid || $pid == -1;
    push(@children_exited, [$pid, $?, $sig, time]);
  }

  $SIG{CHLD} = \&amp;child_handler;    # reset as necessary, should be at end
}

# takes care of dead children, as noted by a child_handler()
# called in a main program flow (not from a signal handler)
#
sub child_cleaner {
  while (@children_exited) {
    my $tuple = shift(@children_exited);
    next if !$tuple;  # just in case
    my($pid, $child_stat, $sig, $timestamp) = @$tuple;

    # ignore this child if we didn't realise we'd forked it. bug 4237
    next if !defined $children{$pid};

    # remove them from our child listing
    delete $children{$pid};

    if ($scaling) {
      $scaling-&gt;child_exited($pid);
    } else {
      my $sock = $backchannel-&gt;get_socket_for_child($pid);
      if ($sock) { $sock-&gt;close(); }
    }
    info(&quot;spamd: handled cleanup of child pid [%s]%s: %s&quot;,
         $pid, (defined $sig ? &quot; due to SIG$sig&quot; : &quot;&quot;),
         exit_status_str($child_stat,0));
  }
}

sub restart_handler {
  my ($sig) = @_;
  info(&quot;spamd: server hit by SIG$sig, restarting&quot;);

  $SIG{CHLD} = 'DEFAULT';    # we're going to kill our children
  if ($scaling) {
    $scaling-&gt;set_exiting_flag(); # don't start new ones
  }

  foreach (keys %children) {
    kill 'INT' =&gt; $_;
    my $pid = waitpid($_, 0);
    my $child_stat = $pid &gt; 0 ? $? : undef;
    if ($scaling) {
      $scaling-&gt;child_exited($pid);
    }
    info(&quot;spamd: child [%s] killed successfully: %s&quot;,
         $pid, exit_status_str($child_stat,0));
  }
  %children = ();

  for my $socket_info (@listen_sockets) {
    next if !$socket_info;
    my $socket = $socket_info-&gt;{socket};
    next if !$socket;
    my $socket_specs = $socket_info-&gt;{specs};
    $socket-&gt;shutdown(2) if !$socket-&gt;eof;
    $socket-&gt;close;
    if ($socket-&gt;isa('IO::Socket::UNIX') &amp;&amp; defined $socket_specs) {
      unlink($socket_specs)
        or warn &quot;spamd: cannot unlink $socket_specs: $!\n&quot;;
    }
    info(&quot;spamd: server socket closed, type %s&quot;, ref $socket);
  }

  $got_sighup = 1;
}

sub backtrace_handler {
  Carp::cluck(&quot;spamd: caught SIGUSR2 - dumping backtrace. &quot;.
        &quot;most recent message: $current_msgid\n&quot;);
}

my  $serverstarted = 0;

sub serverstarted {
  $serverstarted = 1;
}

sub daemonize {
  # bug 8036 - ensure ps legacy name shows up as spamd even if command line call was perl path_to_spamd
  $0 = 'spamd' unless would_log(&quot;dbg&quot;);

  # be a nice daemon and chdir to the root so we don't block any
  # unmount attempts
  chdir '/' or die &quot;spamd: cannot chdir to /: $!\n&quot;;

  # Redirect in and out to the bit bucket
  open STDIN,  &quot;&lt;/dev/null&quot; or die &quot;spamd: cannot read from /dev/null: $!\n&quot;;
  open STDOUT, &quot;&gt;/dev/null&quot; or die &quot;spamd: cannot write to /dev/null: $!\n&quot;;

  # Remove the stderr logger
  Mail::SpamAssassin::Logger::remove('stderr');

  # Here we go...
  $SIG{USR1} = \&amp;serverstarted;
  defined( my $pid = fork ) or die &quot;spamd: cannot fork: $!\n&quot;;
  if ($pid) {
    my $child_stat;
    # Bug 6191, Bug 6258: takes almost two minutes on a slow machine
    # for a forked child process to report back, bump limit to 180 seconds
    for (my $retry=180, my $waited=0;
         $retry &gt; 0 &amp;&amp; !$serverstarted &amp;&amp; $waited != $pid;
         $retry--)
    {
      warn(&quot;waitpid failed: $waited $!&quot;)  if $waited;
      sleep 1;
      $waited = waitpid($pid, WNOHANG);
      $child_stat = $?  if $waited &gt; 0;
    }
    die sprintf(&quot;child process [%s] exited or timed out &quot;.
                &quot;without signaling production of a PID file: %s&quot;,
                $pid, exit_status_str($child_stat,0)) unless $serverstarted;
    exit;
  }
  delete  $SIG{USR1};
  setsid or die &quot;spamd: cannot start new session: $!\n&quot;;

  # Now we can redirect the errors, too.
  open STDERR, '&gt;&amp;STDOUT' or die &quot;spamd: cannot duplicate stdout: $!\n&quot;;

  dbg(&quot;spamd: successfully daemonized&quot;);
}

sub set_allowed_ip {
  foreach (@_) {
    my $ip = $_;
    local($1,$2);
    # strip optional square brackets
    $ip =~ s{^ \[ (.*) \] \z}{$1}xs
    || $ip =~ s{^ \[ (.*) \] ( / \d+ ) \z}{$1$2}xs;
  # dbg(&quot;spamd: set_allowed_ip %s&quot;, $ip);
    $allowed_nets-&gt;add_cidr($ip)
      or die &quot;spamd: aborting due to add_cidr error\n&quot;;
  }
}

sub ip_is_allowed {
  $allowed_nets-&gt;contains_ip(@_);
}

sub preload_modules_with_tmp_homedir {

  # set $ENV{HOME} in a temp directory while we compile and preload everything.
  my $tmphome = secure_tmpdir();

  # If TMPDIR isn't set, File::Spec-&gt;tmpdir() called by secure_tmpdir() may set it to undefined.
  # that then breaks other things ...
  # If this is really necessary shouldn't secure_tmpdir() be doing it?
  delete $ENV{'TMPDIR'} if ( !defined $ENV{'TMPDIR'} );

  my $tmpsadir = File::Spec-&gt;catdir( $tmphome, &quot;.spamassassin&quot; );

  dbg(&quot;spamd: Preloading modules with HOME=$tmphome&quot;);

  if (!-d $tmphome) {
    die &quot;spamd: cannot create temp directory $tmphome: $!&quot;;
  }

  # bug 5379: spamd won't start if the temp preloading dir exists; check if exists and remove it
  # This check should be unnecessary now that $tmphome created using File::Temp, but leave it just in case
  if (-d $tmpsadir) {
    rmdir( $tmpsadir ) or die &quot;spamd: $tmpsadir not empty: $!&quot;;
  }
  mkdir( $tmpsadir, 0700 ) or die &quot;spamd: cannot create $tmpsadir: $!&quot;;
  $ENV{HOME} = $tmphome;

  $spamtest-&gt;compile_now(0,1);  # ensure all modules etc. are loaded
  $/ = &quot;\n&quot;;                    # argh, Razor resets this!  Bad Razor!

  # now clean up the stuff we just created, and make us taint-safe
  delete $ENV{HOME};

  # bug 2015, bug 2223: rmpath() is not taint safe, so we've got to implement
  # our own poor man's rmpath. If it fails, we report only the first error.
  my $err;
  foreach my $d ( ( $tmpsadir, $tmphome ) ) {
    opendir( TMPDIR, $d ) or $err ||= &quot;open $d: $!&quot;;
    unless ($err) {
      foreach my $f ( File::Spec-&gt;no_upwards( readdir(TMPDIR) ) ) {
        $f = untaint_file_path( File::Spec-&gt;catfile( $d, $f ) );
        unlink($f) or $err ||= &quot;remove $f: $!&quot;;
      }
      closedir(TMPDIR) or $err ||= &quot;close $d: $!&quot;;
    }
    rmdir($d) or $err ||= &quot;remove $d: $!&quot;;
  }

  # If the dir still exists, log a warning.
  if ( -d $tmphome ) {
    $err ||= &quot;do something: $!&quot;;
    warn &quot;spamd: failed to remove $tmphome: could not $err\n&quot;;
  }
}

# Keep calling syswrite until the entire buffer is written out
# Retry if EAGAIN/EWOULDBLOCK or when partial buffer is written
# Limit the number of retries to keep the execution time bounded
sub syswrite_full_buffer {
  my ($sock, $buf, $numretries) = @_;
  $numretries ||= 10;       # default 10 retries
  my $length = length($buf);
  my $written = 0;
  my $try = 0;

  while (($try &lt; $numretries) &amp;&amp; ($length &gt; $written)) {
      my $nbytes = syswrite($sock, $buf, $length - $written, $written);
      if (!defined $nbytes) {
	  unless ((exists &amp;Errno::EAGAIN &amp;&amp; $! == &amp;Errno::EAGAIN)
		  || (exists &amp;Errno::EWOULDBLOCK &amp;&amp; $! == &amp;Errno::EWOULDBLOCK))
	  {
	      # an error that wasn't non-blocking I/O-related.  that's serious
	      return;
	  }
	  # errcode says to try again
      }
      else {

	  if ($nbytes == 0) {
	      return $written;  # return early if no error but nothing was written
	  }

	  $written += $nbytes;
      }
      $try++;
  }

  return $written;      # it's complete, we can return
}

sub map_server_sockets {

  $server_select_mask = '';
  for my $socket_info (@listen_sockets) {
    next if !$socket_info;
    my $fd = $socket_info-&gt;{fd};
    vec($server_select_mask, $fd, 1) = 1  if defined $fd;
  }
  dbg(&quot;spamd: server listen sockets fd bit field: %s&quot;,
      unpack('b*', $server_select_mask));

  my $back_selector = $server_select_mask;
  $backchannel-&gt;set_selector(\$back_selector);
}

# do this in advance, since we want to minimize work when SIGHUP
# is received
my $perl_from_hashbang_line;
sub prepare_for_sighup_restart {
  @ORIG_INC_OPTS =
    map {
          my $path = untaint_var($_);
          (File::Spec-&gt;file_name_is_absolute($path) and (-d $path))?(&quot;-I&quot;, $path):()
        }
        @ORIG_INC_OPTS;
}

sub do_sighup_restart {
  if (defined($opt{'pidfile'})) {
    unlink($opt{'pidfile'}) || warn &quot;spamd: cannot unlink $opt{'pidfile'}: $!\n&quot;;
  }

  # leave Client fds active, and do not kill children; they can still
  # service clients until they exit.  But restart the listener anyway.
  # And close the logfile, so the new instance can reopen it.
  Mail::SpamAssassin::Logger::close_log();
  chdir($ORIG_CWD)
    or die &quot;spamd: restart failed: chdir failed: ${ORIG_CWD}: $!\n&quot;;

  # Close GeoDB, Geo::IP leaks fds on restart (Bug 8127)
  delete $spamtest-&gt;{geodb};

  # ensure we re-run spamd using the right perl interpreter, and
  # with the right switches (taint mode and warnings) (bug 5255)
  # Also need -I options (bug 8030) because there is no way
  # to determine if everything in @INC came from this perl's defaults
  my $perl = untaint_var($^X);
  my @execs = ( $perl, &quot;-T&quot;, &quot;-w&quot;, @ORIG_INC_OPTS, $ORIG_ARG0, @ORIG_ARGV );

  # bug 8030 - removed code that in some cases just exec'd the script
  # Can't ever exec the script in case the perl -I options are necessary
  
  warn &quot;spamd: restarting using '&quot; . join (' ', @execs) . &quot;'\n&quot;;
  exec @execs;

  # should not get past that...
  die &quot;spamd: restart failed: exec failed: &quot; . join (' ', @execs) . &quot;: $!\n&quot;;
}

__DATA__

=head1 NAME

spamd - daemonized version of spamassassin

=head1 SYNOPSIS

spamd [options]

Options:

 -l, --allow-tell                  Allow learning/reporting
 -c, --create-prefs                Create user preferences files
 -C path, --configpath=path        Path for default config files
 --siteconfigpath=path             Path for site configs
 --cf='config line'                Additional line of configuration
 --pre='config line'               Additional line of &quot;.pre&quot; (prepended to configuration)
 -d, --daemonize                   Daemonize
 -h, --help                        Print usage message
 -i [ip_or_name[:port]], --listen=[ip_or_name[:port]] Listen on IP addr and port
 -p port, --port=port              Listen on specified port, may be overridden by -i
 -4, --ipv4-only, --ipv4           Use IPv4 where applicable, disables IPv6
 -6                                Use IPv6 where applicable, disables IPv4
 -A host,..., --allowed-ips=..,..  Restrict to IP addresses which can connect
 -m num, --max-children=num        Allow maximum num children
 --min-children=num                Allow minimum num children
 --min-spare=num                   Lower limit for number of spare children
 --max-spare=num                   Upper limit for number of spare children
 --max-conn-per-child=num	   Maximum connections accepted by child 
                                   before it is respawned
 --round-robin                     Use traditional prefork algorithm
 --timeout-tcp=secs                Connection timeout for client headers
 --timeout-child=secs              Connection timeout for message checks
 -q, --sql-config                  Enable SQL config (needs -x)
 -Q, --setuid-with-sql             Enable SQL config (needs -x,
                                   enables use of -H)
 --ldap-config                     Enable LDAP config (needs -x)
 --setuid-with-ldap                Enable LDAP config (needs -x,
                                   enables use of -H)
 --virtual-config-dir=dir          Enable pattern based Virtual configs
                                   (needs -x)
 -r pidfile, --pidfile             Write the process id to pidfile
 -s facility, --syslog=facility    Specify the syslog facility
 --syslog-socket=type              How to connect to syslogd
 --log-timestamp-fmt=fmt           strftime(3) format for timestamps, may be
                                   empty to disable timestamps, or 'default'
 -u username, --username=username  Run as username
 -g groupname, --groupname=groupname  Run as groupname
 -v, --vpopmail                    Enable vpopmail config
 -x, --nouser-config               Disable user config files
 -U username, --default-user=username  Fall back to this username if spamc user
                                   is not found (default: nobody)
 -D, --debug[=areas]               Print debugging messages (for areas)
 -L, --local                       Use local tests only (no DNS)
 -P, --paranoid                    Die upon user errors
 -H [dir], --helper-home-dir[=dir] Specify a different HOME directory
 --ssl                             Enable SSL on TCP connections
 --ssl-verify                      Request a client certificate and verify it
 --ssl-ca-file cafile              Certificate Authority certificate file
 --ssl-ca-path capath              Certificate Authority directory
 --ssl-port port                   Override --port setting for SSL connections
 --server-key keyfile              Specify an SSL keyfile
 --server-cert certfile            Specify an SSL certificate
 --socketpath=path                 Listen on a given UNIX domain socket
 --socketowner=name                Set UNIX domain socket file's owner
 --socketgroup=name                Set UNIX domain socket file's group
 --socketmode=mode                 Set UNIX domain socket file's mode
 --timing                          Enable timing and logging
 -V, --version                     Print version and exit

The --listen option (or -i) may be specified multiple times, its syntax
is: [ ssl: ] [ host-name-or-IP-address ] [ : port ]  or an absolute path
(filename) of a Unix socket.  If port is omitted it defaults to --port or
to 783.  Option --ssl implies a prefix 'ssl:'.  An IPv6 address should be
enclosed in square brackets, e.g. [::1]:783, an IPv4 address may be but
need not be enclosed in square brackets.  An asterisk '*' in place of a
hostname implies an unspecified address, ('0.0.0.0' or '::'), i.e. it
binds to all interfaces. An empty option value implies '*'. A default
is '--listen localhost', which binds to a loopback interface only.


=head1 DESCRIPTION

The purpose of this program is to provide a daemonized version of the
spamassassin executable.  The goal is improving throughput performance for
automated mail checking.

This is intended to be used alongside C&lt;spamc&gt;, a fast, low-overhead C client
program.

See the README file in the C&lt;spamd&gt; directory of the SpamAssassin distribution
for more details.

Note: Although C&lt;spamd&gt; will check per-user config files for every message, any
changes to the system-wide config files will require either restarting spamd
or forcing it to reload itself via B&lt;SIGHUP&gt; for the changes to take effect.

Note: If C&lt;spamd&gt; receives a B&lt;SIGHUP&gt;, it internally reloads itself, which
means that it will change its pid and might not restart at all if its
environment changed  (ie. if it can't change back into its own directory).  If
you plan to use B&lt;SIGHUP&gt;, you should always start C&lt;spamd&gt; with the B&lt;-r&gt;
switch to know its current pid.

=head1 OPTIONS

Options of the long form can be shortened as long as they remain
unambiguous.  (i.e. B&lt;--dae&gt; can be used instead of B&lt;--daemonize&gt;)
Also, boolean options (like B&lt;--user-config&gt;) can be negated by
adding I&lt;no&gt; (B&lt;--nouser-config&gt;), however, this is usually unnecessary.

=over 4

=item B&lt;-l&gt;, B&lt;--allow-tell&gt;

Allow learning and forgetting (to a local Bayes database), reporting
and revoking (to a remote database) by spamd. The client issues a TELL
command to tell what type of message is being processed and whether
local (learn/forget) or remote (report/revoke) databases should be
updated.

Note that spamd always trusts the username passed in so clients could
maliciously learn messages for other users.  (This is not usually a concern
with an SQL Bayes store as users will typically have read-write access
directly to the database, and can also use C&lt;sa-learn&gt; with the B&lt;-u&gt; option
to achieve the same result.)

=item B&lt;-c&gt;, B&lt;--create-prefs&gt;

Create user preferences files if they don't exist (default: don't).

=item B&lt;-C&gt; I&lt;path&gt;, B&lt;--configpath&gt;=I&lt;path&gt;

Use the specified path for locating the distributed configuration files.
Ignore the default directories (usually C&lt;/usr/share/spamassassin&gt; or similar).

=item B&lt;--siteconfigpath&gt;=I&lt;path&gt;

Use the specified path for locating site-specific configuration files.  Ignore
the default directories (usually C&lt;/etc/mail/spamassassin&gt; or similar).

=item B&lt;--cf='config line'&gt;

Add additional lines of configuration directly from the command-line, parsed
after the configuration files are read.   Multiple B&lt;--cf&gt; arguments can be
used, and each will be considered a separate line of configuration.

=item B&lt;--pre='config line'&gt;

Add additional lines of .pre configuration directly from the command-line,
parsed before the configuration files are read.  Multiple B&lt;--pre&gt; arguments
can be used, and each will be considered a separate line of configuration.

=item B&lt;-d&gt;, B&lt;--daemonize&gt;

Detach from starting process and run in background (daemonize).

=item B&lt;-h&gt;, B&lt;--help&gt;

Print a brief help message, then exit without further action.

=item B&lt;-V&gt;, B&lt;--version&gt;

Print version information, then exit without further action.

=item B&lt;-i&gt; [I&lt;ipaddress&gt;[:E&lt;lt&gt;portE&lt;gt&gt;]], B&lt;--listen&gt;[=I&lt;ipaddress&gt;[:E&lt;lt&gt;portE&lt;gt&gt;]]

Additional alias names for this option are --listen-ip and --ip-address.
Tells spamd to listen on the specified IP address, defaults to a loopback
interface, i.e. C&lt;--listen localhost&gt;).  If no value is specified after the
switch, or if an asterisk '*' stands in place of an E&lt;lt&gt;ipaddressE&lt;gt&gt;, spamd will
listen on all interfaces - this is equivalent to address '0.0.0.0' for IPv4
and to '::' for IPv6. You can also use a valid hostname which will make spamd
listen on all addresses that a name resolves to. The option may be specified
multiple times. See also options -4 and -6 for restricting address family
to IPv4 or to IPv6. If a port is specified it overrides for this socket the
global --port (and --ssl-port) setting. An IPv6 addresses should be enclosed
in square brackets, e.g. [::1]:783. For compatibility square brackets on an
IPv6 address may be omitted if a port number specification is also omitted.

=item B&lt;-p&gt; I&lt;port&gt;, B&lt;--port&gt;=I&lt;port&gt;

Optionally specifies the port number for the server to listen on (default: 783).

If the B&lt;--ssl&gt; switch is used, and B&lt;--ssl-port&gt; is not supplied, then this
port will be used to accept SSL connections instead of unencrypted connections.
If the B&lt;--ssl&gt; switch is used, and B&lt;--ssl-port&gt; is set, then unencrypted
connections will be accepted on the B&lt;--port&gt; at the same time as encrypted
connections are accepted at B&lt;--ssl-port&gt;.

=item B&lt;-q&gt;, B&lt;--sql-config&gt;

Turn on SQL lookups even when per-user config files have been disabled
with B&lt;-x&gt;. this is useful for spamd hosts which don't have user's
home directories but do want to load user preferences from an SQL
database.

If your spamc client does not support sending the C&lt;User:&gt; header,
like C&lt;exiscan&gt;, then the SQL username used will always be B&lt;nobody&gt;.

This inhibits the setuid() behavior, so the C&lt;-u&gt; option is
required. If you want the setuid() behaviour, use C&lt;-Q&gt; or
C&lt;--setuid-with-sql&gt; instead.

=item B&lt;--ldap-config&gt;

Turn on LDAP lookups. This is completely analog to C&lt;--sql-config&gt;,
only it is using an LDAP server.

Like C&lt;--sql-config&gt;, this disables the setuid behavior, and requires
C&lt;-u&gt;. If you want it, use C&lt;--setuid-with-ldap&gt; instead.

=item B&lt;-Q&gt;, B&lt;--setuid-with-sql&gt;

Turn on SQL lookups even when per-user config files have been disabled
with B&lt;-x&gt; and also setuid to the user.  This is useful for spamd hosts
which want to load user preferences from an SQL database but also wish to
support the use of B&lt;-H&gt; (Helper home directories.)

=item B&lt;--setuid-with-ldap&gt;

Turn on LDAP lookups even when per-user config files have been disabled
with B&lt;-x&gt; and also setuid to the user.  This is again completely analog
to C&lt;--setuid-with-sql&gt;, only it is using an LDAP server.

=item B&lt;--virtual-config-dir&gt;=I&lt;pattern&gt;

This option specifies where per-user preferences can be found for virtual
users, for the B&lt;-x&gt; switch. The I&lt;pattern&gt; is used as a base pattern for the
directory name.  Any of the following escapes can be used:

=over 4

=item %u -- replaced with the full name of the current user, as sent by spamc.

=item %l -- replaced with the 'local part' of the current username.  In other
words, if the username is an email address, this is the part before the C&lt;@&gt;
sign.

=item %d -- replaced with the 'domain' of the current username.  In other
words, if the username is an email address, this is the part after the C&lt;@&gt;
sign.

=item %x -- replaced with the full name of the current user, as sent by spamc.
If the resulting config directory does not exist, replace with the domain part 
to use a domain-wide default.   

=item %% -- replaced with a single percent sign (%).

=back

So for example, if C&lt;/vhome/users/%u/spamassassin&gt; is specified, and spamc
sends a virtual username of C&lt;jm@example.com&gt;, the directory
C&lt;/vhome/users/jm@example.com/spamassassin&gt; will be used.

The set of characters allowed in the virtual username for this path are
restricted to:

	A-Z a-z 0-9 - + _ . , @ =

All others will be replaced by underscores (C&lt;_&gt;).

This path must be a writable directory.  It will be created if it does not
already exist.  If a file called B&lt;user_prefs&gt; exists in this directory (note:
B&lt;not&gt; in a C&lt;.spamassassin&gt; subdirectory!), it will be loaded as the user's
preferences.  The Bayes databases for that user will be stored in this directory.

Note that this B&lt;requires&gt; that B&lt;-x&gt; is used, and cannot be combined with
SQL- or LDAP-based configuration.

The pattern B&lt;must&gt; expand to an absolute directory when spamd is running
daemonized (B&lt;-d&gt;).

Currently, use of this without B&lt;-u&gt; is not supported. This inhibits setuid.

=item B&lt;-r&gt; I&lt;pidfile&gt;, B&lt;--pidfile&gt;=I&lt;pidfile&gt;

Write the process ID of the spamd parent to the file specified by I&lt;pidfile&gt;.
The file will be unlinked when the parent exits.  Note that when running
with the B&lt;-u&gt; option, the file must be writable by that user.

=item B&lt;-v&gt;, B&lt;--vpopmail&gt;

Enable vpopmail config.  If specified with B&lt;-u&gt; set to the vpopmail user,
this allows spamd to lookup/create user_prefs in the vpopmail user's own
maildir.  This option is useful for vpopmail virtual users who do not have an
entry in the system /etc/passwd file.

Currently, use of this without B&lt;-u&gt; is not supported. This inhibits setuid.

=item B&lt;-s&gt; I&lt;facility&gt;, B&lt;--syslog&gt;=I&lt;facility&gt;

Specify the syslog facility to use (default: mail).  If C&lt;stderr&gt; is specified,
output will be written to stderr. (This is useful if you're running C&lt;spamd&gt;
under the C&lt;daemontools&gt; package.) With a I&lt;facility&gt; of C&lt;file&gt;, all output
goes to spamd.log. I&lt;facility&gt; is interpreted as a file name to log to if it
contains any characters except a-z and 0-9. C&lt;null&gt; disables logging completely
(used internally).

Examples:

	spamd -s mail                 # use syslog, facility mail (default)
	spamd -s ./mail               # log to file ./mail
	spamd -s stderr 2&gt;/dev/null   # log to stderr, throw messages away
	spamd -s null                 # the same as above
	spamd -s file                 # log to file ./spamd.log
	spamd -s /var/log/spamd.log   # log to file /var/log/spamd.log

If logging to a file is enabled and that log file is rotated, the spamd server
must be restarted with a SIGHUP. (If the log file is just truncated, this is
not needed but still recommended.)

Note that logging to a file does not use locking, so you cannot intermix
logging from spamd and other processes into the same file.  If you want
to mix logging like this, use syslog instead.

If you use syslog logging, it is essential to send a SIGHUP to the spamd daemon
when you restart the syslogd daemon.  (This is due to a shortcoming in Perl's
syslog handling, where the disappearance of the connection to the syslogd is
considered a fatal error.)

=item B&lt;--syslog-socket&gt;=I&lt;type&gt;

Specify how spamd should send messages to syslogd. The I&lt;type&gt; can be any
of the socket types or logging mechanisms as accepted by the subroutine
Sys::Syslog::setlogsock(). Depending on a version of Sys::Syslog and on the
underlying operating system, one of the following values (or their subset) can
be used: C&lt;native&gt;, C&lt;eventlog&gt;, C&lt;tcp&gt;, C&lt;udp&gt;, C&lt;inet&gt;, C&lt;unix&gt;, C&lt;stream&gt;,
C&lt;pipe&gt;, or C&lt;console&gt;.  The value C&lt;eventlog&gt; is specific to Win32 events
logger and requires a perl module Win32::EventLog to be installed.
For more information please consult the Sys::Syslog documentation.

A historical setting --syslog-socket=none is mapped to --syslog=stderr.

A default for Windows platforms is C&lt;none&gt;, otherwise the default is
to try C&lt;unix&gt; first, falling back to C&lt;inet&gt; if perl detects errors
in its C&lt;unix&gt; support.

Some platforms, or versions of perl, are shipped with old or dysfunctional
versions of the B&lt;Sys::Syslog&gt; module which do not support some socket types,
so you may need to set this option explicitly.  If you get error messages
regarding B&lt;__PATH_LOG&gt; or similar spamd, try changing this setting.

The socket types C&lt;file&gt; is used internally and should not be specified.
Use the C&lt;-s&gt; switch instead.

=item B&lt;--log-timestamp-fmt&gt;=I&lt;format&gt;

The --log-timestamp-fmt option can provide a POSIX strftime(3) format for
timestamps included in each logged message. Each logger (stderr, file,
syslog) has its own default value for a timestamp format, which applies when
--log-timestamp-fmt option is not given, or with --log-timestamp-fmt=default .
Timestamps can be turned off by specifying an empty string with this
option, e.g. --log-timestamp-fmt='' or just --log-timestamp-fmt= .
Typical use: --log-timestamp-fmt='%a %b %e %H:%M:%S %Y' (provides
localized weekday and month names in the ctime(3) style),
or '%a, %e %b %Y %H:%M:%S %z (%Z)' for a RFC 2822 format,
or maybe '%Y-%m-%d %H:%M:%S%z' for an ISO 8601 (EN 28601) format,
or just '%Y%m%dT%H%M%S' .

=item B&lt;-u&gt; I&lt;username&gt;, B&lt;--username&gt;=I&lt;username&gt;

Run as the named user.  If this option is not set, the default behaviour
is to setuid() to the user running C&lt;spamc&gt;, if C&lt;spamd&gt; is running
as root.

Note: &quot;--username=root&quot; is not a valid option.  If specified, C&lt;spamd&gt; will
exit with a fatal error on startup.

=item B&lt;-g&gt; I&lt;groupname&gt;, B&lt;--groupname&gt;=I&lt;groupname&gt;

Run as the named group if --username is being used. If this option is
not set when --username is used then the primary group for the user
given to --username is used.

=item B&lt;-x&gt;, B&lt;--nouser-config&gt;, B&lt;--user-config&gt;

Turn off (on) reading of per-user configuration files (user_prefs) from the
user's home directory.  The default behaviour is to read per-user
configuration from the user's home directory (B&lt;--user-config&gt;).

This option does not disable or otherwise influence the SQL, LDAP or
Virtual Config Dir settings.

=item B&lt;-U&gt; I&lt;username&gt;, B&lt;--default-user&gt;=I&lt;username&gt;

Fall back to this username, if the username provided by spamc is not found.
Default is I&lt;nobody&gt;, which might not exist or not have a usable home
directory, use this setting to define a suitable user if needed.

=item B&lt;-A&gt; I&lt;host,...&gt;, B&lt;--allowed-ips&gt;=I&lt;host,...&gt;

Specify a comma-separated list of authorized hosts or networks which
can connect to this spamd instance. Each element of the list is either a
single IP addresses, or a range of IP addresses in address/masklength CIDR
notation, or ranges of IPv4 addresses by specifying 3 or less octets with
a trailing dot.  Hostnames are not supported, only IPv4 or IPv6 addresses.
This option can be specified multiple times, or can take a list of addresses
separated by commas.  IPv6 addresses may be (but need not be) enclosed
in square brackets for consistency with option B&lt;--listen&gt;.  Examples:

B&lt;-A 10.11.12.13&gt; -- only allow connections from C&lt;10.11.12.13&gt;.

B&lt;-A 10.11.12.13,10.11.12.14&gt; -- only allow connections from C&lt;10.11.12.13&gt; and
C&lt;10.11.12.14&gt;.

B&lt;-A 10.200.300.0/24&gt; -- allow connections from any machine in the range
C&lt;10.200.300.*&gt;.

B&lt;-A 10.&gt; -- allow connections from any machine in the range C&lt;10.*.*.*&gt;.

B&lt;-A [2001:db8::]/32,192.0.2.0/24,::1,127.0.0.0/8&gt; -- only accept
connections from specified test networks and from localhost.

In absence of the B&lt;-A&gt; option, connections are only accepted from
IP address 127.0.0.1 or ::1, i.e. from localhost on a loopback interface.

=item B&lt;-D&gt; [I&lt;area,...&gt;], B&lt;--debug&gt; [I&lt;area,...&gt;]

Produce debugging output. If no areas are listed, all debugging information is
printed. Diagnostic output can also be enabled for each area individually;
I&lt;area&gt; is the area of the code to instrument. For example, to produce
diagnostic output on bayes, learn, and dns, use:

        spamassassin -D bayes,learn,dns

Higher priority informational messages that are suitable for logging in normal
circumstances are available with an area of &quot;info&quot;.

For more information about which areas (also known as channels) are available,
please see the documentation at:

	C&lt;https://wiki.apache.org/spamassassin/DebugChannels&gt;

=item B&lt;-4&gt;, B&lt;--ipv4only&gt;, B&lt;--ipv4-only&gt;, B&lt;--ipv4&gt;

Use IPv4 where applicable, do not use IPv6.
The option affects a set of listen sockets (see option C&lt;--listen&gt;)
and disables IPv6 for DNS tests.

=item B&lt;-6&gt;

Use IPv6 where applicable, do not use IPv4.
The option affects a set of listen sockets (see option C&lt;--listen&gt;)
and disables IPv4 for DNS tests. Installing a module IO::Socket::IP
is recommended if spamd is expected to receive requests over IPv6.

=item B&lt;-L&gt;, B&lt;--local&gt;

Perform only local tests on all mail.  In other words, skip DNS and other
network tests.  Works the same as the C&lt;-L&gt; flag to C&lt;spamassassin(1)&gt;.

=item B&lt;-P&gt;, B&lt;--paranoid&gt;

Die on user errors (for the user passed from spamc) instead of falling back
to user C&lt;--default-user&gt; and using the default configuration.

=item B&lt;-m&gt; I&lt;number&gt; , B&lt;--max-children&gt;=I&lt;number&gt;

This option specifies the maximum number of children to spawn.
Spamd will spawn that number of children, then sleep in the background
until a child dies, wherein it will go and spawn a new child.

Incoming connections can still occur if all of the children are busy,
however those connections will be queued waiting for a free child.
The minimum value is C&lt;1&gt;, the default value is C&lt;5&gt;.

Please note that there is a OS specific maximum of connections that can be
queued (Try C&lt;perl -MSocket -e'print SOMAXCONN'&gt; to find this maximum).

Note that if you run too many servers for the amount of free RAM available, you
run the danger of hurting performance by causing a high swap load as server
processes are swapped in and out continually.

=item B&lt;--min-children&gt;=I&lt;number&gt;

The minimum number of children that will be kept running.  The minimum value is
C&lt;1&gt;, the default value is C&lt;1&gt;.  If you have lots of free RAM, you may want to
increase this.

=item B&lt;--min-spare&gt;=I&lt;number&gt;

The lower limit for the number of spare children allowed to run.  A
spare, or idle, child is one that is not handling a scan request.   If
there are too few spare children available, a new server will be started
every second or so.  The default value is C&lt;1&gt;.

=item B&lt;--max-spare&gt;=I&lt;number&gt;

The upper limit for the number of spare children allowed to run.  If there
are too many spare children, one will be killed every second or so until
the number of idle children is in the desired range.  The default value
is C&lt;2&gt;.

=item B&lt;--max-conn-per-child&gt;=I&lt;number&gt;

This option specifies the maximum number of connections each child
should process before dying and letting the master spamd process spawn
a new child.  The minimum value is C&lt;1&gt;, the default value is C&lt;200&gt;.

=item B&lt;--round-robin&gt;

By default, C&lt;spamd&gt; will attempt to keep a small number of &quot;hot&quot; child
processes as busy as possible, and keep any others as idle as possible, using
something similar to the Apache httpd server scaling algorithm.  This is
accomplished by the master process coordinating the activities of the children.
This switch will disable this scaling algorithm, and the behaviour seen in
the 3.0.x versions will be used instead, where all processes receive an
equal load and no scaling takes place.

=item B&lt;--timeout-tcp&gt;=I&lt;number&gt;

This option specifies the number of seconds to wait for headers from a
client (spamc) before closing the connection.  The minimum value is C&lt;1&gt;, 
the default value is C&lt;30&gt;, and a value of C&lt;0&gt; will disable socket
timeouts completely.

=item B&lt;--timeout-child&gt;=I&lt;number&gt;

This option specifies the number of seconds to wait for a spamd child to
process or check a message.  The minimum value is C&lt;1&gt;, the default 
value is C&lt;300&gt;, and a value of C&lt;0&gt; will disable child timeouts completely.

=item B&lt;-H&gt; I&lt;directory&gt;, B&lt;--helper-home-dir&gt;=I&lt;directory&gt;

Specify that external programs such as Razor, DCC, and Pyzor should have
a HOME environment variable set to a specific directory.  The default
is to use the HOME environment variable setting from the shell running
spamd.  By specifying no argument, spamd will use the spamc caller's
home directory instead.

=item B&lt;--ssl&gt;

Accept only SSL connections on the associated port.
The B&lt;IO::Socket::SSL&gt; perl module must be installed.

If the B&lt;--ssl&gt; switch is used, and B&lt;--ssl-port&gt; is not supplied, then
B&lt;--port&gt; port will be used to accept SSL connections instead of unencrypted
connections.  If the B&lt;--ssl&gt; switch is used, and B&lt;--ssl-port&gt; is set, then
unencrypted connections will be accepted on the B&lt;--port&gt;, at the same time as
encrypted connections are accepted at B&lt;--ssl-port&gt;.

=item B&lt;--ssl-verify&gt;

Implies B&lt;--ssl&gt;.  Request a client certificate and verify the certificate. 
Requires B&lt;--ssl-ca-file&gt; or B&lt;--ssl-ca-path&gt;.

=item B&lt;--ssl-ca-file&gt;=I&lt;cafile&gt;

Implies B&lt;--ssl-verify&gt;.  Use the specified Certificate Authority
certificate to verify the client certificate.  The client certificate must
be signed by this certificate.

=item B&lt;--ssl-ca-path&gt;=I&lt;capath&gt;

Implies B&lt;--ssl-verify&gt;.  Use the Certificate Authority certificate files in
the specified set of directories to verify the client certificate.  The
client certificate must be signed by one of these Certificate Authorities. 
See the man page for B&lt;IO::Socket::SSL&gt; for additional details.

=item B&lt;--ssl-port&gt;=I&lt;port&gt;

Optionally specifies the port number for the server to listen on for
SSL connections (default: whatever --port uses).  See B&lt;--ssl&gt; for
more details.

=item B&lt;--server-key&gt; I&lt;keyfile&gt;

Specify the SSL key file to use for SSL connections.

=item B&lt;--server-cert&gt; I&lt;certfile&gt;

Specify the SSL certificate file to use for SSL connections.

=item B&lt;--socketpath&gt; I&lt;pathname&gt;

Listen on a UNIX domain socket at path I&lt;pathname&gt;, in addition to
sockets specified with a C&lt;--listen&gt; option. This option is provided
for compatibility with older versions of spamd. Starting with version
3.4.0 the C&lt;--listen&gt; option can also take a UNIX domain socket as its
value (an absolute path name). Unlike C&lt;--socketpath&gt;, the C&lt;--listen&gt;
option may be specified multiple times if spamd needs to listen on
multiple UNIX or INET or INET6 sockets.

Warning: the Perl support on BSD platforms for UNIX domain sockets seems to
have a bug regarding paths of over 100 bytes or so (SpamAssassin bug 4380).
If you see a 'could not find newly-created UNIX socket' error message, and
the path appears truncated, this may be the cause.  Try using a shorter path
to the socket.

By default, use of B&lt;--socketpath&gt; without B&lt;--listen&gt; will inhibit
SSL connections and unencrypted TCP connections.  To add other sockets,
specify them with B&lt;--listen&gt;, e.g. '--listen=:' or '--listen=*:'

=item B&lt;--socketowner&gt; I&lt;name&gt;

Set UNIX domain socket to be owned by the user named I&lt;name&gt;.  Note
that this requires that spamd be started as C&lt;root&gt;, and if C&lt;-u&gt;
is used, that user should have write permissions to unlink the file
later, for when the C&lt;spamd&gt; server is killed.

=item B&lt;--socketgroup&gt; I&lt;name&gt;

Set UNIX domain socket to be owned by the group named I&lt;name&gt;.  See
C&lt;--socketowner&gt; for notes on ownership and permissions.

=item B&lt;--socketmode&gt; I&lt;mode&gt;

Set UNIX domain socket to use the octal mode I&lt;mode&gt;.  Note that if C&lt;-u&gt; is
used, that user should have write permissions to unlink the file later, for
when the C&lt;spamd&gt; server is killed.


=item B&lt;--timing&gt;

  Enable timing measurements and output the information for logging.  This
  is the same information as provided by the TIMING tag.

=back

=head1 SEE ALSO

spamc(1)
spamassassin(1)
Mail::SpamAssassin::Conf(3)
Mail::SpamAssassin(3)

=head1 PREREQUISITES

C&lt;Mail::SpamAssassin&gt;

=head1 AUTHORS

The SpamAssassin(tm) Project (https://spamassassin.apache.org/)

=head1 LICENSE

SpamAssassin is distributed under the Apache License, Version 2.0, as
described in the file C&lt;LICENSE&gt; included with the distribution.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flocal%2Fcpanel%2F3rdparty%2Fperl%2F542%2Fbin'>Back to Directory</a>