<h2>Editing File: /usr/bin/perlthanks</h2><form method='post'><textarea name='content' class='file-edit'>#!/usr/bin/perl
    eval 'exec /usr/bin/perl -S $0 ${1+&quot;$@&quot;}'
	if $running_under_some_shell;

my $config_tag1 = '5.26.3 - Mon Sep 14 03:28:48 EDT 2026';

my $patchlevel_date = 1789370927;
my @patches = Config::local_patches();
my $patch_tags = join &quot;&quot;, map /(\S+)/ ? &quot;+$1 &quot; : (), @patches;

BEGIN { pop @INC if $INC[-1] eq '.' }
use warnings;
use strict;
use Config;
use File::Spec;		# keep perlbug Perl 5.005 compatible
use Getopt::Std;
use File::Basename 'basename';

sub paraprint;

BEGIN {
    eval { require Mail::Send;};
    $::HaveSend = ($@ eq &quot;&quot;);
    eval { require Mail::Util; } ;
    $::HaveUtil = ($@ eq &quot;&quot;);
    # use secure tempfiles wherever possible
    eval { require File::Temp; };
    $::HaveTemp = ($@ eq &quot;&quot;);
    eval { require Module::CoreList; };
    $::HaveCoreList = ($@ eq &quot;&quot;);
    eval { require Text::Wrap; };
    $::HaveWrap = ($@ eq &quot;&quot;);
};

my $Version = &quot;1.40&quot;;

#TODO:
#       make sure failure (transmission-wise) of Mail::Send is accounted for.
#       (This may work now. Unsure of the original author's issue -JESSE 2008-06-08)
#       - Test -b option

my( $file, $usefile, $cc, $address, $bugaddress, $testaddress, $thanksaddress,
    $filename, $messageid, $domain, $subject, $from, $verbose, $ed, $outfile,
    $fh, $me, $body, $andcc, %REP, $ok, $thanks, $progname,
    $Is_MSWin32, $Is_Linux, $Is_VMS, $Is_OpenBSD,
    $report_about_module, $category, $severity,
    %opt, $have_attachment, $attachments, $has_patch, $mime_boundary
);

my $running_noninteractively = !-t STDIN;

my $perl_version = $^V ? sprintf(&quot;%vd&quot;, $^V) : $];

my $config_tag2 = &quot;$perl_version - $Config{cf_time}&quot;;

Init();

if ($opt{h}) { Help(); exit; }
if ($opt{d}) { Dump(*STDOUT); exit; }
if ($running_noninteractively &amp;&amp; !$opt{t} &amp;&amp; !($ok and not $opt{n})) {
    paraprint &lt;&lt;&quot;EOF&quot;;
Please use $progname interactively. If you want to
include a file, you can use the -f switch.
EOF
    die &quot;\n&quot;;
}

Query();
Edit() unless $usefile || ($ok and not $opt{n});
NowWhat();
if ($outfile) {
    save_message_to_disk($outfile);
} else {
    Send();
    if ($thanks) {
	print &quot;\nThank you for taking the time to send a thank-you message!\n\n&quot;;

	paraprint &lt;&lt;EOF
Please note that mailing lists are moderated, your message may take a while to
show up.
EOF
    } else {
	print &quot;\nThank you for taking the time to file a bug report!\n\n&quot;;

	paraprint &lt;&lt;EOF
Please note that mailing lists are moderated, your message may take a while to
show up. If you do not receive an automated response acknowledging your message
within a few hours (check your SPAM folder and outgoing mail) please consider
sending an email directly from your mail client to perlbug\@perl.org.
EOF
    }

}

exit;

sub ask_for_alternatives { # (category|severity)
    my $name = shift;
    my %alts = (
	'category' =&gt; {
	    'default' =&gt; 'core',
	    'ok'      =&gt; 'install',
	    # Inevitably some of these will end up in RT whatever we do:
	    'thanks'  =&gt; 'thanks',
	    'opts'    =&gt; [qw(core docs install library utilities)], # patch, notabug
	},
	'severity' =&gt; {
	    'default' =&gt; 'low',
	    'ok'      =&gt; 'none',
	    'thanks'  =&gt; 'none',
	    'opts'    =&gt; [qw(critical high medium low wishlist none)], # zero
	},
    );
    die &quot;Invalid alternative ($name) requested\n&quot; unless grep(/^$name$/, keys %alts);
    my $alt = &quot;&quot;;
    my $what = $ok || $thanks;
    if ($what) {
	$alt = $alts{$name}{$what};
    } else {
 	my @alts = @{$alts{$name}{'opts'}};
    print &quot;\n\n&quot;;
	paraprint &lt;&lt;EOF;
Please pick a $name from the following list:

    @alts
EOF
	my $err = 0;
	do {
	    if ($err++ &gt; 5) {
		die &quot;Invalid $name: aborting.\n&quot;;
	    }
        $alt = _prompt('', &quot;\u$name&quot;, $alts{$name}{'default'});
		$alt ||= $alts{$name}{'default'};
	} while !((($alt) = grep(/^$alt/i, @alts)));
    }
    lc $alt;
}

