<h2>Editing File: /lib64/perl5/vendor_perl/threads.pm</h2><form method='post'><textarea name='content' class='file-edit'>package threads;

use 5.008;

use strict;
use warnings;

our $VERSION = '2.21';      # remember to update version in POD!
my $XS_VERSION = $VERSION;
$VERSION = eval $VERSION;

# Verify this Perl supports threads
require Config;
if (! $Config::Config{useithreads}) {
    die(&quot;This Perl not built to support threads\n&quot;);
}

# Complain if 'threads' is loaded after 'threads::shared'
if ($threads::shared::threads_shared) {
    warn &lt;&lt;'_MSG_';
Warning, threads::shared has already been loaded.  To
enable shared variables, 'use threads' must be called
before threads::shared or any module that uses it.
_MSG_
}

# Declare that we have been loaded
$threads::threads = 1;

# Load the XS code
require XSLoader;
XSLoader::load('threads', $XS_VERSION);


### Export ###

sub import
{
    my $class = shift;   # Not used

    # Exported subroutines
    my @EXPORT = qw(async);

    # Handle args
    while (my $sym = shift) {
        if ($sym =~ /^(?:stack|exit)/i) {
            if (defined(my $arg = shift)) {
                if ($sym =~ /^stack/i) {
                    threads-&gt;set_stack_size($arg);
                } else {
                    $threads::thread_exit_only = $arg =~ /^thread/i;
                }
            } else {
                require Carp;
                Carp::croak(&quot;threads: Missing argument for option: $sym&quot;);
            }

        } elsif ($sym =~ /^str/i) {
            import overload ('&quot;&quot;' =&gt; \&amp;tid);

        } elsif ($sym =~ /^(?::all|yield)$/) {
            push(@EXPORT, qw(yield));

        } else {
            require Carp;
            Carp::croak(&quot;threads: Unknown import option: $sym&quot;);
        }
    }

    # Export subroutine names
    my $caller = caller();
    foreach my $sym (@EXPORT) {
        no strict 'refs';
        *{$caller.'::'.$sym} = \&amp;{$sym};
    }

    # Set stack size via environment variable
    if (exists($ENV{'PERL5_ITHREADS_STACK_SIZE'})) {
        threads-&gt;set_stack_size($ENV{'PERL5_ITHREADS_STACK_SIZE'});
    }
}


### Methods, etc. ###

# Exit from a thread (only)
sub exit
{
    my ($class, $status) = @_;
    if (! defined($status)) {
        $status = 0;
    }

    # Class method only
    if (ref($class)) {
        require Carp;
        Carp::croak('Usage: threads-&gt;exit(status)');
    }

    $class-&gt;set_thread_exit_only(1);
    CORE::exit($status);
}

# 'Constant' args for threads-&gt;list()
sub threads::all      { }
sub threads::running  { 1 }
sub threads::joinable { 0 }

# 'new' is an alias for 'create'
*new = \&amp;create;

# 'async' is a function alias for the 'threads-&gt;create()' method
sub async (&amp;;@)
{
    unshift(@_, 'threads');
    # Use &quot;goto&quot; trick to avoid pad problems from 5.8.1 (fixed in 5.8.2)
    goto &amp;create;
}

# Thread object equality checking
use overload (
    '==' =&gt; \&amp;equal,
    '!=' =&gt; sub { ! equal(@_) },
    'fallback' =&gt; 1
);

1;

__END__

=head1 NAME

threads - Perl interpreter-based threads

=head1 VERSION

This document describes threads version 2.21

=head1 WARNING

The &quot;interpreter-based threads&quot; provided by Perl are not the fast, lightweight
system for multitasking that one might expect or hope for.  Threads are
implemented in a way that make them easy to misuse.  Few people know how to
use them correctly or will be able to provide help.

The use of interpreter-based threads in perl is officially
L&lt;discouraged|perlpolicy/discouraged&gt;.

