<h2>Editing File: /usr/bin/pod2text</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/bin/perl
    eval 'exec /usr/bin/perl -S $0 ${1+&quot;$@&quot;}'
        if $running_under_some_shell;

# Convert POD data to formatted ASCII text.
#
# The driver script for Pod::Text, Pod::Text::Termcap, and Pod::Text::Color,
# invoked by perldoc -t among other things.
#
# SPDX-License-Identifier: GPL-1.0-or-later OR Artistic-1.0-Perl

use 5.006;
use strict;
use warnings;

use Getopt::Long qw(GetOptions);
use Pod::Text ();
use Pod::Usage qw(pod2usage);

# Clean up $0 for error reporting.
$0 =~ s%.*/%%;

# Take an initial pass through our options, looking for one of the form
# -&lt;number&gt;.  We turn that into -w &lt;number&gt; for compatibility with the
# original pod2text script.
for (my $i = 0; $i &lt; @ARGV; $i++) {
    last if $ARGV[$i] =~ /^--$/;
    if ($ARGV[$i] =~ /^-(\d+)$/) {
        splice (@ARGV, $i++, 1, '-w', $1);
    }
}

# Insert -- into @ARGV before any single dash argument to hide it from
# Getopt::Long; we want to interpret it as meaning stdin (which Pod::Simple
# does correctly).
my $stdin;
@ARGV = map { $_ eq '-' &amp;&amp; !$stdin++ ? ('--', $_) : $_ } @ARGV;

# Parse our options.  Use the same names as Pod::Text for simplicity.
my %options;
Getopt::Long::config ('bundling');
GetOptions (\%options, 'alt|a', 'code', 'color|c', 'errors=s', 'help|h',
            'indent|i=i', 'loose|l', 'margin|left-margin|m=i', 'nourls',
            'overstrike|o', 'quotes|q=s', 'sentence|s', 'stderr', 'termcap|t',
            'utf8|u', 'width|w=i')
    or exit 1;
pod2usage (1) if $options{help};

# Figure out what formatter we're going to use.  -c overrides -t.
my $formatter = 'Pod::Text';
if ($options{color}) {
    $formatter = 'Pod::Text::Color';
    eval { require Term::ANSIColor };
    if ($@) { die &quot;-c (--color) requires Term::ANSIColor be installed\n&quot; }
    require Pod::Text::Color;
} elsif ($options{termcap}) {
    $formatter = 'Pod::Text::Termcap';
    require Pod::Text::Termcap;
} elsif ($options{overstrike}) {
    $formatter = 'Pod::Text::Overstrike';
    require Pod::Text::Overstrike;
}
delete @options{'color', 'termcap', 'overstrike'};

# If neither stderr nor errors is set, default to errors = die.
if (!defined $options{stderr} &amp;&amp; !defined $options{errors}) {
    $options{errors} = 'die';
}

# Initialize and run the formatter.
my $parser = $formatter-&gt;new (%options);
my $status = 0;
do {
    my ($input, $output) = splice (@ARGV, 0, 2);
    $parser-&gt;parse_from_file ($input, $output);
    if ($parser-&gt;{CONTENTLESS}) {
        $status = 1;
        if (defined $input) {
            warn &quot;$0: unable to format $input\n&quot;;
        } else {
            warn &quot;$0: unable to format standard input\n&quot;;
        }
        if (defined ($output) and $output ne '-') {
            unlink $output unless (-s $output);
        }
    }
} while (@ARGV);
exit $status;

__END__

=for stopwords
-aclostu --alt --stderr Allbery --overstrike overstrike --termcap --utf8
UTF-8 subclasses --nourls

=head1 NAME

pod2text - Convert POD data to formatted ASCII text

=head1 SYNOPSIS

pod2text [B&lt;-aclostu&gt;] [B&lt;--code&gt;] [B&lt;--errors&gt;=I&lt;style&gt;] [B&lt;-i&gt; I&lt;indent&gt;]
    S&lt;[B&lt;-q&gt; I&lt;quotes&gt;]&gt; [B&lt;--nourls&gt;] [B&lt;--stderr&gt;] S&lt;[B&lt;-w&gt; I&lt;width&gt;]&gt;
    [I&lt;input&gt; [I&lt;output&gt; ...]]

pod2text B&lt;-h&gt;

=head1 DESCRIPTION

