<h2>Editing File: /lib64/perl5/vendor_perl/DBI/DBD/SqlEngine.pm</h2><form method='post'><textarea name='content' class='file-edit'># -*- perl -*-
#
#   DBI::DBD::SqlEngine - A base class for implementing DBI drivers that
#               have not an own SQL engine
#
#  This module is currently maintained by
#
#      H.Merijn Brand &amp; Jens Rehsack
#
#  The original author is Jochen Wiedmann.
#
#  Copyright (C) 2009-2013 by H.Merijn Brand &amp; Jens Rehsack
#  Copyright (C) 2004 by Jeff Zucker
#  Copyright (C) 1998 by Jochen Wiedmann
#
#  All rights reserved.
#
#  You may distribute this module under the terms of either the GNU
#  General Public License or the Artistic License, as specified in
#  the Perl README file.

require 5.008;

use strict;

use DBI ();
require DBI::SQL::Nano;

package DBI::DBD::SqlEngine;

use strict;

use Carp;
use vars qw( @ISA $VERSION $drh %methods_installed);

$VERSION = &quot;0.06&quot;;

$drh = undef;    # holds driver handle(s) once initialized

DBI-&gt;setup_driver(&quot;DBI::DBD::SqlEngine&quot;);    # only needed once but harmless to repeat

my %accessors = (
                  versions   =&gt; &quot;get_driver_versions&quot;,
                  new_meta   =&gt; &quot;new_sql_engine_meta&quot;,
                  get_meta   =&gt; &quot;get_sql_engine_meta&quot;,
                  set_meta   =&gt; &quot;set_sql_engine_meta&quot;,
                  clear_meta =&gt; &quot;clear_sql_engine_meta&quot;,
                );

sub driver ($;$)
{
    my ( $class, $attr ) = @_;

    # Drivers typically use a singleton object for the $drh
    # We use a hash here to have one singleton per subclass.
    # (Otherwise DBD::CSV and DBD::DBM, for example, would
    # share the same driver object which would cause problems.)
    # An alternative would be to not cache the $drh here at all
    # and require that subclasses do that. Subclasses should do
    # their own caching, so caching here just provides extra safety.
    $drh-&gt;{$class} and return $drh-&gt;{$class};

    $attr ||= {};
    {
        no strict &quot;refs&quot;;
        unless ( $attr-&gt;{Attribution} )
        {
            $class eq &quot;DBI::DBD::SqlEngine&quot;
              and $attr-&gt;{Attribution} = &quot;$class by Jens Rehsack&quot;;
            $attr-&gt;{Attribution} ||= ${ $class . &quot;::ATTRIBUTION&quot; }
              || &quot;oops the author of $class forgot to define this&quot;;
        }
        $attr-&gt;{Version} ||= ${ $class . &quot;::VERSION&quot; };
        $attr-&gt;{Name} or ( $attr-&gt;{Name} = $class ) =~ s/^DBD\:\://;
    }

    $drh-&gt;{$class} = DBI::_new_drh( $class . &quot;::dr&quot;, $attr );
    $drh-&gt;{$class}-&gt;STORE( ShowErrorStatement =&gt; 1 );

    my $prefix = DBI-&gt;driver_prefix($class);
    if ($prefix)
    {
        my $dbclass = $class . &quot;::db&quot;;
        while ( my ( $accessor, $funcname ) = each %accessors )
        {
            my $method = $prefix . $accessor;
            $dbclass-&gt;can($method) and next;
            my $inject = sprintf &lt;&lt;'EOI', $dbclass, $method, $dbclass, $funcname;
sub %s::%s
{
    my $func = %s-&gt;can (q{%s});
    goto &amp;$func;
    }
EOI
            eval $inject;
            $dbclass-&gt;install_method($method);
        }
    }
    else
    {
        warn &quot;Using DBI::DBD::SqlEngine with unregistered driver $class.\n&quot;
          . &quot;Reading documentation how to prevent is strongly recommended.\n&quot;;

    }

    # XXX inject DBD::XXX::Statement unless exists

    my $stclass = $class . &quot;::st&quot;;
    $stclass-&gt;install_method(&quot;sql_get_colnames&quot;) unless ( $methods_installed{__PACKAGE__}++ );

    return $drh-&gt;{$class};
}    # driver

sub CLONE
{
    undef $drh;
}    # CLONE

# ====== DRIVER ================================================================

package DBI::DBD::SqlEngine::dr;

use strict;
use warnings;

use vars qw(@ISA $imp_data_size);

use Carp qw/carp/;

$imp_data_size = 0;