=head1 SYNOPSIS

    use threads ('yield',
                 'stack_size' =&gt; 64*4096,
                 'exit' =&gt; 'threads_only',
                 'stringify');

    sub start_thread {
        my @args = @_;
        print('Thread started: ', join(' ', @args), &quot;\n&quot;);
    }
    my $thr = threads-&gt;create('start_thread', 'argument');
    $thr-&gt;join();

    threads-&gt;create(sub { print(&quot;I am a thread\n&quot;); })-&gt;join();

    my $thr2 = async { foreach (@files) { ... } };
    $thr2-&gt;join();
    if (my $err = $thr2-&gt;error()) {
        warn(&quot;Thread error: $err\n&quot;);
    }

    # Invoke thread in list context (implicit) so it can return a list
    my ($thr) = threads-&gt;create(sub { return (qw/a b c/); });
    # or specify list context explicitly
    my $thr = threads-&gt;create({'context' =&gt; 'list'},
                              sub { return (qw/a b c/); });
    my @results = $thr-&gt;join();

    $thr-&gt;detach();

    # Get a thread's object
    $thr = threads-&gt;self();
    $thr = threads-&gt;object($tid);

    # Get a thread's ID
    $tid = threads-&gt;tid();
    $tid = $thr-&gt;tid();
    $tid = &quot;$thr&quot;;

    # Give other threads a chance to run
    threads-&gt;yield();
    yield();

    # Lists of non-detached threads
    my @threads = threads-&gt;list();
    my $thread_count = threads-&gt;list();

    my @running = threads-&gt;list(threads::running);
    my @joinable = threads-&gt;list(threads::joinable);

    # Test thread objects
    if ($thr1 == $thr2) {
        ...
    }

    # Manage thread stack size
    $stack_size = threads-&gt;get_stack_size();
    $old_size = threads-&gt;set_stack_size(32*4096);

    # Create a thread with a specific context and stack size
    my $thr = threads-&gt;create({ 'context'    =&gt; 'list',
                                'stack_size' =&gt; 32*4096,
                                'exit'       =&gt; 'thread_only' },
                              \&amp;foo);

    # Get thread's context
    my $wantarray = $thr-&gt;wantarray();

    # Check thread's state
    if ($thr-&gt;is_running()) {
        sleep(1);
    }
    if ($thr-&gt;is_joinable()) {
        $thr-&gt;join();
    }

    # Send a signal to a thread
    $thr-&gt;kill('SIGUSR1');

    # Exit a thread
    threads-&gt;exit();

=head1 DESCRIPTION

Since Perl 5.8, thread programming has been available using a model called
I&lt;interpreter threads&gt; which provides a new Perl interpreter for each
thread, and, by default, results in no data or state information being shared
between threads.

(Prior to Perl 5.8, I&lt;5005threads&gt; was available through the C&lt;Thread.pm&gt; API.
This threading model has been deprecated, and was removed as of Perl 5.10.0.)

As just mentioned, all variables are, by default, thread local.  To use shared
variables, you need to also load L&lt;threads::shared&gt;:

    use threads;
    use threads::shared;

When loading L&lt;threads::shared&gt;, you must C&lt;use threads&gt; before you
C&lt;use threads::shared&gt;.  (C&lt;threads&gt; will emit a warning if you do it the
other way around.)

It is strongly recommended that you enable threads via C&lt;use threads&gt; as early
as possible in your script.

If needed, scripts can be written so as to run on both threaded and
non-threaded Perls:

    my $can_use_threads = eval 'use threads; 1';
    if ($can_use_threads) {
        # Do processing using threads
        ...
    } else {
        # Do it without using threads
        ...
    }

=over

=item $thr = threads-&gt;create(FUNCTION, ARGS)

This will create a new thread that will begin execution with the specified
entry point function, and give it the I&lt;ARGS&gt; list as parameters.  It will
return the corresponding threads object, or C&lt;undef&gt; if thread creation failed.

I&lt;FUNCTION&gt; may either be the name of a function, an anonymous subroutine, or
a code ref.

    my $thr = threads-&gt;create('func_name', ...);
        # or
    my $thr = threads-&gt;create(sub { ... }, ...);
        # or
    my $thr = threads-&gt;create(\&amp;func, ...);

The C&lt;-E&lt;gt&gt;new()&gt; method is an alias for C&lt;-E&lt;gt&gt;create()&gt;.

=item $thr-&gt;join()

This will wait for the corresponding thread to complete its execution.  When
the thread finishes, C&lt;-E&lt;gt&gt;join()&gt; will return the return value(s) of the
entry point function.

The context (void, scalar or list) for the return value(s) for C&lt;-E&lt;gt&gt;join()&gt;
is determined at the time of thread creation.

    # Create thread in list context (implicit)
    my ($thr1) = threads-&gt;create(sub {
                                    my @results = qw(a b c);
                                    return (@results);
                                 });
    #   or (explicit)
    my $thr1 = threads-&gt;create({'context' =&gt; 'list'},
                               sub {
                                    my @results = qw(a b c);
                                    return (@results);
                               });
    # Retrieve list results from thread
    my @res1 = $thr1-&gt;join();

    # Create thread in scalar context (implicit)
    my $thr2 = threads-&gt;create(sub {
                                    my $result = 42;
                                    return ($result);
                                 });
    # Retrieve scalar result from thread
    my $res2 = $thr2-&gt;join();

    # Create a thread in void context (explicit)
    my $thr3 = threads-&gt;create({'void' =&gt; 1},
                               sub { print(&quot;Hello, world\n&quot;); });
    # Join the thread in void context (i.e., no return value)
    $thr3-&gt;join();

See L&lt;/&quot;THREAD CONTEXT&quot;&gt; for more details.

If the program exits without all threads having either been joined or
detached, then a warning will be issued.

Calling C&lt;-E&lt;gt&gt;join()&gt; or C&lt;-E&lt;gt&gt;detach()&gt; on an already joined thread will
cause an error to be thrown.

=item $thr-&gt;detach()

Makes the thread unjoinable, and causes any eventual return value to be
discarded.  When the program exits, any detached threads that are still
running are silently terminated.

