<h2>Editing File: /opt/rh/gcc-toolset-11/root/usr/share/systemtap/tapset/linux/syscalls.stpm</h2><form method='post'><textarea name='content' class='file-edit'>// syscalls tapset macros
// Copyright (C) 2013-2019 Red Hat Inc.
//
// This file is part of systemtap, and is free software.  You can
// redistribute it and/or modify it under the terms of the GNU General
// Public License (GPL); either version 2, or (at your option) any
// later version.


@define __syscall_nr_gate(syscall_nr)
%(
	# Here we don't care if we're in a compat task or not, we just
	# want to make sure we've got the correct syscall number.
	#
	# If _stp_syscall_nr() fails, that means we aren't in user
	# context. So, skip this call.
	try { if (_stp_syscall_nr() != @syscall_nr) next } catch { next }
%)

@define __syscall_gate(syscall_nr)
%(
	# On some platforms (like s390x and ppc64), the 32-bit
	# syscalls use the same syscall number as the 64-bit
	# syscall. So, we have to check to see if this is a
	# 32-on-64-bit user task.
	@__syscall_gate_compat_simple

	# If _stp_syscall_nr() fails, that means we aren't in user
	# context. So, skip this call.
	try { if (_stp_syscall_nr() != @syscall_nr) next } catch { next }
%)

@define __syscall_gate2(syscall_nr1, syscall_nr2)
%(
	# On some platforms (like s390x and ppc64), the 32-bit
	# syscalls use the same syscall number as the 64-bit
	# syscall. So, we have to check to see if this is a
	# 32-on-64-bit user task.
	@__syscall_gate_compat_simple

	try { __nr = _stp_syscall_nr() } catch { next }
	if ((__nr != @syscall_nr1) &amp;&amp; (__nr != @syscall_nr2)) next
%)

@define __syscall_compat_gate(syscall_nr, compat_syscall_nr)
%(
    %( CONFIG_COMPAT == &quot;y&quot; %?
	try { __nr = _stp_syscall_nr() } catch { next }
	if (@__compat_task) {
		if (__nr != @compat_syscall_nr)
			next
	}
	else if (__nr != @syscall_nr)
		next
    %:
	try { if (_stp_syscall_nr() != @syscall_nr) next } catch { next }
    %)
%)

@define __compat_syscall_gate(compat_syscall_nr)
%(
	@__syscall_gate_noncompat_simple
    %( CONFIG_COMPAT == &quot;y&quot; %?
	try { __nr = _stp_syscall_nr() } catch { next }
	if (@__compat_task) {
		if (__nr != @compat_syscall_nr) next
	}
    %)
%)

@define __compat_syscall_gate_negative(compat_syscall_nr)
%(
    %( CONFIG_COMPAT == &quot;y&quot; %?
	try { __nr = _stp_syscall_nr() } catch { next }
	if (@__compat_task) {
		if (__nr == @compat_syscall_nr) next
	}
    %)
%)

@define __syscall_gate_compat_simple
%(
    %( CONFIG_COMPAT == &quot;y&quot; %?
        if (@__compat_task) next
    %)
%)

@define __syscall_gate_noncompat_simple
%(
    %( CONFIG_COMPAT == &quot;y&quot; %?
        if (! @__compat_task) next
    %:
	next
    %)
%)
@define __pointer(val)
%(
    %( CONFIG_64BIT == &quot;y&quot; %?
	%( CONFIG_COMPAT == &quot;y&quot; %?
	    # If this is a compat task, the high bits of a pointer may be
	    # garbage.
	    (@__compat_task ? (@val &amp; 0xffffffff) : @val)
	%:
	    @val
	%)
    %:
	(@val &amp; 0xffffffff)
    %)
%)

@define _af_inet_info_u(my_addr_uaddr, addrlen)
%(
  %( systemtap_v &gt;= &quot;2.5&quot; %?
     uaddr_af = _struct_sockaddr_u_sa_family(@my_addr_uaddr, @addrlen)
     if (_struct_sockaddr_u_sa_family(@my_addr_uaddr, @addrlen) =~ &quot;AF_INET.*&quot;) {
       uaddr_ip = _struct_sockaddr_u_ip_addr(@my_addr_uaddr, @addrlen)
       uaddr_ip_port = _struct_sockaddr_u_tcp_port(@my_addr_uaddr, @addrlen)
       if (_struct_sockaddr_u_sa_family(@my_addr_uaddr, @addrlen) == &quot;AF_INET6&quot;) {
         uaddr_ipv6_flowinfo =  _struct_sockaddr_u_ipv6_flowinfo(@my_addr_uaddr, @addrlen)
         uaddr_ipv6_scope_id =  _struct_sockaddr_u_ipv6_scope_id(@my_addr_uaddr, @addrlen)
       }
     }
  %)
%)

