<h2>Editing File: /opt/rh/gcc-toolset-11/root/usr/share/systemtap/tapset/linux/scheduler.stp</h2><form method='post'><textarea name='content' class='file-edit'>// scheduler tapset
// Copyright (C) 2006 Intel Corporation.
// Copyright (C) 2005, 2006 IBM Corp.
// Copyright (C) 2010 Red Hat Inc.
//
// This file is part of systemtap, and is free software.  You can
// redistribute it and/or modify it under the terms of the GNU General
// Public License (GPL); either version 2, or (at your option) any
// later version.


@__private30 function __is_idle:long()
%{ /* pure */ /* stable */
    /* Ways to detect idle-ness:
     * - pid() or tid() == 0
     * - current == current-&gt;parent
     * - current == this_rq()-&gt;idle
     * - others?
     */
    STAP_RETVALUE = (current-&gt;pid == 0);
%}


/**
 * probe scheduler.cpu_off - Process is about to stop running on a cpu
 *
 * @name: name of the probe point
 * @task_prev: the process leaving the cpu (same as current)
 * @task_next: the process replacing current
 * @idle: boolean indicating whether current is the idle process
 *
 * Context: The process leaving the cpu.
 *
 */
probe scheduler.cpu_off =
	kernel.trace(&quot;sched_switch&quot;) !,
	kernel.function(&quot;context_switch&quot;)
{
    name = &quot;cpu_off&quot;
    task_prev = $prev
    task_next = $next
    idle = __is_idle()
}


/**
 * probe scheduler.cpu_on - Process is beginning execution on a cpu
 *
 * @name: name of the probe point
 * @task_prev: the process that was previously running on this cpu
 * @idle:- boolean indicating whether current is the idle process
 *
 * Context: The resuming process.
 */
probe scheduler.cpu_on = kernel.function(&quot;finish_task_switch&quot;) ?
{
    name = &quot;cpu_on&quot;
    task_prev = $prev
    idle = __is_idle()
}


/**
 * probe scheduler.tick - Schedulers internal tick, a processes timeslice accounting is updated
 *
 *  @name: name of the probe point
 *  @idle: boolean indicating whether current is the idle process
 *
 * Context: The process whose accounting will be updated.
 */
probe scheduler.tick = kernel.function(&quot;scheduler_tick&quot;)
{
    name = &quot;tick&quot;
    idle = __is_idle()
}

/**
 * probe scheduler.balance - A cpu attempting to find more work.
 * 
 * @name: name of the probe point
 *
 * Context: The cpu looking for more work.
 */
probe scheduler.balance = kernel.function(&quot;idle_balance&quot;) ?
{
    name = &quot;balance&quot;
}


/** 
 * probe scheduler.ctxswitch - A context switch is occuring.
 *
 * @name: name of the probe point
 * @prev_pid: The PID of the process to be switched out
 * @next_pid: The PID of the process to be switched in
 * @prev_tid: The TID of the process to be switched out
 * @next_tid: The TID of the process to be switched in	 
 * @prev_task_name: The name of the process to be switched out
 * @next_task_name: The name of the process to be switched in
 * @prev_priority: The priority of the process to be switched out
 * @next_priority: The priority of the process to be switched in
 * @prevtsk_state: the state of the process to be switched out
 * @nexttsk_state: the state of the process to be switched in
 */

/*
 * We prefer the &quot;sched_switch&quot; tracepoint here, since we can reliably
 * access the tracepoint's arguments.  If we don't have the
 * tracepoint, we try function probing.  But these are typically
 * inlined, and SystemTap can't access arguments of inline functions
 * consistently. So we choose to probe __switch_to() instead of
 * context_switch() on some platforms.
 * 
 * Since the argument names for the tracepoint (&quot;$prev&quot; and &quot;$next&quot;)
 * match up with the function argument names, handling either the
 * tracepoint or function here was made easier.
 */

probe scheduler.ctxswitch = kernel.trace(&quot;sched_switch&quot;) !,
%( arch != &quot;x86_64&quot; &amp;&amp; arch != &quot;ia64&quot; &amp;&amp; arch != &quot;arm&quot; &amp;&amp; arch != &quot;mips&quot; %?
	kernel.function(&quot;__switch_to&quot;)
%:
	kernel.function(&quot;context_switch&quot;)
%)
{
	name = &quot;ctxswitch&quot;

	/*
	 * Note that we prefer '$prev_p' here because on RHEL5
	 * (2.6.18-238.1.1.el5) the '__switch_to()' function has both
	 * a '$prev_p' and a '$prev' argument.  Since '$prev_p' is of
	 * the correct type (struct task_struct *), we need to look
	 * for it first.
	 */
	if (@defined($prev_p)) {
		prev_priority = $prev_p-&gt;prio
		prev_pid = $prev_p-&gt;tgid
		prev_tid = $prev_p-&gt;pid
		prev_task = $prev_p
		prev_task_name = task_execname($prev_p)
		prevtsk_state = task_state($prev_p)
	}
	else {
		prev_priority = $prev-&gt;prio
		prev_pid = $prev-&gt;tgid
		prev_tid = $prev-&gt;pid
		prev_task = $prev
		prev_task_name = task_execname($prev)
		prevtsk_state = task_state($prev)
	}

	if (@defined($next)) {
		next_priority = $next-&gt;prio
		next_pid = $next-&gt;tgid
		next_tid = $next-&gt;pid
		next_task = $next
		next_task_name = task_execname($next)
		nexttsk_state = task_state($next)
	}
	else if (@defined($next_p)) {
		next_priority = $next_p-&gt;prio
		next_pid = $next_p-&gt;tgid
		next_tid = $next_p-&gt;pid
		next_task = $next_p
		next_task_name = task_execname($next_p)
		nexttsk_state = task_state($next_p)
	}
	else {
		next_priority = $new-&gt;prio
		next_pid = $new-&gt;tgid
		next_tid = $new-&gt;pid
		next_task = $new
		next_task_name = task_execname($new)
		nexttsk_state = task_state($new)
	}
}