B&lt;pod2text&gt; is a front-end for Pod::Text and its subclasses.  It uses them
to generate formatted ASCII text from POD source.  It can optionally use
either termcap sequences or ANSI color escape sequences to format the text.

I&lt;input&gt; is the file to read for POD source (the POD can be embedded in
code).  If I&lt;input&gt; isn't given, it defaults to C&lt;STDIN&gt;.  I&lt;output&gt;, if
given, is the file to which to write the formatted output.  If I&lt;output&gt;
isn't given, the formatted output is written to C&lt;STDOUT&gt;.  Several POD
files can be processed in the same B&lt;pod2text&gt; invocation (saving module
load and compile times) by providing multiple pairs of I&lt;input&gt; and
I&lt;output&gt; files on the command line.

=head1 OPTIONS

=over 4

=item B&lt;-a&gt;, B&lt;--alt&gt;

Use an alternate output format that, among other things, uses a different
heading style and marks C&lt;=item&gt; entries with a colon in the left margin.

=item B&lt;--code&gt;

Include any non-POD text from the input file in the output as well.  Useful
for viewing code documented with POD blocks with the POD rendered and the
code left intact.

=item B&lt;-c&gt;, B&lt;--color&gt;

Format the output with ANSI color escape sequences.  Using this option
requires that Term::ANSIColor be installed on your system.

=item B&lt;--errors&gt;=I&lt;style&gt;

Set the error handling style.  C&lt;die&gt; says to throw an exception on any
POD formatting error.  C&lt;stderr&gt; says to report errors on standard error,
but not to throw an exception.  C&lt;pod&gt; says to include a POD ERRORS
section in the resulting documentation summarizing the errors.  C&lt;none&gt;
ignores POD errors entirely, as much as possible.

The default is C&lt;die&gt;.

=item B&lt;-i&gt; I&lt;indent&gt;, B&lt;--indent=&gt;I&lt;indent&gt;

Set the number of spaces to indent regular text, and the default indentation
for C&lt;=over&gt; blocks.  Defaults to 4 spaces if this option isn't given.

=item B&lt;-h&gt;, B&lt;--help&gt;

Print out usage information and exit.

=item B&lt;-l&gt;, B&lt;--loose&gt;

Print a blank line after a C&lt;=head1&gt; heading.  Normally, no blank line is
printed after C&lt;=head1&gt;, although one is still printed after C&lt;=head2&gt;,
because this is the expected formatting for manual pages; if you're
formatting arbitrary text documents, using this option is recommended.

=item B&lt;-m&gt; I&lt;width&gt;, B&lt;--left-margin&gt;=I&lt;width&gt;, B&lt;--margin&gt;=I&lt;width&gt;

The width of the left margin in spaces.  Defaults to 0.  This is the margin
for all text, including headings, not the amount by which regular text is
indented; for the latter, see B&lt;-i&gt; option.

=item B&lt;--nourls&gt;

Normally, LZ&lt;&gt;&lt;&gt; formatting codes with a URL but anchor text are formatted
to show both the anchor text and the URL.  In other words:

    L&lt;foo|http://example.com/&gt;

is formatted as:

    foo &lt;http://example.com/&gt;

This flag, if given, suppresses the URL when anchor text is given, so this
example would be formatted as just C&lt;foo&gt;.  This can produce less
cluttered output in cases where the URLs are not particularly important.

=item B&lt;-o&gt;, B&lt;--overstrike&gt;

Format the output with overstrike printing.  Bold text is rendered as
character, backspace, character.  Italics and file names are rendered as
underscore, backspace, character.  Many pagers, such as B&lt;less&gt;, know how
to convert this to bold or underlined text.

=item B&lt;-q&gt; I&lt;quotes&gt;, B&lt;--quotes&gt;=I&lt;quotes&gt;

Sets the quote marks used to surround CE&lt;lt&gt;&gt; text to I&lt;quotes&gt;.  If
I&lt;quotes&gt; is a single character, it is used as both the left and right
quote.  Otherwise, it is split in half, and the first half of the string
is used as the left quote and the second is used as the right quote.

I&lt;quotes&gt; may also be set to the special value C&lt;none&gt;, in which case no
quote marks are added around CE&lt;lt&gt;&gt; text.

=item B&lt;-s&gt;, B&lt;--sentence&gt;