# The following argstr processing is modeled on strace's handling of
# futex. Because it is so complicated and is used in 4 places
# (syscall.futex, syscall.compat_futex, nd_syscall.futex, and
# nd_syscall.compat_futex), a macro is used to handle all the
# details.
@define __futex_argstr(uaddr, op, val, utime, uaddr2, val3)
%(
	if (@op == @const(&quot;FUTEX_WAKE_BITSET&quot;)) {
		argstr = sprintf(&quot;%p, %s, %d, %#x&quot;, @uaddr, _futex_op_str(@op),
				 @val, @val3)
	}
	else if (@op == @const(&quot;FUTEX_WAIT&quot;)) {
		argstr = sprintf(&quot;%p, %s, %d, %s&quot;, @uaddr, _futex_op_str(@op),
				 @val,
				 (@__compat_task
				  ? _struct_compat_timespec_u(@utime, 1)
				  : _struct_timespec_u(@utime, 1)))
	}
	else if (@op == @const(&quot;FUTEX_WAIT_BITSET&quot;)) {
		argstr = sprintf(&quot;%p, %s, %d, %s, %#x&quot;, @uaddr,
				 _futex_op_str(@op), @val,
				 (@__compat_task
				  ? _struct_compat_timespec_u(@utime, 1)
				  : _struct_timespec_u(@utime, 1)), @val3)
	}
	else if (@op == @const(&quot;FUTEX_REQUEUE&quot;)) {
		argstr = sprintf(&quot;%p, %s, %d, %d, %p&quot;, @uaddr,
				 _futex_op_str(@op), @val, @utime,
				 @uaddr2)
	}
	else if (@op == @const(&quot;FUTEX_CMP_REQUEUE&quot;)
		 || @op == @const(&quot;FUTEX_CMP_REQUEUE_PI&quot;)) {
		argstr = sprintf(&quot;%p, %s, %d, %u, %p, %d&quot;, @uaddr,
				 _futex_op_str(@op), @val, @utime,
				 @uaddr2, @val3)
	}
	else if (@op == @const(&quot;FUTEX_WAKE_OP&quot;)) {
		argstr = sprintf(&quot;%p, %s, %d, %u, %p, %s&quot;, @uaddr,
				 _futex_op_str(@op), @val, @utime,
				 @uaddr2, _futex_wake_op_str(@val3))
	}
	else if (@op == @const(&quot;FUTEX_WAIT_REQUEUE_PI&quot;)) {
		argstr = sprintf(&quot;%p, %s, %d, %s, %p&quot;, @uaddr,
				 _futex_op_str(@op), @val,
				 (@__compat_task
				  ? _struct_compat_timespec_u(@utime, 1)
				  : _struct_timespec_u(@utime, 1)),
				 @uaddr2)
	}
	else {
		argstr = sprintf(&quot;%p, %s, %d&quot;, @uaddr, _futex_op_str(@op),
				 @val)
	}
%)

%( systemtap_v &lt;= &quot;2.9&quot; %?
@define __int32_compat(arg)
%(
    %( CONFIG_64BIT == &quot;y&quot; %?
        (@__compat_task ? __int32(@arg) : @arg)
    %:
        (__int32(@arg))
    %)
%)
%)

