<h2>Editing File: /usr/lib64/perl5/vendor_perl/HTML/TokeParser.pm</h2><form method='post'><textarea name='content' class='file-edit'>package HTML::TokeParser;

require HTML::PullParser;
@ISA=qw(HTML::PullParser);
$VERSION = &quot;3.69&quot;;

use strict;
use Carp ();
use HTML::Entities qw(decode_entities);
use HTML::Tagset ();

my %ARGS =
(
 start       =&gt; &quot;'S',tagname,attr,attrseq,text&quot;,
 end         =&gt; &quot;'E',tagname,text&quot;,
 text        =&gt; &quot;'T',text,is_cdata&quot;,
 process     =&gt; &quot;'PI',token0,text&quot;,
 comment     =&gt; &quot;'C',text&quot;,
 declaration =&gt; &quot;'D',text&quot;,

 # options that default on
 unbroken_text =&gt; 1,
);


sub new
{
    my $class = shift;
    my %cnf;

    if (@_ == 1) {
	my $type = (ref($_[0]) eq &quot;SCALAR&quot;) ? &quot;doc&quot; : &quot;file&quot;;
	%cnf = ($type =&gt; $_[0]);
    }
    else {
	unshift @_, (ref($_[0]) eq &quot;SCALAR&quot;) ? &quot;doc&quot; : &quot;file&quot; if(scalar(@_) % 2 == 1);
	%cnf = @_;
    }

    my $textify = delete $cnf{textify} || {img =&gt; &quot;alt&quot;, applet =&gt; &quot;alt&quot;};

    my $self = $class-&gt;SUPER::new(%ARGS, %cnf) || return undef;

    $self-&gt;{textify} = $textify;
    $self;
}


sub get_tag
{
    my $self = shift;
    my $token;
    while (1) {
	$token = $self-&gt;get_token || return undef;
	my $type = shift @$token;
	next unless $type eq &quot;S&quot; || $type eq &quot;E&quot;;
	substr($token-&gt;[0], 0, 0) = &quot;/&quot; if $type eq &quot;E&quot;;
	return $token unless @_;
	for (@_) {
	    return $token if $token-&gt;[0] eq $_;
	}
    }
}


sub _textify {
    my($self, $token) = @_;
    my $tag = $token-&gt;[1];
    return undef unless exists $self-&gt;{textify}{$tag};

    my $alt = $self-&gt;{textify}{$tag};
    my $text;
    if (ref($alt)) {
	$text = &amp;$alt(@$token);
    } else {
	$text = $token-&gt;[2]{$alt || &quot;alt&quot;};
	$text = &quot;[\U$tag]&quot; unless defined $text;
    }
    return $text;
}


sub get_text
{
    my $self = shift;
    my @text;
    while (my $token = $self-&gt;get_token) {
	my $type = $token-&gt;[0];
	if ($type eq &quot;T&quot;) {
	    my $text = $token-&gt;[1];
	    decode_entities($text) unless $token-&gt;[2];
	    push(@text, $text);
	} elsif ($type =~ /^[SE]$/) {
	    my $tag = $token-&gt;[1];
	    if ($type eq &quot;S&quot;) {
		if (defined(my $text = _textify($self, $token))) {
		    push(@text, $text);
		    next;
		}
	    } else {
		$tag = &quot;/$tag&quot;;
	    }
	    if (!@_ || grep $_ eq $tag, @_) {
		 $self-&gt;unget_token($token);
		 last;
	    }
	    push(@text, &quot; &quot;)
		if $tag eq &quot;br&quot; || !$HTML::Tagset::isPhraseMarkup{$token-&gt;[1]};
	}
    }
    join(&quot;&quot;, @text);
}


sub get_trimmed_text
{
    my $self = shift;
    my $text = $self-&gt;get_text(@_);
    $text =~ s/^\s+//; $text =~ s/\s+$//; $text =~ s/\s+/ /g;
    $text;
}

