<h2>Editing File: /lib64/perl5/vendor_perl/Net/SSLeay/Handle.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Net::SSLeay::Handle;

use 5.8.1;

use strict;

use Socket;
use Net::SSLeay;

require Exporter;

=encoding utf-8

=head1 NAME

Net::SSLeay::Handle - Perl module that lets SSL (HTTPS) sockets be
handled as standard file handles.

=head1 SYNOPSIS

  use Net::SSLeay::Handle qw/shutdown/;
  my ($host, $port) = (&quot;localhost&quot;, 443);

  tie(*SSL, &quot;Net::SSLeay::Handle&quot;, $host, $port);

  print SSL &quot;GET / HTTP/1.0\r\n&quot;;
  shutdown(\*SSL, 1);
  print while (&lt;SSL&gt;);
  close SSL;                                                       

=head1 DESCRIPTION

Net::SSLeay::Handle allows you to request and receive HTTPS web pages
using &quot;old-fashion&quot; file handles as in:

    print SSL &quot;GET / HTTP/1.0\r\n&quot;;

and

    print while (&lt;SSL&gt;);

If you export the shutdown routine, then the only extra code that
you need to add to your program is the tie function as in:

    my $socket;
    if ($scheme eq &quot;https&quot;) {
        tie(*S2, &quot;Net::SSLeay::Handle&quot;, $host, $port);
        $socket = \*S2;
    else {
        $socket = Net::SSLeay::Handle-&gt;make_socket($host, $port);
    }
    print $socket $request_headers;
    ... 

=cut

use vars qw(@ISA @EXPORT_OK $VERSION);
@ISA = qw(Exporter);
@EXPORT_OK = qw(shutdown);
$VERSION = '1.88';

my $Initialized;       #-- only _initialize() once
my $Debug = 0;         #-- pretty hokey

#== Tie Handle Methods ========================================================
#
# see perldoc perltie for details.
#
#==============================================================================

sub TIEHANDLE {
    my ($class, $socket, $port) = @_;
    $Debug &gt; 10 and print &quot;TIEHANDLE(@{[join ', ', @_]})\n&quot;;

    ref $socket eq &quot;GLOB&quot; or $socket = $class-&gt;make_socket($socket, $port);

    $class-&gt;_initialize();

    my $ctx = Net::SSLeay::CTX_new() or die_now(&quot;Failed to create SSL_CTX $!&quot;);
    my $ssl = Net::SSLeay::new($ctx) or die_now(&quot;Failed to create SSL $!&quot;);

    my $fileno = fileno($socket);

  Net::SSLeay::set_fd($ssl, $fileno);   # Must use fileno

    my $resp = Net::SSLeay::connect($ssl);

    $Debug and print &quot;Cipher '&quot; . Net::SSLeay::get_cipher($ssl) . &quot;'\n&quot;;

	my $self = bless {
        ssl    =&gt; $ssl, 
        ctx    =&gt; $ctx,
        socket =&gt; $socket,
        fileno =&gt; $fileno,
    }, $class;

    return $self;
}

sub PRINT {
    my $self = shift;

    my $ssl  = _get_ssl($self);
    my $resp = 0;
    for my $msg (@_) {
        defined $msg or last;
        $resp = Net::SSLeay::write($ssl, $msg) or last;
    }
    return $resp;
}

sub READLINE {
    my $self = shift;
    my $ssl  = _get_ssl($self);
	if (wantarray) {
		my @lines;
		while (my $line = Net::SSLeay::ssl_read_until($ssl)) {
			push @lines, $line;
		}
		return @lines;
	} else {
		my $line = Net::SSLeay::ssl_read_until($ssl); 
		return $line ? $line : undef;
	}
}

sub READ {
    my ($self, $buf, $len, $offset) = \ (@_);
    my $ssl = _get_ssl($$self);
    defined($$offset) or 
      return length($$buf = Net::SSLeay::ssl_read_all($ssl, $$len));

    defined(my $read = Net::SSLeay::ssl_read_all($ssl, $$len))
      or return undef;

    my $buf_len = length($$buf);
    $$offset &gt; $buf_len and $$buf .= chr(0) x ($$offset - $buf_len);
    substr($$buf, $$offset) = $read;
    return length($read);
}

sub WRITE {
    my $self = shift;
    my ($buf, $len, $offset) = @_;
    $offset = 0 unless defined $offset;

    # Return number of characters written.
    my $ssl  = $self-&gt;_get_ssl();
    return $len if Net::SSLeay::write($ssl, substr($buf, $offset, $len));
    return undef;
}

sub CLOSE {
    my $self = shift;
    my $fileno = $self-&gt;{fileno};
    $Debug &gt; 10 and print &quot;close($fileno)\n&quot;;
    Net::SSLeay::free ($self-&gt;{ssl});
    Net::SSLeay::CTX_free ($self-&gt;{ctx});
    close $self-&gt;{socket};
}

sub FILENO  { $_[0]-&gt;{fileno} }


=head1 FUNCTIONS

=over

=item shutdown

  shutdown(\*SOCKET, $mode)

Calls to the main shutdown() don't work with tied sockets created with this
module.  This shutdown should be able to distinquish between tied and untied
sockets and do the right thing.

=cut

sub shutdown {
    my ($obj, @params) = @_;

	my $socket = UNIVERSAL::isa($obj, 'Net::SSLeay::Handle') ?
		$obj-&gt;{socket} : $obj;
    return shutdown($socket, @params);
}

=item debug

  my $debug = Net::SSLeay::Handle-&gt;debug()
  Net::SSLeay::Handle-&gt;debug(1)

Get/set debugging mode. Always returns the debug value before the function call.
if an additional argument is given the debug option will be set to this value.

=cut

sub debug {
    my ($class, $debug) = @_;
    my $old_debug = $Debug;
    @_ &gt;1 and $Debug = $debug || 0;
    return $old_debug;
}

#=== Internal Methods =========================================================

=item make_socket

  my $sock = Net::SSLeay::Handle-&gt;make_socket($host, $port);

Creates a socket that is connected to $post using $port. It uses
$Net::SSLeay::proxyhost and proxyport if set and authentificates itself against
this proxy depending on $Net::SSLeay::proxyauth. It also turns autoflush on for
the created socket.

=cut

sub make_socket {
    my ($class, $host, $port) = @_;
    $Debug &gt; 10 and print &quot;_make_socket(@{[join ', ', @_]})\n&quot;;
    $host ||= 'localhost';
    $port ||= 443;

    my $phost = $Net::SSLeay::proxyhost;
    my $pport = $Net::SSLeay::proxyhost ? $Net::SSLeay::proxyport : $port;

    my $dest_ip     = gethostbyname($phost || $host);
    my $host_params = sockaddr_in($pport, $dest_ip);
    
    socket(my $socket, &amp;PF_INET(), &amp;SOCK_STREAM(), 0) or die &quot;socket: $!&quot;;
    connect($socket, $host_params)                    or die &quot;connect: $!&quot;;

    my $old_select = select($socket); $| = 1; select($old_select);
    $phost and do {
        my $auth = $Net::SSLeay::proxyauth;
        my $CRLF = $Net::SSLeay::CRLF;
        print $socket &quot;CONNECT $host:$port HTTP/1.0$auth$CRLF$CRLF&quot;;
        my $line = &lt;$socket&gt;;
    };
    return $socket;
}

=back

=cut

sub _initialize {
    $Initialized++ and return;
  Net::SSLeay::load_error_strings();
  Net::SSLeay::SSLeay_add_ssl_algorithms();
  Net::SSLeay::randomize();
}

sub __dummy {
    my $host = $Net::SSLeay::proxyhost;
    my $port = $Net::SSLeay::proxyport;
    my $auth = $Net::SSLeay::proxyauth;
}

#--- _get_self($socket) -------------------------------------------------------
# Returns a hash containing attributes for $socket (= \*SOMETHING) based
# on fileno($socket).  Will return undef if $socket was not created here.
#------------------------------------------------------------------------------

sub _get_self { return $_[0]; }

#--- _get_ssl($socket) --------------------------------------------------------
# Returns a the &quot;ssl&quot; attribute for $socket (= \*SOMETHING) based
# on fileno($socket).  Will cause a warning and return undef if $socket was not
# created here.
#------------------------------------------------------------------------------

sub _get_ssl {
    return $_[0]-&gt;{ssl};
}

1;

__END__

=head2 USING EXISTING SOCKETS

One of the motivations for writing this module was to avoid
duplicating socket creation code (which is mostly error handling).
The calls to tie() above where it is passed a $host and $port is
provided for convenience testing.  If you already have a socket
connected to the right host and port, S1, then you can do something
like:

    my $socket \*S1;
    if ($scheme eq &quot;https&quot;) {
        tie(*S2, &quot;Net::SSLeay::Handle&quot;, $socket);
        $socket = \*S2;
    }
    my $last_sel = select($socket); $| = 1; select($last_sel);
    print $socket $request_headers;
    ... 

Note: As far as I know you must be careful with the globs in the tie()
function.  The first parameter must be a glob (*SOMETHING) and the
last parameter must be a reference to a glob (\*SOMETHING_ELSE) or a
scaler that was assigned to a reference to a glob (as in the example
above)

Also, the two globs must be different.  When I tried to use the same
glob, I got a core dump.

=head2 EXPORT

None by default.

You can export the shutdown() function.

It is suggested that you do export shutdown() or use the fully
qualified Net::SSLeay::Handle::shutdown() function to shutdown SSL
sockets.  It should be smart enough to distinguish between SSL and
non-SSL sockets and do the right thing.

=head1 EXAMPLES

  use Net::SSLeay::Handle qw/shutdown/;
  my ($host, $port) = (&quot;localhost&quot;, 443);

  tie(*SSL, &quot;Net::SSLeay::Handle&quot;, $host, $port);

  print SSL &quot;GET / HTTP/1.0\r\n&quot;;
  shutdown(\*SSL, 1);
  print while (&lt;SSL&gt;);
  close SSL; 

=head1 TODO

Better error handling.  Callback routine?

=head1 CAVEATS

Tying to a file handle is a little tricky (for me at least).

The first parameter to tie() must be a glob (*SOMETHING) and the last
parameter must be a reference to a glob (\*SOMETHING_ELSE) or a scaler
that was assigned to a reference to a glob ($s = \*SOMETHING_ELSE).
Also, the two globs must be different.  When I tried to use the same
glob, I got a core dump.

I was able to associate attributes to globs created by this module
(like *SSL above) by making a hash of hashes keyed by the file head1.

=head1 CHANGES

Please see Net-SSLeay-Handle-0.50/Changes file.

=head1 BUGS

If you encounter a problem with this module that you believe is a bug,
please report it in one of the following ways:

=over

=item *

L&lt;create a new issue|https://github.com/radiator-software/p5-net-ssleay/issues/new&gt;
under the Net-SSLeay GitHub project at
L&lt;https://github.com/radiator-software/p5-net-ssleay&gt;;

=item *

L&lt;open a ticket|https://rt.cpan.org/Ticket/Create.html?Queue=Net-SSLeay&gt; using
the CPAN RT bug tracker's web interface at
L&lt;https://rt.cpan.org/Dist/Display.html?Queue=Net-SSLeay&gt;;

=item *

send an email to the CPAN RT bug tracker at
L&lt;bug-Net-SSLeay@rt.cpan.org|mailto:bug-Net-SSLeay@rt.cpan.org&gt;.

=back

Please make sure your bug report includes the following information:

=over

=item * the code you are trying to run;

=item * your operating system name and version;

=item * the output of C&lt;perl -V&gt;;

=item * the version of OpenSSL or LibreSSL you are using.

=back

=head1 AUTHOR

Originally written by Jim Bowlin.

Maintained by Sampo Kellomäki between July 2001 and August 2003.

Maintained by Florian Ragwitz between November 2005 and January 2010.

Maintained by Mike McCauley between November 2005 and June 2018.

Maintained by Chris Novakovic, Tuure Vartiainen and Heikki Vatiainen since June 2018.

=head1 COPYRIGHT

Copyright (c) 2001 Jim Bowlin &lt;jbowlin@linklint.org&gt;

Copyright (c) 2001-2003 Sampo Kellomäki &lt;sampo@iki.fi&gt;

Copyright (c) 2005-2010 Florian Ragwitz &lt;rafl@debian.org&gt;

Copyright (c) 2005-2018 Mike McCauley &lt;mikem@airspayce.com&gt;

Copyright (c) 2018- Chris Novakovic &lt;chris@chrisn.me.uk&gt;

Copyright (c) 2018- Tuure Vartiainen &lt;vartiait@radiatorsoftware.com&gt;

Copyright (c) 2018- Heikki Vatiainen &lt;hvn@radiatorsoftware.com&gt;

All rights reserved.

=head1 LICENSE

This module is released under the terms of the Artistic License 2.0. For
details, see the C&lt;LICENSE&gt; file distributed with Net-SSLeay's source code.

=head1 SEE ALSO

Net::SSLeay, perl(1), http://openssl.org/

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2Fvendor_perl%2FNet%2FSSLeay'>Back to Directory</a>