sub connect ($$;$$$)
{
    my ( $drh, $dbname, $user, $auth, $attr ) = @_;

    # create a 'blank' dbh
    my $dbh = DBI::_new_dbh(
                             $drh,
                             {
                                Name         =&gt; $dbname,
                                USER         =&gt; $user,
                                CURRENT_USER =&gt; $user,
                             }
                           );

    if ($dbh)
    {
        # must be done first, because setting flags implicitly calls $dbdname::db-&gt;STORE
        $dbh-&gt;func( 0, &quot;init_default_attributes&quot; );
        my $two_phased_init;
        defined $dbh-&gt;{sql_init_phase} and $two_phased_init = ++$dbh-&gt;{sql_init_phase};
        my %second_phase_attrs;
        my @func_inits;

        # this must be done to allow DBI.pm reblessing got handle after successful connecting
        exists $attr-&gt;{RootClass} and $second_phase_attrs{RootClass} = delete $attr-&gt;{RootClass};

        my ( $var, $val );
        while ( length $dbname )
        {
            if ( $dbname =~ s/^((?:[^\\;]|\\.)*?);//s )
            {
                $var = $1;
            }
            else
            {
                $var    = $dbname;
                $dbname = &quot;&quot;;
            }

            if ( $var =~ m/^(.+?)=(.*)/s )
            {
                $var = $1;
                ( $val = $2 ) =~ s/\\(.)/$1/g;
                exists $attr-&gt;{$var}
                  and carp(&quot;$var is given in DSN *and* \$attr during DBI-&gt;connect()&quot;)
                  if ($^W);
                exists $attr-&gt;{$var} or $attr-&gt;{$var} = $val;
            }
            elsif ( $var =~ m/^(.+?)=&gt;(.*)/s )
            {
                $var = $1;
                ( $val = $2 ) =~ s/\\(.)/$1/g;
                my $ref = eval $val;
                # $dbh-&gt;$var($ref);
                push( @func_inits, $var, $ref );
            }
        }

        # The attributes need to be sorted in a specific way as the
        # assignment is through tied hashes and calls STORE on each
        # attribute.  Some attributes require to be called prior to
        # others
        # e.g. f_dir *must* be done before xx_tables in DBD::File
        # The dbh attribute sql_init_order is a hash with the order
        # as key (low is first, 0 .. 100) and the attributes that
        # are set to that oreder as anon-list as value:
        # {  0 =&gt; [qw( AutoCommit PrintError RaiseError Profile ... )],
        #   10 =&gt; [ list of attr to be dealt with immediately after first ],
        #   50 =&gt; [ all fields that are unspecified or default sort order ],
        #   90 =&gt; [ all fields that are needed after other initialisation ],
        #   }

        my %order = map {
            my $order = $_;
            map { ( $_ =&gt; $order ) } @{ $dbh-&gt;{sql_init_order}{$order} };
        } sort { $a &lt;=&gt; $b } keys %{ $dbh-&gt;{sql_init_order} || {} };
        my @ordered_attr =
          map  { $_-&gt;[0] }
          sort { $a-&gt;[1] &lt;=&gt; $b-&gt;[1] }
          map  { [ $_, defined $order{$_} ? $order{$_} : 50 ] }
          keys %$attr;

        # initialize given attributes ... lower weighted before higher weighted
        foreach my $a (@ordered_attr)
        {
            exists $attr-&gt;{$a} or next;
            $two_phased_init and eval {
                $dbh-&gt;{$a} = $attr-&gt;{$a};
                delete $attr-&gt;{$a};
            };
            $@ and $second_phase_attrs{$a} = delete $attr-&gt;{$a};
            $two_phased_init or $dbh-&gt;STORE( $a, delete $attr-&gt;{$a} );
        }

        $two_phased_init and $dbh-&gt;func( 1, &quot;init_default_attributes&quot; );
        %$attr = %second_phase_attrs;

        for ( my $i = 0; $i &lt; scalar(@func_inits); $i += 2 )
        {
            my $func = $func_inits[$i];
            my $arg  = $func_inits[ $i + 1 ];
            $dbh-&gt;$func($arg);
        }

        $dbh-&gt;func(&quot;init_done&quot;);

        $dbh-&gt;STORE( Active =&gt; 1 );
    }

    return $dbh;
}    # connect

sub data_sources ($;$)
{
    my ( $drh, $attr ) = @_;

    my $tbl_src;
    $attr
      and defined $attr-&gt;{sql_table_source}
      and $attr-&gt;{sql_table_source}-&gt;isa('DBI::DBD::SqlEngine::TableSource')
      and $tbl_src = $attr-&gt;{sql_table_source};

    !defined($tbl_src)
      and $drh-&gt;{ImplementorClass}-&gt;can('default_table_source')
      and $tbl_src = $drh-&gt;{ImplementorClass}-&gt;default_table_source();
    defined($tbl_src) or return;

    $tbl_src-&gt;data_sources( $drh, $attr );
}    # data_sources

sub disconnect_all
{
}    # disconnect_all

sub DESTROY
{
    undef;
}    # DESTROY

# ====== DATABASE ==============================================================

package DBI::DBD::SqlEngine::db;

use strict;
use warnings;

use vars qw(@ISA $imp_data_size);

use Carp;

if ( eval { require Clone; } )
{
    Clone-&gt;import(&quot;clone&quot;);
}
else
{
    require Storable;    # in CORE since 5.7.3
    *clone = \&amp;Storable::dclone;
}

$imp_data_size = 0;

sub ping
{
    ( $_[0]-&gt;FETCH(&quot;Active&quot;) ) ? 1 : 0;
}    # ping

sub data_sources
{
    my ( $dbh, $attr, @other ) = @_;
    my $drh = $dbh-&gt;{Driver};    # XXX proxy issues?
    ref($attr) eq 'HASH' or $attr = {};
    defined( $attr-&gt;{sql_table_source} ) or $attr-&gt;{sql_table_source} = $dbh-&gt;{sql_table_source};
    return $drh-&gt;data_sources( $attr, @other );
}

sub prepare ($$;@)
{
    my ( $dbh, $statement, @attribs ) = @_;

    # create a 'blank' sth
    my $sth = DBI::_new_sth( $dbh, { Statement =&gt; $statement } );

    if ($sth)
    {
        my $class = $sth-&gt;FETCH(&quot;ImplementorClass&quot;);
        $class =~ s/::st$/::Statement/;
        my $stmt;

        # if using SQL::Statement version &gt; 1
        # cache the parser object if the DBD supports parser caching
        # SQL::Nano and older SQL::Statements don't support this

        if ( $class-&gt;isa(&quot;SQL::Statement&quot;) )
        {
            my $parser = $dbh-&gt;{sql_parser_object};
            $parser ||= eval { $dbh-&gt;func(&quot;sql_parser_object&quot;) };
            if ($@)
            {
                $stmt = eval { $class-&gt;new($statement) };
            }
            else
            {
                $stmt = eval { $class-&gt;new( $statement, $parser ) };
            }
        }
        else
        {
            $stmt = eval { $class-&gt;new($statement) };
        }
        if ( $@ || $stmt-&gt;{errstr} )
        {
            $dbh-&gt;set_err( $DBI::stderr, $@ || $stmt-&gt;{errstr} );
            undef $sth;
        }
        else
        {
            $sth-&gt;STORE( &quot;sql_stmt&quot;, $stmt );
            $sth-&gt;STORE( &quot;sql_params&quot;, [] );
            $sth-&gt;STORE( &quot;NUM_OF_PARAMS&quot;, scalar( $stmt-&gt;params() ) );
            my @colnames = $sth-&gt;sql_get_colnames();
            $sth-&gt;STORE( &quot;NUM_OF_FIELDS&quot;, scalar @colnames );
        }
    }
    return $sth;
}    # prepare

sub set_versions
{
    my $dbh = $_[0];
    $dbh-&gt;{sql_engine_version} = $DBI::DBD::SqlEngine::VERSION;
    for (qw( nano_version statement_version ))
    {
        defined $DBI::SQL::Nano::versions-&gt;{$_} or next;
        $dbh-&gt;{&quot;sql_$_&quot;} = $DBI::SQL::Nano::versions-&gt;{$_};
    }
    $dbh-&gt;{sql_handler} =
      $dbh-&gt;{sql_statement_version}
      ? &quot;SQL::Statement&quot;
      : &quot;DBI::SQL::Nano&quot;;

    return $dbh;
}    # set_versions

sub init_valid_attributes
{
    my $dbh = $_[0];

    $dbh-&gt;{sql_valid_attrs} = {
                             sql_engine_version         =&gt; 1,    # DBI::DBD::SqlEngine version
                             sql_handler                =&gt; 1,    # Nano or S:S
                             sql_nano_version           =&gt; 1,    # Nano version
                             sql_statement_version      =&gt; 1,    # S:S version
                             sql_flags                  =&gt; 1,    # flags for SQL::Parser
                             sql_dialect                =&gt; 1,    # dialect for SQL::Parser
                             sql_quoted_identifier_case =&gt; 1,    # case for quoted identifiers
                             sql_identifier_case        =&gt; 1,    # case for non-quoted identifiers
                             sql_parser_object          =&gt; 1,    # SQL::Parser instance
                             sql_sponge_driver          =&gt; 1,    # Sponge driver for table_info ()
                             sql_valid_attrs            =&gt; 1,    # SQL valid attributes
                             sql_readonly_attrs         =&gt; 1,    # SQL readonly attributes
                             sql_init_phase             =&gt; 1,    # Only during initialization
                             sql_meta                   =&gt; 1,    # meta data for tables
                             sql_meta_map               =&gt; 1,    # mapping table for identifier case
			     sql_data_source            =&gt; 1,    # reasonable datasource class
                              };
    $dbh-&gt;{sql_readonly_attrs} = {
                               sql_engine_version         =&gt; 1,    # DBI::DBD::SqlEngine version
                               sql_handler                =&gt; 1,    # Nano or S:S
                               sql_nano_version           =&gt; 1,    # Nano version
                               sql_statement_version      =&gt; 1,    # S:S version
                               sql_quoted_identifier_case =&gt; 1,    # case for quoted identifiers
                               sql_parser_object          =&gt; 1,    # SQL::Parser instance
                               sql_sponge_driver          =&gt; 1,    # Sponge driver for table_info ()
                               sql_valid_attrs            =&gt; 1,    # SQL valid attributes
                               sql_readonly_attrs         =&gt; 1,    # SQL readonly attributes
                                 };

    return $dbh;
}    # init_valid_attributes

sub init_default_attributes
{
    my ( $dbh, $phase ) = @_;
    my $given_phase = $phase;

    unless ( defined($phase) )
    {
        # we have an &quot;old&quot; driver here
        $phase = defined $dbh-&gt;{sql_init_phase};
        $phase and $phase = $dbh-&gt;{sql_init_phase};
    }

    if ( 0 == $phase )
    {
        # must be done first, because setting flags implicitly calls $dbdname::db-&gt;STORE
        $dbh-&gt;func(&quot;init_valid_attributes&quot;);

        $dbh-&gt;func(&quot;set_versions&quot;);

        $dbh-&gt;{sql_identifier_case}        = 2;    # SQL_IC_LOWER
        $dbh-&gt;{sql_quoted_identifier_case} = 3;    # SQL_IC_SENSITIVE

        $dbh-&gt;{sql_dialect} = &quot;CSV&quot;;

        $dbh-&gt;{sql_init_phase} = $given_phase;

        # complete derived attributes, if required
        ( my $drv_class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$//;
        my $drv_prefix  = DBI-&gt;driver_prefix($drv_class);
        my $valid_attrs = $drv_prefix . &quot;valid_attrs&quot;;
        my $ro_attrs    = $drv_prefix . &quot;readonly_attrs&quot;;

        # check whether we're running in a Gofer server or not (see
        # validate_FETCH_attr for details)
        $dbh-&gt;{sql_engine_in_gofer} =
          ( defined $INC{&quot;DBD/Gofer.pm&quot;} &amp;&amp; ( caller(5) )[0] eq &quot;DBI::Gofer::Execute&quot; );
        $dbh-&gt;{sql_meta}     = {};
        $dbh-&gt;{sql_meta_map} = {};    # choose new name because it contains other keys

        # init_default_attributes calls inherited routine before derived DBD's
        # init their default attributes, so we don't override something here
        #
        # defining an order of attribute initialization from connect time
        # specified ones with a magic baarier (see next statement)
        my $drv_pfx_meta = $drv_prefix . &quot;meta&quot;;
        $dbh-&gt;{sql_init_order} = {
                           0  =&gt; [qw( Profile RaiseError PrintError AutoCommit )],
                           90 =&gt; [ &quot;sql_meta&quot;, $dbh-&gt;{$drv_pfx_meta} ? $dbh-&gt;{$drv_pfx_meta} : () ],
        };
        # ensuring Profile, RaiseError, PrintError, AutoCommit are initialized
        # first when initializing attributes from connect time specified
        # attributes
        # further, initializations to predefined tables are happens after any
        # unspecified attribute initialization (that default to order 50)

        my @comp_attrs = qw(valid_attrs version readonly_attrs);

        if ( exists $dbh-&gt;{$drv_pfx_meta} and !$dbh-&gt;{sql_engine_in_gofer} )
        {
            my $attr = $dbh-&gt;{$drv_pfx_meta};
                  defined $attr
              and defined $dbh-&gt;{$valid_attrs}
              and !defined $dbh-&gt;{$valid_attrs}{$attr}
              and $dbh-&gt;{$valid_attrs}{$attr} = 1;

            my %h;
            tie %h, &quot;DBI::DBD::SqlEngine::TieTables&quot;, $dbh;
            $dbh-&gt;{$attr} = \%h;

            push @comp_attrs, &quot;meta&quot;;
        }

        foreach my $comp_attr (@comp_attrs)
        {
            my $attr = $drv_prefix . $comp_attr;
            defined $dbh-&gt;{$valid_attrs}
              and !defined $dbh-&gt;{$valid_attrs}{$attr}
              and $dbh-&gt;{$valid_attrs}{$attr} = 1;
            defined $dbh-&gt;{$ro_attrs}
              and !defined $dbh-&gt;{$ro_attrs}{$attr}
              and $dbh-&gt;{$ro_attrs}{$attr} = 1;
        }
    }

    return $dbh;
}    # init_default_attributes

sub init_done
{
    defined $_[0]-&gt;{sql_init_phase} and delete $_[0]-&gt;{sql_init_phase};
    delete $_[0]-&gt;{sql_valid_attrs}-&gt;{sql_init_phase};
    return;
}

sub sql_parser_object
{
    my $dbh = $_[0];
    my $dialect = $dbh-&gt;{sql_dialect} || &quot;CSV&quot;;
    my $parser = {
                   RaiseError =&gt; $dbh-&gt;FETCH(&quot;RaiseError&quot;),
                   PrintError =&gt; $dbh-&gt;FETCH(&quot;PrintError&quot;),
                 };
    my $sql_flags = $dbh-&gt;FETCH(&quot;sql_flags&quot;) || {};
    %$parser = ( %$parser, %$sql_flags );
    $parser = SQL::Parser-&gt;new( $dialect, $parser );
    $dbh-&gt;{sql_parser_object} = $parser;
    return $parser;
}    # sql_parser_object

sub sql_sponge_driver
{
    my $dbh  = $_[0];
    my $dbh2 = $dbh-&gt;{sql_sponge_driver};
    unless ($dbh2)
    {
        $dbh2 = $dbh-&gt;{sql_sponge_driver} = DBI-&gt;connect(&quot;DBI:Sponge:&quot;);
        unless ($dbh2)
        {
            $dbh-&gt;set_err( $DBI::stderr, $DBI::errstr );
            return;
        }
    }
}

sub disconnect ($)
{
    %{ $_[0]-&gt;{sql_meta} }     = ();
    %{ $_[0]-&gt;{sql_meta_map} } = ();
    $_[0]-&gt;STORE( Active =&gt; 0 );
    return 1;
}    # disconnect

sub validate_FETCH_attr
{
    my ( $dbh, $attrib ) = @_;

    # If running in a Gofer server, access to our tied compatibility hash
    # would force Gofer to serialize the tieing object including it's
    # private $dbh reference used to do the driver function calls.
    # This will result in nasty exceptions. So return a copy of the
    # sql_meta structure instead, which is the source of for the compatibility
    # tie-hash. It's not as good as liked, but the best we can do in this
    # situation.
    if ( $dbh-&gt;{sql_engine_in_gofer} )
    {
        ( my $drv_class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$//;
        my $drv_prefix = DBI-&gt;driver_prefix($drv_class);
        exists $dbh-&gt;{ $drv_prefix . &quot;meta&quot; } &amp;&amp; $attrib eq $dbh-&gt;{ $drv_prefix . &quot;meta&quot; }
          and $attrib = &quot;sql_meta&quot;;
    }

    return $attrib;
}

sub FETCH ($$)
{
    my ( $dbh, $attrib ) = @_;
    $attrib eq &quot;AutoCommit&quot;
      and return 1;

    # Driver private attributes are lower cased
    if ( $attrib eq ( lc $attrib ) )
    {
        # first let the implementation deliver an alias for the attribute to fetch
        # after it validates the legitimation of the fetch request
        $attrib = $dbh-&gt;func( $attrib, &quot;validate_FETCH_attr&quot; ) or return;

        my $attr_prefix;
        $attrib =~ m/^([a-z]+_)/ and $attr_prefix = $1;
        unless ($attr_prefix)
        {
            ( my $drv_class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$//;
            $attr_prefix = DBI-&gt;driver_prefix($drv_class);
            $attrib      = $attr_prefix . $attrib;
        }
        my $valid_attrs = $attr_prefix . &quot;valid_attrs&quot;;
        my $ro_attrs    = $attr_prefix . &quot;readonly_attrs&quot;;

        exists $dbh-&gt;{$valid_attrs}
          and ( $dbh-&gt;{$valid_attrs}{$attrib}
                or return $dbh-&gt;set_err( $DBI::stderr, &quot;Invalid attribute '$attrib'&quot; ) );
        exists $dbh-&gt;{$ro_attrs}
          and $dbh-&gt;{$ro_attrs}{$attrib}
          and defined $dbh-&gt;{$attrib}
          and refaddr( $dbh-&gt;{$attrib} )
          and return clone( $dbh-&gt;{$attrib} );

        return $dbh-&gt;{$attrib};
    }
    # else pass up to DBI to handle
    return $dbh-&gt;SUPER::FETCH($attrib);
}    # FETCH

sub validate_STORE_attr
{
    my ( $dbh, $attrib, $value ) = @_;

    if (     $attrib eq &quot;sql_identifier_case&quot; || $attrib eq &quot;sql_quoted_identifier_case&quot;
         and $value &lt; 1 || $value &gt; 4 )
    {
        croak &quot;attribute '$attrib' must have a value from 1 .. 4 (SQL_IC_UPPER .. SQL_IC_MIXED)&quot;;
        # XXX correctly a remap of all entries in sql_meta/sql_meta_map is required here
    }

    ( my $drv_class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$//;
    my $drv_prefix = DBI-&gt;driver_prefix($drv_class);

    exists $dbh-&gt;{ $drv_prefix . &quot;meta&quot; }
      and $attrib eq $dbh-&gt;{ $drv_prefix . &quot;meta&quot; }
      and $attrib = &quot;sql_meta&quot;;

    return ( $attrib, $value );
}

# the ::db::STORE method is what gets called when you set
# a lower-cased database handle attribute such as $dbh-&gt;{somekey}=$someval;
#
# STORE should check to make sure that &quot;somekey&quot; is a valid attribute name
# but only if it is really one of our attributes (starts with dbm_ or foo_)
# You can also check for valid values for the attributes if needed
# and/or perform other operations
#
sub STORE ($$$)
{
    my ( $dbh, $attrib, $value ) = @_;

    if ( $attrib eq &quot;AutoCommit&quot; )
    {
        $value and return 1;    # is already set
        croak &quot;Can't disable AutoCommit&quot;;
    }

    if ( $attrib eq lc $attrib )
    {
        # Driver private attributes are lower cased

        ( $attrib, $value ) = $dbh-&gt;func( $attrib, $value, &quot;validate_STORE_attr&quot; );
        $attrib or return;

        my $attr_prefix;
        $attrib =~ m/^([a-z]+_)/ and $attr_prefix = $1;
        unless ($attr_prefix)
        {
            ( my $drv_class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$//;
            $attr_prefix = DBI-&gt;driver_prefix($drv_class);
            $attrib      = $attr_prefix . $attrib;
        }
        my $valid_attrs = $attr_prefix . &quot;valid_attrs&quot;;
        my $ro_attrs    = $attr_prefix . &quot;readonly_attrs&quot;;

        exists $dbh-&gt;{$valid_attrs}
          and ( $dbh-&gt;{$valid_attrs}{$attrib}
                or return $dbh-&gt;set_err( $DBI::stderr, &quot;Invalid attribute '$attrib'&quot; ) );
        exists $dbh-&gt;{$ro_attrs}
          and $dbh-&gt;{$ro_attrs}{$attrib}
          and defined $dbh-&gt;{$attrib}
          and return $dbh-&gt;set_err( $DBI::stderr,
                                    &quot;attribute '$attrib' is readonly and must not be modified&quot; );

        if ( $attrib eq &quot;sql_meta&quot; )
        {
            while ( my ( $k, $v ) = each %$value )
            {
                $dbh-&gt;{$attrib}{$k} = $v;
            }
        }
        else
        {
            $dbh-&gt;{$attrib} = $value;
        }

        return 1;
    }

    return $dbh-&gt;SUPER::STORE( $attrib, $value );
}    # STORE

sub get_driver_versions
{
    my ( $dbh, $table ) = @_;
    my %vsn = (
                OS   =&gt; &quot;$^O ($Config::Config{osvers})&quot;,
                Perl =&gt; &quot;$] ($Config::Config{archname})&quot;,
                DBI  =&gt; $DBI::VERSION,
              );
    my %vmp;

    my $sql_engine_verinfo =
      join &quot; &quot;,
      $dbh-&gt;{sql_engine_version}, &quot;using&quot;, $dbh-&gt;{sql_handler},
      $dbh-&gt;{sql_handler} eq &quot;SQL::Statement&quot;
      ? $dbh-&gt;{sql_statement_version}
      : $dbh-&gt;{sql_nano_version};

    my $indent   = 0;
    my @deriveds = ( $dbh-&gt;{ImplementorClass} );
    while (@deriveds)
    {
        my $derived = shift @deriveds;
        $derived eq &quot;DBI::DBD::SqlEngine::db&quot; and last;
        $derived-&gt;isa(&quot;DBI::DBD::SqlEngine::db&quot;) or next;
        #no strict 'refs';
        eval &quot;push \@deriveds, \@${derived}::ISA&quot;;
        #use strict;
        ( my $drv_class = $derived ) =~ s/::db$//;
        my $drv_prefix  = DBI-&gt;driver_prefix($drv_class);
        my $ddgv        = $dbh-&gt;{ImplementorClass}-&gt;can(&quot;get_${drv_prefix}versions&quot;);
        my $drv_version = $ddgv ? &amp;$ddgv( $dbh, $table ) : $dbh-&gt;{ $drv_prefix . &quot;version&quot; };
        $drv_version ||=
          eval { $derived-&gt;VERSION() };    # XXX access $drv_class::VERSION via symbol table
        $vsn{$drv_class} = $drv_version;
        $indent and $vmp{$drv_class} = &quot; &quot; x $indent . $drv_class;
        $indent += 2;
    }

    $vsn{&quot;DBI::DBD::SqlEngine&quot;} = $sql_engine_verinfo;
    $indent and $vmp{&quot;DBI::DBD::SqlEngine&quot;} = &quot; &quot; x $indent . &quot;DBI::DBD::SqlEngine&quot;;

    $DBI::PurePerl and $vsn{&quot;DBI::PurePerl&quot;} = $DBI::PurePerl::VERSION;

    $indent += 20;
    my @versions = map { sprintf &quot;%-${indent}s %s&quot;, $vmp{$_} || $_, $vsn{$_} }
      sort {
        $a-&gt;isa($b)                    and return -1;
        $b-&gt;isa($a)                    and return 1;
        $a-&gt;isa(&quot;DBI::DBD::SqlEngine&quot;) and return -1;
        $b-&gt;isa(&quot;DBI::DBD::SqlEngine&quot;) and return 1;
        return $a cmp $b;
      } keys %vsn;

    return wantarray ? @versions : join &quot;\n&quot;, @versions;
}    # get_versions

sub get_single_table_meta
{
    my ( $dbh, $table, $attr ) = @_;
    my $meta;

    $table eq &quot;.&quot;
      and return $dbh-&gt;FETCH($attr);

    ( my $class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$/::Table/;
    ( undef, $meta ) = $class-&gt;get_table_meta( $dbh, $table, 1 );
    $meta or croak &quot;No such table '$table'&quot;;

    # prevent creation of undef attributes
    return $class-&gt;get_table_meta_attr( $meta, $attr );
}    # get_single_table_meta

sub get_sql_engine_meta
{
    my ( $dbh, $table, $attr ) = @_;

    my $gstm = $dbh-&gt;{ImplementorClass}-&gt;can(&quot;get_single_table_meta&quot;);

    $table eq &quot;*&quot;
      and $table = [ &quot;.&quot;, keys %{ $dbh-&gt;{sql_meta} } ];
    $table eq &quot;+&quot;
      and $table = [ grep { m/^[_A-Za-z0-9]+$/ } keys %{ $dbh-&gt;{sql_meta} } ];
    ref $table eq &quot;Regexp&quot;
      and $table = [ grep { $_ =~ $table } keys %{ $dbh-&gt;{sql_meta} } ];

    ref $table || ref $attr
      or return $gstm-&gt;( $dbh, $table, $attr );

    ref $table or $table = [$table];
    ref $attr  or $attr  = [$attr];
    &quot;ARRAY&quot; eq ref $table
      or return
      $dbh-&gt;set_err( $DBI::stderr,
          &quot;Invalid argument for \$table - SCALAR, Regexp or ARRAY expected but got &quot; . ref $table );
    &quot;ARRAY&quot; eq ref $attr
      or return $dbh-&gt;set_err(
                    &quot;Invalid argument for \$attr - SCALAR or ARRAY expected but got &quot; . ref $attr );

    my %results;
    foreach my $tname ( @{$table} )
    {
        my %tattrs;
        foreach my $aname ( @{$attr} )
        {
            $tattrs{$aname} = $gstm-&gt;( $dbh, $tname, $aname );
        }
        $results{$tname} = \%tattrs;
    }

    return \%results;
}    # get_sql_engine_meta

sub new_sql_engine_meta
{
    my ( $dbh, $table, $values ) = @_;
    my $respect_case = 0;

    &quot;HASH&quot; eq ref $values
      or croak &quot;Invalid argument for \$values - SCALAR or HASH expected but got &quot; . ref $values;

    $table =~ s/^\&quot;// and $respect_case = 1;    # handle quoted identifiers
    $table =~ s/\&quot;$//;

    unless ($respect_case)
    {
        defined $dbh-&gt;{sql_meta_map}{$table} and $table = $dbh-&gt;{sql_meta_map}{$table};
    }

    $dbh-&gt;{sql_meta}{$table} = { %{$values} };
    my $class;
    defined $values-&gt;{sql_table_class} and $class = $values-&gt;{sql_table_class};
    defined $class or ( $class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$/::Table/;
    # XXX we should never hit DBD::File::Table::get_table_meta here ...
    my ( undef, $meta ) = $class-&gt;get_table_meta( $dbh, $table, $respect_case );
    1;
}    # new_sql_engine_meta

sub set_single_table_meta
{
    my ( $dbh, $table, $attr, $value ) = @_;
    my $meta;

    $table eq &quot;.&quot;
      and return $dbh-&gt;STORE( $attr, $value );

    ( my $class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$/::Table/;
    ( undef, $meta ) = $class-&gt;get_table_meta( $dbh, $table, 1 ); # 1 means: respect case
    $meta or croak &quot;No such table '$table'&quot;;
    $class-&gt;set_table_meta_attr( $meta, $attr, $value );

    return $dbh;
}    # set_single_table_meta

sub set_sql_engine_meta
{
    my ( $dbh, $table, $attr, $value ) = @_;

    my $sstm = $dbh-&gt;{ImplementorClass}-&gt;can(&quot;set_single_table_meta&quot;);

    $table eq &quot;*&quot;
      and $table = [ &quot;.&quot;, keys %{ $dbh-&gt;{sql_meta} } ];
    $table eq &quot;+&quot;
      and $table = [ grep { m/^[_A-Za-z0-9]+$/ } keys %{ $dbh-&gt;{sql_meta} } ];
    ref($table) eq &quot;Regexp&quot;
      and $table = [ grep { $_ =~ $table } keys %{ $dbh-&gt;{sql_meta} } ];

    ref $table || ref $attr
      or return $sstm-&gt;( $dbh, $table, $attr, $value );

    ref $table or $table = [$table];
    ref $attr or $attr = { $attr =&gt; $value };
    &quot;ARRAY&quot; eq ref $table
      or croak &quot;Invalid argument for \$table - SCALAR, Regexp or ARRAY expected but got &quot;
      . ref $table;
    &quot;HASH&quot; eq ref $attr
      or croak &quot;Invalid argument for \$attr - SCALAR or HASH expected but got &quot; . ref $attr;

    foreach my $tname ( @{$table} )
    {
        while ( my ( $aname, $aval ) = each %$attr )
        {
            $sstm-&gt;( $dbh, $tname, $aname, $aval );
        }
    }

    return $dbh;
}    # set_file_meta

sub clear_sql_engine_meta
{
    my ( $dbh, $table ) = @_;

    ( my $class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$/::Table/;
    my ( undef, $meta ) = $class-&gt;get_table_meta( $dbh, $table, 1 );
    $meta and %{$meta} = ();

    return;
}    # clear_file_meta

sub DESTROY ($)
{
    my $dbh = shift;
    $dbh-&gt;SUPER::FETCH(&quot;Active&quot;) and $dbh-&gt;disconnect;
    undef $dbh-&gt;{sql_parser_object};
}    # DESTROY

sub type_info_all ($)
{
    [
       {
          TYPE_NAME          =&gt; 0,
          DATA_TYPE          =&gt; 1,
          PRECISION          =&gt; 2,
          LITERAL_PREFIX     =&gt; 3,
          LITERAL_SUFFIX     =&gt; 4,
          CREATE_PARAMS      =&gt; 5,
          NULLABLE           =&gt; 6,
          CASE_SENSITIVE     =&gt; 7,
          SEARCHABLE         =&gt; 8,
          UNSIGNED_ATTRIBUTE =&gt; 9,
          MONEY              =&gt; 10,
          AUTO_INCREMENT     =&gt; 11,
          LOCAL_TYPE_NAME    =&gt; 12,
          MINIMUM_SCALE      =&gt; 13,
          MAXIMUM_SCALE      =&gt; 14,
       },
       [
          &quot;VARCHAR&quot;, DBI::SQL_VARCHAR(), undef, &quot;'&quot;, &quot;'&quot;, undef, 0, 1, 1, 0, 0, 0, undef, 1, 999999,
       ],
       [ &quot;CHAR&quot;, DBI::SQL_CHAR(), undef, &quot;'&quot;, &quot;'&quot;, undef, 0, 1, 1, 0, 0, 0, undef, 1, 999999, ],
       [ &quot;INTEGER&quot;, DBI::SQL_INTEGER(), undef, &quot;&quot;, &quot;&quot;, undef, 0, 0, 1, 0, 0, 0, undef, 0, 0, ],
       [ &quot;REAL&quot;,    DBI::SQL_REAL(),    undef, &quot;&quot;, &quot;&quot;, undef, 0, 0, 1, 0, 0, 0, undef, 0, 0, ],
       [
          &quot;BLOB&quot;, DBI::SQL_LONGVARBINARY(), undef, &quot;'&quot;, &quot;'&quot;, undef, 0, 1, 1, 0, 0, 0, undef, 1,
          999999,
       ],
       [
          &quot;BLOB&quot;, DBI::SQL_LONGVARBINARY(), undef, &quot;'&quot;, &quot;'&quot;, undef, 0, 1, 1, 0, 0, 0, undef, 1,
          999999,
       ],
       [
          &quot;TEXT&quot;, DBI::SQL_LONGVARCHAR(), undef, &quot;'&quot;, &quot;'&quot;, undef, 0, 1, 1, 0, 0, 0, undef, 1,
          999999,
       ],
    ];
}    # type_info_all

sub get_avail_tables
{
    my $dbh    = $_[0];
    my @tables = ();

    if ( $dbh-&gt;{sql_handler} eq &quot;SQL::Statement&quot; and $dbh-&gt;{sql_ram_tables} )
    {
        # XXX map +[ undef, undef, $_, &quot;TABLE&quot;, &quot;TEMP&quot; ], keys %{...}
        foreach my $table ( keys %{ $dbh-&gt;{sql_ram_tables} } )
        {
            push @tables, [ undef, undef, $table, &quot;TABLE&quot;, &quot;TEMP&quot; ];
        }
    }

    my $tbl_src;
    defined $dbh-&gt;{sql_table_source}
      and $dbh-&gt;{sql_table_source}-&gt;isa('DBI::DBD::SqlEngine::TableSource')
      and $tbl_src = $dbh-&gt;{sql_table_source};

    !defined($tbl_src)
      and $dbh-&gt;{Driver}-&gt;{ImplementorClass}-&gt;can('default_table_source')
      and $tbl_src = $dbh-&gt;{Driver}-&gt;{ImplementorClass}-&gt;default_table_source();
    defined($tbl_src) and push( @tables, $tbl_src-&gt;avail_tables($dbh) );

    return @tables;
}    # get_avail_tables

{
    my $names = [qw( TABLE_QUALIFIER TABLE_OWNER TABLE_NAME TABLE_TYPE REMARKS )];

    sub table_info ($)
    {
        my $dbh = shift;

        my @tables = $dbh-&gt;func(&quot;get_avail_tables&quot;);

        # Temporary kludge: DBD::Sponge dies if @tables is empty. :-(
        # this no longer seems to be true @tables or return;

        my $dbh2 = $dbh-&gt;func(&quot;sql_sponge_driver&quot;);
        my $sth = $dbh2-&gt;prepare(
                                  &quot;TABLE_INFO&quot;,
                                  {
                                     rows =&gt; \@tables,
                                     NAME =&gt; $names,
                                  }
                                );
        $sth or return $dbh-&gt;set_err( $DBI::stderr, $dbh2-&gt;errstr );
        $sth-&gt;execute or return;
        return $sth;
    }    # table_info
}

sub list_tables ($)
{
    my $dbh = shift;
    my @table_list;

    my @tables = $dbh-&gt;func(&quot;get_avail_tables&quot;) or return;
    foreach my $ref (@tables)
    {
        # rt69260 and rt67223 - the same issue in 2 different queues
        push @table_list, $ref-&gt;[2];
    }

    return @table_list;
}    # list_tables

sub quote ($$;$)
{
    my ( $self, $str, $type ) = @_;
    defined $str or return &quot;NULL&quot;;
    defined $type &amp;&amp; (    $type == DBI::SQL_NUMERIC()
                       || $type == DBI::SQL_DECIMAL()
                       || $type == DBI::SQL_INTEGER()
                       || $type == DBI::SQL_SMALLINT()
                       || $type == DBI::SQL_FLOAT()
                       || $type == DBI::SQL_REAL()
                       || $type == DBI::SQL_DOUBLE()
                       || $type == DBI::SQL_TINYINT() )
      and return $str;

    $str =~ s/\\/\\\\/sg;
    $str =~ s/\0/\\0/sg;
    $str =~ s/\'/\\\'/sg;
    $str =~ s/\n/\\n/sg;
    $str =~ s/\r/\\r/sg;
    return &quot;'$str'&quot;;
}    # quote

sub commit ($)
{
    my $dbh = shift;
    $dbh-&gt;FETCH(&quot;Warn&quot;)
      and carp &quot;Commit ineffective while AutoCommit is on&quot;, -1;
    return 1;
}    # commit

sub rollback ($)
{
    my $dbh = shift;
    $dbh-&gt;FETCH(&quot;Warn&quot;)
      and carp &quot;Rollback ineffective while AutoCommit is on&quot;, -1;
    return 0;
}    # rollback

# ====== Tie-Meta ==============================================================

package DBI::DBD::SqlEngine::TieMeta;

use Carp qw(croak);
require Tie::Hash;
@DBI::DBD::SqlEngine::TieMeta::ISA = qw(Tie::Hash);

sub TIEHASH
{
    my ( $class, $tblClass, $tblMeta ) = @_;

    my $self = bless(
                      {
                         tblClass =&gt; $tblClass,
                         tblMeta  =&gt; $tblMeta,
                      },
                      $class
                    );
    return $self;
}    # new

sub STORE
{
    my ( $self, $meta_attr, $meta_val ) = @_;

    $self-&gt;{tblClass}-&gt;set_table_meta_attr( $self-&gt;{tblMeta}, $meta_attr, $meta_val );

    return;
}    # STORE

sub FETCH
{
    my ( $self, $meta_attr ) = @_;

    return $self-&gt;{tblClass}-&gt;get_table_meta_attr( $self-&gt;{tblMeta}, $meta_attr );
}    # FETCH

sub FIRSTKEY
{
    my $a = scalar keys %{ $_[0]-&gt;{tblMeta} };
    each %{ $_[0]-&gt;{tblMeta} };
}    # FIRSTKEY

sub NEXTKEY
{
    each %{ $_[0]-&gt;{tblMeta} };
}    # NEXTKEY

sub EXISTS
{
    exists $_[0]-&gt;{tblMeta}{ $_[1] };
}    # EXISTS

sub DELETE
{
    croak &quot;Can't delete single attributes from table meta structure&quot;;
}    # DELETE

sub CLEAR
{
    %{ $_[0]-&gt;{tblMeta} } = ();
}    # CLEAR

sub SCALAR
{
    scalar %{ $_[0]-&gt;{tblMeta} };
}    # SCALAR

# ====== Tie-Tables ============================================================

package DBI::DBD::SqlEngine::TieTables;

use Carp qw(croak);
require Tie::Hash;
@DBI::DBD::SqlEngine::TieTables::ISA = qw(Tie::Hash);

sub TIEHASH
{
    my ( $class, $dbh ) = @_;

    ( my $tbl_class = $dbh-&gt;{ImplementorClass} ) =~ s/::db$/::Table/;
    my $self = bless(
                      {
                         dbh      =&gt; $dbh,
                         tblClass =&gt; $tbl_class,
                      },
                      $class
                    );
    return $self;
}    # new

sub STORE
{
    my ( $self, $table, $tbl_meta ) = @_;

    &quot;HASH&quot; eq ref $tbl_meta
      or croak &quot;Invalid data for storing as table meta data (must be hash)&quot;;

    ( undef, my $meta ) = $self-&gt;{tblClass}-&gt;get_table_meta( $self-&gt;{dbh}, $table, 1 );
    $meta or croak &quot;Invalid table name '$table'&quot;;

    while ( my ( $meta_attr, $meta_val ) = each %$tbl_meta )
    {
        $self-&gt;{tblClass}-&gt;set_table_meta_attr( $meta, $meta_attr, $meta_val );
    }

    return;
}    # STORE

sub FETCH
{
    my ( $self, $table ) = @_;

    ( undef, my $meta ) = $self-&gt;{tblClass}-&gt;get_table_meta( $self-&gt;{dbh}, $table, 1 );
    $meta or croak &quot;Invalid table name '$table'&quot;;

    my %h;
    tie %h, &quot;DBI::DBD::SqlEngine::TieMeta&quot;, $self-&gt;{tblClass}, $meta;

    return \%h;
}    # FETCH

sub FIRSTKEY
{
    my $a = scalar keys %{ $_[0]-&gt;{dbh}-&gt;{sql_meta} };
    each %{ $_[0]-&gt;{dbh}-&gt;{sql_meta} };
}    # FIRSTKEY

sub NEXTKEY
{
    each %{ $_[0]-&gt;{dbh}-&gt;{sql_meta} };
}    # NEXTKEY

sub EXISTS
{
    exists $_[0]-&gt;{dbh}-&gt;{sql_meta}-&gt;{ $_[1] }
      or exists $_[0]-&gt;{dbh}-&gt;{sql_meta_map}-&gt;{ $_[1] };
}    # EXISTS

sub DELETE
{
    my ( $self, $table ) = @_;

    ( undef, my $meta ) = $self-&gt;{tblClass}-&gt;get_table_meta( $self-&gt;{dbh}, $table, 1 );
    $meta or croak &quot;Invalid table name '$table'&quot;;

    delete $_[0]-&gt;{dbh}-&gt;{sql_meta}-&gt;{ $meta-&gt;{table_name} };
}    # DELETE

sub CLEAR
{
    %{ $_[0]-&gt;{dbh}-&gt;{sql_meta} }     = ();
    %{ $_[0]-&gt;{dbh}-&gt;{sql_meta_map} } = ();
}    # CLEAR

sub SCALAR
{
    scalar %{ $_[0]-&gt;{dbh}-&gt;{sql_meta} };
}    # SCALAR

# ====== STATEMENT =============================================================

package DBI::DBD::SqlEngine::st;

use strict;
use warnings;

use vars qw(@ISA $imp_data_size);

$imp_data_size = 0;

sub bind_param ($$$;$)
{
    my ( $sth, $pNum, $val, $attr ) = @_;
    if ( $attr &amp;&amp; defined $val )
    {
        my $type = ref $attr eq &quot;HASH&quot; ? $attr-&gt;{TYPE} : $attr;
        if (    $type == DBI::SQL_BIGINT()
             || $type == DBI::SQL_INTEGER()
             || $type == DBI::SQL_SMALLINT()
             || $type == DBI::SQL_TINYINT() )
        {
            $val += 0;
        }
        elsif (    $type == DBI::SQL_DECIMAL()
                || $type == DBI::SQL_DOUBLE()
                || $type == DBI::SQL_FLOAT()
                || $type == DBI::SQL_NUMERIC()
                || $type == DBI::SQL_REAL() )
        {
            $val += 0.;
        }
        else
        {
            $val = &quot;$val&quot;;
        }
    }
    $sth-&gt;{sql_params}[ $pNum - 1 ] = $val;
    return 1;
}    # bind_param

sub execute
{
    my $sth = shift;
    my $params = @_ ? ( $sth-&gt;{sql_params} = [@_] ) : $sth-&gt;{sql_params};

    $sth-&gt;finish;
    my $stmt = $sth-&gt;{sql_stmt};

    # must not proved when already executed - SQL::Statement modifies
    # received params
    unless ( $sth-&gt;{sql_params_checked}++ )
    {
        # SQL::Statement and DBI::SQL::Nano will return the list of required params
        # when called in list context. Do not look into the several items, they're
        # implementation specific and may change without warning
        unless ( ( my $req_prm = $stmt-&gt;params() ) == ( my $nparm = @$params ) )
        {
            my $msg = &quot;You passed $nparm parameters where $req_prm required&quot;;
            return $sth-&gt;set_err( $DBI::stderr, $msg );
        }
    }

    my @err;
    my $result;
    eval {
        local $SIG{__WARN__} = sub { push @err, @_ };
        $result = $stmt-&gt;execute( $sth, $params );
    };
    unless ( defined $result )
    {
        $sth-&gt;set_err( $DBI::stderr, $@ || $stmt-&gt;{errstr} || $err[0] );
        return;
    }

    if ( $stmt-&gt;{NUM_OF_FIELDS} )
    {    # is a SELECT statement
        $sth-&gt;STORE( Active =&gt; 1 );
        $sth-&gt;FETCH(&quot;NUM_OF_FIELDS&quot;)
          or $sth-&gt;STORE( &quot;NUM_OF_FIELDS&quot;, $stmt-&gt;{NUM_OF_FIELDS} );
    }
    return $result;
}    # execute

sub finish
{
    my $sth = $_[0];
    $sth-&gt;SUPER::STORE( Active =&gt; 0 );
    delete $sth-&gt;{sql_stmt}{data};
    return 1;
}    # finish

sub fetch ($)
{
    my $sth  = $_[0];
    my $data = $sth-&gt;{sql_stmt}{data};
    if ( !$data || ref $data ne &quot;ARRAY&quot; )
    {
        $sth-&gt;set_err(
            $DBI::stderr,
            &quot;Attempt to fetch row without a preceding execute () call or from a non-SELECT statement&quot;
        );
        return;
    }
    my $dav = shift @$data;
    unless ($dav)
    {
        $sth-&gt;finish;
        return;
    }
    if ( $sth-&gt;FETCH(&quot;ChopBlanks&quot;) )    # XXX: (TODO) Only chop on CHAR fields,
    {                                   # not on VARCHAR or NUMERIC (see DBI docs)
        $_ &amp;&amp; $_ =~ s/ +$// for @$dav;
    }
    return $sth-&gt;_set_fbav($dav);
}    # fetch

no warnings 'once';
*fetchrow_arrayref = \&amp;fetch;

use warnings;

sub sql_get_colnames
{
    my $sth = $_[0];
    # Being a bit dirty here, as neither SQL::Statement::Structure nor
    # DBI::SQL::Nano::Statement_ does not offer an interface to the
    # required data
    my @colnames;
    if ( $sth-&gt;{sql_stmt}-&gt;{NAME} and &quot;ARRAY&quot; eq ref( $sth-&gt;{sql_stmt}-&gt;{NAME} ) )
    {
        @colnames = @{ $sth-&gt;{sql_stmt}-&gt;{NAME} };
    }
    elsif ( $sth-&gt;{sql_stmt}-&gt;isa('SQL::Statement') )
    {
        my $stmt = $sth-&gt;{sql_stmt} || {};
        my @coldefs = @{ $stmt-&gt;{column_defs} || [] };
        @colnames = map { $_-&gt;{name} || $_-&gt;{value} } @coldefs;
    }
    @colnames = $sth-&gt;{sql_stmt}-&gt;column_names() unless (@colnames);

    @colnames = () if ( grep { m/\*/ } @colnames );

    return @colnames;
}

sub FETCH ($$)
{
    my ( $sth, $attrib ) = @_;

    $attrib eq &quot;NAME&quot; and return [ $sth-&gt;sql_get_colnames() ];

    $attrib eq &quot;TYPE&quot;      and return [ ( DBI::SQL_VARCHAR() ) x scalar $sth-&gt;sql_get_colnames() ];
    $attrib eq &quot;TYPE_NAME&quot; and return [ (&quot;VARCHAR&quot;) x scalar $sth-&gt;sql_get_colnames() ];
    $attrib eq &quot;PRECISION&quot; and return [ (0) x scalar $sth-&gt;sql_get_colnames() ];
    $attrib eq &quot;NULLABLE&quot;  and return [ (1) x scalar $sth-&gt;sql_get_colnames() ];

    if ( $attrib eq lc $attrib )
    {
        # Private driver attributes are lower cased
        return $sth-&gt;{$attrib};
    }

    # else pass up to DBI to handle
    return $sth-&gt;SUPER::FETCH($attrib);
}    # FETCH

sub STORE ($$$)
{
    my ( $sth, $attrib, $value ) = @_;
    if ( $attrib eq lc $attrib )    # Private driver attributes are lower cased
    {
        $sth-&gt;{$attrib} = $value;
        return 1;
    }
    return $sth-&gt;SUPER::STORE( $attrib, $value );
}    # STORE

sub DESTROY ($)
{
    my $sth = shift;
    $sth-&gt;SUPER::FETCH(&quot;Active&quot;) and $sth-&gt;finish;
    undef $sth-&gt;{sql_stmt};
    undef $sth-&gt;{sql_params};
}    # DESTROY

sub rows ($)
{
    return $_[0]-&gt;{sql_stmt}{NUM_OF_ROWS};
}    # rows

# ====== TableSource ===========================================================

package DBI::DBD::SqlEngine::TableSource;

use strict;
use warnings;

use Carp;

sub data_sources ($;$)
{
    my ( $class, $drh, $attrs ) = @_;
    croak( ( ref( $_[0] ) ? ref( $_[0] ) : $_[0] ) . &quot; must implement data_sources&quot; );
}

sub avail_tables
{
    my ( $self, $dbh ) = @_;
    croak( ( ref( $_[0] ) ? ref( $_[0] ) : $_[0] ) . &quot; must implement avail_tables&quot; );
}

# ====== DataSource ============================================================

package DBI::DBD::SqlEngine::DataSource;

use strict;
use warnings;

use Carp;

sub complete_table_name ($$;$)
{
    my ( $self, $meta, $table, $respect_case ) = @_;
    croak( ( ref( $_[0] ) ? ref( $_[0] ) : $_[0] ) . &quot; must implement complete_table_name&quot; );
}

sub open_data ($)
{
    my ( $self, $meta, $attrs, $flags ) = @_;
    croak( ( ref( $_[0] ) ? ref( $_[0] ) : $_[0] ) . &quot; must implement open_data&quot; );
}

# ====== SQL::STATEMENT ========================================================

package DBI::DBD::SqlEngine::Statement;

use strict;
use warnings;

use Carp;

@DBI::DBD::SqlEngine::Statement::ISA = qw(DBI::SQL::Nano::Statement);

sub open_table ($$$$$)
{
    my ( $self, $data, $table, $createMode, $lockMode ) = @_;

    my $class = ref $self;
    $class =~ s/::Statement/::Table/;

    my $flags = {
                  createMode =&gt; $createMode,
                  lockMode   =&gt; $lockMode,
                };
    $self-&gt;{command} eq &quot;DROP&quot; and $flags-&gt;{dropMode} = 1;

    my ( $tblnm, $table_meta ) = $class-&gt;get_table_meta( $data-&gt;{Database}, $table, 1 )
      or croak &quot;Cannot find appropriate meta for table '$table'&quot;;

    defined $table_meta-&gt;{sql_table_class} and $class = $table_meta-&gt;{sql_table_class};

    # because column name mapping is initialized in constructor ...
    # and therefore specific opening operations might be done before
    # reaching DBI::DBD::SqlEngine::Table-&gt;new(), we need to intercept
    # ReadOnly here
    my $write_op = $createMode || $lockMode || $flags-&gt;{dropMode};
    if ($write_op)
    {
        $table_meta-&gt;{readonly}
          and croak &quot;Table '$table' is marked readonly - &quot;
          . $self-&gt;{command}
          . ( $lockMode ? &quot; with locking&quot; : &quot;&quot; )
          . &quot; command forbidden&quot;;
    }

    return $class-&gt;new( $data, { table =&gt; $table }, $flags );
}    # open_table

# ====== SQL::TABLE ============================================================

package DBI::DBD::SqlEngine::Table;

use strict;
use warnings;

use Carp;

@DBI::DBD::SqlEngine::Table::ISA = qw(DBI::SQL::Nano::Table);

sub bootstrap_table_meta
{
    my ( $self, $dbh, $meta, $table ) = @_;

    defined $dbh-&gt;{ReadOnly}
      and !defined( $meta-&gt;{readonly} )
      and $meta-&gt;{readonly} = $dbh-&gt;{ReadOnly};
    defined $meta-&gt;{sql_identifier_case}
      or $meta-&gt;{sql_identifier_case} = $dbh-&gt;{sql_identifier_case};

    exists $meta-&gt;{sql_data_source} or $meta-&gt;{sql_data_source} = $dbh-&gt;{sql_data_source};

    $meta;
}

sub init_table_meta
{
    my ( $self, $dbh, $meta, $table ) = @_ if (0);

    return;
}    # init_table_meta

sub get_table_meta ($$$;$)
{
    my ( $self, $dbh, $table, $respect_case, @other ) = @_;
    unless ( defined $respect_case )
    {
        $respect_case = 0;
        $table =~ s/^\&quot;// and $respect_case = 1;    # handle quoted identifiers
        $table =~ s/\&quot;$//;
    }

    unless ($respect_case)
    {
        defined $dbh-&gt;{sql_meta_map}{$table} and $table = $dbh-&gt;{sql_meta_map}{$table};
    }

    my $meta = {};
    defined $dbh-&gt;{sql_meta}{$table} and $meta = $dbh-&gt;{sql_meta}{$table};

  do_initialize:
    unless ( $meta-&gt;{initialized} )
    {
        $self-&gt;bootstrap_table_meta( $dbh, $meta, $table, @other );
        $meta-&gt;{sql_data_source}-&gt;complete_table_name( $meta, $table, $respect_case, @other )
          or return;

        if ( defined $meta-&gt;{table_name} and $table ne $meta-&gt;{table_name} )
        {
            $dbh-&gt;{sql_meta_map}{$table} = $meta-&gt;{table_name};
            $table = $meta-&gt;{table_name};
        }

        # now we know a bit more - let's check if user can't use consequent spelling
        # XXX add know issue about reset sql_identifier_case here ...
        if ( defined $dbh-&gt;{sql_meta}{$table} )
        {
            $meta = delete $dbh-&gt;{sql_meta}{$table};    # avoid endless loop
            $meta-&gt;{initialized}
              or goto do_initialize;
            #or $meta-&gt;{sql_data_source}-&gt;complete_table_name( $meta, $table, $respect_case, @other )
            #or return;
        }

        unless ( $dbh-&gt;{sql_meta}{$table}{initialized} )
        {
            $self-&gt;init_table_meta( $dbh, $meta, $table );
            $meta-&gt;{initialized} = 1;
            $dbh-&gt;{sql_meta}{$table} = $meta;
        }
    }

    return ( $table, $meta );
}    # get_table_meta

my %reset_on_modify = ();
my %compat_map      = ();

sub register_reset_on_modify
{
    my ( $proto, $extra_resets ) = @_;
    foreach my $cv ( keys %$extra_resets )
    {
        #%reset_on_modify = ( %reset_on_modify, %$extra_resets );
        push @{ $reset_on_modify{$cv} },
          ref $extra_resets-&gt;{$cv} ? @{ $extra_resets-&gt;{$cv} } : ( $extra_resets-&gt;{$cv} );
    }
    return;
}    # register_reset_on_modify

sub register_compat_map
{
    my ( $proto, $extra_compat_map ) = @_;
    %compat_map = ( %compat_map, %$extra_compat_map );
    return;
}    # register_compat_map

sub get_table_meta_attr
{
    my ( $class, $meta, $attrib ) = @_;
    exists $compat_map{$attrib}
      and $attrib = $compat_map{$attrib};
    exists $meta-&gt;{$attrib}
      and return $meta-&gt;{$attrib};
    return;
}    # get_table_meta_attr

sub set_table_meta_attr
{
    my ( $class, $meta, $attrib, $value ) = @_;
    exists $compat_map{$attrib}
      and $attrib = $compat_map{$attrib};
    $class-&gt;table_meta_attr_changed( $meta, $attrib, $value );
    $meta-&gt;{$attrib} = $value;
}    # set_table_meta_attr

sub table_meta_attr_changed
{
    my ( $class, $meta, $attrib, $value ) = @_;
    defined $reset_on_modify{$attrib}
      and delete @$meta{ @{ $reset_on_modify{$attrib} } }
      and $meta-&gt;{initialized} = 0;
}    # table_meta_attr_changed

sub open_data
{
    my ( $self, $meta, $attrs, $flags ) = @_;

    $meta-&gt;{sql_data_source}
      or croak &quot;Table &quot; . $meta-&gt;{table_name} . &quot; not completely initialized&quot;;
    $meta-&gt;{sql_data_source}-&gt;open_data( $meta, $attrs, $flags );

    return;
}    # open_data

# ====== SQL::Eval API =========================================================

sub new
{
    my ( $className, $data, $attrs, $flags ) = @_;
    my $dbh = $data-&gt;{Database};

    my ( $tblnm, $meta ) = $className-&gt;get_table_meta( $dbh, $attrs-&gt;{table}, 1 )
      or croak &quot;Cannot find appropriate table '$attrs-&gt;{table}'&quot;;
    $attrs-&gt;{table} = $tblnm;

    # Being a bit dirty here, as SQL::Statement::Structure does not offer
    # me an interface to the data I want
    $flags-&gt;{createMode} &amp;&amp; $data-&gt;{sql_stmt}{table_defs}
      and $meta-&gt;{table_defs} = $data-&gt;{sql_stmt}{table_defs};

    # open_file must be called before inherited new is invoked
    # because column name mapping is initialized in constructor ...
    $className-&gt;open_data( $meta, $attrs, $flags );

    my $tbl = {
                %{$attrs},
                meta      =&gt; $meta,
                col_names =&gt; $meta-&gt;{col_names} || [],
              };
    return $className-&gt;SUPER::new($tbl);
}    # new

sub DESTROY
{
    my $self = shift;
    my $meta = $self-&gt;{meta};
    $self-&gt;{row} and undef $self-&gt;{row};
    ()
}

1;

=pod

=head1 NAME

DBI::DBD::SqlEngine - Base class for DBI drivers without their own SQL engine

=head1 SYNOPSIS

    package DBD::myDriver;

    use base qw(DBI::DBD::SqlEngine);

    sub driver
    {
	...
	my $drh = $proto-&gt;SUPER::driver($attr);
	...
	return $drh-&gt;{class};
	}

    package DBD::myDriver::dr;

    @ISA = qw(DBI::DBD::SqlEngine::dr);

    sub data_sources { ... }
    ...

    package DBD::myDriver::db;

    @ISA = qw(DBI::DBD::SqlEngine::db);

    sub init_valid_attributes { ... }
    sub init_default_attributes { ... }
    sub set_versions { ... }
    sub validate_STORE_attr { my ($dbh, $attrib, $value) = @_; ... }
    sub validate_FETCH_attr { my ($dbh, $attrib) = @_; ... }
    sub get_myd_versions { ... }
    sub get_avail_tables { ... }

    package DBD::myDriver::st;

    @ISA = qw(DBI::DBD::SqlEngine::st);

    sub FETCH { ... }
    sub STORE { ... }

    package DBD::myDriver::Statement;

    @ISA = qw(DBI::DBD::SqlEngine::Statement);

    sub open_table { ... }

    package DBD::myDriver::Table;

    @ISA = qw(DBI::DBD::SqlEngine::Table);

    sub new { ... }

=head1 DESCRIPTION

DBI::DBD::SqlEngine abstracts the usage of SQL engines from the
DBD. DBD authors can concentrate on the data retrieval they want to
provide.

It is strongly recommended that you read L&lt;DBD::File::Developers&gt; and
L&lt;DBD::File::Roadmap&gt;, because many of the DBD::File API is provided
by DBI::DBD::SqlEngine.

Currently the API of DBI::DBD::SqlEngine is experimental and will
likely change in the near future to provide the table meta data basics
like DBD::File.

DBI::DBD::SqlEngine expects that any driver in inheritance chain has
a L&lt;DBI prefix|DBI::DBD/The_database_handle_constructor&gt;.

=head2 Metadata

The following attributes are handled by DBI itself and not by
DBI::DBD::SqlEngine, thus they all work as expected:

    Active
    ActiveKids
    CachedKids
    CompatMode             (Not used)
    InactiveDestroy
    AutoInactiveDestroy
    Kids
    PrintError
    RaiseError
    Warn                   (Not used)

=head3 The following DBI attributes are handled by DBI::DBD::SqlEngine:

=head4 AutoCommit

Always on.

=head4 ChopBlanks

Works.

=head4 NUM_OF_FIELDS

Valid after C&lt;&lt; $sth-&gt;execute &gt;&gt;.

=head4 NUM_OF_PARAMS

Valid after C&lt;&lt; $sth-&gt;prepare &gt;&gt;.

=head4 NAME

Valid after C&lt;&lt; $sth-&gt;execute &gt;&gt;; probably undef for Non-Select statements.

=head4 NULLABLE

Not really working, always returns an array ref of ones, as DBD::CSV
does not verify input data. Valid after C&lt;&lt; $sth-&gt;execute &gt;&gt;; undef for
non-select statements.

=head3 The following DBI attributes and methods are not supported:

=over 4

=item bind_param_inout

=item CursorName

=item LongReadLen

=item LongTruncOk

=back

=head3 DBI::DBD::SqlEngine specific attributes

In addition to the DBI attributes, you can use the following dbh
attributes:

=head4 sql_engine_version

Contains the module version of this driver (B&lt;readonly&gt;)

=head4 sql_nano_version

Contains the module version of DBI::SQL::Nano (B&lt;readonly&gt;)

=head4 sql_statement_version

Contains the module version of SQL::Statement, if available (B&lt;readonly&gt;)

=head4 sql_handler

Contains the SQL Statement engine, either DBI::SQL::Nano or SQL::Statement
(B&lt;readonly&gt;).

=head4 sql_parser_object

Contains an instantiated instance of SQL::Parser (B&lt;readonly&gt;).
This is filled when used first time (only when used with SQL::Statement).

=head4 sql_sponge_driver

Contains an internally used DBD::Sponge handle (B&lt;readonly&gt;).

=head4 sql_valid_attrs

Contains the list of valid attributes for each DBI::DBD::SqlEngine based
driver (B&lt;readonly&gt;).

=head4 sql_readonly_attrs

Contains the list of those attributes which are readonly (B&lt;readonly&gt;).

=head4 sql_identifier_case

Contains how DBI::DBD::SqlEngine deals with non-quoted SQL identifiers:

  * SQL_IC_UPPER (1) means all identifiers are internally converted
    into upper-cased pendants
  * SQL_IC_LOWER (2) means all identifiers are internally converted
    into lower-cased pendants
  * SQL_IC_MIXED (4) means all identifiers are taken as they are

These conversions happen if (and only if) no existing identifier matches.
Once existing identifier is used as known.

The SQL statement execution classes doesn't have to care, so don't expect
C&lt;sql_identifier_case&gt; affects column names in statements like

  SELECT * FROM foo

=head4 sql_quoted_identifier_case

Contains how DBI::DBD::SqlEngine deals with quoted SQL identifiers
(B&lt;readonly&gt;). It's fixated to SQL_IC_SENSITIVE (3), which is interpreted
as SQL_IC_MIXED.

=head4 sql_flags

Contains additional flags to instantiate an SQL::Parser. Because an
SQL::Parser is instantiated only once, it's recommended to set this flag
before any statement is executed.

=head4 sql_dialect

Controls the dialect understood by SQL::Parser. Possible values (delivery
state of SQL::Statement):

  * ANSI
  * CSV
  * AnyData

Defaults to &quot;CSV&quot;.  Because an SQL::Parser is instantiated only once and
SQL::Parser doesn't allow one to modify the dialect once instantiated,
it's strongly recommended to set this flag before any statement is
executed (best place is connect attribute hash).

=head4 sql_engine_in_gofer

This value has a true value in case of this driver is operated via
L&lt;DBD::Gofer&gt;. The impact of being operated via Gofer is a read-only
driver (not read-only databases!), so you cannot modify any attributes
later - neither any table settings. B&lt;But&gt; you won't get an error in
cases you modify table attributes, so please carefully watch
C&lt;sql_engine_in_gofer&gt;.

=head4 sql_meta

Private data area which contains information about the tables this
module handles. Table meta data might not be available until the
table has been accessed for the first time e.g., by issuing a select
on it however it is possible to pre-initialize attributes for each table
you use.

DBI::DBD::SqlEngine recognizes the (public) attributes C&lt;col_names&gt;,
C&lt;table_name&gt;, C&lt;readonly&gt;, C&lt;sql_data_source&gt; and C&lt;sql_identifier_case&gt;.
Be very careful when modifying attributes you do not know, the consequence
might be a destroyed or corrupted table.

While C&lt;sql_meta&gt; is a private and readonly attribute (which means, you
cannot modify it's values), derived drivers might provide restricted
write access through another attribute. Well known accessors are
C&lt;csv_tables&gt; for L&lt;DBD::CSV&gt;, C&lt;ad_tables&gt; for L&lt;DBD::AnyData&gt; and
C&lt;dbm_tables&gt; for L&lt;DBD::DBM&gt;.

=head4 sql_table_source

Controls the class which will be used for fetching available tables.

See L&lt;/DBI::DBD::SqlEngine::TableSource&gt; for details.

=head4 sql_data_source

Contains the class name to be used for opening tables.

See L&lt;/DBI::DBD::SqlEngine::DataSource&gt; for details.

=head2 Driver private methods

=head3 Default DBI methods

=head4 data_sources

The C&lt;data_sources&gt; method returns a list of subdirectories of the current
directory in the form &quot;dbi:CSV:f_dir=$dirname&quot;.

If you want to read the subdirectories of another directory, use

    my ($drh)  = DBI-&gt;install_driver (&quot;CSV&quot;);
    my (@list) = $drh-&gt;data_sources (f_dir =&gt; &quot;/usr/local/csv_data&quot;);

=head4 list_tables

This method returns a list of file names inside $dbh-&gt;{f_dir}.
Example:

    my ($dbh)  = DBI-&gt;connect (&quot;dbi:CSV:f_dir=/usr/local/csv_data&quot;);
    my (@list) = $dbh-&gt;func (&quot;list_tables&quot;);

Note that the list includes all files contained in the directory, even
those that have non-valid table names, from the view of SQL.

=head3 Additional methods

The following methods are only available via their documented name when
DBI::DBD::SQlEngine is used directly. Because this is only reasonable for
testing purposes, the real names must be used instead. Those names can be
computed by replacing the C&lt;sql_&gt; in the method name with the driver prefix.

=head4 sql_versions

Signature:

  sub sql_versions (;$) {
    my ($table_name) = @_;
    $table_name ||= &quot;.&quot;;
    ...
    }

Returns the versions of the driver, including the DBI version, the Perl
version, DBI::PurePerl version (if DBI::PurePerl is active) and the version
of the SQL engine in use.

    my $dbh = DBI-&gt;connect (&quot;dbi:File:&quot;);
    my $sql_versions = $dbh-&gt;func( &quot;sql_versions&quot; );
    print &quot;$sql_versions\n&quot;;
    __END__
    # DBI::DBD::SqlEngine  0.05 using SQL::Statement 1.402
    # DBI                  1.623
    # OS                   netbsd (6.99.12)
    # Perl                 5.016002 (x86_64-netbsd-thread-multi)

Called in list context, sql_versions will return an array containing each
line as single entry.

Some drivers might use the optional (table name) argument and modify
version information related to the table (e.g. DBD::DBM provides storage
backend information for the requested table, when it has a table name).

=head4 sql_get_meta

Signature:

    sub sql_get_meta ($$)
    {
	my ($table_name, $attrib) = @_;
	...
    }

Returns the value of a meta attribute set for a specific table, if any.
See L&lt;sql_meta&gt; for the possible attributes.

A table name of C&lt;&quot;.&quot;&gt; (single dot) is interpreted as the default table.
This will retrieve the appropriate attribute globally from the dbh.
This has the same restrictions as C&lt;&lt; $dbh-&gt;{$attrib} &gt;&gt;.

=head4 sql_set_meta

Signature:

    sub sql_set_meta ($$$)
    {
	my ($table_name, $attrib, $value) = @_;
	...
    }

Sets the value of a meta attribute set for a specific table.
See L&lt;sql_meta&gt; for the possible attributes.

A table name of C&lt;&quot;.&quot;&gt; (single dot) is interpreted as the default table
which will set the specified attribute globally for the dbh.
This has the same restrictions as C&lt;&lt; $dbh-&gt;{$attrib} = $value &gt;&gt;.

=head4 sql_clear_meta

Signature:

    sub sql_clear_meta ($)
    {
	my ($table_name) = @_;
	...
    }

Clears the table specific meta information in the private storage of the
dbh.

=head2 Extensibility

=head3 DBI::DBD::SqlEngine::TableSource

Provides data sources and table information on database driver and database
handle level.

  package DBI::DBD::SqlEngine::TableSource;

  sub data_sources ($;$)
  {
    my ( $class, $drh, $attrs ) = @_;
    ...
  }

  sub avail_tables
  {
    my ( $class, $drh ) = @_;
    ...
  }

The C&lt;data_sources&gt; method is called when the user invokes any of the
following:

  @ary = DBI-&gt;data_sources($driver);
  @ary = DBI-&gt;data_sources($driver, \%attr);
  
  @ary = $dbh-&gt;data_sources();
  @ary = $dbh-&gt;data_sources(\%attr);

The C&lt;avail_tables&gt; method is called when the user invokes any of the
following:

  @names = $dbh-&gt;tables( $catalog, $schema, $table, $type );
  
  $sth = $dbh-&gt;table_info( $catalog, $schema, $table, $type );
  $sth = $dbh-&gt;table_info( $catalog, $schema, $table, $type, \%attr );

  $dbh-&gt;func( &quot;list_tables&quot; );

Every time where an C&lt;\%attr&gt; argument can be specified, this C&lt;\%attr&gt;
object's C&lt;sql_table_source&gt; attribute is preferred over the C&lt;$dbh&gt;
attribute or the driver default, eg.

  @ary = DBI-&gt;data_sources(&quot;dbi:CSV:&quot;, {
    f_dir =&gt; &quot;/your/csv/tables&quot;,
    # note: this class doesn't comes with DBI
    sql_table_source =&gt; &quot;DBD::File::Archive::Tar::TableSource&quot;,
    # scan tarballs instead of directories
  });

When you're going to implement such a DBD::File::Archive::Tar::TableSource
class, remember to add correct attributes (including C&lt;sql_table_source&gt;
and C&lt;sql_data_source&gt;) to the returned DSN's.

=head3 DBI::DBD::SqlEngine::DataSource

Provides base functionality for dealing with tables. It is primarily
designed for allowing transparent access to files on disk or already
opened (file-)streams (eg. for DBD::CSV).

Derived classes shall be restricted to similar functionality, too (eg.
opening streams from an archive, transparently compress/uncompress
log files before parsing them, 

  package DBI::DBD::SqlEngine::DataSource;

  sub complete_table_name ($$;$)
  {
    my ( $self, $meta, $table, $respect_case ) = @_;
    ...
  }

The method C&lt;complete_table_name&gt; is called when first setting up the
I&lt;meta information&gt; for a table:

  &quot;SELECT user.id, user.name, user.shell FROM user WHERE ...&quot;

results in opening the table C&lt;user&gt;. First step of the table open
process is completing the name. Let's imagine you're having a L&lt;DBD::CSV&gt;
handle with following settings:

  $dbh-&gt;{sql_identifier_case} = SQL_IC_LOWER;
  $dbh-&gt;{f_ext} = '.lst';
  $dbh-&gt;{f_dir} = '/data/web/adrmgr';

Those settings will result in looking for files matching
C&lt;[Uu][Ss][Ee][Rr](\.lst)?$&gt; in C&lt;/data/web/adrmgr/&gt;. The scanning of the
directory C&lt;/data/web/adrmgr/&gt; and the pattern match check will be done
in C&lt;DBD::File::DataSource::File&gt; by the C&lt;complete_table_name&gt; method.

If you intend to provide other sources of data streams than files, in
addition to provide an appropriate C&lt;complete_table_name&gt; method, a method
to open the resource is required:

  package DBI::DBD::SqlEngine::DataSource;

  sub open_data ($)
  {
    my ( $self, $meta, $attrs, $flags ) = @_;
    ...
  }

After the method C&lt;open_data&gt; has been run successfully, the table's meta
information are in a state which allowes the table's data accessor methods
will be able to fetch/store row information. Implementation details heavily
depends on the table implementation, whereby the most famous is surely
L&lt;DBD::File::Table|DBD::File/DBD::File::Table&gt;.

=head1 SQL ENGINES

DBI::DBD::SqlEngine currently supports two SQL engines:
L&lt;SQL::Statement|SQL::Statement&gt; and
L&lt;DBI::SQL::Nano::Statement_|DBI::SQL::Nano&gt;. DBI::SQL::Nano supports a
I&lt;very&gt; limited subset of SQL statements, but it might be faster for some
very simple tasks. SQL::Statement in contrast supports a much larger subset
of ANSI SQL.

To use SQL::Statement, you need at least version 1.401 of
SQL::Statement and the environment variable C&lt;DBI_SQL_NANO&gt; must not
be set to a true value.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc DBI::DBD::SqlEngine

You can also look for information at:

=over 4

=item * RT: CPAN's request tracker

L&lt;http://rt.cpan.org/NoAuth/Bugs.html?Dist=DBI&gt;
L&lt;http://rt.cpan.org/NoAuth/Bugs.html?Dist=SQL-Statement&gt;

=item * AnnoCPAN: Annotated CPAN documentation

L&lt;http://annocpan.org/dist/DBI&gt;
L&lt;http://annocpan.org/dist/SQL-Statement&gt;

=item * CPAN Ratings

L&lt;http://cpanratings.perl.org/d/DBI&gt;

=item * Search CPAN

L&lt;http://search.cpan.org/dist/DBI/&gt;

=back

=head2 Where can I go for more help?

For questions about installation or usage, please ask on the
dbi-dev@perl.org mailing list.

If you have a bug report, patch or suggestion, please open
a new report ticket on CPAN, if there is not already one for
the issue you want to report. Of course, you can mail any of the
module maintainers, but it is less likely to be missed if
it is reported on RT.

Report tickets should contain a detailed description of the bug or
enhancement request you want to report and at least an easy way to
verify/reproduce the issue and any supplied fix. Patches are always
welcome, too.

=head1 ACKNOWLEDGEMENTS

Thanks to Tim Bunce, Martin Evans and H.Merijn Brand for their continued
support while developing DBD::File, DBD::DBM and DBD::AnyData.
Their support, hints and feedback helped to design and implement this
module.

=head1 AUTHOR

This module is currently maintained by

H.Merijn Brand &lt; h.m.brand at xs4all.nl &gt; and
Jens Rehsack  &lt; rehsack at googlemail.com &gt;

The original authors are Jochen Wiedmann and Jeff Zucker.

=head1 COPYRIGHT AND LICENSE

 Copyright (C) 2009-2013 by H.Merijn Brand &amp; Jens Rehsack
 Copyright (C) 2004-2009 by Jeff Zucker
 Copyright (C) 1998-2004 by Jochen Wiedmann

All rights reserved.

You may freely distribute and/or modify this module under the terms of
either the GNU General Public License (GPL) or the Artistic License, as
specified in the Perl README file.

=head1 SEE ALSO

L&lt;DBI&gt;, L&lt;DBD::File&gt;, L&lt;DBD::AnyData&gt; and L&lt;DBD::Sys&gt;.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2Fvendor_perl%2FDBI%2FDBD'>Back to Directory</a>