If the program exits without all threads having either been joined or
detached, then a warning will be issued.

Calling C&lt;-E&lt;gt&gt;join()&gt; or C&lt;-E&lt;gt&gt;detach()&gt; on an already detached thread
will cause an error to be thrown.

=item threads-&gt;detach()

Class method that allows a thread to detach itself.

=item threads-&gt;self()

Class method that allows a thread to obtain its own I&lt;threads&gt; object.

=item $thr-&gt;tid()

Returns the ID of the thread.  Thread IDs are unique integers with the main
thread in a program being 0, and incrementing by 1 for every thread created.

=item threads-&gt;tid()

Class method that allows a thread to obtain its own ID.

=item &quot;$thr&quot;

If you add the C&lt;stringify&gt; import option to your C&lt;use threads&gt; declaration,
then using a threads object in a string or a string context (e.g., as a hash
key) will cause its ID to be used as the value:

    use threads qw(stringify);

    my $thr = threads-&gt;create(...);
    print(&quot;Thread $thr started\n&quot;);  # Prints: Thread 1 started

=item threads-&gt;object($tid)

This will return the I&lt;threads&gt; object for the I&lt;active&gt; thread associated
with the specified thread ID.  If C&lt;$tid&gt; is the value for the current thread,
then this call works the same as C&lt;-E&lt;gt&gt;self()&gt;.  Otherwise, returns C&lt;undef&gt;
if there is no thread associated with the TID, if the thread is joined or
detached, if no TID is specified or if the specified TID is undef.

=item threads-&gt;yield()

This is a suggestion to the OS to let this thread yield CPU time to other
threads.  What actually happens is highly dependent upon the underlying
thread implementation.

You may do C&lt;use threads qw(yield)&gt;, and then just use C&lt;yield()&gt; in your
code.

=item threads-&gt;list()

=item threads-&gt;list(threads::all)

=item threads-&gt;list(threads::running)

=item threads-&gt;list(threads::joinable)

With no arguments (or using C&lt;threads::all&gt;) and in a list context, returns a
list of all non-joined, non-detached I&lt;threads&gt; objects.  In a scalar context,
returns a count of the same.

With a I&lt;true&gt; argument (using C&lt;threads::running&gt;), returns a list of all
non-joined, non-detached I&lt;threads&gt; objects that are still running.

With a I&lt;false&gt; argument (using C&lt;threads::joinable&gt;), returns a list of all
non-joined, non-detached I&lt;threads&gt; objects that have finished running (i.e.,
for which C&lt;-E&lt;gt&gt;join()&gt; will not I&lt;block&gt;).

=item $thr1-&gt;equal($thr2)

Tests if two threads objects are the same thread or not.  This is overloaded
to the more natural forms:

    if ($thr1 == $thr2) {
        print(&quot;Threads are the same\n&quot;);
    }
    # or
    if ($thr1 != $thr2) {
        print(&quot;Threads differ\n&quot;);
    }

(Thread comparison is based on thread IDs.)

=item async BLOCK;

C&lt;async&gt; creates a thread to execute the block immediately following
it.  This block is treated as an anonymous subroutine, and so must have a
semicolon after the closing brace.  Like C&lt;threads-E&lt;gt&gt;create()&gt;, C&lt;async&gt;
returns a I&lt;threads&gt; object.

=item $thr-&gt;error()

Threads are executed in an C&lt;eval&gt; context.  This method will return C&lt;undef&gt;
if the thread terminates I&lt;normally&gt;.  Otherwise, it returns the value of
C&lt;$@&gt; associated with the thread's execution status in its C&lt;eval&gt; context.

=item $thr-&gt;_handle()

This I&lt;private&gt; method returns a pointer (i.e., the memory location expressed
as an unsigned integer) to the internal thread structure associated with a
threads object.  For Win32, this is a pointer to the C&lt;HANDLE&gt; value returned
by C&lt;CreateThread&gt; (i.e., C&lt;HANDLE *&gt;); for other platforms, it is a pointer
to the C&lt;pthread_t&gt; structure used in the C&lt;pthread_create&gt; call (i.e.,
C&lt;pthread_t *&gt;).

This method is of no use for general Perl threads programming.  Its intent is
to provide other (XS-based) thread modules with the capability to access, and
possibly manipulate, the underlying thread structure associated with a Perl
thread.

=item threads-&gt;_handle()

Class method that allows a thread to obtain its own I&lt;handle&gt;.

=back

=head1 EXITING A THREAD

The usual method for terminating a thread is to
L&lt;return()|perlfunc/&quot;return EXPR&quot;&gt; from the entry point function with the
appropriate return value(s).

=over

=item threads-&gt;exit()

If needed, a thread can be exited at any time by calling
C&lt;threads-E&lt;gt&gt;exit()&gt;.  This will cause the thread to return C&lt;undef&gt; in a
scalar context, or the empty list in a list context.

When called from the I&lt;main&gt; thread, this behaves the same as C&lt;exit(0)&gt;.

=item threads-&gt;exit(status)

