<h2>Editing File: /usr/lib64/perl5/attributes.pm</h2><form method='post'><textarea name='content' class='file-edit'>package attributes;

our $VERSION = 0.29;

@EXPORT_OK = qw(get reftype);
@EXPORT = ();
%EXPORT_TAGS = (ALL =&gt; [@EXPORT, @EXPORT_OK]);

use strict;

sub croak {
    require Carp;
    goto &amp;Carp::croak;
}

sub carp {
    require Carp;
    goto &amp;Carp::carp;
}

my %deprecated;
$deprecated{CODE} = qr/\A-?(locked)\z/;
$deprecated{ARRAY} = $deprecated{HASH} = $deprecated{SCALAR}
    = qr/\A-?(unique)\z/;

my %msg = (
    lvalue =&gt; 'lvalue attribute applied to already-defined subroutine',
   -lvalue =&gt; 'lvalue attribute removed from already-defined subroutine',
    const  =&gt; 'Useless use of attribute &quot;const&quot;',
);

sub _modify_attrs_and_deprecate {
    my $svtype = shift;
    # Now that we've removed handling of locked from the XS code, we need to
    # remove it here, else it ends up in @badattrs. (If we do the deprecation in
    # XS, we can't control the warning based on *our* caller's lexical settings,
    # and the warned line is in this package)
    grep {
	$deprecated{$svtype} &amp;&amp; /$deprecated{$svtype}/ ? do {
	    require warnings;
	    warnings::warnif('deprecated', &quot;Attribute \&quot;$1\&quot; is deprecated, &quot; .
                                           &quot;and will disappear in Perl 5.28&quot;);
	    0;
	} : $svtype eq 'CODE' &amp;&amp; exists $msg{$_} ? do {
	    require warnings;
	    warnings::warnif(
		'misc',
		 $msg{$_}
	    );
	    0;
	} : 1
    } _modify_attrs(@_);
}

