<h2>Editing File: /opt/rh/gcc-toolset-11/root/usr/share/systemtap/examples/process/cycle_thief.stp</h2><form method='post'><textarea name='content' class='file-edit'>#!/opt/rh/gcc-toolset-11/root/usr/bin/stap
# Copyright (C) 2010-2016 Red Hat, Inc.
# Write by William Cohen &lt;wcohen@redhat.com&gt;
#
# cycle_thief provide the following information for the specified pid:
#   Number of times the task is migrated to another cpu
#   How long the task is scheduled on and off a processor
#   Tasks that run when the task is scheduled off the processor
#   IRQs that run when the task is scheduled on the processor
#
# Run the script with:
#   stap cycle_thief.stp -x pid
#
# control-c to exit data collection

global last_cpu = -1
global pid_on, pid_off, migrated
global time_on, time_off, irq_entry
global cycle_thief, irq_thief, cycle_thief_name


probe kernel.trace(&quot;sched_switch&quot;) {
  t = gettimeofday_us(); c = cpu();
  if ($prev-&gt;pid == target() &amp;&amp; $next-&gt;pid != target()) {
    /* being switched out */
    pid_off = t; last_cpu = c;
    if (pid_on) time_on &lt;&lt;&lt; pid_off - pid_on;
  } else if ($prev-&gt;pid != target() &amp;&amp; $next-&gt;pid == target()) {
    /* being switched in */
    pid_on = t;
    if (pid_off) time_off &lt;&lt;&lt; pid_on - pid_off;
    if (c != last_cpu) ++migrated;
  }
  /* watch what other processes scheduled while pid off */
  if (pid_off &gt; pid_on &amp;&amp; c == last_cpu) {
    cycle_thief[$next-&gt;pid] &lt;&lt;&lt; 1;
    cycle_thief_name[$next-&gt;pid] = kernel_string($next-&gt;comm)
  }
}

/* what interrupts occur while process is running */
probe kernel.{trace(&quot;irq_handler_entry&quot;)!, trace(&quot;irq_entry&quot;)}
{
  t = gettimeofday_us(); c = cpu();
  i = @defined($irq) ? $irq : $id;
  /* watch what irq run while pid is running */
  if (pid_on &gt; pid_off &amp;&amp; c == last_cpu) {
    irq_entry[i] = t;
  }
}


probe kernel.{trace(&quot;irq_handler_exit&quot;)!, trace(&quot;irq_exit&quot;)}
{
  i = @defined($irq) ? $irq : $id;
  t = gettimeofday_us(); c = cpu(); irqt=irq_entry[i]
  /* watch what irq run while pid is running */
  if (pid_on &gt; pid_off &amp;&amp; c == last_cpu &amp;&amp;  irqt) {
     irq_thief[i] &lt;&lt;&lt; t - irqt;
     delete irq_entry[i];
  }
}


probe end {
  printf(&quot;\n&quot;)
  printf(&quot;task %d migrated: %d\n&quot;, target(), migrated)
  if (@count(time_on)) {
    printf(&quot;\n&quot;)
    printf(&quot;task %d on processor (us):\n&quot;, target())
    print(@hist_log(time_on));
  }
  if (@count(time_off)) {
    printf(&quot;\n&quot;)
    printf(&quot;task %d off processor (us)\n&quot;, target())
      print(@hist_log(time_off));
  }

  printf(&quot;\n&quot;)
  printf(&quot;other pids taking processor from task %d\n&quot;, target())
  printf(&quot;%6s %10s %s\n&quot;, &quot;PID&quot;, &quot;count&quot;, &quot;command&quot;);
  foreach (p in cycle_thief-)
    printf(&quot;%6d %10d %s\n&quot;, p, @count(cycle_thief[p]), cycle_thief_name[p])

  printf(&quot;\n&quot;)
  printf(&quot;irq taking processor from task %d\n&quot;, target())

  printf(&quot;%6s %10s %10s %10s %10s %10s\n&quot;, &quot;irq&quot;, &quot;count&quot;,
      &quot;min(us)&quot;, &quot;avg(us)&quot;, &quot;max(us)&quot;, &quot;variance(us^2)&quot;)
  foreach (p in irq_thief-)
    printf(&quot;%6d %10d %10d %10d %10d %10d\n&quot;, p, @count(irq_thief[p]),
      @min(irq_thief[p]), @avg(irq_thief[p]), @max(irq_thief[p]),
      @variance(irq_thief[p]))

}
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fopt%2Frh%2Fgcc-toolset-11%2Froot%2Fusr%2Fshare%2Fsystemtap%2Fexamples%2Fprocess'>Back to Directory</a>