When called from a thread, this behaves like C&lt;threads-E&lt;gt&gt;exit()&gt; (i.e., the
exit status code is ignored).

When called from the I&lt;main&gt; thread, this behaves the same as C&lt;exit(status)&gt;.

=item die()

Calling C&lt;die()&gt; in a thread indicates an abnormal exit for the thread.  Any
C&lt;$SIG{__DIE__}&gt; handler in the thread will be called first, and then the
thread will exit with a warning message that will contain any arguments passed
in the C&lt;die()&gt; call.

=item exit(status)

Calling L&lt;exit()|perlfunc/&quot;exit EXPR&quot;&gt; inside a thread causes the whole
application to terminate.  Because of this, the use of C&lt;exit()&gt; inside
threaded code, or in modules that might be used in threaded applications, is
strongly discouraged.

If C&lt;exit()&gt; really is needed, then consider using the following:

    threads-&gt;exit() if threads-&gt;can('exit');   # Thread friendly
    exit(status);

=item use threads 'exit' =&gt; 'threads_only'

This globally overrides the default behavior of calling C&lt;exit()&gt; inside a
thread, and effectively causes such calls to behave the same as
C&lt;threads-E&lt;gt&gt;exit()&gt;.  In other words, with this setting, calling C&lt;exit()&gt;
causes only the thread to terminate.

Because of its global effect, this setting should not be used inside modules
or the like.

The I&lt;main&gt; thread is unaffected by this setting.

=item threads-&gt;create({'exit' =&gt; 'thread_only'}, ...)

This overrides the default behavior of C&lt;exit()&gt; inside the newly created
thread only.

=item $thr-&gt;set_thread_exit_only(boolean)

This can be used to change the I&lt;exit thread only&gt; behavior for a thread after
it has been created.  With a I&lt;true&gt; argument, C&lt;exit()&gt; will cause only the
thread to exit.  With a I&lt;false&gt; argument, C&lt;exit()&gt; will terminate the
application.

The I&lt;main&gt; thread is unaffected by this call.

=item threads-&gt;set_thread_exit_only(boolean)

Class method for use inside a thread to change its own behavior for C&lt;exit()&gt;.

The I&lt;main&gt; thread is unaffected by this call.

=back

=head1 THREAD STATE

The following boolean methods are useful in determining the I&lt;state&gt; of a
thread.

=over

=item $thr-&gt;is_running()

Returns true if a thread is still running (i.e., if its entry point function
has not yet finished or exited).

=item $thr-&gt;is_joinable()

Returns true if the thread has finished running, is not detached and has not
yet been joined.  In other words, the thread is ready to be joined, and a call
to C&lt;$thr-E&lt;gt&gt;join()&gt; will not I&lt;block&gt;.

=item $thr-&gt;is_detached()

Returns true if the thread has been detached.

=item threads-&gt;is_detached()

Class method that allows a thread to determine whether or not it is detached.

=back

=head1 THREAD CONTEXT

As with subroutines, the type of value returned from a thread's entry point
function may be determined by the thread's I&lt;context&gt;:  list, scalar or void.
The thread's context is determined at thread creation.  This is necessary so
that the context is available to the entry point function via
L&lt;wantarray()|perlfunc/&quot;wantarray&quot;&gt;.  The thread may then specify a value of
the appropriate type to be returned from C&lt;-E&lt;gt&gt;join()&gt;.

=head2 Explicit context

Because thread creation and thread joining may occur in different contexts, it
may be desirable to state the context explicitly to the thread's entry point
function.  This may be done by calling C&lt;-E&lt;gt&gt;create()&gt; with a hash reference
as the first argument:

    my $thr = threads-&gt;create({'context' =&gt; 'list'}, \&amp;foo);
    ...
    my @results = $thr-&gt;join();

In the above, the threads object is returned to the parent thread in scalar
context, and the thread's entry point function C&lt;foo&gt; will be called in list
(array) context such that the parent thread can receive a list (array) from
the C&lt;-E&lt;gt&gt;join()&gt; call.  (C&lt;'array'&gt; is synonymous with C&lt;'list'&gt;.)

Similarly, if you need the threads object, but your thread will not be
returning a value (i.e., I&lt;void&gt; context), you would do the following:

    my $thr = threads-&gt;create({'context' =&gt; 'void'}, \&amp;foo);
    ...
    $thr-&gt;join();

The context type may also be used as the I&lt;key&gt; in the hash reference followed
by a I&lt;true&gt; value:

    threads-&gt;create({'scalar' =&gt; 1}, \&amp;foo);
    ...
    my ($thr) = threads-&gt;list();
    my $result = $thr-&gt;join();

=head2 Implicit context

If not explicitly stated, the thread's context is implied from the context
of the C&lt;-E&lt;gt&gt;create()&gt; call:

    # Create thread in list context
    my ($thr) = threads-&gt;create(...);

    # Create thread in scalar context
    my $thr = threads-&gt;create(...);

    # Create thread in void context
    threads-&gt;create(...);