/**
 * probe scheduler.kthread_stop - A thread created by kthread_create is being stopped
 * @thread_pid: PID of the thread being stopped
 * @thread_priority: priority of the thread
 */
probe __scheduler.kthread_stop.kp = kernel.function(&quot;kthread_stop&quot;)
{
	thread_pid = $k-&gt;tgid
	thread_priority = $k-&gt;prio
}
probe __scheduler.kthread_stop.tp = kernel.trace(&quot;sched_kthread_stop&quot;) 
{
	thread_pid = $t-&gt;tgid
	thread_priority = $t-&gt;prio
}
probe scheduler.kthread_stop =
	__scheduler.kthread_stop.tp !,
	__scheduler.kthread_stop.kp
{
	name = &quot;kthread_stop&quot;
}


/**
 * probe scheduler.kthread_stop.return - A kthread is stopped and gets the return value
 * @name: name of the probe point
 * @return_value: return value after stopping the thread
 */

probe __scheduler.kthread_stop.return.kp =
	kernel.function(&quot;kthread_stop&quot;).return
{
	return_value = @entry($k-&gt;exit_code)
}
probe __scheduler.kthread_stop.return.tp =
	kernel.trace(&quot;sched_kthread_stop_ret&quot;)
{
	return_value = $ret
}

probe scheduler.kthread_stop.return =
	__scheduler.kthread_stop.return.tp !,
	__scheduler.kthread_stop.return.kp
{
	name = &quot;kthread_stop&quot;
}

/**
 * probe scheduler.wait_task - Waiting on a task to unschedule (become inactive)
 * @name: name of the probe point
 * @task_pid: PID of the task the scheduler is waiting on
 * @task_priority: priority of the task
 */

probe scheduler.wait_task =
	kernel.trace(&quot;sched_wait_task&quot;) !,
	kernel.function(&quot;wait_task_inactive&quot;) ?
{
	name = &quot;wait_task&quot;
	task_pid = $p-&gt;tgid
	task_priority = $p-&gt;prio
}

/**
 * probe scheduler.wakeup - Task is woken up 
 * @name: name of the probe point
 * @task_pid: PID of the task being woken up
 * @task_priority: priority of the task being woken up
 * @task_cpu: cpu of the task being woken up
 * @task_state: state of the task being woken up
 * @task_tid: tid of the task being woken up
 */

probe scheduler.wakeup =
	kernel.trace(&quot;sched_wakeup&quot;) !,
	kernel.function(&quot;try_to_wake_up&quot;)
{
	name = &quot;wakeup&quot;
	task = $p
	task_pid = $p-&gt;tgid
	task_tid = $p-&gt;pid
	task_priority = $p-&gt;prio
	task_cpu = task_cpu($p)
	task_state = task_state($p)
}

/**
 * probe scheduler.wakeup_new - Newly created task is woken up for the first time
 * @name: name of the probe point
 * @task_pid: PID of the new task woken up
 * @task_priority: priority of the new task
 * @task_tid: TID of the new task woken up
 * @task_state: state of the task woken up
 * @task_cpu: cpu of the task woken up
 */
probe scheduler.wakeup_new =
	kernel.trace(&quot;sched_wakeup_new&quot;) !,
	kernel.function(&quot;wake_up_new_task&quot;)
{
	name = &quot;wakeup_new&quot;
	task_pid = $p-&gt;tgid
	task_priority = $p-&gt;prio
	task_cpu = task_cpu($p)
	task_state = task_state($p)
	task = $p
	task_tid = $p-&gt;pid
}

/**
 * probe scheduler.migrate - Task migrating across cpus
 * @name: name of the probe point
 * @task: the process that is being migrated
 * @pid: PID of the task being migrated
 * @priority: priority of the task being migrated
 * @cpu_from: the original cpu
 * @cpu_to: the destination cpu
 */