sub Init {
    # -------- Setup --------

    $Is_MSWin32 = $^O eq 'MSWin32';
    $Is_VMS = $^O eq 'VMS';
    $Is_Linux = lc($^O) eq 'linux';
    $Is_OpenBSD = lc($^O) eq 'openbsd';

    if (!getopts(&quot;Adhva:s:b:f:F:r:e:SCc:to:n:T:p:&quot;, \%opt)) { Help(); exit; };

    # This comment is needed to notify metaconfig that we are
    # using the $perladmin, $cf_by, and $cf_time definitions.

    # -------- Configuration ---------

    # perlbug address
    $bugaddress = 'perlbug@perl.org';

    # Test address
    $testaddress = 'perlbug-test@perl.org';

    # Thanks address
    $thanksaddress = 'perl-thanks@perl.org';

    if (basename ($0) =~ /^perlthanks/i) {
	# invoked as perlthanks
	$opt{T} = 1;
	$opt{C} = 1; # don't send a copy to the local admin
    }

    if ($opt{T}) {
	$thanks = 'thanks';
    }
    
    $progname = $thanks ? 'perlthanks' : 'perlbug';
    # Target address
    $address = $opt{a} || ($opt{t} ? $testaddress
			    : $thanks ? $thanksaddress : $bugaddress);

    # Users address, used in message and in From and Reply-To headers
    $from = $opt{r} || &quot;&quot;;

    # Include verbose configuration information
    $verbose = $opt{v} || 0;

    # Subject of bug-report message
    $subject = $opt{s} || &quot;&quot;;

    # Send a file
    $usefile = ($opt{f} || 0);

    # File to send as report
    $file = $opt{f} || &quot;&quot;;

    # We have one or more attachments
    $have_attachment = ($opt{p} || 0);
    $mime_boundary = ('-' x 12) . &quot;$Version.perlbug&quot; if $have_attachment;

    # Comma-separated list of attachments
    $attachments = $opt{p} || &quot;&quot;;
    $has_patch = 0; # TBD based on file type

    for my $attachment (split /\s*,\s*/, $attachments) {
        unless (-f $attachment &amp;&amp; -r $attachment) {
            die &quot;The attachment $attachment is not a readable file: $!\n&quot;;
        }
        $has_patch = 1 if $attachment =~ m/\.(patch|diff)$/;
    }

    # File to output to
    $outfile = $opt{F} || &quot;&quot;;

    # Body of report
    $body = $opt{b} || &quot;&quot;;
	
    # Editor
    $ed = $opt{e} || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
	|| ($Is_VMS &amp;&amp; &quot;edit/tpu&quot;)
	|| ($Is_MSWin32 &amp;&amp; &quot;notepad&quot;)
	|| &quot;vi&quot;;

    # Not OK - provide build failure template by finessing OK report
    if ($opt{n}) {
	if (substr($opt{n}, 0, 2) eq 'ok' )	{
	    $opt{o} = substr($opt{n}, 1);
	} else {
	    Help();
	    exit();
	}
    }

    # OK - send &quot;OK&quot; report for build on this system
    $ok = '';
    if ($opt{o}) {
	if ($opt{o} eq 'k' or $opt{o} eq 'kay') {
	    # force these options
	    unless ($opt{n}) {
		$opt{S} = 1; # don't prompt for send
		$opt{b} = 1; # we have a body
		$body = &quot;Perl reported to build OK on this system.\n&quot;;
	    }
	    $opt{C} = 1; # don't send a copy to the local admin
	    $opt{s} = 1; # we have a subject line
	    $subject = ($opt{n} ? 'Not ' : '')
		    . &quot;OK: perl $perl_version ${patch_tags}on&quot;
		    .&quot; $::Config{'archname'} $::Config{'osvers'} $subject&quot;;
	    $ok = 'ok';
	} else {
	    Help();
	    exit();
	}
    }

    # Possible administrator addresses, in order of confidence
    # (Note that cf_email is not mentioned to metaconfig, since
    # we don't really want it. We'll just take it if we have to.)
    #
    # This has to be after the $ok stuff above because of the way
    # that $opt{C} is forced.
    $cc = $opt{C} ? &quot;&quot; : (
	$opt{c} || $::Config{'perladmin'}
	|| $::Config{'cf_email'} || $::Config{'cf_by'}
    );

    if ($::HaveUtil) {
		$domain = Mail::Util::maildomain();
    } elsif ($Is_MSWin32) {
		$domain = $ENV{'USERDOMAIN'};
    } else {
		require Sys::Hostname;
		$domain = Sys::Hostname::hostname();
    }

    # Message-Id - rjsf
    $messageid = &quot;&lt;$::Config{'version'}_${$}_&quot;.time.&quot;\@$domain&gt;&quot;; 

    # My username
    $me = $Is_MSWin32 ? $ENV{'USERNAME'}
	    : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
	    : eval { getpwuid($&lt;) };	# May be missing

    $from = $::Config{'cf_email'}
       if !$from &amp;&amp; $::Config{'cf_email'} &amp;&amp; $::Config{'cf_by'} &amp;&amp; $me &amp;&amp;
               ($me eq $::Config{'cf_by'});
} # sub Init