=head2 $thr-&gt;wantarray()

This returns the thread's context in the same manner as
L&lt;wantarray()|perlfunc/&quot;wantarray&quot;&gt;.

=head2 threads-&gt;wantarray()

Class method to return the current thread's context.  This returns the same
value as running L&lt;wantarray()|perlfunc/&quot;wantarray&quot;&gt; inside the current
thread's entry point function.

=head1 THREAD STACK SIZE

The default per-thread stack size for different platforms varies
significantly, and is almost always far more than is needed for most
applications.  On Win32, Perl's makefile explicitly sets the default stack to
16 MB; on most other platforms, the system default is used, which again may be
much larger than is needed.

By tuning the stack size to more accurately reflect your application's needs,
you may significantly reduce your application's memory usage, and increase the
number of simultaneously running threads.

Note that on Windows, address space allocation granularity is 64 KB,
therefore, setting the stack smaller than that on Win32 Perl will not save any
more memory.

=over

=item threads-&gt;get_stack_size();

Returns the current default per-thread stack size.  The default is zero, which
means the system default stack size is currently in use.

=item $size = $thr-&gt;get_stack_size();

Returns the stack size for a particular thread.  A return value of zero
indicates the system default stack size was used for the thread.

=item $old_size = threads-&gt;set_stack_size($new_size);

Sets a new default per-thread stack size, and returns the previous setting.

Some platforms have a minimum thread stack size.  Trying to set the stack size
below this value will result in a warning, and the minimum stack size will be
used.

Some Linux platforms have a maximum stack size.  Setting too large of a stack
size will cause thread creation to fail.

If needed, C&lt;$new_size&gt; will be rounded up to the next multiple of the memory
page size (usually 4096 or 8192).

Threads created after the stack size is set will then either call
C&lt;pthread_attr_setstacksize()&gt; I&lt;(for pthreads platforms)&gt;, or supply the
stack size to C&lt;CreateThread()&gt; I&lt;(for Win32 Perl)&gt;.

(Obviously, this call does not affect any currently extant threads.)

=item use threads ('stack_size' =&gt; VALUE);

This sets the default per-thread stack size at the start of the application.

=item $ENV{'PERL5_ITHREADS_STACK_SIZE'}

The default per-thread stack size may be set at the start of the application
through the use of the environment variable C&lt;PERL5_ITHREADS_STACK_SIZE&gt;:

    PERL5_ITHREADS_STACK_SIZE=1048576
    export PERL5_ITHREADS_STACK_SIZE
    perl -e'use threads; print(threads-&gt;get_stack_size(), &quot;\n&quot;)'

This value overrides any C&lt;stack_size&gt; parameter given to C&lt;use threads&gt;.  Its
primary purpose is to permit setting the per-thread stack size for legacy
threaded applications.

=item threads-&gt;create({'stack_size' =&gt; VALUE}, FUNCTION, ARGS)

To specify a particular stack size for any individual thread, call
C&lt;-E&lt;gt&gt;create()&gt; with a hash reference as the first argument:

    my $thr = threads-&gt;create({'stack_size' =&gt; 32*4096},
                              \&amp;foo, @args);

=item $thr2 = $thr1-&gt;create(FUNCTION, ARGS)

This creates a new thread (C&lt;$thr2&gt;) that inherits the stack size from an
existing thread (C&lt;$thr1&gt;).  This is shorthand for the following:

    my $stack_size = $thr1-&gt;get_stack_size();
    my $thr2 = threads-&gt;create({'stack_size' =&gt; $stack_size},
                               FUNCTION, ARGS);

=back

=head1 THREAD SIGNALLING

When safe signals is in effect (the default behavior - see L&lt;/&quot;Unsafe signals&quot;&gt;
for more details), then signals may be sent and acted upon by individual
threads.

=over 4

=item $thr-&gt;kill('SIG...');

Sends the specified signal to the thread.  Signal names and (positive) signal
numbers are the same as those supported by
L&lt;kill()|perlfunc/&quot;kill SIGNAL, LIST&quot;&gt;.  For example, 'SIGTERM', 'TERM' and
(depending on the OS) 15 are all valid arguments to C&lt;-E&lt;gt&gt;kill()&gt;.

Returns the thread object to allow for method chaining:

    $thr-&gt;kill('SIG...')-&gt;join();

=back

Signal handlers need to be set up in the threads for the signals they are
expected to act upon.  Here's an example for I&lt;cancelling&gt; a thread:

    use threads;

    sub thr_func
    {
        # Thread 'cancellation' signal handler
        $SIG{'KILL'} = sub { threads-&gt;exit(); };

        ...
    }

    # Create a thread
    my $thr = threads-&gt;create('thr_func');

    ...

    # Signal the thread to terminate, and then detach
    # it so that it will get cleaned up automatically
    $thr-&gt;kill('KILL')-&gt;detach();

