<h2>Editing File: /lib64/perl5/vendor_perl/DBI/SQL/Nano.pm</h2><form method='post'><textarea name='content' class='file-edit'>#######################################################################
#
#  DBI::SQL::Nano - a very tiny SQL engine
#
#  Copyright (c) 2010 by Jens Rehsack &lt; rehsack AT cpan.org &gt;
#  Copyright (c) 2004 by Jeff Zucker &lt; jzucker AT cpan.org &gt;
#
#  All rights reserved.
#
#  You may freely distribute and/or modify this  module under the terms
#  of either the GNU  General Public License (GPL) or the Artistic License,
#  as specified in the Perl README file.
#
#  See the pod at the bottom of this file for help information
#
#######################################################################

#######################
package DBI::SQL::Nano;
#######################
use strict;
use warnings;
use vars qw( $VERSION $versions );

use Carp qw(croak);

require DBI;    # for looks_like_number()

BEGIN
{
    $VERSION = &quot;1.015544&quot;;

    $versions-&gt;{nano_version} = $VERSION;
    if ( $ENV{DBI_SQL_NANO} || !eval { require SQL::Statement; $SQL::Statement::VERSION ge '1.400' } )
    {
        @DBI::SQL::Nano::Statement::ISA = qw(DBI::SQL::Nano::Statement_);
        @DBI::SQL::Nano::Table::ISA     = qw(DBI::SQL::Nano::Table_);
    }
    else
    {
        @DBI::SQL::Nano::Statement::ISA = qw( SQL::Statement );
        @DBI::SQL::Nano::Table::ISA     = qw( SQL::Eval::Table);
        $versions-&gt;{statement_version}  = $SQL::Statement::VERSION;
    }
}

###################################
package DBI::SQL::Nano::Statement_;
###################################

use Carp qw(croak);
use Errno;

if ( eval { require Clone; } )
{
    Clone-&gt;import(&quot;clone&quot;);
}
else
{
    require Storable;    # in CORE since 5.7.3
    *clone = \&amp;Storable::dclone;
}

sub new
{
    my ( $class, $sql ) = @_;
    my $self = {};
    bless $self, $class;
    return $self-&gt;prepare($sql);
}

#####################################################################
# PREPARE
#####################################################################
sub prepare
{
    my ( $self, $sql ) = @_;
    $sql =~ s/\s+$//;
    $sql =~ s/\s*;$//;
    for ($sql)
    {
        /^\s*CREATE\s+TABLE\s+(.*?)\s*\((.+)\)\s*$/is
          &amp;&amp; do
        {
            $self-&gt;{command}      = 'CREATE';
            $self-&gt;{table_name}   = $1;
	    defined $2 and $2 ne &quot;&quot; and
            $self-&gt;{column_names} = parse_coldef_list($2);
            $self-&gt;{column_names} or croak &quot;Can't find columns&quot;;
        };
        /^\s*DROP\s+TABLE\s+(IF\s+EXISTS\s+)?(.*?)\s*$/is
          &amp;&amp; do
        {
            $self-&gt;{command}              = 'DROP';
            $self-&gt;{table_name}           = $2;
	    defined $1 and $1 ne &quot;&quot; and
            $self-&gt;{ignore_missing_table} = 1;
        };
        /^\s*SELECT\s+(.*?)\s+FROM\s+(\S+)((.*))?/is
          &amp;&amp; do
        {
            $self-&gt;{command} = 'SELECT';
	    defined $1 and $1 ne &quot;&quot; and
            $self-&gt;{column_names} = parse_comma_list($1);
            $self-&gt;{column_names} or croak &quot;Can't find columns&quot;;
            $self-&gt;{table_name} = $2;
            if ( my $clauses = $4 )
            {
                if ( $clauses =~ /^(.*)\s+ORDER\s+BY\s+(.*)$/is )
                {
                    $clauses = $1;
                    $self-&gt;{order_clause} = $self-&gt;parse_order_clause($2);
                }
                $self-&gt;{where_clause} = $self-&gt;parse_where_clause($clauses) if ($clauses);
            }
        };
        /^\s*INSERT\s+(?:INTO\s+)?(\S+)\s*(\((.*?)\))?\s*VALUES\s*\((.+)\)/is
          &amp;&amp; do
        {
            $self-&gt;{command}      = 'INSERT';
            $self-&gt;{table_name}   = $1;
	    defined $2 and $2 ne &quot;&quot; and
            $self-&gt;{column_names} = parse_comma_list($2);
	    defined $4 and $4 ne &quot;&quot; and
            $self-&gt;{values}       = $self-&gt;parse_values_list($4);
            $self-&gt;{values} or croak &quot;Can't parse values&quot;;
        };
        /^\s*DELETE\s+FROM\s+(\S+)((.*))?/is
          &amp;&amp; do
        {
            $self-&gt;{command}      = 'DELETE';
            $self-&gt;{table_name}   = $1;
	    defined $3 and $3 ne &quot;&quot; and
            $self-&gt;{where_clause} = $self-&gt;parse_where_clause($3);
        };
        /^\s*UPDATE\s+(\S+)\s+SET\s+(.+)(\s+WHERE\s+.+)/is
          &amp;&amp; do
        {
            $self-&gt;{command}    = 'UPDATE';
            $self-&gt;{table_name} = $1;
	    defined $2 and $2 ne &quot;&quot; and
            $self-&gt;parse_set_clause($2);
	    defined $3 and $3 ne &quot;&quot; and
            $self-&gt;{where_clause} = $self-&gt;parse_where_clause($3);
        };
    }
    croak &quot;Couldn't parse&quot; unless ( $self-&gt;{command} and $self-&gt;{table_name} );
    return $self;
}

