<h2>Editing File: /lib64/perl5/vendor_perl/DBI/Gofer/Request.pm</h2><form method='post'><textarea name='content' class='file-edit'>package DBI::Gofer::Request;

#   $Id: Request.pm 12536 2009-02-24 22:37:09Z Tim $
#
#   Copyright (c) 2007, Tim Bunce, Ireland
#
#   You may distribute under the terms of either the GNU General Public
#   License or the Artistic License, as specified in the Perl README file.

use strict;

use DBI qw(neat neat_list);

use base qw(DBI::Util::_accessor);

our $VERSION = &quot;0.012537&quot;;

use constant GOf_REQUEST_IDEMPOTENT =&gt; 0x0001;
use constant GOf_REQUEST_READONLY   =&gt; 0x0002;

our @EXPORT = qw(GOf_REQUEST_IDEMPOTENT GOf_REQUEST_READONLY);


__PACKAGE__-&gt;mk_accessors(qw(
    version
    flags
    dbh_connect_call
    dbh_method_call
    dbh_attributes
    dbh_last_insert_id_args
    sth_method_calls
    sth_result_attr
));
__PACKAGE__-&gt;mk_accessors_using(make_accessor_autoviv_hashref =&gt; qw(
    meta
));


sub new {
    my ($self, $args) = @_;
    $args-&gt;{version} ||= $VERSION;
    return $self-&gt;SUPER::new($args);
}


sub reset {
    my ($self, $flags) = @_;
    # remove everything except connect and version
    %$self = (
        version =&gt; $self-&gt;{version},
        dbh_connect_call =&gt; $self-&gt;{dbh_connect_call},
    );
    $self-&gt;{flags} = $flags if $flags;
}


sub init_request {
    my ($self, $method_and_args, $dbh) = @_;
    $self-&gt;reset( $dbh-&gt;{ReadOnly} ? GOf_REQUEST_READONLY : 0 );
    $self-&gt;dbh_method_call($method_and_args);
}


sub is_sth_request {
    return shift-&gt;{sth_result_attr};
}


sub statements {
    my $self = shift;
    my @statements;
    if (my $dbh_method_call = $self-&gt;dbh_method_call) {
        my $statement_method_regex = qr/^(?:do|prepare)$/;
        my (undef, $method, $arg1) = @$dbh_method_call;
        push @statements, $arg1 if $method &amp;&amp; $method =~ $statement_method_regex;
    }
    return @statements;
}


sub is_idempotent {
    my $self = shift;

    if (my $flags = $self-&gt;flags) {
        return 1 if $flags &amp; (GOf_REQUEST_IDEMPOTENT|GOf_REQUEST_READONLY);
    }

    # else check if all statements are SELECT statement that don't include FOR UPDATE
    my @statements = $self-&gt;statements;
    # XXX this is very minimal for now, doesn't even allow comments before the select
    # (and can't ever work for &quot;exec stored_procedure_name&quot; kinds of statements)
    # XXX it also doesn't deal with multiple statements: prepare(&quot;select foo; update bar&quot;)
    return 1 if @statements == grep {
                m/^ \s* SELECT \b /xmsi &amp;&amp; !m/ \b FOR \s+ UPDATE \b /xmsi
             } @statements;

    return 0;
}


sub summary_as_text {
    my $self = shift;
    my ($context) = @_;
    my @s = '';

    if ($context &amp;&amp; %$context) {
        my @keys = sort keys %$context;
        push @s, join(&quot;, &quot;, map { &quot;$_=&gt;&quot;.$context-&gt;{$_} } @keys);
    }

    my ($method, $dsn, $user, $pass, $attr) = @{ $self-&gt;dbh_connect_call };
    $method ||= 'connect_cached';
    $pass = '***' if defined $pass;
    my $tmp = '';
    if ($attr) {
        $tmp = { %{$attr||{}} }; # copy so we can edit
        $tmp-&gt;{Password} = '***' if exists $tmp-&gt;{Password};
        $tmp = &quot;{ &quot;.neat_list([ %$tmp ]).&quot; }&quot;;
    }
    push @s, sprintf &quot;dbh= $method(%s, %s)&quot;, neat_list([$dsn, $user, $pass]), $tmp;

    if (my $flags = $self-&gt;flags) {
        push @s, sprintf &quot;flags: 0x%x&quot;, $flags;
    }

    if (my $dbh_attr = $self-&gt;dbh_attributes) {
        push @s, sprintf &quot;dbh-&gt;FETCH: %s&quot;, @$dbh_attr
            if @$dbh_attr;
    }

    my ($wantarray, $meth, @args) = @{ $self-&gt;dbh_method_call };
    my $args = neat_list(\@args);
    $args =~ s/\n+/ /g;
    push @s, sprintf &quot;dbh-&gt;%s(%s)&quot;, $meth, $args;

    if (my $lii_args = $self-&gt;dbh_last_insert_id_args) {
        push @s, sprintf &quot;dbh-&gt;last_insert_id(%s)&quot;, neat_list($lii_args);
    }

    for my $call (@{ $self-&gt;sth_method_calls || [] }) {
        my ($meth, @args) = @$call;
        ($args = neat_list(\@args)) =~ s/\n+/ /g;
        push @s, sprintf &quot;sth-&gt;%s(%s)&quot;, $meth, $args;
    }

    if (my $sth_attr = $self-&gt;sth_result_attr) {
        push @s, sprintf &quot;sth-&gt;FETCH: %s&quot;, %$sth_attr
            if %$sth_attr;
    }

    return join(&quot;\n\t&quot;, @s) . &quot;\n&quot;;
}


sub outline_as_text { # one-line version of summary_as_text
    my $self = shift;
    my @s = '';
    my $neatlen = 80;

    if (my $flags = $self-&gt;flags) {
        push @s, sprintf &quot;flags=0x%x&quot;, $flags;
    }

    my (undef, $meth, @args) = @{ $self-&gt;dbh_method_call };
    push @s, sprintf &quot;%s(%s)&quot;, $meth, neat_list(\@args, $neatlen);

    for my $call (@{ $self-&gt;sth_method_calls || [] }) {
        my ($meth, @args) = @$call;
        push @s, sprintf &quot;%s(%s)&quot;, $meth, neat_list(\@args, $neatlen);
    }

    my ($method, $dsn) = @{ $self-&gt;dbh_connect_call };
    push @s, &quot;$method($dsn,...)&quot;; # dsn last as it's usually less interesting

    (my $outline = join(&quot;; &quot;, @s)) =~ s/\s+/ /g; # squish whitespace, incl newlines
    return $outline;
}

1;

=head1 NAME

DBI::Gofer::Request - Encapsulate a request from DBD::Gofer to DBI::Gofer::Execute

=head1 DESCRIPTION

This is an internal class.

=head1 AUTHOR

Tim Bunce, L&lt;http://www.tim.bunce.name&gt;

=head1 LICENCE AND COPYRIGHT

Copyright (c) 2007, Tim Bunce, Ireland. All rights reserved.

This module is free software; you can redistribute it and/or
modify it under the same terms as Perl itself. See L&lt;perlartistic&gt;.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2Fvendor_perl%2FDBI%2FGofer'>Back to Directory</a>