Assume each sentence ends with two spaces and try to preserve that spacing.
Without this option, all consecutive whitespace in non-verbatim paragraphs
is compressed into a single space.

=item B&lt;--stderr&gt;

By default, B&lt;pod2text&gt; dies if any errors are detected in the POD input.
If B&lt;--stderr&gt; is given and no B&lt;--errors&gt; flag is present, errors are
sent to standard error, but B&lt;pod2text&gt; does not abort.  This is
equivalent to C&lt;--errors=stderr&gt; and is supported for backward
compatibility.

=item B&lt;-t&gt;, B&lt;--termcap&gt;

Try to determine the width of the screen and the bold and underline
sequences for the terminal from termcap, and use that information in
formatting the output.  Output will be wrapped at two columns less than the
width of your terminal device.  Using this option requires that your system
have a termcap file somewhere where Term::Cap can find it and requires that
your system support termios.  With this option, the output of B&lt;pod2text&gt;
will contain terminal control sequences for your current terminal type.

=item B&lt;-u&gt;, B&lt;--utf8&gt;

By default, B&lt;pod2text&gt; tries to use the same output encoding as its input
encoding (to be backward-compatible with older versions).  This option
says to instead force the output encoding to UTF-8.

Be aware that, when using this option, the input encoding of your POD
source should be properly declared unless it's US-ASCII.  Pod::Simple
will attempt to guess the encoding and may be successful if it's
Latin-1 or UTF-8, but it will warn, which by default results in a
B&lt;pod2text&gt; failure.  Use the C&lt;=encoding&gt; command to declare the
encoding.  See L&lt;perlpod(1)&gt; for more information.

=item B&lt;-w&gt;, B&lt;--width=&gt;I&lt;width&gt;, B&lt;-&gt;I&lt;width&gt;

The column at which to wrap text on the right-hand side.  Defaults to 76,
unless B&lt;-t&gt; is given, in which case it's two columns less than the width of
your terminal device.

=back

=head1 EXIT STATUS

As long as all documents processed result in some output, even if that
output includes errata (a C&lt;POD ERRORS&gt; section generated with
C&lt;--errors=pod&gt;), B&lt;pod2text&gt; will exit with status 0.  If any of the
documents being processed do not result in an output document, B&lt;pod2text&gt;
will exit with status 1.  If there are syntax errors in a POD document
being processed and the error handling style is set to the default of
C&lt;die&gt;, B&lt;pod2text&gt; will abort immediately with exit status 255.

=head1 DIAGNOSTICS

If B&lt;pod2text&gt; fails with errors, see L&lt;Pod::Text&gt; and L&lt;Pod::Simple&gt; for
information about what those errors might mean.  Internally, it can also
produce the following diagnostics:

=over 4

=item -c (--color) requires Term::ANSIColor be installed

(F) B&lt;-c&gt; or B&lt;--color&gt; were given, but Term::ANSIColor could not be
loaded.

=item Unknown option: %s

(F) An unknown command line option was given.

=back

In addition, other L&lt;Getopt::Long&gt; error messages may result from invalid
command-line options.

=head1 ENVIRONMENT

=over 4

=item COLUMNS

If B&lt;-t&gt; is given, B&lt;pod2text&gt; will take the current width of your screen
from this environment variable, if available.  It overrides terminal width
information in TERMCAP.

=item TERMCAP

If B&lt;-t&gt; is given, B&lt;pod2text&gt; will use the contents of this environment
variable if available to determine the correct formatting sequences for your
current terminal device.

=back

=head1 AUTHOR

Russ Allbery &lt;rra@cpan.org&gt;.

=head1 COPYRIGHT AND LICENSE

Copyright 1999-2001, 2004, 2006, 2008, 2010, 2012-2018 Russ Allbery
&lt;rra@cpan.org&gt;

This program is free software; you may redistribute it and/or modify it
under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;Pod::Text&gt;, L&lt;Pod::Text::Color&gt;, L&lt;Pod::Text::Overstrike&gt;,
L&lt;Pod::Text::Termcap&gt;, L&lt;Pod::Simple&gt;, L&lt;perlpod(1)&gt;

The current version of this script is always available from its web site at
L&lt;https://www.eyrie.org/~eagle/software/podlators/&gt;.  It is also part of the
Perl core distribution as of 5.6.0.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fbin'>Back to Directory</a>