sub parse_order_clause
{
    my ( $self, $str ) = @_;
    my @clause = split /\s+/, $str;
    return { $clause[0] =&gt; 'ASC' } if ( @clause == 1 );
    croak &quot;Bad ORDER BY clause '$str'&quot; if ( @clause &gt; 2 );
    $clause[1] ||= '';
    return { $clause[0] =&gt; uc $clause[1] }
      if $clause[1] =~ /^ASC$/i
          or $clause[1] =~ /^DESC$/i;
    croak &quot;Bad ORDER BY clause '$clause[1]'&quot;;
}

sub parse_coldef_list
{    # check column definitions
    my @col_defs;
    for ( split ',', shift )
    {
        my $col = clean_parse_str($_);
        if ( $col =~ /^(\S+?)\s+.+/ )
        {    # doesn't check what it is
            $col = $1;    # just checks if it exists
        }
        else
        {
            croak &quot;No column definition for '$_'&quot;;
        }
        push @col_defs, $col;
    }
    return \@col_defs;
}

sub parse_comma_list
{
    [ map { clean_parse_str($_) } split( ',', shift ) ];
}
sub clean_parse_str { local $_ = shift; s/\(//; s/\)//; s/^\s+//; s/\s+$//; $_; }

sub parse_values_list
{
    my ( $self, $str ) = @_;
    [ map { $self-&gt;parse_value( clean_parse_str($_) ) } split( ',', $str ) ];
}

sub parse_set_clause
{
    my $self = shift;
    my @cols = split /,/, shift;
    my $set_clause;
    for my $col (@cols)
    {
        my ( $col_name, $value ) = $col =~ /^\s*(.+?)\s*=\s*(.+?)\s*$/s;
        push @{ $self-&gt;{column_names} }, $col_name;
        push @{ $self-&gt;{values} },       $self-&gt;parse_value($value);
    }
    croak &quot;Can't parse set clause&quot; unless ( $self-&gt;{column_names} and $self-&gt;{values} );
}

sub parse_value
{
    my ( $self, $str ) = @_;
    return unless ( defined $str );
    $str =~ s/\s+$//;
    $str =~ s/^\s+//;
    if ( $str =~ /^\?$/ )
    {
        push @{ $self-&gt;{params} }, '?';
        return {
                 value =&gt; '?',
                 type  =&gt; 'placeholder'
               };
    }
    return {
             value =&gt; undef,
             type  =&gt; 'NULL'
           } if ( $str =~ /^NULL$/i );
    return {
             value =&gt; $1,
             type  =&gt; 'string'
           } if ( $str =~ /^'(.+)'$/s );
    return {
             value =&gt; $str,
             type  =&gt; 'number'
           } if ( DBI::looks_like_number($str) );
    return {
             value =&gt; $str,
             type  =&gt; 'column'
           };
}

sub parse_where_clause
{
    my ( $self, $str ) = @_;
    $str =~ s/\s+$//;
    if ( $str =~ /^\s*WHERE\s+(.*)/i )
    {
        $str = $1;
    }
    else
    {
        croak &quot;Couldn't find WHERE clause in '$str'&quot;;
    }
    my ($neg) = $str =~ s/^\s*(NOT)\s+//is;
    my $opexp = '=|&lt;&gt;|&lt;=|&gt;=|&lt;|&gt;|LIKE|CLIKE|IS';
    my ( $val1, $op, $val2 ) = $str =~ /^(.+?)\s*($opexp)\s*(.+)\s*$/iso;
    croak &quot;Couldn't parse WHERE expression '$str'&quot; unless ( defined $val1 and defined $op and defined $val2 );
    return {
             arg1 =&gt; $self-&gt;parse_value($val1),
             arg2 =&gt; $self-&gt;parse_value($val2),
             op   =&gt; $op,
             neg  =&gt; $neg,
           };
}

#####################################################################
# EXECUTE
#####################################################################
sub execute
{
    my ( $self, $data, $params ) = @_;
    my $num_placeholders = $self-&gt;params;
    my $num_params = scalar @$params || 0;
    croak &quot;Number of params '$num_params' does not match number of placeholders '$num_placeholders'&quot;
      unless ( $num_placeholders == $num_params );
    if ( scalar @$params )
    {
        for my $i ( 0 .. $#{ $self-&gt;{values} } )
        {
            if ( $self-&gt;{values}-&gt;[$i]-&gt;{type} eq 'placeholder' )
            {
                $self-&gt;{values}-&gt;[$i]-&gt;{value} = shift @$params;
            }
        }
        if ( $self-&gt;{where_clause} )
        {
            if ( $self-&gt;{where_clause}-&gt;{arg1}-&gt;{type} eq 'placeholder' )
            {
                $self-&gt;{where_clause}-&gt;{arg1}-&gt;{value} = shift @$params;
            }
            if ( $self-&gt;{where_clause}-&gt;{arg2}-&gt;{type} eq 'placeholder' )
            {
                $self-&gt;{where_clause}-&gt;{arg2}-&gt;{value} = shift @$params;
            }
        }
    }
    my $command = $self-&gt;{command};
    ( $self-&gt;{'NUM_OF_ROWS'}, $self-&gt;{'NUM_OF_FIELDS'}, $self-&gt;{'data'}, ) = $self-&gt;$command( $data, $params );
    $self-&gt;{NAME} ||= $self-&gt;{column_names};
    return $self-&gt;{'NUM_OF_ROWS'} || '0E0';
}

my $enoentstr = &quot;Cannot open .*\(&quot; . Errno::ENOENT . &quot;\)&quot;;
my $enoentrx  = qr/$enoentstr/;

sub DROP ($$$)
{
    my ( $self, $data, $params ) = @_;

    my $table;
    my @err;
    eval {
        local $SIG{__WARN__} = sub { push @err, @_ };
        ($table) = $self-&gt;open_tables( $data, 0, 1 );
    };
    if ( $self-&gt;{ignore_missing_table} and ( $@ or @err ) and grep { $_ =~ $enoentrx } ( @err, $@ ) )
    {
        $@ = '';
        return ( -1, 0 );
    }

    croak( $@ || $err[0] ) if ( $@ || @err );
    return ( -1, 0 ) unless $table;

    $table-&gt;drop($data);
    ( -1, 0 );
}

sub CREATE ($$$)
{
    my ( $self, $data, $params ) = @_;
    my $table = $self-&gt;open_tables( $data, 1, 1 );
    $table-&gt;push_names( $data, $self-&gt;{column_names} );
    ( 0, 0 );
}

sub INSERT ($$$)
{
    my ( $self, $data, $params ) = @_;
    my $table = $self-&gt;open_tables( $data, 0, 1 );
    $self-&gt;verify_columns($table);
    my $all_columns = $table-&gt;{col_names};
    $table-&gt;seek( $data, 0, 2 ) unless ( $table-&gt;can('insert_one_row') );
    my ($array) = [];
    my ( $val, $col, $i );
    $self-&gt;{column_names} = $table-&gt;col_names() unless ( $self-&gt;{column_names} );
    my $cNum = scalar( @{ $self-&gt;{column_names} } ) if ( $self-&gt;{column_names} );
    my $param_num = 0;

    $cNum or
        croak &quot;Bad col names in INSERT&quot;;

    my $maxCol = $#$all_columns;

    for ( $i = 0; $i &lt; $cNum; $i++ )
    {
       $col = $self-&gt;{column_names}-&gt;[$i];
       $array-&gt;[ $self-&gt;column_nums( $table, $col ) ] = $self-&gt;row_values($i);
    }

    # Extend row to put values in ALL fields
    $#$array &lt; $maxCol and $array-&gt;[$maxCol] = undef;

    $table-&gt;can('insert_new_row') ? $table-&gt;insert_new_row( $data, $array ) : $table-&gt;push_row( $data, $array );

    return ( 1, 0 );
}

sub DELETE ($$$)
{
    my ( $self, $data, $params ) = @_;
    my $table = $self-&gt;open_tables( $data, 0, 1 );
    $self-&gt;verify_columns($table);
    my ($affected) = 0;
    my ( @rows, $array );
    my $can_dor = $table-&gt;can('delete_one_row');
    while ( $array = $table-&gt;fetch_row($data) )
    {
        if ( $self-&gt;eval_where( $table, $array ) )
        {
            ++$affected;
            if ( $self-&gt;{fetched_from_key} )
            {
                $array = $self-&gt;{fetched_value};
                $table-&gt;delete_one_row( $data, $array );
                return ( $affected, 0 );
            }
            push( @rows, $array ) if ($can_dor);
        }
        else
        {
            push( @rows, $array ) unless ($can_dor);
        }
    }
    if ($can_dor)
    {
        foreach $array (@rows)
        {
            $table-&gt;delete_one_row( $data, $array );
        }
    }
    else
    {
        $table-&gt;seek( $data, 0, 0 );
        foreach $array (@rows)
        {
            $table-&gt;push_row( $data, $array );
        }
        $table-&gt;truncate($data);
    }
    return ( $affected, 0 );
}

sub _anycmp($$;$)
{
    my ( $a, $b, $case_fold ) = @_;

    if ( !defined($a) || !defined($b) )
    {
        return defined($a) - defined($b);
    }
    elsif ( DBI::looks_like_number($a) &amp;&amp; DBI::looks_like_number($b) )
    {
        return $a &lt;=&gt; $b;
    }
    else
    {
        return $case_fold ? lc($a) cmp lc($b) || $a cmp $b : $a cmp $b;
    }
}

sub SELECT ($$$)
{
    my ( $self, $data, $params ) = @_;
    my $table = $self-&gt;open_tables( $data, 0, 0 );
    $self-&gt;verify_columns($table);
    my $tname = $self-&gt;{table_name};
    my ($affected) = 0;
    my ( @rows, %cols, $array, $val, $col, $i );
    while ( $array = $table-&gt;fetch_row($data) )
    {
        if ( $self-&gt;eval_where( $table, $array ) )
        {
            $array = $self-&gt;{fetched_value} if ( $self-&gt;{fetched_from_key} );
            unless ( keys %cols )
            {
                my $col_nums = $self-&gt;column_nums($table);
                %cols = reverse %{$col_nums};
            }

            my $rowhash;
            for ( sort keys %cols )
            {
                $rowhash-&gt;{ $cols{$_} } = $array-&gt;[$_];
            }
            my @newarray;
            for ( $i = 0; $i &lt; @{ $self-&gt;{column_names} }; $i++ )
            {
                $col = $self-&gt;{column_names}-&gt;[$i];
                push @newarray, $rowhash-&gt;{$col};
            }
            push( @rows, \@newarray );
            return ( scalar(@rows), scalar @{ $self-&gt;{column_names} }, \@rows )
              if ( $self-&gt;{fetched_from_key} );
        }
    }
    if ( $self-&gt;{order_clause} )
    {
        my ( $sort_col, $desc ) = each %{ $self-&gt;{order_clause} };
        my @sortCols = ( $self-&gt;column_nums( $table, $sort_col, 1 ) );
        $sortCols[1] = uc $desc eq 'DESC' ? 1 : 0;

        @rows = sort {
            my ( $result, $colNum, $desc );
            my $i = 0;
            do
            {
                $colNum = $sortCols[ $i++ ];
                $desc   = $sortCols[ $i++ ];
                $result = _anycmp( $a-&gt;[$colNum], $b-&gt;[$colNum] );
                $result = -$result if ($desc);
            } while ( !$result &amp;&amp; $i &lt; @sortCols );
            $result;
        } @rows;
    }
    ( scalar(@rows), scalar @{ $self-&gt;{column_names} }, \@rows );
}

sub UPDATE ($$$)
{
    my ( $self, $data, $params ) = @_;
    my $table = $self-&gt;open_tables( $data, 0, 1 );
    $self-&gt;verify_columns($table);
    return undef unless $table;
    my $affected = 0;
    my $can_usr  = $table-&gt;can('update_specific_row');
    my $can_uor  = $table-&gt;can('update_one_row');
    my $can_rwu  = $can_usr || $can_uor;
    my ( @rows, $array, $f_array, $val, $col, $i );

    while ( $array = $table-&gt;fetch_row($data) )
    {
        if ( $self-&gt;eval_where( $table, $array ) )
        {
            $array = $self-&gt;{fetched_value} if ( $self-&gt;{fetched_from_key} and $can_rwu );
            my $orig_ary = clone($array) if ($can_usr);
            for ( $i = 0; $i &lt; @{ $self-&gt;{column_names} }; $i++ )
            {
                $col = $self-&gt;{column_names}-&gt;[$i];
                $array-&gt;[ $self-&gt;column_nums( $table, $col ) ] = $self-&gt;row_values($i);
            }
            $affected++;
            if ( $self-&gt;{fetched_value} )
            {
                if ($can_usr)
                {
                    $table-&gt;update_specific_row( $data, $array, $orig_ary );
                }
                elsif ($can_uor)
                {
                    $table-&gt;update_one_row( $data, $array );
                }
                return ( $affected, 0 );
            }
            push( @rows, $can_usr ? [ $array, $orig_ary ] : $array );
        }
        else
        {
            push( @rows, $array ) unless ($can_rwu);
        }
    }
    if ($can_rwu)
    {
        foreach my $array (@rows)
        {
            if ($can_usr)
            {
                $table-&gt;update_specific_row( $data, @$array );
            }
            elsif ($can_uor)
            {
                $table-&gt;update_one_row( $data, $array );
            }
        }
    }
    else
    {
        $table-&gt;seek( $data, 0, 0 );
        foreach my $array (@rows)
        {
            $table-&gt;push_row( $data, $array );
        }
        $table-&gt;truncate($data);
    }

    return ( $affected, 0 );
}

sub verify_columns
{
    my ( $self, $table ) = @_;
    my @cols = @{ $self-&gt;{column_names} };
    if ( $self-&gt;{where_clause} )
    {
        if ( my $col = $self-&gt;{where_clause}-&gt;{arg1} )
        {
            push @cols, $col-&gt;{value} if $col-&gt;{type} eq 'column';
        }
        if ( my $col = $self-&gt;{where_clause}-&gt;{arg2} )
        {
            push @cols, $col-&gt;{value} if $col-&gt;{type} eq 'column';
        }
    }
    for (@cols)
    {
        $self-&gt;column_nums( $table, $_ );
    }
}

sub column_nums
{
    my ( $self, $table, $stmt_col_name, $find_in_stmt ) = @_;
    my %dbd_nums = %{ $table-&gt;col_nums() };
    my @dbd_cols = @{ $table-&gt;col_names() };
    my %stmt_nums;
    if ( $stmt_col_name and !$find_in_stmt )
    {
        while ( my ( $k, $v ) = each %dbd_nums )
        {
            return $v if uc $k eq uc $stmt_col_name;
        }
        croak &quot;No such column '$stmt_col_name'&quot;;
    }
    if ( $stmt_col_name and $find_in_stmt )
    {
        for my $i ( 0 .. @{ $self-&gt;{column_names} } )
        {
            return $i if uc $stmt_col_name eq uc $self-&gt;{column_names}-&gt;[$i];
        }
        croak &quot;No such column '$stmt_col_name'&quot;;
    }
    for my $i ( 0 .. $#dbd_cols )
    {
        for my $stmt_col ( @{ $self-&gt;{column_names} } )
        {
            $stmt_nums{$stmt_col} = $i if uc $dbd_cols[$i] eq uc $stmt_col;
        }
    }
    return \%stmt_nums;
}

sub eval_where
{
    my ( $self, $table, $rowary ) = @_;
    my $where    = $self-&gt;{&quot;where_clause&quot;} || return 1;
    my $col_nums = $table-&gt;col_nums();
    my %cols     = reverse %{$col_nums};
    my $rowhash;
    for ( sort keys %cols )
    {
        $rowhash-&gt;{ uc $cols{$_} } = $rowary-&gt;[$_];
    }
    return $self-&gt;process_predicate( $where, $table, $rowhash );
}

sub process_predicate
{
    my ( $self, $pred, $table, $rowhash ) = @_;
    my $val1 = $pred-&gt;{arg1};
    if ( $val1-&gt;{type} eq 'column' )
    {
        $val1 = $rowhash-&gt;{ uc $val1-&gt;{value} };
    }
    else
    {
        $val1 = $val1-&gt;{value};
    }
    my $val2 = $pred-&gt;{arg2};
    if ( $val2-&gt;{type} eq 'column' )
    {
        $val2 = $rowhash-&gt;{ uc $val2-&gt;{value} };
    }
    else
    {
        $val2 = $val2-&gt;{value};
    }
    my $op  = $pred-&gt;{op};
    my $neg = $pred-&gt;{neg};
    if ( $op eq '=' and !$neg and $table-&gt;can('fetch_one_row') )
    {
        my $key_col = $table-&gt;fetch_one_row( 1, 1 );
        if ( $pred-&gt;{arg1}-&gt;{value} =~ /^$key_col$/i )
        {
            $self-&gt;{fetched_from_key} = 1;
            $self-&gt;{fetched_value} = $table-&gt;fetch_one_row( 0, $pred-&gt;{arg2}-&gt;{value} );
            return 1;
        }
    }
    my $match = $self-&gt;is_matched( $val1, $op, $val2 ) || 0;
    if ($neg) { $match = $match ? 0 : 1; }
    return $match;
}

sub is_matched
{
    my ( $self, $val1, $op, $val2 ) = @_;
    if ( $op eq 'IS' )
    {
        return 1 if ( !defined $val1 or $val1 eq '' );
        return 0;
    }
    $val1 = '' unless ( defined $val1 );
    $val2 = '' unless ( defined $val2 );
    if ( $op =~ /LIKE|CLIKE/i )
    {
        $val2 = quotemeta($val2);
        $val2 =~ s/\\%/.*/g;
        $val2 =~ s/_/./g;
    }
    if ( $op eq 'LIKE' )  { return $val1 =~ /^$val2$/s; }
    if ( $op eq 'CLIKE' ) { return $val1 =~ /^$val2$/si; }
    if ( DBI::looks_like_number($val1) &amp;&amp; DBI::looks_like_number($val2) )
    {
        if ( $op eq '&lt;' )  { return $val1 &lt; $val2; }
        if ( $op eq '&gt;' )  { return $val1 &gt; $val2; }
        if ( $op eq '=' )  { return $val1 == $val2; }
        if ( $op eq '&lt;&gt;' ) { return $val1 != $val2; }
        if ( $op eq '&lt;=' ) { return $val1 &lt;= $val2; }
        if ( $op eq '&gt;=' ) { return $val1 &gt;= $val2; }
    }
    else
    {
        if ( $op eq '&lt;' )  { return $val1 lt $val2; }
        if ( $op eq '&gt;' )  { return $val1 gt $val2; }
        if ( $op eq '=' )  { return $val1 eq $val2; }
        if ( $op eq '&lt;&gt;' ) { return $val1 ne $val2; }
        if ( $op eq '&lt;=' ) { return $val1 ge $val2; }
        if ( $op eq '&gt;=' ) { return $val1 le $val2; }
    }
}

sub params
{
    my ( $self, $val_num ) = @_;
    if ( !$self-&gt;{&quot;params&quot;} ) { return 0; }
    if ( defined $val_num )
    {
        return $self-&gt;{&quot;params&quot;}-&gt;[$val_num];
    }

    return wantarray ? @{ $self-&gt;{&quot;params&quot;} } : scalar @{ $self-&gt;{&quot;params&quot;} };
}

sub open_tables
{
    my ( $self, $data, $createMode, $lockMode ) = @_;
    my $table_name = $self-&gt;{table_name};
    my $table;
    eval { $table = $self-&gt;open_table( $data, $table_name, $createMode, $lockMode ) };
    if ($@)
    {
        chomp $@;
        croak $@;
    }
    croak &quot;Couldn't open table '$table_name'&quot; unless $table;
    if ( !$self-&gt;{column_names} or $self-&gt;{column_names}-&gt;[0] eq '*' )
    {
        $self-&gt;{column_names} = $table-&gt;col_names();
    }
    return $table;
}

sub row_values
{
    my ( $self, $val_num ) = @_;
    if ( !$self-&gt;{&quot;values&quot;} ) { return 0; }
    if ( defined $val_num )
    {
        return $self-&gt;{&quot;values&quot;}-&gt;[$val_num]-&gt;{value};
    }
    if (wantarray)
    {
        return map { $_-&gt;{&quot;value&quot;} } @{ $self-&gt;{&quot;values&quot;} };
    }
    else
    {
        return scalar @{ $self-&gt;{&quot;values&quot;} };
    }
}

sub column_names
{
    my ($self) = @_;
    my @col_names;
    if ( $self-&gt;{column_names} and $self-&gt;{column_names}-&gt;[0] ne '*' )
    {
        @col_names = @{ $self-&gt;{column_names} };
    }
    return @col_names;
}

###############################
package DBI::SQL::Nano::Table_;
###############################

use Carp qw(croak);

sub new ($$)
{
    my ( $proto, $attr ) = @_;
    my ($self) = {%$attr};

    defined( $self-&gt;{col_names} ) and &quot;ARRAY&quot; eq ref( $self-&gt;{col_names} )
      or croak(&quot;attribute 'col_names' must be defined as an array&quot;);
    exists( $self-&gt;{col_nums} ) or $self-&gt;{col_nums} = _map_colnums( $self-&gt;{col_names} );
    defined( $self-&gt;{col_nums} ) and &quot;HASH&quot; eq ref( $self-&gt;{col_nums} )
      or croak(&quot;attribute 'col_nums' must be defined as a hash&quot;);

    bless( $self, ( ref($proto) || $proto ) );
    return $self;
}

sub _map_colnums
{
    my $col_names = $_[0];
    my %col_nums;
    for my $i ( 0 .. $#$col_names )
    {
        next unless $col_names-&gt;[$i];
        $col_nums{ $col_names-&gt;[$i] } = $i;
    }
    return \%col_nums;
}

sub row()         { return $_[0]-&gt;{row}; }
sub column($)     { return $_[0]-&gt;{row}-&gt;[ $_[0]-&gt;column_num( $_[1] ) ]; }
sub column_num($) { $_[0]-&gt;{col_nums}-&gt;{ $_[1] }; }
sub col_nums()    { $_[0]-&gt;{col_nums} }
sub col_names()   { $_[0]-&gt;{col_names}; }

sub drop ($$)        { croak &quot;Abstract method &quot; . ref( $_[0] ) . &quot;::drop called&quot; }
sub fetch_row ($$$)  { croak &quot;Abstract method &quot; . ref( $_[0] ) . &quot;::fetch_row called&quot; }
sub push_row ($$$)   { croak &quot;Abstract method &quot; . ref( $_[0] ) . &quot;::push_row called&quot; }
sub push_names ($$$) { croak &quot;Abstract method &quot; . ref( $_[0] ) . &quot;::push_names called&quot; }
sub truncate ($$)    { croak &quot;Abstract method &quot; . ref( $_[0] ) . &quot;::truncate called&quot; }
sub seek ($$$$)      { croak &quot;Abstract method &quot; . ref( $_[0] ) . &quot;::seek called&quot; }

1;
__END__

=pod

=head1 NAME

DBI::SQL::Nano - a very tiny SQL engine

=head1 SYNOPSIS

 BEGIN { $ENV{DBI_SQL_NANO}=1 } # forces use of Nano rather than SQL::Statement
 use DBI::SQL::Nano;
 use Data::Dumper;
 my $stmt = DBI::SQL::Nano::Statement-&gt;new(
     &quot;SELECT bar,baz FROM foo WHERE qux = 1&quot;
 ) or die &quot;Couldn't parse&quot;;
 print Dumper $stmt;

=head1 DESCRIPTION

C&lt;&lt; DBI::SQL::Nano &gt;&gt; is meant as a I&lt;very&gt; minimal SQL engine for use in
situations where SQL::Statement is not available. In most situations you are
better off installing L&lt;SQL::Statement&gt; although DBI::SQL::Nano may be faster
for some B&lt;very&gt; simple tasks.

DBI::SQL::Nano, like SQL::Statement is primarily intended to provide a SQL
engine for use with some pure perl DBDs including L&lt;DBD::DBM&gt;, L&lt;DBD::CSV&gt;,
L&lt;DBD::AnyData&gt;, and L&lt;DBD::Excel&gt;. It is not of much use in and of itself.
You can dump out the structure of a parsed SQL statement, but that is about
it.

=head1 USAGE

=head2 Setting the DBI_SQL_NANO flag

By default, when a C&lt;&lt; DBD &gt;&gt; uses C&lt;&lt; DBI::SQL::Nano &gt;&gt;, the module will
look to see if C&lt;&lt; SQL::Statement &gt;&gt; is installed. If it is, SQL::Statement
objects are used.  If SQL::Statement is not available, DBI::SQL::Nano
objects are used.

In some cases, you may wish to use DBI::SQL::Nano objects even if
SQL::Statement is available.  To force usage of DBI::SQL::Nano objects
regardless of the availability of SQL::Statement, set the environment
variable DBI_SQL_NANO to 1.

You can set the environment variable in your shell prior to running your
script (with SET or EXPORT or whatever), or else you can set it in your
script by putting this at the top of the script:

 BEGIN { $ENV{DBI_SQL_NANO} = 1 }

=head2 Supported SQL syntax

 Here's a pseudo-BNF.  Square brackets [] indicate optional items;
 Angle brackets &lt;&gt; indicate items defined elsewhere in the BNF.

  statement ::=
      DROP TABLE [IF EXISTS] &lt;table_name&gt;
    | CREATE TABLE &lt;table_name&gt; &lt;col_def_list&gt;
    | INSERT INTO &lt;table_name&gt; [&lt;insert_col_list&gt;] VALUES &lt;val_list&gt;
    | DELETE FROM &lt;table_name&gt; [&lt;where_clause&gt;]
    | UPDATE &lt;table_name&gt; SET &lt;set_clause&gt; &lt;where_clause&gt;
    | SELECT &lt;select_col_list&gt; FROM &lt;table_name&gt; [&lt;where_clause&gt;]
                                                 [&lt;order_clause&gt;]

  the optional IF EXISTS clause ::=
    * similar to MySQL - prevents errors when trying to drop
      a table that doesn't exist

  identifiers ::=
    * table and column names should be valid SQL identifiers
    * especially avoid using spaces and commas in identifiers
    * note: there is no error checking for invalid names, some
      will be accepted, others will cause parse failures

  table_name ::=
    * only one table (no multiple table operations)
    * see identifier for valid table names

  col_def_list ::=
    * a parens delimited, comma-separated list of column names
    * see identifier for valid column names
    * column types and column constraints may be included but are ignored
      e.g. these are all the same:
        (id,phrase)
        (id INT, phrase VARCHAR(40))
        (id INT PRIMARY KEY, phrase VARCHAR(40) NOT NULL)
    * you are *strongly* advised to put in column types even though
      they are ignored ... it increases portability

  insert_col_list ::=
    * a parens delimited, comma-separated list of column names
    * as in standard SQL, this is optional

  select_col_list ::=
    * a comma-separated list of column names
    * or an asterisk denoting all columns

  val_list ::=
    * a parens delimited, comma-separated list of values which can be:
       * placeholders (an unquoted question mark)
       * numbers (unquoted numbers)
       * column names (unquoted strings)
       * nulls (unquoted word NULL)
       * strings (delimited with single quote marks);
       * note: leading and trailing percent mark (%) and underscore (_)
         can be used as wildcards in quoted strings for use with
         the LIKE and CLIKE operators
       * note: escaped single quotation marks within strings are not
         supported, neither are embedded commas, use placeholders instead

  set_clause ::=
    * a comma-separated list of column = value pairs
    * see val_list for acceptable value formats

  where_clause ::=
    * a single &quot;column/value &lt;op&gt; column/value&quot; predicate, optionally
      preceded by &quot;NOT&quot;
    * note: multiple predicates combined with ORs or ANDs are not supported
    * see val_list for acceptable value formats
    * op may be one of:
         &lt; &gt; &gt;= &lt;= = &lt;&gt; LIKE CLIKE IS
    * CLIKE is a case insensitive LIKE

  order_clause ::= column_name [ASC|DESC]
    * a single column optional ORDER BY clause is supported
    * as in standard SQL, if neither ASC (ascending) nor
      DESC (descending) is specified, ASC becomes the default

=head1 TABLES

DBI::SQL::Nano::Statement operates on exactly one table. This table will be
opened by inherit from DBI::SQL::Nano::Statement and implements the
C&lt;&lt; open_table &gt;&gt; method.

  sub open_table ($$$$$)
  {
      ...
      return Your::Table-&gt;new( \%attributes );
  }

DBI::SQL::Nano::Statement_ expects a rudimentary interface is implemented by
the table object, as well as SQL::Statement expects.

  package Your::Table;

  use vars qw(@ISA);
  @ISA = qw(DBI::SQL::Nano::Table);

  sub drop ($$)        { ... }
  sub fetch_row ($$$)  { ... }
  sub push_row ($$$)   { ... }
  sub push_names ($$$) { ... }
  sub truncate ($$)    { ... }
  sub seek ($$$$)      { ... }

The base class interfaces are provided by DBI::SQL::Nano::Table_ in case of
relying on DBI::SQL::Nano or SQL::Eval::Table (see L&lt;SQL::Eval&gt; for details)
otherwise.

=head1 BUGS AND LIMITATIONS

There are no known bugs in DBI::SQL::Nano::Statement. If you find a one
and want to report, please see L&lt;DBI&gt; for how to report bugs.

DBI::SQL::Nano::Statement is designed to provide a minimal subset for
executing SQL statements.

The most important limitation might be the restriction on one table per
statement. This implies, that no JOINs are supported and there cannot be
any foreign key relation between tables.

The where clause evaluation of DBI::SQL::Nano::Statement is very slow
(SQL::Statement uses a precompiled evaluation).

INSERT can handle only one row per statement. To insert multiple rows,
use placeholders as explained in DBI.

The DBI::SQL::Nano parser is very limited and does not support any
additional syntax such as brackets, comments, functions, aggregations
etc.

In contrast to SQL::Statement, temporary tables are not supported.

=head1 ACKNOWLEDGEMENTS

Tim Bunce provided the original idea for this module, helped me out of the
tangled trap of namespaces, and provided help and advice all along the way.
Although I wrote it from the ground up, it is based on Jochen Wiedmann's
original design of SQL::Statement, so much of the credit for the API goes
to him.

=head1 AUTHOR AND COPYRIGHT

This module is originally written by Jeff Zucker &lt; jzucker AT cpan.org &gt;

This module is currently maintained by Jens Rehsack &lt; jrehsack AT cpan.org &gt;

Copyright (C) 2010 by Jens Rehsack, all rights reserved.
Copyright (C) 2004 by Jeff Zucker, all rights reserved.

You may freely distribute and/or modify this module under the terms of
either the GNU General Public License (GPL) or the Artistic License,
as specified in the Perl README file.

=cut

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2Fvendor_perl%2FDBI%2FSQL'>Back to Directory</a>