Here's another simplistic example that illustrates the use of thread
signalling in conjunction with a semaphore to provide rudimentary I&lt;suspend&gt;
and I&lt;resume&gt; capabilities:

    use threads;
    use Thread::Semaphore;

    sub thr_func
    {
        my $sema = shift;

        # Thread 'suspend/resume' signal handler
        $SIG{'STOP'} = sub {
            $sema-&gt;down();      # Thread suspended
            $sema-&gt;up();        # Thread resumes
        };

        ...
    }

    # Create a semaphore and pass it to a thread
    my $sema = Thread::Semaphore-&gt;new();
    my $thr = threads-&gt;create('thr_func', $sema);

    # Suspend the thread
    $sema-&gt;down();
    $thr-&gt;kill('STOP');

    ...

    # Allow the thread to continue
    $sema-&gt;up();

CAVEAT:  The thread signalling capability provided by this module does not
actually send signals via the OS.  It I&lt;emulates&gt; signals at the Perl-level
such that signal handlers are called in the appropriate thread.  For example,
sending C&lt;$thr-E&lt;gt&gt;kill('STOP')&gt; does not actually suspend a thread (or the
whole process), but does cause a C&lt;$SIG{'STOP'}&gt; handler to be called in that
thread (as illustrated above).

As such, signals that would normally not be appropriate to use in the
C&lt;kill()&gt; command (e.g., C&lt;kill('KILL', $$)&gt;) are okay to use with the
C&lt;-E&lt;gt&gt;kill()&gt; method (again, as illustrated above).

Correspondingly, sending a signal to a thread does not disrupt the operation
the thread is currently working on:  The signal will be acted upon after the
current operation has completed.  For instance, if the thread is I&lt;stuck&gt; on
an I/O call, sending it a signal will not cause the I/O call to be interrupted
such that the signal is acted up immediately.

Sending a signal to a terminated/finished thread is ignored.

=head1 WARNINGS

=over 4

=item Perl exited with active threads:

If the program exits without all threads having either been joined or
detached, then this warning will be issued.

NOTE:  If the I&lt;main&gt; thread exits, then this warning cannot be suppressed
using C&lt;no warnings 'threads';&gt; as suggested below.

=item Thread creation failed: pthread_create returned #

See the appropriate I&lt;man&gt; page for C&lt;pthread_create&gt; to determine the actual
cause for the failure.

=item Thread # terminated abnormally: ...

A thread terminated in some manner other than just returning from its entry
point function, or by using C&lt;threads-E&lt;gt&gt;exit()&gt;.  For example, the thread
may have terminated because of an error, or by using C&lt;die&gt;.

=item Using minimum thread stack size of #

Some platforms have a minimum thread stack size.  Trying to set the stack size
below this value will result in the above warning, and the stack size will be
set to the minimum.

=item Thread creation failed: pthread_attr_setstacksize(I&lt;SIZE&gt;) returned 22

The specified I&lt;SIZE&gt; exceeds the system's maximum stack size.  Use a smaller
value for the stack size.

=back

If needed, thread warnings can be suppressed by using:

    no warnings 'threads';

in the appropriate scope.

=head1 ERRORS

=over 4

=item This Perl not built to support threads

The particular copy of Perl that you're trying to use was not built using the
C&lt;useithreads&gt; configuration option.

Having threads support requires all of Perl and all of the XS modules in the
Perl installation to be rebuilt; it is not just a question of adding the
L&lt;threads&gt; module (i.e., threaded and non-threaded Perls are binary
incompatible).

=item Cannot change stack size of an existing thread

The stack size of currently extant threads cannot be changed, therefore, the
following results in the above error:

    $thr-&gt;set_stack_size($size);

=item Cannot signal threads without safe signals

Safe signals must be in effect to use the C&lt;-E&lt;gt&gt;kill()&gt; signalling method.
See L&lt;/&quot;Unsafe signals&quot;&gt; for more details.

=item Unrecognized signal name: ...

The particular copy of Perl that you're trying to use does not support the
specified signal being used in a C&lt;-E&lt;gt&gt;kill()&gt; call.

=back

=head1 BUGS AND LIMITATIONS

Before you consider posting a bug report, please consult, and possibly post a
message to the discussion forum to see if what you've encountered is a known
problem.

=over

=item Thread-safe modules

See L&lt;perlmod/&quot;Making your module threadsafe&quot;&gt; when creating modules that may
be used in threaded applications, especially if those modules use non-Perl
data, or XS code.

=item Using non-thread-safe modules

Unfortunately, you may encounter Perl modules that are not I&lt;thread-safe&gt;.
For example, they may crash the Perl interpreter during execution, or may dump
core on termination.  Depending on the module and the requirements of your
application, it may be possible to work around such difficulties.

If the module will only be used inside a thread, you can try loading the
module from inside the thread entry point function using C&lt;require&gt; (and
C&lt;import&gt; if needed):

    sub thr_func
    {
        require Unsafe::Module
        # Unsafe::Module-&gt;import(...);

        ....
    }

If the module is needed inside the I&lt;main&gt; thread, try modifying your
application so that the module is loaded (again using C&lt;require&gt; and
C&lt;-E&lt;gt&gt;import()&gt;) after any threads are started, and in such a way that no
other threads are started afterwards.

