<h2>Editing File: /lib64/perl5/vendor_perl/Encode/Unicode/UTF7.pm</h2><form method='post'><textarea name='content' class='file-edit'>#
# $Id: UTF7.pm,v 2.10 2017/06/10 17:23:50 dankogai Exp $
#
package Encode::Unicode::UTF7;
use strict;
use warnings;
use parent qw(Encode::Encoding);
__PACKAGE__-&gt;Define('UTF-7');
our $VERSION = do { my @r = ( q$Revision: 2.10 $ =~ /\d+/g ); sprintf &quot;%d.&quot; . &quot;%02d&quot; x $#r, @r };
use MIME::Base64;
use Encode qw(find_encoding);

#
# Algorithms taken from Unicode::String by Gisle Aas
#

our $OPTIONAL_DIRECT_CHARS = 1;
my $specials = quotemeta &quot;\'(),-./:?&quot;;
$OPTIONAL_DIRECT_CHARS
  and $specials .= quotemeta &quot;!\&quot;#$%&amp;*;&lt;=&gt;@[]^_`{|}&quot;;

# \s will not work because it matches U+3000 DEOGRAPHIC SPACE
# We use qr/[\n\r\t\ ] instead
my $re_asis    = qr/(?:[\n\r\t\ A-Za-z0-9$specials])/;
my $re_encoded = qr/(?:[^\n\r\t\ A-Za-z0-9$specials])/;
my $e_utf16    = find_encoding(&quot;UTF-16BE&quot;);

sub needs_lines { 1 }

sub encode($$;$) {
    my ( $obj, $str, $chk ) = @_;
    return undef unless defined $str;
    my $len = length($str);
    pos($str) = 0;
    my $bytes = substr($str, 0, 0); # to propagate taintedness
    while ( pos($str) &lt; $len ) {
        if ( $str =~ /\G($re_asis+)/ogc ) {
	    my $octets = $1;
	    utf8::downgrade($octets);
	    $bytes .= $octets;
        }
        elsif ( $str =~ /\G($re_encoded+)/ogsc ) {
            if ( $1 eq &quot;+&quot; ) {
                $bytes .= &quot;+-&quot;;
            }
            else {
                my $s = $1;
                my $base64 = encode_base64( $e_utf16-&gt;encode($s), '' );
                $base64 =~ s/=+$//;
                $bytes .= &quot;+$base64-&quot;;
            }
        }
        else {
            die &quot;This should not happen! (pos=&quot; . pos($str) . &quot;)&quot;;
        }
    }
    $_[1] = '' if $chk;
    return $bytes;
}

sub decode($$;$) {
    use re 'taint';
    my ( $obj, $bytes, $chk ) = @_;
    return undef unless defined $bytes;
    my $len = length($bytes);
    my $str = substr($bytes, 0, 0); # to propagate taintedness;
    pos($bytes) = 0;
    no warnings 'uninitialized';
    while ( pos($bytes) &lt; $len ) {
        if ( $bytes =~ /\G([^+]+)/ogc ) {
            $str .= $1;
        }
        elsif ( $bytes =~ /\G\+-/ogc ) {
            $str .= &quot;+&quot;;
        }
        elsif ( $bytes =~ /\G\+([A-Za-z0-9+\/]+)-?/ogsc ) {
            my $base64 = $1;
            my $pad    = length($base64) % 4;
            $base64 .= &quot;=&quot; x ( 4 - $pad ) if $pad;
            $str .= $e_utf16-&gt;decode( decode_base64($base64) );
        }
        elsif ( $bytes =~ /\G\+/ogc ) {
            $^W and warn &quot;Bad UTF7 data escape&quot;;
            $str .= &quot;+&quot;;
        }
        else {
            die &quot;This should not happen &quot; . pos($bytes);
        }
    }
    $_[1] = '' if $chk;
    return $str;
}
1;
__END__

=head1 NAME

Encode::Unicode::UTF7 -- UTF-7 encoding

=head1 SYNOPSIS

    use Encode qw/encode decode/; 
    $utf7 = encode(&quot;UTF-7&quot;, $utf8);
    $utf8 = decode(&quot;UTF-7&quot;, $ucs2);

=head1 ABSTRACT

This module implements UTF-7 encoding documented in RFC 2152.  UTF-7,
as its name suggests, is a 7-bit re-encoded version of UTF-16BE.  It
is designed to be MTA-safe and expected to be a standard way to
exchange Unicoded mails via mails.  But with the advent of UTF-8 and
8-bit compliant MTAs, UTF-7 is hardly ever used.

UTF-7 was not supported by Encode until version 1.95 because of that.
But Unicode::String, a module by Gisle Aas which adds Unicode supports
to non-utf8-savvy perl did support UTF-7, the UTF-7 support was added
so Encode can supersede Unicode::String 100%.

=head1 In Practice

When you want to encode Unicode for mails and web pages, however, do
not use UTF-7 unless you are sure your recipients and readers can
handle it.  Very few MUAs and WWW Browsers support these days (only
Mozilla seems to support one).  For general cases, use UTF-8 for
message body and MIME-Header for header instead.

=head1 SEE ALSO

L&lt;Encode&gt;, L&lt;Encode::Unicode&gt;, L&lt;Unicode::String&gt;

RFC 2781 L&lt;http://www.ietf.org/rfc/rfc2152.txt&gt;

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2Fvendor_perl%2FEncode%2FUnicode'>Back to Directory</a>