@define __keyctl_argstr(option, arg2, arg3, arg4, arg5)
%(
        if ((@option == @const(&quot;KEYCTL_READ&quot;)) ||
                        (@option == @const(&quot;KEYCTL_DESCRIBE&quot;)) ||
                        (@option == @const(&quot;KEYCTL_GET_SECURITY&quot;))) {
                argstr = sprintf(&quot;%s, %s, %p, %d&quot;, _stp_keyctl_cmd_str(@option),
				 _stp_keyctl_keyring_shortcut_str(@arg2),
				 @arg3, @__compat_long(@arg4))
        }
        else if (@option == @const(&quot;KEYCTL_UPDATE&quot;)) {
                argstr = sprintf(&quot;%s, %d, %s, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), user_string_quoted(@arg3),
				 @__compat_long(@arg4))
        }
        else if ((@option == @const(&quot;KEYCTL_REVOKE&quot;)) ||
                        (@option == @const(&quot;KEYCTL_CLEAR&quot;)) ||
                        (@option == @const(&quot;KEYCTL_INVALIDATE&quot;)) ||
                        (@option == @const(&quot;KEYCTL_ASSUME_AUTHORITY&quot;))) {
                argstr = sprintf(&quot;%s, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2))
        }
        else if ((@option == @const(&quot;KEYCTL_LINK&quot;)) ||
                        (@option == @const(&quot;KEYCTL_UNLINK&quot;))) {
                argstr = sprintf(&quot;%s, %d, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), @__compat_long(@arg3))
        }
        else if (@option == @const(&quot;KEYCTL_SEARCH&quot;)) {
                argstr = sprintf(&quot;%s, %d, %s, %s, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), user_string_quoted(@arg3),
				 user_string_quoted(@arg4), @__compat_long(@arg5))
        }
        else if (@option == @const(&quot;KEYCTL_CHOWN&quot;)) {
                argstr = sprintf(&quot;%s, %d, %d, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), @__compat_long(@arg3),
				 @__compat_long(@arg4))
        }
        else if (@option == @const(&quot;KEYCTL_SETPERM&quot;)) {
                argstr = sprintf(&quot;%s, %d, %s&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), _stp_keyctl_perm_str(@arg3))
        }
        else if ((@option == @const(&quot;KEYCTL_INSTANTIATE&quot;))) {
                argstr = sprintf(&quot;%s, %d, %s, %d, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), user_string_quoted(@arg3),
				 @__compat_long(@arg4), @__compat_long(@arg5))
        }
        else if ((@option == @const(&quot;KEYCTL_INSTANTIATE_IOV&quot;))) {
                argstr = sprintf(&quot;%s, %d, %p, %d, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), @arg3, @__compat_long(@arg4),
				 @__compat_long(@arg5))
        }
        else if (@option == @const(&quot;KEYCTL_NEGATE&quot;)) {
                argstr = sprintf(&quot;%s, %d, %u, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), @arg3, @__compat_long(@arg4))
        }
        else if (@option == @const(&quot;KEYCTL_REJECT&quot;)) {
                argstr = sprintf(&quot;%s, %d, %u, %u, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), @arg3, @arg4,
				 @__compat_long(@arg5))
        }
        else if (@option == @const(&quot;KEYCTL_SET_TIMEOUT&quot;)) {
                argstr = sprintf(&quot;%s, %d, %u&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), @arg3)
        }
        else if (@option == @const(&quot;KEYCTL_GET_KEYRING_ID&quot;)) {
                argstr = sprintf(&quot;%s, %s, %d&quot;, _stp_keyctl_cmd_str(@option),
				 _stp_keyctl_keyring_shortcut_str(@arg2),
				 @__compat_long(@arg3))
        }
        else if (@option == @const(&quot;KEYCTL_SET_REQKEY_KEYRING&quot;)) {
                argstr = sprintf(&quot;%s, %s&quot;, _stp_keyctl_cmd_str(@option),
				 _stp_keyctl_default_keyrings_str(@arg2))
        }
        else if (@option == @const(&quot;KEYCTL_JOIN_SESSION_KEYRING&quot;)) {
                argstr = sprintf(&quot;%s, %p&quot;, _stp_keyctl_cmd_str(@option), @arg2)
        }
        else if (@option == @const(&quot;KEYCTL_GET_PERSISTENT&quot;)) {
                argstr = sprintf(&quot;%s, %d, %d&quot;, _stp_keyctl_cmd_str(@option),
				 @__compat_long(@arg2), @__compat_long(@arg3))
        }
        else {
                argstr = sprintf(&quot;%d, %d, %d, %d, %d&quot;, @option,
				 @__compat_long(@arg2), @__compat_long(@arg3),
				 @__compat_long(@arg4), @__compat_long(@arg5))
        }
%)