sub Query {
    # Explain what perlbug is
    unless ($ok) {
	if ($thanks) {
	    paraprint &lt;&lt;'EOF';
This program provides an easy way to send a thank-you message back to the
authors and maintainers of perl.

If you wish to submit a bug report, please run it without the -T flag
(or run the program perlbug rather than perlthanks)
EOF
	} else {
	    paraprint &lt;&lt;&quot;EOF&quot;;
This program provides an easy way to create a message reporting a
bug in the core perl distribution (along with tests or patches)
to the volunteers who maintain perl at $address.  To send a thank-you
note to $thanksaddress instead of a bug report, please run 'perlthanks'.

Please do not use $0 to send test messages, test whether perl
works, or to report bugs in perl modules from CPAN.

Suggestions for how to find help using Perl can be found at
http://perldoc.perl.org/perlcommunity.html
EOF
	}
    }

    # Prompt for subject of message, if needed
    
    if ($subject &amp;&amp; TrivialSubject($subject)) {
	$subject = '';
    }

    unless ($subject) {
	    print 
&quot;First of all, please provide a subject for the message.\n&quot;;
	if ( not $thanks)  {
	    paraprint &lt;&lt;EOF;
This should be a concise description of your bug or problem
which will help the volunteers working to improve perl to categorize
and resolve the issue.  Be as specific and descriptive as
you can. A subject like &quot;perl bug&quot; or &quot;perl problem&quot; will make it
much less likely that your issue gets the attention it deserves.
EOF
	}

	my $err = 0;
	do {
        $subject = _prompt('','Subject');
	    if ($err++ == 5) {
		if ($thanks) {
		    $subject = 'Thanks for Perl';
		} else {
		    die &quot;Aborting.\n&quot;;
		}
	    }
	} while (TrivialSubject($subject));
    }
    $subject = '[PATCH] ' . $subject
        if $has_patch &amp;&amp; ($subject !~ m/^\[PATCH/i);

    # Prompt for return address, if needed
    unless ($opt{r}) {
	# Try and guess return address
	my $guess;

	$guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || $ENV{'EMAIL'}
	    || $from || '';

	unless ($guess) {
		# move $domain to where we can use it elsewhere	
        if ($domain) {
		if ($Is_VMS &amp;&amp; !$::Config{'d_socket'}) {
		    $guess = &quot;$domain\:\:$me&quot;;
		} else {
		    $guess = &quot;$me\@$domain&quot; if $domain;
		}
	    }
	}

	if ($guess) {
	    unless ($ok) {
		paraprint &lt;&lt;EOF;
Perl's developers may need your email address to contact you for
further information about your issue or to inform you when it is
resolved.  If the default shown is not your email address, please
correct it.
EOF
	    }
	} else {
	    paraprint &lt;&lt;EOF;
Please enter your full internet email address so that Perl's
developers can contact you with questions about your issue or to
inform you that it has been resolved.
EOF
	}

	if ($ok &amp;&amp; $guess) {
	    # use it
	    $from = $guess;
	} else {
	    # verify it
        $from = _prompt('','Your address',$guess);
	    $from = $guess if $from eq '';
	}
    }

    if ($from eq $cc or $me eq $cc) {
	# Try not to copy ourselves
	$cc = &quot;yourself&quot;;
    }

    # Prompt for administrator address, unless an override was given
    if( !$opt{C} and !$opt{c} ) {
	my $description =  &lt;&lt;EOF;
$0 can send a copy of this report to your local perl
administrator.  If the address below is wrong, please correct it,
or enter 'none' or 'yourself' to not send a copy.
EOF
	my $entry = _prompt($description, &quot;Local perl administrator&quot;, $cc);

	if ($entry ne &quot;&quot;) {
	    $cc = $entry;
	    $cc = '' if $me eq $cc;
	}
    }

    $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
    if ($cc) { 
        $andcc = &quot; and $cc&quot; 
    } else {
        $andcc = ''
    }

    # Prompt for editor, if no override is given
editor:
    unless ($opt{e} || $opt{f} || $opt{b}) {

    my $description;

	chomp (my $common_end = &lt;&lt;&quot;EOF&quot;);
You will probably want to use a text editor to enter the body of
your report. If &quot;$ed&quot; is the editor you want to use, then just press
Enter, otherwise type in the name of the editor you would like to
use.

If you have already composed the body of your report, you may enter
&quot;file&quot;, and $0 will prompt you to enter the name of the file
containing your report.
EOF

	if ($thanks) {
	    $description = &lt;&lt;&quot;EOF&quot;;
It's now time to compose your thank-you message.

Some information about your local perl configuration will automatically
be included at the end of your message, because we're curious about
the different ways that people build and use perl. If you'd rather
not share this information, you're welcome to delete it.

$common_end
EOF
	} else {
	    $description =  &lt;&lt;&quot;EOF&quot;;
It's now time to compose your bug report. Try to make the report
concise but descriptive. Please include any detail which you think
might be relevant or might help the volunteers working to improve
perl. If you are reporting something that does not work as you think
it should, please try to include examples of the actual result and of
what you expected.

Some information about your local perl configuration will automatically
be included at the end of your report. If you are using an unusual
version of perl, it would be useful if you could confirm that you
can replicate the problem on a standard build of perl as well.

$common_end
EOF
	}

    my $entry = _prompt($description, &quot;Editor&quot;, $ed);
	$usefile = 0;
	if ($entry eq &quot;file&quot;) {
	    $usefile = 1;
	} elsif ($entry ne &quot;&quot;) {
	    $ed = $entry;
	}
    }
    if ($::HaveCoreList &amp;&amp; !$ok &amp;&amp; !$thanks) {
	my $description =  &lt;&lt;EOF;
If your bug is about a Perl module rather than a core language
feature, please enter its name here. If it's not, just hit Enter
to skip this question.
EOF

    my $entry = '';
	while ($entry eq '') {
        $entry = _prompt($description, 'Module');
	    my $first_release = Module::CoreList-&gt;first_release($entry);
	    if ($entry and not $first_release) {
		paraprint &lt;&lt;EOF;
$entry is not a &quot;core&quot; Perl module. Please check that you entered
its name correctly. If it is correct, quit this program, try searching
for $entry on http://rt.cpan.org, and report your issue there.
EOF

            $entry = '';
	} elsif (my $bug_tracker = $Module::CoreList::bug_tracker{$entry}) {
		paraprint &lt;&lt;&quot;EOF&quot;;
$entry included with core Perl is copied directly from the CPAN distribution.
Please report bugs in $entry directly to its maintainers using $bug_tracker
EOF
            $entry = '';
        } elsif ($entry) {
	        $category ||= 'library';
	        $report_about_module = $entry;
            last;
        } else {
            last;
        }
	}
    }

    # Prompt for category of bug
    $category ||= ask_for_alternatives('category');

    # Prompt for severity of bug
    $severity ||= ask_for_alternatives('severity');

    # Generate scratch file to edit report in
    $filename = filename();

    # Prompt for file to read report from, if needed
    if ($usefile and !$file) {
filename:
	my $description = &lt;&lt;EOF;
What is the name of the file that contains your report?
EOF
	my $entry = _prompt($description, &quot;Filename&quot;);

	if ($entry eq &quot;&quot;) {
	    paraprint &lt;&lt;EOF;
It seems you didn't enter a filename. Please choose to use a text
editor or enter a filename.
EOF
	    goto editor;
	}

	unless (-f $entry and -r $entry) {
	    paraprint &lt;&lt;EOF;
'$entry' doesn't seem to be a readable file.  You may have mistyped
its name or may not have permission to read it.

If you don't want to use a file as the content of your report, just
hit Enter and you'll be able to select a text editor instead.
EOF
	    goto filename;
	}
	$file = $entry;
    }

    # Generate report
    open(REP, '&gt;:raw', $filename) or die &quot;Unable to create report file '$filename': $!\n&quot;;
    binmode(REP, ':raw :crlf') if $Is_MSWin32;

    my $reptype = !$ok ? ($thanks ? 'thank-you' : 'bug')
	: $opt{n} ? &quot;build failure&quot; : &quot;success&quot;;

    print REP &lt;&lt;EOF;
This is a $reptype report for perl from $from,
generated with the help of perlbug $Version running under perl $perl_version.

EOF

    if ($body) {
	print REP $body;
    } elsif ($usefile) {
	open(F, '&lt;:raw', $file)
		or die &quot;Unable to read report file from '$file': $!\n&quot;;
	binmode(F, ':raw :crlf') if $Is_MSWin32;
	while (&lt;F&gt;) {
	    print REP $_
	}
	close(F) or die &quot;Error closing '$file': $!&quot;;
    } else {
	if ($thanks) {
	    print REP &lt;&lt;'EOF';

-----------------------------------------------------------------
[Please enter your thank-you message here]


[You're welcome to delete anything below this line]
-----------------------------------------------------------------
EOF
	} else {
	    print REP &lt;&lt;'EOF';

-----------------------------------------------------------------
[Please describe your issue here]


[Please do not change anything below this line]
-----------------------------------------------------------------
EOF
	}
    }
    Dump(*REP);
    close(REP) or die &quot;Error closing report file: $!&quot;;

    # Set up an initial report fingerprint so we can compare it later
    _fingerprint_lines_in_report();

} # sub Query

sub Dump {
    local(*OUT) = @_;

    # these won't have been set if run with -d
    $category ||= 'core';
    $severity ||= 'low';

    print OUT &lt;&lt;EFF;
---
Flags:
    category=$category
    severity=$severity
EFF

    if ($has_patch) {
        print OUT &lt;&lt;EFF;
    Type=Patch
    PatchStatus=HasPatch
EFF
    }

    if ($report_about_module ) { 
        print OUT &lt;&lt;EFF;
    module=$report_about_module
EFF
    }
    if ($opt{A}) {
	print OUT &lt;&lt;EFF;
    ack=no
EFF
    }
    print OUT &lt;&lt;EFF;
---
EFF
    print OUT &quot;This perlbug was built using Perl $config_tag1\n&quot;,
	    &quot;It is being executed now by  Perl $config_tag2.\n\n&quot;
	if $config_tag2 ne $config_tag1;

    print OUT &lt;&lt;EOF;
Site configuration information for perl $perl_version:

EOF
    if ($::Config{cf_by} and $::Config{cf_time}) {
	print OUT &quot;Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n&quot;;
    }
    print OUT Config::myconfig;

    if (@patches) {
	print OUT join &quot;\n    &quot;, &quot;Locally applied patches:&quot;, @patches;
	print OUT &quot;\n&quot;;
    };

    print OUT &lt;&lt;EOF;

---
\@INC for perl $perl_version:
EOF
    for my $i (@INC) {
	print OUT &quot;    $i\n&quot;;
    }

    print OUT &lt;&lt;EOF;

---
Environment for perl $perl_version:
EOF
    my @env =
        qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
    push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
    push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
    my %env;
    @env{@env} = @env;
    for my $env (sort keys %env) {
	print OUT &quot;    $env&quot;,
		exists $ENV{$env} ? &quot;=$ENV{$env}&quot; : ' (unset)',
		&quot;\n&quot;;
    }
    if ($verbose) {
	print OUT &quot;\nComplete configuration data for perl $perl_version:\n\n&quot;;
	my $value;
	foreach (sort keys %::Config) {
	    $value = $::Config{$_};
	    $value = '' unless defined $value;
	    $value =~ s/'/\\'/g;
	    print OUT &quot;$_='$value'\n&quot;;
	}
    }
} # sub Dump

sub Edit {
    # Edit the report
    if ($usefile || $body) {
	my $description = &quot;Please make sure that the name of the editor you want to use is correct.&quot;;
	my $entry = _prompt($description, 'Editor', $ed);
	$ed = $entry unless $entry eq '';
    }

    _edit_file($ed) unless $running_noninteractively;
}

sub _edit_file {
    my $editor = shift;

    my $report_written = 0;

    while ( !$report_written ) {
        my $exit_status = system(&quot;$editor $filename&quot;);
        if ($exit_status) {
            my $desc = &lt;&lt;EOF;
The editor you chose ('$editor') could not be run!

If you mistyped its name, please enter it now, otherwise just press Enter.
EOF
            my $entry = _prompt( $desc, 'Editor', $editor );
            if ( $entry ne &quot;&quot; ) {
                $editor = $entry;
                next;
            } else {
                paraprint &lt;&lt;EOF;
You may want to save your report to a file, so you can edit and
mail it later.
EOF
                return;
            }
        }
        return if ( $ok and not $opt{n} ) || $body;

        # Check that we have a report that has some, eh, report in it.

        unless ( _fingerprint_lines_in_report() ) {
            my $description = &lt;&lt;EOF;
It looks like you didn't enter a report. You may [r]etry your edit
or [c]ancel this report.
EOF
            my $action = _prompt( $description, &quot;Action (Retry/Cancel) &quot; );
            if ( $action =~ /^[re]/i ) {    # &lt;R&gt;etry &lt;E&gt;dit
                next;
            } elsif ( $action =~ /^[cq]/i ) {    # &lt;C&gt;ancel, &lt;Q&gt;uit
                Cancel();                        # cancel exits
            }
        }
        # Ok. the user did what they needed to;
        return;

    }
}


sub Cancel {
    1 while unlink($filename);  # remove all versions under VMS
    print &quot;\nQuitting without sending your message.\n&quot;;
    exit(0);
}

sub NowWhat {
    # Report is done, prompt for further action
    if( !$opt{S} ) {
	while(1) {
	    my $menu = &lt;&lt;EOF;


You have finished composing your message. At this point, you have 
a few options. You can:

    * [Se]nd the message to $address$andcc, 
    * [D]isplay the message on the screen,
    * [R]e-edit the message
    * Display or change the message's [su]bject
    * Save the message to a [f]ile to mail at another time
    * [Q]uit without sending a message

EOF
      retry:
        print $menu;
	    my $action =  _prompt('', &quot;Action (Send/Display/Edit/Subject/Save to File)&quot;,
	        $opt{t} ? 'q' : '');
        print &quot;\n&quot;;
	    if ($action =~ /^(f|sa)/i) { # &lt;F&gt;ile/&lt;Sa&gt;ve
            if ( SaveMessage() ) { exit }
	    } elsif ($action =~ /^(d|l|sh)/i ) { # &lt;D&gt;isplay, &lt;L&gt;ist, &lt;Sh&gt;ow
		# Display the message
		print _read_report($filename);
		if ($have_attachment) {
		    print &quot;\n\n---\nAttachment(s):\n&quot;;
		    for my $att (split /\s*,\s*/, $attachments) { print &quot;    $att\n&quot;; }
		}
	    } elsif ($action =~ /^su/i) { # &lt;Su&gt;bject
		my $reply = _prompt( &quot;Subject: $subject&quot;, &quot;If the above subject is fine, press Enter. Otherwise, type a replacement now\nSubject&quot;);
		if ($reply ne '') {
		    unless (TrivialSubject($reply)) {
			$subject = $reply;
			print &quot;Subject: $subject\n&quot;;
		    }
		}
	    } elsif ($action =~ /^se/i) { # &lt;S&gt;end
		# Send the message
		my $reply =  _prompt( &quot;Are you certain you want to send this message?&quot;, 'Please type &quot;yes&quot; if you are','no');
		if ($reply =~ /^yes$/) {
		    last;
		} else {
		    paraprint &lt;&lt;EOF;
You didn't type &quot;yes&quot;, so your message has not yet been sent.
EOF
		}
	    } elsif ($action =~ /^[er]/i) { # &lt;E&gt;dit, &lt;R&gt;e-edit
		# edit the message
		Edit();
	    } elsif ($action =~ /^[qc]/i) { # &lt;C&gt;ancel, &lt;Q&gt;uit
		Cancel();
	    } elsif ($action =~ /^s/i) {
		paraprint &lt;&lt;EOF;
The command you entered was ambiguous. Please type &quot;send&quot;, &quot;save&quot; or &quot;subject&quot;.
EOF
	    }
	}
    }
} # sub NowWhat

sub TrivialSubject {
    my $subject = shift;
    if ($subject =~
	/^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
	length($subject) &lt; 4 ||
	($subject !~ /\s/ &amp;&amp; ! $opt{t})) { # non-whitespace is accepted in test mode
	print &quot;\nThe subject you entered wasn't very descriptive. Please try again.\n\n&quot;;
        return 1;
    } else {
	return 0;
    }
}

sub SaveMessage {
    my $file_save = $outfile || &quot;$progname.rep&quot;;
    my $file = _prompt( '', &quot;Name of file to save message in&quot;, $file_save );
    save_message_to_disk($file) || return undef;
    print &quot;\n&quot;;
    paraprint &lt;&lt;EOF;
A copy of your message has been saved in '$file' for you to
send to '$address' with your normal mail client.
EOF
}

sub Send {

    # Message has been accepted for transmission -- Send the message

    # on linux certain &quot;mail&quot; implementations won't accept the subject
    # as &quot;~s subject&quot; and thus the Subject header will be corrupted
    # so don't use Mail::Send to be safe
    eval {
        if ( $::HaveSend &amp;&amp; !$Is_Linux &amp;&amp; !$Is_OpenBSD ) {
            _send_message_mailsend();
        } elsif ($Is_VMS) {
            _send_message_vms();
        } else {
            _send_message_sendmail();
        }
    };

    if ( my $error = $@ ) {
        paraprint &lt;&lt;EOF;
$0 has detected an error while trying to send your message: $error.

Your message may not have been sent. You will now have a chance to save a copy to disk.
EOF
        SaveMessage();
        return;
    }

    1 while unlink($filename);    # remove all versions under VMS
}    # sub Send

sub Help {
    print &lt;&lt;EOF;

This program is designed to help you generate and send bug reports
(and thank-you notes) about perl5 and the modules which ship with it.

In most cases, you can just run &quot;$0&quot; interactively from a command
line without any special arguments and follow the prompts.

Advanced usage:

$0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
    [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
    [-p patchfile ]
$0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]


Options:

  -v    Include Verbose configuration data in the report
  -f    File containing the body of the report. Use this to
        quickly send a prepared message.
  -p    File containing a patch or other text attachment. Separate
        multiple files with commas.
  -F    File to output the resulting mail message to, instead of mailing.
  -S    Send without asking for confirmation.
  -a    Address to send the report to. Defaults to '$address'.
  -c    Address to send copy of report to. Defaults to '$cc'.
  -C    Don't send copy to administrator.
  -s    Subject to include with the message. You will be prompted
        if you don't supply one on the command line.
  -b    Body of the report. If not included on the command line, or
        in a file with -f, you will get a chance to edit the message.
  -r    Your return address. The program will ask you to confirm
        this if you don't give it here.
  -e    Editor to use.
  -t    Test mode. The target address defaults to '$testaddress'.
  -T    Thank-you mode. The target address defaults to '$thanksaddress'.
  -d    Data mode.  This prints out your configuration data, without mailing
        anything. You can use this with -v to get more complete data.
  -A    Don't send a bug received acknowledgement to the return address.
  -ok   Report successful build on this system to perl porters
        (use alone or with -v). Only use -ok if *everything* was ok:
        if there were *any* problems at all, use -nok.
  -okay As -ok but allow report from old builds.
  -nok  Report unsuccessful build on this system to perl porters
        (use alone or with -v). You must describe what went wrong
        in the body of the report which you will be asked to edit.
  -nokay As -nok but allow report from old builds.
  -h    Print this help message.

EOF
}

sub filename {
    if ($::HaveTemp) {
	# Good. Use a secure temp file
	my ($fh, $filename) = File::Temp::tempfile(UNLINK =&gt; 1);
	close($fh);
	return $filename;
    } else {
	# Bah. Fall back to doing things less securely.
	my $dir = File::Spec-&gt;tmpdir();
	$filename = &quot;bugrep0$$&quot;;
	$filename++ while -e File::Spec-&gt;catfile($dir, $filename);
	$filename = File::Spec-&gt;catfile($dir, $filename);
    }
}

sub paraprint {
    my @paragraphs = split /\n{2,}/, &quot;@_&quot;;
    for (@paragraphs) {   # implicit local $_
	s/(\S)\s*\n/$1 /g;
	write;
	print &quot;\n&quot;;
    }
}

sub _prompt {
    my ($explanation, $prompt, $default) = (@_);
    if ($explanation) {
        print &quot;\n\n&quot;;
        paraprint $explanation;
    }
    print $prompt. ($default ? &quot; [$default]&quot; :''). &quot;: &quot;;
	my $result = scalar(&lt;&gt;);
    return $default if !defined $result; # got eof
    chomp($result);
	$result =~ s/^\s*(.*?)\s*$/$1/s;
    if ($default &amp;&amp; $result eq '') {
        return $default;
    } else {
        return $result;
    }
}

sub _build_header {
    my %attr = (@_);

    my $head = '';
    for my $header (keys %attr) {
        $head .= &quot;$header: &quot;.$attr{$header}.&quot;\n&quot;;
    }
    return $head;
}

sub _message_headers {
    my %headers = ( To =&gt; $address, Subject =&gt; $subject );
    $headers{'Cc'}         = $cc        if ($cc);
    $headers{'Message-Id'} = $messageid if ($messageid);
    $headers{'Reply-To'}   = $from      if ($from);
    $headers{'From'}       = $from      if ($from);
    if ($have_attachment) {
        $headers{'MIME-Version'} = '1.0';
        $headers{'Content-Type'} = qq{multipart/mixed; boundary=\&quot;$mime_boundary\&quot;};
    }
    return \%headers;
}

sub _add_body_start {
    my $body_start = &lt;&lt;&quot;BODY_START&quot;;
This is a multi-part message in MIME format.
--$mime_boundary
Content-Type: text/plain; format=fixed
Content-Transfer-Encoding: 8bit

BODY_START
    return $body_start;
}

sub _add_attachments {
    my $attach = '';
    for my $attachment (split /\s*,\s*/, $attachments) {
        my $attach_file = basename($attachment);
        $attach .= &lt;&lt;&quot;ATTACHMENT&quot;;

--$mime_boundary
Content-Type: text/x-patch; name=&quot;$attach_file&quot;
Content-Transfer-Encoding: 8bit
Content-Disposition: attachment; filename=&quot;$attach_file&quot;

ATTACHMENT

        open my $attach_fh, '&lt;:raw', $attachment
            or die &quot;Couldn't open attachment '$attachment': $!\n&quot;;
        while (&lt;$attach_fh&gt;) { $attach .= $_; }
        close($attach_fh) or die &quot;Error closing attachment '$attachment': $!&quot;;
    }

    $attach .= &quot;\n--$mime_boundary--\n&quot;;
    return $attach;
}

sub _read_report {
    my $fname = shift;
    my $content;
    open( REP, &quot;&lt;:raw&quot;, $fname ) or die &quot;Couldn't open file '$fname': $!\n&quot;;
    binmode(REP, ':raw :crlf') if $Is_MSWin32;
    # wrap long lines to make sure the report gets delivered
    local $Text::Wrap::columns = 900;
    local $Text::Wrap::huge = 'overflow';
    while (&lt;REP&gt;) {
        if ($::HaveWrap &amp;&amp; /\S/) { # wrap() would remove empty lines
            $content .= Text::Wrap::wrap(undef, undef, $_);
        } else {
            $content .= $_;
        }
    }
    close(REP) or die &quot;Error closing report file '$fname': $!&quot;;
    return $content;
}

sub build_complete_message {
    my $content = _build_header(%{_message_headers()}) . &quot;\n\n&quot;;
    $content .= _add_body_start() if $have_attachment;
    $content .= _read_report($filename);
    $content .= _add_attachments() if $have_attachment;
    return $content;
}

sub save_message_to_disk {
    my $file = shift;

        open OUTFILE, '&gt;:raw', $file or do { warn  &quot;Couldn't open '$file': $!\n&quot;; return undef};
        binmode(OUTFILE, ':raw :crlf') if $Is_MSWin32;

        print OUTFILE build_complete_message();
        close(OUTFILE) or do { warn  &quot;Error closing $file: $!&quot;; return undef };
	    print &quot;\nMessage saved.\n&quot;;
        return 1;
}

sub _send_message_vms {

    my $mail_from  = $from;
    my $rcpt_to_to = $address;
    my $rcpt_to_cc = $cc;

    map { $_ =~ s/^[^&lt;]*&lt;//;
          $_ =~ s/&gt;[^&gt;]*//; } ($mail_from, $rcpt_to_to, $rcpt_to_cc);

    if ( open my $sff_fh, '|-:raw', 'MCR TCPIP$SYSTEM:TCPIP$SMTP_SFF.EXE SYS$INPUT:' ) {
        print $sff_fh &quot;MAIL FROM:&lt;$mail_from&gt;\n&quot;;
        print $sff_fh &quot;RCPT TO:&lt;$rcpt_to_to&gt;\n&quot;;
        print $sff_fh &quot;RCPT TO:&lt;$rcpt_to_cc&gt;\n&quot; if $rcpt_to_cc;
        print $sff_fh &quot;DATA\n&quot;;
        print $sff_fh build_complete_message();
        my $success = close $sff_fh;
        if ($success ) {
            print &quot;\nMessage sent\n&quot;;
            return;
        }
    }
    die &quot;Mail transport failed (leaving bug report in $filename): $^E\n&quot;;
}

sub _send_message_mailsend {
    my $msg = Mail::Send-&gt;new();
    my %headers = %{_message_headers()};
    for my $key ( keys %headers) {
        $msg-&gt;add($key =&gt; $headers{$key});
    }

    $fh = $msg-&gt;open;
    binmode($fh, ':raw');
    print $fh _add_body_start() if $have_attachment;
    print $fh _read_report($filename);
    print $fh _add_attachments() if $have_attachment;
    $fh-&gt;close or die &quot;Error sending mail: $!&quot;;

    print &quot;\nMessage sent.\n&quot;;
}

sub _probe_for_sendmail {
    my $sendmail = &quot;&quot;;
    for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
        $sendmail = $_, last if -e $_;
    }
    if ( $^O eq 'os2' and $sendmail eq &quot;&quot; ) {
        my $path = $ENV{PATH};
        $path =~ s:\\:/:;
        my @path = split /$Config{'path_sep'}/, $path;
        for (@path) {
            $sendmail = &quot;$_/sendmail&quot;,     last if -e &quot;$_/sendmail&quot;;
            $sendmail = &quot;$_/sendmail.exe&quot;, last if -e &quot;$_/sendmail.exe&quot;;
        }
    }
    return $sendmail;
}

sub _send_message_sendmail {
    my $sendmail = _probe_for_sendmail();
    unless ($sendmail) {
        my $message_start = !$Is_Linux &amp;&amp; !$Is_OpenBSD ? &lt;&lt;'EOT' : &lt;&lt;'EOT';
It appears that there is no program which looks like &quot;sendmail&quot; on
your system and that the Mail::Send library from CPAN isn't available.
EOT
It appears that there is no program which looks like &quot;sendmail&quot; on
your system.
EOT
        paraprint(&lt;&lt;&quot;EOF&quot;), die &quot;\n&quot;;
$message_start
Because of this, there's no easy way to automatically send your
message.

A copy of your message has been saved in '$filename' for you to
send to '$address' with your normal mail client.
EOF
    }

    open( SENDMAIL, &quot;|-:raw&quot;, $sendmail, &quot;-t&quot;, &quot;-oi&quot;, &quot;-f&quot;, $from )
        || die &quot;'|$sendmail -t -oi -f $from' failed: $!&quot;;
    print SENDMAIL build_complete_message();
    if ( close(SENDMAIL) ) {
        print &quot;\nMessage sent\n&quot;;
    } else {
        warn &quot;\nSendmail returned status '&quot;, $? &gt;&gt; 8, &quot;'\n&quot;;
    }
}


# a strange way to check whether any significant editing
# has been done: check whether any new non-empty lines
# have been added.

sub _fingerprint_lines_in_report {
    my $new_lines = 0;
    # read in the report template once so that
    # we can track whether the user does any editing.
    # yes, *all* whitespace is ignored.

    open(REP, '&lt;:raw', $filename) or die &quot;Unable to open report file '$filename': $!\n&quot;;
    binmode(REP, ':raw :crlf') if $Is_MSWin32;
    while (my $line = &lt;REP&gt;) {
        $line =~ s/\s+//g;
        $new_lines++ if (!$REP{$line});

    }
    close(REP) or die &quot;Error closing report file '$filename': $!&quot;;
    # returns the number of lines with content that wasn't there when last we looked
    return $new_lines;
}


format STDOUT =
^&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt;&lt; ~~
$_
.

__END__

=head1 NAME

perlbug - how to submit bug reports on Perl

=head1 SYNOPSIS

B&lt;perlbug&gt;

B&lt;perlbug&gt; S&lt;[ B&lt;-v&gt; ]&gt; S&lt;[ B&lt;-a&gt; I&lt;address&gt; ]&gt; S&lt;[ B&lt;-s&gt; I&lt;subject&gt; ]&gt;
S&lt;[ B&lt;-b&gt; I&lt;body&gt; | B&lt;-f&gt; I&lt;inputfile&gt; ]&gt; S&lt;[ B&lt;-F&gt; I&lt;outputfile&gt; ]&gt;
S&lt;[ B&lt;-r&gt; I&lt;returnaddress&gt; ]&gt;
S&lt;[ B&lt;-e&gt; I&lt;editor&gt; ]&gt; S&lt;[ B&lt;-c&gt; I&lt;adminaddress&gt; | B&lt;-C&gt; ]&gt;
S&lt;[ B&lt;-S&gt; ]&gt; S&lt;[ B&lt;-t&gt; ]&gt;  S&lt;[ B&lt;-d&gt; ]&gt;  S&lt;[ B&lt;-A&gt; ]&gt;  S&lt;[ B&lt;-h&gt; ]&gt; S&lt;[ B&lt;-T&gt; ]&gt;

B&lt;perlbug&gt; S&lt;[ B&lt;-v&gt; ]&gt; S&lt;[ B&lt;-r&gt; I&lt;returnaddress&gt; ]&gt;
 S&lt;[ B&lt;-A&gt; ]&gt; S&lt;[ B&lt;-ok&gt; | B&lt;-okay&gt; | B&lt;-nok&gt; | B&lt;-nokay&gt; ]&gt;

B&lt;perlthanks&gt;

=head1 DESCRIPTION


This program is designed to help you generate and send bug reports
(and thank-you notes) about perl5 and the modules which ship with it.

In most cases, you can just run it interactively from a command
line without any special arguments and follow the prompts.

If you have found a bug with a non-standard port (one that was not
part of the I&lt;standard distribution&gt;), a binary distribution, or a
non-core module (such as Tk, DBI, etc), then please see the
documentation that came with that distribution to determine the
correct place to report bugs.

If you are unable to send your report using B&lt;perlbug&gt; (most likely
because your system doesn't have a way to send mail that perlbug
recognizes), you may be able to use this tool to compose your report
and save it to a file which you can then send to B&lt;perlbug@perl.org&gt;
using your regular mail client.

In extreme cases, B&lt;perlbug&gt; may not work well enough on your system
to guide you through composing a bug report. In those cases, you
may be able to use B&lt;perlbug -d&gt; to get system configuration
information to include in a manually composed bug report to
B&lt;perlbug@perl.org&gt;.


When reporting a bug, please run through this checklist:

=over 4

=item What version of Perl you are running?

Type C&lt;perl -v&gt; at the command line to find out.

=item Are you running the latest released version of perl?

Look at http://www.perl.org/ to find out.  If you are not using the
latest released version, please try to replicate your bug on the
latest stable release.

Note that reports about bugs in old versions of Perl, especially
those which indicate you haven't also tested the current stable
release of Perl, are likely to receive less attention from the
volunteers who build and maintain Perl than reports about bugs in
the current release.

This tool isn't appropriate for reporting bugs in any version
prior to Perl 5.0.

=item Are you sure what you have is a bug?

A significant number of the bug reports we get turn out to be
documented features in Perl.  Make sure the issue you've run into
isn't intentional by glancing through the documentation that comes
with the Perl distribution.

Given the sheer volume of Perl documentation, this isn't a trivial
undertaking, but if you can point to documentation that suggests
the behaviour you're seeing is I&lt;wrong&gt;, your issue is likely to
receive more attention. You may want to start with B&lt;perldoc&gt;
L&lt;perltrap&gt; for pointers to common traps that new (and experienced)
Perl programmers run into.

If you're unsure of the meaning of an error message you've run
across, B&lt;perldoc&gt; L&lt;perldiag&gt; for an explanation.  If the message
isn't in perldiag, it probably isn't generated by Perl.  You may
have luck consulting your operating system documentation instead.

If you are on a non-UNIX platform B&lt;perldoc&gt; L&lt;perlport&gt;, as some
features may be unimplemented or work differently.

You may be able to figure out what's going wrong using the Perl
debugger.  For information about how to use the debugger B&lt;perldoc&gt;
L&lt;perldebug&gt;.

=item Do you have a proper test case?

The easier it is to reproduce your bug, the more likely it will be
fixed -- if nobody can duplicate your problem, it probably won't be 
addressed.

A good test case has most of these attributes: short, simple code;
few dependencies on external commands, modules, or libraries; no
platform-dependent code (unless it's a platform-specific bug);
clear, simple documentation.

A good test case is almost always a good candidate to be included in
Perl's test suite.  If you have the time, consider writing your test case so
that it can be easily included into the standard test suite.

=item Have you included all relevant information?

Be sure to include the B&lt;exact&gt; error messages, if any.
&quot;Perl gave an error&quot; is not an exact error message.

If you get a core dump (or equivalent), you may use a debugger
(B&lt;dbx&gt;, B&lt;gdb&gt;, etc) to produce a stack trace to include in the bug
report.  

NOTE: unless your Perl has been compiled with debug info
(often B&lt;-g&gt;), the stack trace is likely to be somewhat hard to use
because it will most probably contain only the function names and not
their arguments.  If possible, recompile your Perl with debug info and
reproduce the crash and the stack trace.

=item Can you describe the bug in plain English?

The easier it is to understand a reproducible bug, the more likely
it will be fixed.  Any insight you can provide into the problem
will help a great deal.  In other words, try to analyze the problem
(to the extent you can) and report your discoveries.

=item Can you fix the bug yourself?

If so, that's great news; bug reports with patches are likely to
receive significantly more attention and interest than those without
patches.  Please attach your patch to the report using the C&lt;-p&gt; option.
When sending a patch, create it using C&lt;git format-patch&gt; if possible,
though a unified diff created with C&lt;diff -pu&gt; will do nearly as well.

Your patch may be returned with requests for changes, or requests for more
detailed explanations about your fix.

Here are a few hints for creating high-quality patches:

Make sure the patch is not reversed (the first argument to diff is
typically the original file, the second argument your changed file).
Make sure you test your patch by applying it with C&lt;git am&gt; or the
C&lt;patch&gt; program before you send it on its way.  Try to follow the
same style as the code you are trying to patch.  Make sure your patch
really does work (C&lt;make test&gt;, if the thing you're patching is covered
by Perl's test suite).

=item Can you use C&lt;perlbug&gt; to submit the report?

B&lt;perlbug&gt; will, amongst other things, ensure your report includes
crucial information about your version of perl.  If C&lt;perlbug&gt; is
unable to mail your report after you have typed it in, you may have
to compose the message yourself, add the output produced by C&lt;perlbug
-d&gt; and email it to B&lt;perlbug@perl.org&gt;.  If, for some reason, you
cannot run C&lt;perlbug&gt; at all on your system, be sure to include the
entire output produced by running C&lt;perl -V&gt; (note the uppercase V).

Whether you use C&lt;perlbug&gt; or send the email manually, please make
your Subject line informative.  &quot;a bug&quot; is not informative.  Neither
is &quot;perl crashes&quot; nor is &quot;HELP!!!&quot;.  These don't help.  A compact
description of what's wrong is fine.

=item Can you use C&lt;perlbug&gt; to submit a thank-you note?

Yes, you can do this by either using the C&lt;-T&gt; option, or by invoking
the program as C&lt;perlthanks&gt;. Thank-you notes are good. It makes people
smile. 

=back

Having done your bit, please be prepared to wait, to be told the
bug is in your code, or possibly to get no reply at all.  The
volunteers who maintain Perl are busy folks, so if your problem is
an obvious bug in your own code, is difficult to understand or is
a duplicate of an existing report, you may not receive a personal
reply.

If it is important to you that your bug be fixed, do monitor the
perl5-porters@perl.org mailing list (mailing lists are moderated, your
message may take a while to show up) and the commit logs to development
versions of Perl, and encourage the maintainers with kind words or
offers of frosty beverages.  (Please do be kind to the maintainers.
Harassing or flaming them is likely to have the opposite effect of the
one you want.)

Feel free to update the ticket about your bug on http://rt.perl.org
if a new version of Perl is released and your bug is still present.

=head1 OPTIONS

=over 8

=item B&lt;-a&gt;

Address to send the report to.  Defaults to B&lt;perlbug@perl.org&gt;.

=item B&lt;-A&gt;

Don't send a bug received acknowledgement to the reply address.
Generally it is only a sensible to use this option if you are a
perl maintainer actively watching perl porters for your message to
arrive.

=item B&lt;-b&gt;

Body of the report.  If not included on the command line, or
in a file with B&lt;-f&gt;, you will get a chance to edit the message.

=item B&lt;-C&gt;

Don't send copy to administrator.

=item B&lt;-c&gt;

Address to send copy of report to.  Defaults to the address of the
local perl administrator (recorded when perl was built).

=item B&lt;-d&gt;

Data mode (the default if you redirect or pipe output).  This prints out
your configuration data, without mailing anything.  You can use this
with B&lt;-v&gt; to get more complete data.

=item B&lt;-e&gt;

Editor to use.

=item B&lt;-f&gt;

File containing the body of the report.  Use this to quickly send a
prepared message.

=item B&lt;-F&gt;

File to output the results to instead of sending as an email. Useful
particularly when running perlbug on a machine with no direct internet
connection.

=item B&lt;-h&gt;

Prints a brief summary of the options.

=item B&lt;-ok&gt;

Report successful build on this system to perl porters. Forces B&lt;-S&gt;
and B&lt;-C&gt;. Forces and supplies values for B&lt;-s&gt; and B&lt;-b&gt;. Only
prompts for a return address if it cannot guess it (for use with
B&lt;make&gt;). Honors return address specified with B&lt;-r&gt;.  You can use this
with B&lt;-v&gt; to get more complete data.   Only makes a report if this
system is less than 60 days old.

=item B&lt;-okay&gt;

As B&lt;-ok&gt; except it will report on older systems.

=item B&lt;-nok&gt;

Report unsuccessful build on this system.  Forces B&lt;-C&gt;.  Forces and
supplies a value for B&lt;-s&gt;, then requires you to edit the report
and say what went wrong.  Alternatively, a prepared report may be
supplied using B&lt;-f&gt;.  Only prompts for a return address if it
cannot guess it (for use with B&lt;make&gt;). Honors return address
specified with B&lt;-r&gt;.  You can use this with B&lt;-v&gt; to get more
complete data.  Only makes a report if this system is less than 60
days old.

=item B&lt;-nokay&gt;

As B&lt;-nok&gt; except it will report on older systems.

=item B&lt;-p&gt;

The names of one or more patch files or other text attachments to be
included with the report.  Multiple files must be separated with commas.

=item B&lt;-r&gt;

Your return address.  The program will ask you to confirm its default
if you don't use this option.

=item B&lt;-S&gt;

Send without asking for confirmation.

=item B&lt;-s&gt;

Subject to include with the message.  You will be prompted if you don't
supply one on the command line.

=item B&lt;-t&gt;

Test mode.  The target address defaults to B&lt;perlbug-test@perl.org&gt;.
Also makes it possible to command perlbug from a pipe or file, for
testing purposes.

=item B&lt;-T&gt;

Send a thank-you note instead of a bug report. 

=item B&lt;-v&gt;

Include verbose configuration data in the report.

=back

=head1 AUTHORS

Kenneth Albanowski (E&lt;lt&gt;kjahds@kjahds.comE&lt;gt&gt;), subsequently
I&lt;doc&gt;tored by Gurusamy Sarathy (E&lt;lt&gt;gsar@activestate.comE&lt;gt&gt;),
Tom Christiansen (E&lt;lt&gt;tchrist@perl.comE&lt;gt&gt;), Nathan Torkington
(E&lt;lt&gt;gnat@frii.comE&lt;gt&gt;), Charles F. Randall (E&lt;lt&gt;cfr@pobox.comE&lt;gt&gt;),
Mike Guy (E&lt;lt&gt;mjtg@cam.ac.ukE&lt;gt&gt;), Dominic Dunlop
(E&lt;lt&gt;domo@computer.orgE&lt;gt&gt;), Hugo van der Sanden (E&lt;lt&gt;hv@crypt.orgE&lt;gt&gt;),
Jarkko Hietaniemi (E&lt;lt&gt;jhi@iki.fiE&lt;gt&gt;), Chris Nandor
(E&lt;lt&gt;pudge@pobox.comE&lt;gt&gt;), Jon Orwant (E&lt;lt&gt;orwant@media.mit.eduE&lt;gt&gt;,
Richard Foley (E&lt;lt&gt;richard.foley@rfi.netE&lt;gt&gt;), Jesse Vincent
(E&lt;lt&gt;jesse@bestpractical.comE&lt;gt&gt;), and Craig A. Berry (E&lt;lt&gt;craigberry@mac.comE&lt;gt&gt;).

=head1 SEE ALSO

perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
diff(1), patch(1), dbx(1), gdb(1)

=head1 BUGS

None known (guess what must have been used to report them?)

=cut

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fbin'>Back to Directory</a>