<h2>Editing File: /usr/lib/grub/i386-pc/gdb_grub</h2><form method='post'><textarea name='content' class='file-edit'>###
### Load debuging information about GNU GRUB 2 modules into GDB
### automatically. Needs readelf, Perl and gmodule.pl script
###
### Has to be launched from the writable and trusted
### directory containing *.image and *.module
###
### $Id: .gdbinit,v 1.1 2006/05/14 11:38:08 lkundrak Exp $
### Lubomir Kundrak &lt;lkudrak@skosi.org&gt;
###

# Add section numbers and addresses to .segments.tmp
define dump_module_sections
	set $mod = $arg0

	# FIXME: save logging status
	set logging file .segments.tmp
	set logging redirect on
	set logging overwrite off
	set logging on

	printf &quot;%s&quot;, $mod-&gt;name
	set $segment = $mod-&gt;segment
	while ($segment)
		printf &quot; %i 0x%lx&quot;, $segment-&gt;section, $segment-&gt;addr
		set $segment = $segment-&gt;next
	end
	printf &quot;\n&quot;

	set logging off
	# FIXME: restore logging status
end
document dump_module_sections
	Gather information about module whose mod structure was
	given for use with match_and_load_symbols
end

# Generate and execute GDB commands and delete temporary files
# afterwards
define match_and_load_symbols
	shell perl gmodule.pl &lt;.segments.tmp &gt;.loadsym.gdb
	source .loadsym.gdb
	shell rm -f .segments.tmp .loadsym.gdb
end
document match_and_load_symbols
	Launch script, that matches section names with information
	generated by dump_module_sections and load debugging info
	apropriately
end

###

define load_module
	dump_module_sections $arg0
	match_and_load_symbols
end
document load_module
	Load debugging information for module given as argument.
end

define load_all_modules
	set $this = grub_dl_head
	while ($this != 0)
		dump_module_sections $this
		set $this = $this-&gt;next
	end
	match_and_load_symbols
end
document load_all_modules
	Load debugging information for all loaded modules.
end

###

set confirm off
file kernel.exec
target remote :1234

# inform when module is loaded
break grub_dl_add
commands
	silent
	load_module mod
	cont
end
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Flib%2Fgrub%2Fi386-pc'>Back to Directory</a>