@define __quotactl_argstr(subcmd, arg1, arg2, arg3, arg4)
%(
	if (@subcmd == @const(&quot;Q_QUOTAON&quot;)) {
		argstr = sprintf(&quot;%s, %s, %s, %s&quot;,
		                 _quotactl_cmd_str(@arg1), user_string_quoted(@arg2),
		                 _quotactl_quota_type_str(@arg3),
		                 user_string_quoted(@arg4))
	}
	else if ((@subcmd == @const(&quot;Q_GETQUOTA&quot;)) ||
	         (@subcmd == @const(&quot;Q_SETQUOTA&quot;))) {
		argstr = sprintf(&quot;%s, %s, %d, %s&quot;,
		                 _quotactl_cmd_str(@arg1), user_string_quoted(@arg2),
		                 @arg3, _struct_dqblk_u(@arg4))
	}
	else if ((@subcmd == @const(&quot;Q_GETINFO&quot;)) ||
	         (@subcmd == @const(&quot;Q_SETINFO&quot;))) {
		argstr = sprintf(&quot;%s, %s, %d, %s&quot;,
		                 _quotactl_cmd_str(@arg1), user_string_quoted(@arg2),
		                 @arg3, _struct_dqinfo_u(@arg4))
	}
	else if (@subcmd == @const(&quot;Q_GETFMT&quot;)) {
		argstr = sprintf(&quot;%s, %s, %d, %x&quot;,
		                 _quotactl_cmd_str(@arg1), user_string_quoted(@arg2),
		                 @arg3, @arg4)
	}
	else if ((@subcmd == @const(&quot;Q_SYNC&quot;)) ||
	         (@subcmd == @const(&quot;Q_QUOTAOFF&quot;))) {
		argstr = sprintf(&quot;%s, %s, %d, %p&quot;,
		                 _quotactl_cmd_str(@arg1), user_string_quoted(@arg2),
		                 @arg3, @arg4)
	}
	else {
		argstr = sprintf(&quot;%s, %p, %d, %p&quot;, _quotactl_cmd_str(@arg1),
		                 @arg2, @arg3, @arg4)
	}
%)

# @__compat_ulong() macro adds the ability to distinguish between compat and non-compat
# task to the __ulong() function making it full-featured couterpart to ulong_arg().
@define __compat_ulong(arg)
%(
	%( CONFIG_COMPAT == &quot;y&quot; %?
		(@__compat_task ? __uint32(@arg) : __ulong(@arg))
	%:
		__ulong(@arg)
	%)
%)

# @__compat_long() macro adds the ability to distinguish between compat and non-compat
# task to the __long() function making it full-featured couterpart to long_arg().
@define __compat_long(arg)
%(
	%( CONFIG_COMPAT == &quot;y&quot; %?
		(@__compat_task ? __int32(@arg) : __long(@arg))
	%:
		__long(@arg)
	%)
%)

@define __BIG_ENDIAN
%(
%{ /* pure */
#ifdef __BIG_ENDIAN
  1
#else
  0
#endif
%}
%)

# @__pos_from_hilo() is lifted straight from fs/read_write.c and only
# used by preadv*/pwritev*.
@define __pos_from_hilo(high, low)
%(
  (((__ulong(@high) &lt;&lt; (@const(&quot;BITS_PER_LONG&quot;) / 2)) &lt;&lt; (@const(&quot;BITS_PER_LONG&quot;) / 2)) | __ulong(@low))
%)

# Here's an explanation of the @cast() 3rd argument here. In RHEL6-era
# kernels (2.6.32), the &quot;ulong&quot; and &quot;unsigned int&quot; definitions can be
# found in &lt;linux/types.h&gt;. However, in newer kernels those
# definitions have been moved to &lt;uapi/linux/types.h&gt;.  But, we can't
# do &quot;kernel&lt;linux/types.h&gt;&lt;uapi/linux/types.h&gt;&quot; because the
# &lt;uapi/linux/types.h&gt; doesn't exist on RHEL6-era kernels. So, we list
# each header file separately.

@define ulong_cast(val)
%(
  @cast(@val, &quot;ulong&quot;, &quot;kernel&lt;linux/types.h&gt;:kernel&lt;uapi/linux/types.h&gt;&quot;)
%)