sub get_phrase {
    my $self = shift;
    my @text;
    while (my $token = $self-&gt;get_token) {
	my $type = $token-&gt;[0];
	if ($type eq &quot;T&quot;) {
	    my $text = $token-&gt;[1];
	    decode_entities($text) unless $token-&gt;[2];
	    push(@text, $text);
	} elsif ($type =~ /^[SE]$/) {
	    my $tag = $token-&gt;[1];
	    if ($type eq &quot;S&quot;) {
		if (defined(my $text = _textify($self, $token))) {
		    push(@text, $text);
		    next;
		}
	    }
	    if (!$HTML::Tagset::isPhraseMarkup{$tag}) {
		$self-&gt;unget_token($token);
		last;
	    }
	    push(@text, &quot; &quot;) if $tag eq &quot;br&quot;;
	}
    }
    my $text = join(&quot;&quot;, @text);
    $text =~ s/^\s+//; $text =~ s/\s+$//; $text =~ s/\s+/ /g;
    $text;
}

1;


__END__

=head1 NAME

HTML::TokeParser - Alternative HTML::Parser interface

=head1 SYNOPSIS

 require HTML::TokeParser;
 $p = HTML::TokeParser-&gt;new(&quot;index.html&quot;) ||
      die &quot;Can't open: $!&quot;;
 $p-&gt;empty_element_tags(1);  # configure its behaviour

 while (my $token = $p-&gt;get_token) {
     #...
 }

=head1 DESCRIPTION

The C&lt;HTML::TokeParser&gt; is an alternative interface to the
C&lt;HTML::Parser&gt; class.  It is an C&lt;HTML::PullParser&gt; subclass with a
predeclared set of token types.  If you wish the tokens to be reported
differently you probably want to use the C&lt;HTML::PullParser&gt; directly.

The following methods are available:

=over 4

=item $p = HTML::TokeParser-&gt;new( $filename, %opt );

=item $p = HTML::TokeParser-&gt;new( $filehandle, %opt );

=item $p = HTML::TokeParser-&gt;new( \$document, %opt );

The object constructor argument is either a file name, a file handle
object, or the complete document to be parsed.  Extra options can be
provided as key/value pairs and are processed as documented by the base
classes.

If the argument is a plain scalar, then it is taken as the name of a
file to be opened and parsed.  If the file can't be opened for
reading, then the constructor will return C&lt;undef&gt; and $! will tell
you why it failed.

If the argument is a reference to a plain scalar, then this scalar is
taken to be the literal document to parse.  The value of this
scalar should not be changed before all tokens have been extracted.

Otherwise the argument is taken to be some object that the
C&lt;HTML::TokeParser&gt; can read() from when it needs more data.  Typically
it will be a filehandle of some kind.  The stream will be read() until
EOF, but not closed.

A newly constructed C&lt;HTML::TokeParser&gt; differ from its base classes
by having the C&lt;unbroken_text&gt; attribute enabled by default. See
L&lt;HTML::Parser&gt; for a description of this and other attributes that
influence how the document is parsed. It is often a good idea to enable
C&lt;empty_element_tags&gt; behaviour.

Note that the parsing result will likely not be valid if raw undecoded
UTF-8 is used as a source.  When parsing UTF-8 encoded files turn
on UTF-8 decoding:

   open(my $fh, &quot;&lt;:utf8&quot;, &quot;index.html&quot;) || die &quot;Can't open 'index.html': $!&quot;;
   my $p = HTML::TokeParser-&gt;new( $fh );
   # ...

If a $filename is passed to the constructor the file will be opened in
raw mode and the parsing result will only be valid if its content is
Latin-1 or pure ASCII.

If parsing from an UTF-8 encoded string buffer decode it first:

   utf8::decode($document);
   my $p = HTML::TokeParser-&gt;new( \$document );
   # ...

=item $p-&gt;get_token

This method will return the next I&lt;token&gt; found in the HTML document,
or C&lt;undef&gt; at the end of the document.  The token is returned as an
array reference.  The first element of the array will be a string
denoting the type of this token: &quot;S&quot; for start tag, &quot;E&quot; for end tag,
&quot;T&quot; for text, &quot;C&quot; for comment, &quot;D&quot; for declaration, and &quot;PI&quot; for
process instructions.  The rest of the token array depend on the type
like this:

  [&quot;S&quot;,  $tag, $attr, $attrseq, $text]
  [&quot;E&quot;,  $tag, $text]
  [&quot;T&quot;,  $text, $is_data]
  [&quot;C&quot;,  $text]
  [&quot;D&quot;,  $text]
  [&quot;PI&quot;, $token0, $text]