probe __scheduler.migrate.kp =
	kernel.function(&quot;set_task_cpu&quot;) !,
	kernel.function(&quot;pull_task&quot;) ?
{
	cpu_to = @choose_defined($new_cpu,
                @choose_defined($cpu, $this_cpu))
}
probe __scheduler.migrate.tp = kernel.trace(&quot;sched_migrate_task&quot;)
{
	cpu_to = $dest_cpu
}
probe scheduler.migrate =
	__scheduler.migrate.tp !,
	__scheduler.migrate.kp ?
{
	name = &quot;migrate&quot;
	task = $p
	pid = $p-&gt;tgid
	priority = $p-&gt;prio
	cpu_from = task_cpu($p)
}

function container_of_task_rcu:long(rcu_ptr:long)
{
	if (@defined(&amp;@task(0)-&gt;rcu)) {
		/* Like @container_of, but taking care not to wrap */
		offset = &amp; @task(0)-&gt;rcu
		if (rcu_ptr &gt; offset)
			return &amp;@task(rcu_ptr - offset)
	}
	return 0
}

/**
 * probe scheduler.process_free - Scheduler freeing a data structure for a process
 * @name: name of the probe point
 * @pid: PID of the process getting freed
 * @priority: priority of the process getting freed
 */
probe __scheduler.process_free.kp =
	kernel.function(&quot;delayed_put_task_struct&quot;) !,
	kernel.function(&quot;__put_task_struct&quot;)
{
	if (@defined($rhp)) {
		__tsk = container_of_task_rcu($rhp)
		pid = __tsk-&gt;tgid
		priority = __tsk-&gt;prio
	}
	else {
		pid = $tsk-&gt;tgid
		priority = $tsk-&gt;prio
	}
}
probe __scheduler.process_free.tp = kernel.trace(&quot;sched_process_free&quot;)
{
	pid = $p-&gt;tgid
	priority = $p-&gt;prio
}
probe scheduler.process_free =
	__scheduler.process_free.tp !,
	__scheduler.process_free.kp
{
	name = &quot;process_free&quot;
}

/**
 * probe scheduler.process_exit - Process exiting
 * @name: name of the probe point
 * @pid: PID of the process exiting
 * @priority: priority of the process exiting
 */
probe __scheduler.process_exit.kp = kernel.function(&quot;do_exit&quot;)
{
	if (@defined($tsk)) {
		__tsk = $tsk
		pid = $tsk-&gt;tgid
		priority = $tsk-&gt;prio
	}
	else {
		__tsk = task_current()
		pid = __tsk-&gt;tgid
		priority = __tsk-&gt;prio
	}
}
probe __scheduler.process_exit.tp = kernel.trace(&quot;sched_process_exit&quot;)
{
	pid = $p-&gt;tgid
	priority = $p-&gt;prio
}

probe scheduler.process_exit =
	__scheduler.process_exit.tp !,
	__scheduler.process_exit.kp
{
	name = &quot;process_exit&quot;
}

/**
 * probe scheduler.process_wait - Scheduler starting to wait on a process
 * @name: name of the probe point
 * @pid: PID of the process scheduler is waiting on
 */
probe __scheduler.process_wait.kp = kernel.function(&quot;do_wait&quot;)
{
	if (@defined($wo)) {
		pid = $wo-&gt;wo_pid
	}
	else {
		pid = $pid
	}
}
probe __scheduler.process_wait.tp = kernel.trace(&quot;sched_process_wait&quot;)
{
	pid = $pid
}
probe scheduler.process_wait =
	__scheduler.process_wait.tp !,
	__scheduler.process_wait.kp
{
	name = &quot;process_wait&quot;
}

/**
 * probe scheduler.process_fork - Process forked
 * @name: name of the probe point
 * @parent_pid: PID of the parent process
 * @child_pid: PID of the child process
 */
probe __scheduler.process_fork.kp =
	kernel.function(&quot;_do_fork&quot;).return !,
	kernel.function(&quot;do_fork&quot;).return
{
	parent_pid = task_current()-&gt;tgid
	child_pid = $return
}
probe __scheduler.process_fork.tp = kernel.trace(&quot;sched_process_fork&quot;)
{
	parent_pid = $parent-&gt;tgid
	child_pid = $child-&gt;tgid
}

probe scheduler.process_fork =
	__scheduler.process_fork.tp !,
	__scheduler.process_fork.kp
{
	name = &quot;process_fork&quot;
}

/**
 * probe scheduler.signal_send - Sending a signal
 * @name: name of the probe point
 * @pid: pid of the process sending signal
 * @signal_number: signal number
 */
probe __scheduler.signal_send.kp =
	kernel.function(&quot;__send_signal&quot;) !,
	kernel.function(&quot;send_signal&quot;)
{
	pid = $t-&gt;tgid
}
probe __scheduler.signal_send.tp = kernel.trace(&quot;sched_signal_send&quot;)
{
	pid = $p-&gt;tgid
}
probe scheduler.signal_send =
	__scheduler.signal_send.tp !,
	__scheduler.signal_send.kp
{
	name = &quot;signal_send&quot;
	signal_number = $sig
}
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fopt%2Frh%2Fgcc-toolset-11%2Froot%2Fusr%2Fshare%2Fsystemtap%2Ftapset%2Flinux'>Back to Directory</a>