If the above does not work, or is not adequate for your application, then file
a bug report on L&lt;http://rt.cpan.org/Public/&gt; against the problematic module.

=item Memory consumption

On most systems, frequent and continual creation and destruction of threads
can lead to ever-increasing growth in the memory footprint of the Perl
interpreter.  While it is simple to just launch threads and then
C&lt;-E&lt;gt&gt;join()&gt; or C&lt;-E&lt;gt&gt;detach()&gt; them, for long-lived applications, it is
better to maintain a pool of threads, and to reuse them for the work needed,
using L&lt;queues|Thread::Queue&gt; to notify threads of pending work.  The CPAN
distribution of this module contains a simple example
(F&lt;examples/pool_reuse.pl&gt;) illustrating the creation, use and monitoring of a
pool of I&lt;reusable&gt; threads.

=item Current working directory

On all platforms except MSWin32, the setting for the current working directory
is shared among all threads such that changing it in one thread (e.g., using
C&lt;chdir()&gt;) will affect all the threads in the application.

On MSWin32, each thread maintains its own the current working directory
setting.

=item Environment variables

Currently, on all platforms except MSWin32, all I&lt;system&gt; calls (e.g., using
C&lt;system()&gt; or back-ticks) made from threads use the environment variable
settings from the I&lt;main&gt; thread.  In other words, changes made to C&lt;%ENV&gt; in
a thread will not be visible in I&lt;system&gt; calls made by that thread.

To work around this, set environment variables as part of the I&lt;system&gt; call.
For example:

    my $msg = 'hello';
    system(&quot;FOO=$msg; echo \$FOO&quot;);   # Outputs 'hello' to STDOUT

On MSWin32, each thread maintains its own set of environment variables.

=item Catching signals

Signals are I&lt;caught&gt; by the main thread (thread ID = 0) of a script.
Therefore, setting up signal handlers in threads for purposes other than
L&lt;/&quot;THREAD SIGNALLING&quot;&gt; as documented above will not accomplish what is
intended.

This is especially true if trying to catch C&lt;SIGALRM&gt; in a thread.  To handle
alarms in threads, set up a signal handler in the main thread, and then use
L&lt;/&quot;THREAD SIGNALLING&quot;&gt; to relay the signal to the thread:

  # Create thread with a task that may time out
  my $thr = threads-&gt;create(sub {
      threads-&gt;yield();
      eval {
          $SIG{ALRM} = sub { die(&quot;Timeout\n&quot;); };
          alarm(10);
          ...  # Do work here
          alarm(0);
      };
      if ($@ =~ /Timeout/) {
          warn(&quot;Task in thread timed out\n&quot;);
      }
  };

  # Set signal handler to relay SIGALRM to thread
  $SIG{ALRM} = sub { $thr-&gt;kill('ALRM') };

  ... # Main thread continues working

=item Parent-child threads

On some platforms, it might not be possible to destroy I&lt;parent&gt; threads while
there are still existing I&lt;child&gt; threads.

=item Unsafe signals

Since Perl 5.8.0, signals have been made safer in Perl by postponing their
handling until the interpreter is in a I&lt;safe&gt; state.  See
L&lt;perl58delta/&quot;Safe Signals&quot;&gt; and L&lt;perlipc/&quot;Deferred Signals (Safe Signals)&quot;&gt;
for more details.

Safe signals is the default behavior, and the old, immediate, unsafe
signalling behavior is only in effect in the following situations:

=over 4

=item * Perl has been built with C&lt;PERL_OLD_SIGNALS&gt; (see C&lt;perl -V&gt;).

=item * The environment variable C&lt;PERL_SIGNALS&gt; is set to C&lt;unsafe&gt;
(see L&lt;perlrun/&quot;PERL_SIGNALS&quot;&gt;).

=item * The module L&lt;Perl::Unsafe::Signals&gt; is used.

=back

If unsafe signals is in effect, then signal handling is not thread-safe, and
the C&lt;-E&lt;gt&gt;kill()&gt; signalling method cannot be used.

=item Identity of objects returned from threads

When a value is returned from a thread through a C&lt;join&gt; operation,
the value and everything that it references is copied across to the
joining thread, in much the same way that values are copied upon thread
creation.  This works fine for most kinds of value, including arrays,
hashes, and subroutines.  The copying recurses through array elements,
reference scalars, variables closed over by subroutines, and other kinds
of reference.

However, everything referenced by the returned value is a fresh copy in
the joining thread, even if a returned object had in the child thread
been a copy of something that previously existed in the parent thread.
After joining, the parent will therefore have a duplicate of each such
object.  This sometimes matters, especially if the object gets mutated;
this can especially matter for private data to which a returned subroutine
provides access.

=item Returning blessed objects from threads

Returning blessed objects from threads does not work.  Depending on the classes
involved, you may be able to work around this by returning a serialized
version of the object (e.g., using L&lt;Data::Dumper&gt; or L&lt;Storable&gt;), and then
reconstituting it in the joining thread.  If you're using Perl 5.10.0 or
later, and if the class supports L&lt;shared objects|threads::shared/&quot;OBJECTS&quot;&gt;,
you can pass them via L&lt;shared queues|Thread::Queue&gt;.

=item END blocks in threads

It is possible to add L&lt;END blocks|perlmod/&quot;BEGIN, UNITCHECK, CHECK, INIT and
END&quot;&gt; to threads by using L&lt;require|perlfunc/&quot;require VERSION&quot;&gt; or
L&lt;eval|perlfunc/&quot;eval EXPR&quot;&gt; with the appropriate code.  These C&lt;END&gt; blocks
will then be executed when the thread's interpreter is destroyed (i.e., either
during a C&lt;-E&lt;gt&gt;join()&gt; call, or at program termination).