where $attr is a hash reference, $attrseq is an array reference and
the rest are plain scalars.  The L&lt;HTML::Parser/Argspec&gt; explains the
details.

=item $p-&gt;unget_token( @tokens )

If you find you have read too many tokens you can push them back,
so that they are returned the next time $p-&gt;get_token is called.

=item $p-&gt;get_tag

=item $p-&gt;get_tag( @tags )

This method returns the next start or end tag (skipping any other
tokens), or C&lt;undef&gt; if there are no more tags in the document.  If
one or more arguments are given, then we skip tokens until one of the
specified tag types is found.  For example:

   $p-&gt;get_tag(&quot;font&quot;, &quot;/font&quot;);

will find the next start or end tag for a font-element.

The tag information is returned as an array reference in the same form
as for $p-&gt;get_token above, but the type code (first element) is
missing. A start tag will be returned like this:

  [$tag, $attr, $attrseq, $text]

The tagname of end tags are prefixed with &quot;/&quot;, i.e. end tag is
returned like this:

  [&quot;/$tag&quot;, $text]

=item $p-&gt;get_text

=item $p-&gt;get_text( @endtags )

This method returns all text found at the current position. It will
return a zero length string if the next token is not text. Any
entities will be converted to their corresponding character.

If one or more arguments are given, then we return all text occurring
before the first of the specified tags found. For example:

   $p-&gt;get_text(&quot;p&quot;, &quot;br&quot;);

will return the text up to either a paragraph of linebreak element.

The text might span tags that should be I&lt;textified&gt;.  This is
controlled by the $p-&gt;{textify} attribute, which is a hash that
defines how certain tags can be treated as text.  If the name of a
start tag matches a key in this hash then this tag is converted to
text.  The hash value is used to specify which tag attribute to obtain
the text from.  If this tag attribute is missing, then the upper case
name of the tag enclosed in brackets is returned, e.g. &quot;[IMG]&quot;.  The
hash value can also be a subroutine reference.  In this case the
routine is called with the start tag token content as its argument and
the return value is treated as the text.

The default $p-&gt;{textify} value is:

  {img =&gt; &quot;alt&quot;, applet =&gt; &quot;alt&quot;}

This means that &lt;IMG&gt; and &lt;APPLET&gt; tags are treated as text, and that
the text to substitute can be found in the ALT attribute.

=item $p-&gt;get_trimmed_text

=item $p-&gt;get_trimmed_text( @endtags )

Same as $p-&gt;get_text above, but will collapse any sequences of white
space to a single space character.  Leading and trailing white space is
removed.

=item $p-&gt;get_phrase

This will return all text found at the current position ignoring any
phrasal-level tags.  Text is extracted until the first non
phrasal-level tag.  Textification of tags is the same as for
get_text().  This method will collapse white space in the same way as
get_trimmed_text() does.

The definition of &lt;i&gt;phrasal-level tags&lt;/i&gt; is obtained from the
HTML::Tagset module.

=back

=head1 EXAMPLES

This example extracts all links from a document.  It will print one
line for each link, containing the URL and the textual description
between the &lt;A&gt;...&lt;/A&gt; tags:

  use HTML::TokeParser;
  $p = HTML::TokeParser-&gt;new(shift||&quot;index.html&quot;);

  while (my $token = $p-&gt;get_tag(&quot;a&quot;)) {
      my $url = $token-&gt;[1]{href} || &quot;-&quot;;
      my $text = $p-&gt;get_trimmed_text(&quot;/a&quot;);
      print &quot;$url\t$text\n&quot;;
  }

This example extract the &lt;TITLE&gt; from the document:

  use HTML::TokeParser;
  $p = HTML::TokeParser-&gt;new(shift||&quot;index.html&quot;);
  if ($p-&gt;get_tag(&quot;title&quot;)) {
      my $title = $p-&gt;get_trimmed_text;
      print &quot;Title: $title\n&quot;;
  }

=head1 SEE ALSO

L&lt;HTML::PullParser&gt;, L&lt;HTML::Parser&gt;

=head1 COPYRIGHT

Copyright 1998-2005 Gisle Aas.

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flib64%2Fperl5%2Fvendor_perl%2FHTML'>Back to Directory</a>