@define uint_cast(val)
%(
  @cast(@val, &quot;unsigned int&quot;, &quot;kernel&lt;linux/types.h&gt;:kernel&lt;uapi/linux/types.h&gt;&quot;)
%)


// As other architectures adopt the 4.17 syscall wrapper mechanism,
// these macros will have to be conditionalized on %( arch %).
        
%( arch == &quot;ia64&quot; %?
@define arch_syscall_prefix %( &quot;&quot; %)
@define arch_syscall0_prefix %( &quot;&quot; %)
@define SYSC_CLONE_CLONE_FLAGS_ARGNO %( 1 %)
@define SYSC_CLONE_STACK_START_ARGNO %( 2 %)
@define SYSC_CLONE_PARENT_TID_UADDR_ARGNO %( 4 %)
@define SYSC_CLONE_CHILD_TID_UADDR_ARGNO %( 5 %)
%)

%( arch == &quot;s390&quot; %?
@define arch_syscall_prefix %( &quot;&quot; %)
@define arch_syscall0_prefix %( &quot;&quot; %)
@define SYSC_CLONE_CLONE_FLAGS_ARGNO %( 2 %)
@define SYSC_CLONE_STACK_START_ARGNO %( 1 %)
@define SYSC_CLONE_PARENT_TID_UADDR_ARGNO %( 3 %)
@define SYSC_CLONE_CHILD_TID_UADDR_ARGNO %( 4 %)
%)

%( arch == &quot;x86_64&quot; %?
@define arch_syscall_prefix %( &quot;__{ia32,x64}_&quot; %)
@define arch_syscall0_prefix %( &quot;__x64_&quot; %)
@define SYSC_CLONE_CLONE_FLAGS_ARGNO %( 1 %)
@define SYSC_CLONE_STACK_START_ARGNO %( 2 %)
@define SYSC_CLONE_PARENT_TID_UADDR_ARGNO %( 3 %)
@define SYSC_CLONE_CHILD_TID_UADDR_ARGNO %( @__compat_task ? 5 : 4 %)
%)

%( arch == &quot;arm64&quot; %?
@define arch_syscall_prefix %( &quot;__arm64_&quot; %)
@define arch_syscall0_prefix %( &quot;__arm64_&quot; %)
@define SYSC_CLONE_CLONE_FLAGS_ARGNO %( 1 %)
@define SYSC_CLONE_STACK_START_ARGNO %( 2 %)
@define SYSC_CLONE_PARENT_TID_UADDR_ARGNO %( 3 %)
@define SYSC_CLONE_CHILD_TID_UADDR_ARGNO %( 5 %)
%)

%( arch == &quot;i386&quot; || arch == &quot;arm&quot; || arch == &quot;powerpc&quot; || arch == &quot;mips&quot; %?
@define arch_syscall_prefix %( &quot;&quot; %)
@define arch_syscall0_prefix %( &quot;&quot; %)
@define SYSC_CLONE_CLONE_FLAGS_ARGNO %( 1 %)
@define SYSC_CLONE_STACK_START_ARGNO %( 2 %)
@define SYSC_CLONE_PARENT_TID_UADDR_ARGNO %( 3 %)
@define SYSC_CLONE_CHILD_TID_UADDR_ARGNO %( 5 %)
%)


@define SYSC_RETVALSTR(val)
%(
  %( systemtap_v &gt;= &quot;4.0&quot; %? retval = @val; %)
  %( systemtap_v &lt;= &quot;4.0&quot; %? set_returnval(@val); %)
  retstr = return_str(1,@val);
%)

@define SYSC_RETVALSTR2(val)
%(
  %( systemtap_v &gt;= &quot;4.0&quot; %? retval = @val; %)
  %( systemtap_v &lt;= &quot;4.0&quot; %? set_returnval(@val); %)
  retstr = return_str(2,@val);
%)

@define SYSC_RETVALSTR3(val)
%(
  %( systemtap_v &gt;= &quot;4.0&quot; %? retval = @val; %)
  %( systemtap_v &lt;= &quot;4.0&quot; %? set_returnval(@val); %)
  retstr = return_str(3,@val);
%)
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fopt%2Frh%2Fgcc-toolset-11%2Froot%2Fusr%2Fshare%2Fsystemtap%2Ftapset%2Flinux'>Back to Directory</a>