However, calling any L&lt;threads&gt; methods in such an C&lt;END&gt; block will most
likely I&lt;fail&gt; (e.g., the application may hang, or generate an error) due to
mutexes that are needed to control functionality within the L&lt;threads&gt; module.

For this reason, the use of C&lt;END&gt; blocks in threads is B&lt;strongly&gt;
discouraged.

=item Open directory handles

In perl 5.14 and higher, on systems other than Windows that do
not support the C&lt;fchdir&gt; C function, directory handles (see
L&lt;opendir|perlfunc/&quot;opendir DIRHANDLE,EXPR&quot;&gt;) will not be copied to new
threads. You can use the C&lt;d_fchdir&gt; variable in L&lt;Config.pm|Config&gt; to
determine whether your system supports it.

In prior perl versions, spawning threads with open directory handles would
crash the interpreter.
L&lt;[perl #75154]|http://rt.perl.org/rt3/Public/Bug/Display.html?id=75154&gt;

=item Detached threads and global destruction

If the main thread exits while there are detached threads which are still
running, then Perl's global destruction phase is not executed because
otherwise certain global structures that control the operation of threads and
that are allocated in the main thread's memory may get destroyed before the
detached thread is destroyed.

If you are using any code that requires the execution of the global
destruction phase for clean up (e.g., removing temp files), then do not use
detached threads, but rather join all threads before exiting the program.

=item Perl Bugs and the CPAN Version of L&lt;threads&gt;

Support for threads extends beyond the code in this module (i.e.,
F&lt;threads.pm&gt; and F&lt;threads.xs&gt;), and into the Perl interpreter itself.  Older
versions of Perl contain bugs that may manifest themselves despite using the
latest version of L&lt;threads&gt; from CPAN.  There is no workaround for this other
than upgrading to the latest version of Perl.

Even with the latest version of Perl, it is known that certain constructs
with threads may result in warning messages concerning leaked scalars or
unreferenced scalars.  However, such warnings are harmless, and may safely be
ignored.

You can search for L&lt;threads&gt; related bug reports at
L&lt;http://rt.cpan.org/Public/&gt;.  If needed submit any new bugs, problems,
patches, etc. to: L&lt;http://rt.cpan.org/Public/Dist/Display.html?Name=threads&gt;

=back

=head1 REQUIREMENTS

Perl 5.8.0 or later

=head1 SEE ALSO

threads on MetaCPAN:
L&lt;https://metacpan.org/release/threads&gt;

Code repository for CPAN distribution:
L&lt;https://github.com/Dual-Life/threads&gt;

L&lt;threads::shared&gt;, L&lt;perlthrtut&gt;

L&lt;http://www.perl.com/pub/a/2002/06/11/threads.html&gt; and
L&lt;http://www.perl.com/pub/a/2002/09/04/threads.html&gt;

Perl threads mailing list:
L&lt;http://lists.perl.org/list/ithreads.html&gt;

Stack size discussion:
L&lt;http://www.perlmonks.org/?node_id=532956&gt;

Sample code in the I&lt;examples&gt; directory of this distribution on CPAN.

=head1 AUTHOR

Artur Bergman E&lt;lt&gt;sky AT crucially DOT netE&lt;gt&gt;

CPAN version produced by Jerry D. Hedden &lt;jdhedden AT cpan DOT org&gt;

=head1 LICENSE

threads is released under the same license as Perl.

=head1 ACKNOWLEDGEMENTS

Richard Soderberg E&lt;lt&gt;perl AT crystalflame DOT netE&lt;gt&gt; -
Helping me out tons, trying to find reasons for races and other weird bugs!

Simon Cozens E&lt;lt&gt;simon AT brecon DOT co DOT ukE&lt;gt&gt; -
Being there to answer zillions of annoying questions

Rocco Caputo E&lt;lt&gt;troc AT netrus DOT netE&lt;gt&gt;

Vipul Ved Prakash E&lt;lt&gt;mail AT vipul DOT netE&lt;gt&gt; -
Helping with debugging

Dean Arnold E&lt;lt&gt;darnold AT presicient DOT comE&lt;gt&gt; -
Stack size API

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2Fvendor_perl'>Back to Directory</a>