sub import {
    @_ &gt; 2 &amp;&amp; ref $_[2] or do {
	require Exporter;
	goto &amp;Exporter::import;
    };
    my (undef,$home_stash,$svref,@attrs) = @_;

    my $svtype = uc reftype($svref);
    my $pkgmeth;
    $pkgmeth = UNIVERSAL::can($home_stash, &quot;MODIFY_${svtype}_ATTRIBUTES&quot;)
	if defined $home_stash &amp;&amp; $home_stash ne '';
    my @badattrs;
    if ($pkgmeth) {
	my @pkgattrs = _modify_attrs_and_deprecate($svtype, $svref, @attrs);
	@badattrs = $pkgmeth-&gt;($home_stash, $svref, @pkgattrs);
	if (!@badattrs &amp;&amp; @pkgattrs) {
            require warnings;
	    return unless warnings::enabled('reserved');
	    @pkgattrs = grep { m/\A[[:lower:]]+(?:\z|\()/ } @pkgattrs;
	    if (@pkgattrs) {
		for my $attr (@pkgattrs) {
		    $attr =~ s/\(.+\z//s;
		}
		my $s = ((@pkgattrs == 1) ? '' : 's');
		carp &quot;$svtype package attribute$s &quot; .
		    &quot;may clash with future reserved word$s: &quot; .
		    join(' : ' , @pkgattrs);
	    }
	}
    }
    else {
	@badattrs = _modify_attrs_and_deprecate($svtype, $svref, @attrs);
    }
    if (@badattrs) {
	croak &quot;Invalid $svtype attribute&quot; .
	    (( @badattrs == 1 ) ? '' : 's') .
	    &quot;: &quot; .
	    join(' : ', @badattrs);
    }
}

sub get ($) {
    @_ == 1  &amp;&amp; ref $_[0] or
	croak 'Usage: '.__PACKAGE__.'::get $ref';
    my $svref = shift;
    my $svtype = uc reftype($svref);
    my $stash = _guess_stash($svref);
    $stash = caller unless defined $stash;
    my $pkgmeth;
    $pkgmeth = UNIVERSAL::can($stash, &quot;FETCH_${svtype}_ATTRIBUTES&quot;)
	if defined $stash &amp;&amp; $stash ne '';
    return $pkgmeth ?
		(_fetch_attrs($svref), $pkgmeth-&gt;($stash, $svref)) :
		(_fetch_attrs($svref))
	;
}

sub require_version { goto &amp;UNIVERSAL::VERSION }

require XSLoader;
XSLoader::load();

1;
__END__
#The POD goes here

=head1 NAME

attributes - get/set subroutine or variable attributes

=head1 SYNOPSIS

  sub foo : method ;
  my ($x,@y,%z) : Bent = 1;
  my $s = sub : method { ... };

  use attributes ();	# optional, to get subroutine declarations
  my @attrlist = attributes::get(\&amp;foo);

  use attributes 'get'; # import the attributes::get subroutine
  my @attrlist = get \&amp;foo;

=head1 DESCRIPTION

Subroutine declarations and definitions may optionally have attribute lists
associated with them.  (Variable C&lt;my&gt; declarations also may, but see the
warning below.)  Perl handles these declarations by passing some information
about the call site and the thing being declared along with the attribute
list to this module.  In particular, the first example above is equivalent to
the following:

    use attributes __PACKAGE__, \&amp;foo, 'method';

The second example in the synopsis does something equivalent to this:

    use attributes ();
    my ($x,@y,%z);
    attributes::-&gt;import(__PACKAGE__, \$x, 'Bent');
    attributes::-&gt;import(__PACKAGE__, \@y, 'Bent');
    attributes::-&gt;import(__PACKAGE__, \%z, 'Bent');
    ($x,@y,%z) = 1;

Yes, that's a lot of expansion.

B&lt;WARNING&gt;: attribute declarations for variables are still evolving.
The semantics and interfaces of such declarations could change in
future versions.  They are present for purposes of experimentation
with what the semantics ought to be.  Do not rely on the current
implementation of this feature.

There are only a few attributes currently handled by Perl itself (or
directly by this module, depending on how you look at it.)  However,
package-specific attributes are allowed by an extension mechanism.
(See L&lt;&quot;Package-specific Attribute Handling&quot;&gt; below.)

The setting of subroutine attributes happens at compile time.
Variable attributes in C&lt;our&gt; declarations are also applied at compile time.
However, C&lt;my&gt; variables get their attributes applied at run-time.
This means that you have to I&lt;reach&gt; the run-time component of the C&lt;my&gt;
before those attributes will get applied.  For example:

    my $x : Bent = 42 if 0;

will neither assign 42 to $x I&lt;nor&gt; will it apply the C&lt;Bent&gt; attribute
to the variable.

An attempt to set an unrecognized attribute is a fatal error.  (The
error is trappable, but it still stops the compilation within that
C&lt;eval&gt;.)  Setting an attribute with a name that's all lowercase
letters that's not a built-in attribute (such as &quot;foo&quot;) will result in
a warning with B&lt;-w&gt; or C&lt;use warnings 'reserved'&gt;.

=head2 What C&lt;import&gt; does

In the description it is mentioned that

  sub foo : method;

is equivalent to

  use attributes __PACKAGE__, \&amp;foo, 'method';

As you might know this calls the C&lt;import&gt; function of C&lt;attributes&gt; at compile 
time with these parameters: 'attributes', the caller's package name, the reference 
to the code and 'method'.

  attributes-&gt;import( __PACKAGE__, \&amp;foo, 'method' );

So you want to know what C&lt;import&gt; actually does?

First of all C&lt;import&gt; gets the type of the third parameter ('CODE' in this case).
C&lt;attributes.pm&gt; checks if there is a subroutine called C&lt;&lt; MODIFY_&lt;reftype&gt;_ATTRIBUTES &gt;&gt;
in the caller's namespace (here: 'main').  In this case a
subroutine C&lt;MODIFY_CODE_ATTRIBUTES&gt; is required.  Then this
method is called to check if you have used a &quot;bad attribute&quot;.
The subroutine call in this example would look like

  MODIFY_CODE_ATTRIBUTES( 'main', \&amp;foo, 'method' );

C&lt;&lt; MODIFY_&lt;reftype&gt;_ATTRIBUTES &gt;&gt; has to return a list of all &quot;bad attributes&quot;.
If there are any bad attributes C&lt;import&gt; croaks.

(See L&lt;&quot;Package-specific Attribute Handling&quot;&gt; below.)

=head2 Built-in Attributes

The following are the built-in attributes for subroutines:

=over 4

=item lvalue

Indicates that the referenced subroutine is a valid lvalue and can
be assigned to.  The subroutine must return a modifiable value such
as a scalar variable, as described in L&lt;perlsub&gt;.

This module allows one to set this attribute on a subroutine that is
already defined.  For Perl subroutines (XSUBs are fine), it may or may not
do what you want, depending on the code inside the subroutine, with details
subject to change in future Perl versions.  You may run into problems with
lvalue context not being propagated properly into the subroutine, or maybe
even assertion failures.  For this reason, a warning is emitted if warnings
are enabled.  In other words, you should only do this if you really know
what you are doing.  You have been warned.

=item method

Indicates that the referenced subroutine
is a method.  A subroutine so marked
will not trigger the &quot;Ambiguous call resolved as CORE::%s&quot; warning.

=item prototype(..)

The &quot;prototype&quot; attribute is an alternate means of specifying a prototype
on a sub.  The desired prototype is within the parens.

The prototype from the attribute is assigned to the sub immediately after
the prototype from the sub, which means that if both are declared at the
same time, the traditionally defined prototype is ignored.  In other words,
C&lt;sub foo($$) : prototype(@) {}&gt; is indistinguishable from C&lt;sub foo(@){}&gt;.

If illegalproto warnings are enabled, the prototype declared inside this
attribute will be sanity checked at compile time.

=item locked

The &quot;locked&quot; attribute is deprecated, and has no effect in 5.10.0 and later.
It was used as part of the now-removed &quot;Perl 5.005 threads&quot;. It will
disappear in Perl 5.28, after which its use will be fatal.

=item const

This experimental attribute, introduced in Perl 5.22, only applies to
anonymous subroutines.  It causes the subroutine to be called as soon as
the C&lt;sub&gt; expression is evaluated.  The return value is captured and
turned into a constant subroutine.

=back

The following are the built-in attributes for variables:

=over 4

=item shared

Indicates that the referenced variable can be shared across different threads
when used in conjunction with the L&lt;threads&gt; and L&lt;threads::shared&gt; modules.

=item unique

The &quot;unique&quot; attribute is deprecated, and has no effect in 5.10.0 and later.
It used to indicate that a single copy of an C&lt;our&gt; variable was to be used by
all interpreters should the program happen to be running in a
multi-interpreter environment. It will disappear in 5.28, after which its
use will be fatal.

=back

=head2 Available Subroutines

The following subroutines are available for general use once this module
has been loaded:

=over 4

=item get

This routine expects a single parameter--a reference to a
subroutine or variable.  It returns a list of attributes, which may be
empty.  If passed invalid arguments, it uses die() (via L&lt;Carp::croak|Carp&gt;)
to raise a fatal exception.  If it can find an appropriate package name
for a class method lookup, it will include the results from a
C&lt;FETCH_I&lt;type&gt;_ATTRIBUTES&gt; call in its return list, as described in
L&lt;&quot;Package-specific Attribute Handling&quot;&gt; below.
Otherwise, only L&lt;built-in attributes|&quot;Built-in Attributes&quot;&gt; will be returned.

=item reftype

This routine expects a single parameter--a reference to a subroutine or
variable.  It returns the built-in type of the referenced variable,
ignoring any package into which it might have been blessed.
This can be useful for determining the I&lt;type&gt; value which forms part of
the method names described in L&lt;&quot;Package-specific Attribute Handling&quot;&gt; below.

=back

Note that these routines are I&lt;not&gt; exported by default.

=head2 Package-specific Attribute Handling

B&lt;WARNING&gt;: the mechanisms described here are still experimental.  Do not
rely on the current implementation.  In particular, there is no provision
for applying package attributes to 'cloned' copies of subroutines used as
closures.  (See L&lt;perlref/&quot;Making References&quot;&gt; for information on closures.)
Package-specific attribute handling may change incompatibly in a future
release.

When an attribute list is present in a declaration, a check is made to see
whether an attribute 'modify' handler is present in the appropriate package
(or its @ISA inheritance tree).  Similarly, when C&lt;attributes::get&gt; is
called on a valid reference, a check is made for an appropriate attribute
'fetch' handler.  See L&lt;&quot;EXAMPLES&quot;&gt; to see how the &quot;appropriate package&quot;
determination works.

The handler names are based on the underlying type of the variable being
declared or of the reference passed.  Because these attributes are
associated with subroutine or variable declarations, this deliberately
ignores any possibility of being blessed into some package.  Thus, a
subroutine declaration uses &quot;CODE&quot; as its I&lt;type&gt;, and even a blessed
hash reference uses &quot;HASH&quot; as its I&lt;type&gt;.

The class methods invoked for modifying and fetching are these:

=over 4

=item FETCH_I&lt;type&gt;_ATTRIBUTES

This method is called with two arguments:  the relevant package name,
and a reference to a variable or subroutine for which package-defined
attributes are desired.  The expected return value is a list of
associated attributes.  This list may be empty.

=item MODIFY_I&lt;type&gt;_ATTRIBUTES

This method is called with two fixed arguments, followed by the list of
attributes from the relevant declaration.  The two fixed arguments are
the relevant package name and a reference to the declared subroutine or
variable.  The expected return value is a list of attributes which were
not recognized by this handler.  Note that this allows for a derived class
to delegate a call to its base class, and then only examine the attributes
which the base class didn't already handle for it.

The call to this method is currently made I&lt;during&gt; the processing of the
declaration.  In particular, this means that a subroutine reference will
probably be for an undefined subroutine, even if this declaration is
actually part of the definition.

=back

Calling C&lt;attributes::get()&gt; from within the scope of a null package
declaration C&lt;package ;&gt; for an unblessed variable reference will
not provide any starting package name for the 'fetch' method lookup.
Thus, this circumstance will not result in a method call for package-defined
attributes.  A named subroutine knows to which symbol table entry it belongs
(or originally belonged), and it will use the corresponding package.
An anonymous subroutine knows the package name into which it was compiled
(unless it was also compiled with a null package declaration), and so it
will use that package name.

=head2 Syntax of Attribute Lists

An attribute list is a sequence of attribute specifications, separated by
whitespace or a colon (with optional whitespace).
Each attribute specification is a simple
name, optionally followed by a parenthesised parameter list.
If such a parameter list is present, it is scanned past as for the rules
for the C&lt;q()&gt; operator.  (See L&lt;perlop/&quot;Quote and Quote-like Operators&quot;&gt;.)
The parameter list is passed as it was found, however, and not as per C&lt;q()&gt;.

Some examples of syntactically valid attribute lists:

    switch(10,foo(7,3))  :  expensive
    Ugly('\(&quot;) :Bad
    _5x5
    lvalue method

Some examples of syntactically invalid attribute lists (with annotation):

    switch(10,foo()		# ()-string not balanced
    Ugly('(')			# ()-string not balanced
    5x5				# &quot;5x5&quot; not a valid identifier
    Y2::north			# &quot;Y2::north&quot; not a simple identifier
    foo + bar			# &quot;+&quot; neither a colon nor whitespace

=head1 EXPORTS

=head2 Default exports

None.

=head2 Available exports

The routines C&lt;get&gt; and C&lt;reftype&gt; are exportable.

=head2 Export tags defined

The C&lt;:ALL&gt; tag will get all of the above exports.

=head1 EXAMPLES

Here are some samples of syntactically valid declarations, with annotation
as to how they resolve internally into C&lt;use attributes&gt; invocations by
perl.  These examples are primarily useful to see how the &quot;appropriate
package&quot; is found for the possible method lookups for package-defined
attributes.

=over 4

=item 1.

Code:

    package Canine;
    package Dog;
    my Canine $spot : Watchful ;

Effect:

    use attributes ();
    attributes::-&gt;import(Canine =&gt; \$spot, &quot;Watchful&quot;);

=item 2.

Code:

    package Felis;
    my $cat : Nervous;

Effect:

    use attributes ();
    attributes::-&gt;import(Felis =&gt; \$cat, &quot;Nervous&quot;);

=item 3.

Code:

    package X;
    sub foo : lvalue ;

Effect:

    use attributes X =&gt; \&amp;foo, &quot;lvalue&quot;;

=item 4.

Code:

    package X;
    sub Y::x : lvalue { 1 }

Effect:

    use attributes Y =&gt; \&amp;Y::x, &quot;lvalue&quot;;

=item 5.

Code:

    package X;
    sub foo { 1 }

    package Y;
    BEGIN { *bar = \&amp;X::foo; }

    package Z;
    sub Y::bar : lvalue ;

Effect:

    use attributes X =&gt; \&amp;X::foo, &quot;lvalue&quot;;

=back

This last example is purely for purposes of completeness.  You should not
be trying to mess with the attributes of something in a package that's
not your own.

=head1 MORE EXAMPLES

=over 4

=item 1.

    sub MODIFY_CODE_ATTRIBUTES {
       my ($class,$code,@attrs) = @_;

       my $allowed = 'MyAttribute';
       my @bad = grep { $_ ne $allowed } @attrs;

       return @bad;
    }

    sub foo : MyAttribute {
       print &quot;foo\n&quot;;
    }

This example runs.  At compile time
C&lt;MODIFY_CODE_ATTRIBUTES&gt; is called.  In that
subroutine, we check if any attribute is disallowed and we return a list of
these &quot;bad attributes&quot;.

As we return an empty list, everything is fine.

=item 2.

  sub MODIFY_CODE_ATTRIBUTES {
     my ($class,$code,@attrs) = @_;

     my $allowed = 'MyAttribute';
     my @bad = grep{ $_ ne $allowed }@attrs;

     return @bad;
  }

  sub foo : MyAttribute Test {
     print &quot;foo\n&quot;;
  }

This example is aborted at compile time as we use the attribute &quot;Test&quot; which
isn't allowed.  C&lt;MODIFY_CODE_ATTRIBUTES&gt;
returns a list that contains a single
element ('Test').

=back

=head1 SEE ALSO

L&lt;perlsub/&quot;Private Variables via my()&quot;&gt; and
L&lt;perlsub/&quot;Subroutine Attributes&quot;&gt; for details on the basic declarations;
L&lt;perlfunc/use&gt; for details on the normal invocation mechanism.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flib64%2Fperl5'>Back to Directory</a>