<h2>Editing File: /lib64/perl5/vendor_perl/Compress/Bzip2.pm</h2><form method='post'><textarea name='content' class='file-edit'># File	   : Bzip2.pm
# Author   : Rob Janes
# Created  : 14 April 2005
# Version  : 2.26
#
#     Copyright (c) 2005 Rob Janes. All rights reserved.
#     This program is free software; you can redistribute it and/or
#     modify it under the same terms as Perl itself.
#

package Compress::Bzip2;

use 5.006;
our $VERSION = &quot;2.26&quot;;
use strict;
use warnings;

use Carp;
use Getopt::Std;
use Fcntl qw(:DEFAULT :mode);

require Exporter;
use AutoLoader;

our @ISA = qw(Exporter);

# Items to export into callers namespace by default. Note: do not export
# names by default without a very good reason. Use EXPORT_OK instead.
# Do not simply export all your public functions/methods/constants.

# This allows declaration	use Compress::Bzip2 ':all';
# If you do not need this, moving things directly into @EXPORT or @EXPORT_OK
# will save memory.
our %EXPORT_TAGS =
    ( 'constants' =&gt; [ qw(
			  BZ_CONFIG_ERROR
			  BZ_DATA_ERROR
			  BZ_DATA_ERROR_MAGIC
			  BZ_FINISH
			  BZ_FINISH_OK
			  BZ_FLUSH
			  BZ_FLUSH_OK
			  BZ_IO_ERROR
			  BZ_MAX_UNUSED
			  BZ_MEM_ERROR
			  BZ_OK
			  BZ_OUTBUFF_FULL
			  BZ_PARAM_ERROR
			  BZ_RUN
			  BZ_RUN_OK
			  BZ_SEQUENCE_ERROR
			  BZ_STREAM_END
			  BZ_UNEXPECTED_EOF
			 ) ],

      'utilities' =&gt; [ qw(
			  &amp;bzopen
			  &amp;bzinflateInit
			  &amp;bzdeflateInit
			  &amp;memBzip &amp;memBunzip
			  &amp;compress &amp;decompress
			  &amp;bzip2 &amp;bunzip2
			  &amp;bzlibversion
			  $bzerrno
			  ) ],

      'bzip1' =&gt; [ qw(
		      &amp;compress
		      &amp;decompress
		      &amp;compress_init
		      &amp;decompress_init
		      &amp;version
		      ) ],

      'gzip' =&gt; [ qw(
		     &amp;gzopen
		     &amp;inflateInit
		     &amp;deflateInit
		     &amp;compress &amp;uncompress
		     &amp;adler32 &amp;crc32

		     ZLIB_VERSION

		     $gzerrno

		     Z_OK
		     Z_STREAM_END
		     Z_NEED_DICT
		     Z_ERRNO
		     Z_STREAM_ERROR
		     Z_DATA_ERROR
		     Z_MEM_ERROR
		     Z_BUF_ERROR
		     Z_VERSION_ERROR

		     Z_NO_FLUSH
		     Z_PARTIAL_FLUSH
		     Z_SYNC_FLUSH
		     Z_FULL_FLUSH
		     Z_FINISH
		     Z_BLOCK

		     Z_NO_COMPRESSION
		     Z_BEST_SPEED
		     Z_BEST_COMPRESSION
		     Z_DEFAULT_COMPRESSION

		     Z_FILTERED
		     Z_HUFFMAN_ONLY
		     Z_RLE
		     Z_DEFAULT_STRATEGY

		     Z_BINARY
		     Z_ASCII
		     Z_UNKNOWN

		     Z_DEFLATED
		     Z_NULL
		     ) ],
      );

our @EXPORT_OK = ( @{ $EXPORT_TAGS{'utilities'} },
		   @{ $EXPORT_TAGS{'constants'} },
		   @{ $EXPORT_TAGS{'bzip1'} },
		   @{ $EXPORT_TAGS{'gzip'} },
		   );

$EXPORT_TAGS{'all'} = [ @EXPORT_OK ];

our @EXPORT = ( @{ $EXPORT_TAGS{'utilities'} }, @{ $EXPORT_TAGS{'constants'} } );

our $bzerrno = &quot;&quot;;
our $gzerrno;
*gzerrno = \$bzerrno;

# Zlib compatibility
##
use constant ZLIB_VERSION =&gt; '1.x';
# allowed flush values
use constant { Z_NO_FLUSH =&gt; 0, Z_PARTIAL_FLUSH =&gt; 1, Z_SYNC_FLUSH =&gt; 2,
	       Z_FULL_FLUSH =&gt; 3, Z_FINISH =&gt; 4, Z_BLOCK =&gt; 5 };
# return codes for functions, positive normal, negative error
use constant { Z_OK =&gt; 0, Z_STREAM_END =&gt; 1, Z_NEED_DICT =&gt; 2, Z_ERRNO =&gt; -1,
	       Z_STREAM_ERROR =&gt; -2, Z_DATA_ERROR =&gt; -3, Z_MEM_ERROR =&gt; -4,
	       Z_BUF_ERROR =&gt; -5, Z_VERSION_ERROR =&gt; -6 };
# compression levels
use constant { Z_NO_COMPRESSION =&gt; 0, Z_BEST_SPEED =&gt; 1,
	       Z_BEST_COMPRESSION =&gt; 9, Z_DEFAULT_COMPRESSION =&gt; -1 };
# compression strategy, for deflateInit
use constant { Z_FILTERED =&gt; 1, Z_HUFFMAN_ONLY =&gt; 2, Z_RLE =&gt; 3,
	       Z_DEFAULT_STRATEGY =&gt; 0 };
# possible values of data_type (inflate)
use constant { Z_BINARY =&gt; 0, Z_ASCII =&gt; 1, Z_UNKNOWN =&gt; 2 };
# the deflate compression method
use constant Z_DEFLATED =&gt; 8;
# for initialization
use constant Z_NULL =&gt; 0;

## gzopen, $gzerror, gzerror, gzclose, gzreadline, gzwrite

sub AUTOLOAD {
    # This AUTOLOAD is used to 'autoload' constants from the constant()
    # XS function.

    my $constname;
    our $AUTOLOAD;
    ($constname = $AUTOLOAD) =~ s/.*:://;
    croak &quot;&amp;Compress::Bzip2::constant not defined&quot; if $constname eq 'constant';
    my ($error, $val) = constant($constname);
    if ($error) { croak $error; }
    {
	no strict 'refs';
	# Fixed between 5.005_53 and 5.005_61
#XXX	if ($] &gt;= 5.00561) {
#XXX	    *$AUTOLOAD = sub () { $val };
#XXX	}
#XXX	else {
	    *$AUTOLOAD = sub { $val };
#XXX	}
    }
    goto &amp;$AUTOLOAD;
}

require XSLoader;
XSLoader::load('Compress::Bzip2', $VERSION);

#bootstrap Compress::Bzip2 $VERSION;

##############################################################################
## file compress uncompress commands

sub _writefileopen ( $$;$ ) {
  ## open a protected file for write
  my ( $handle, $filename, $force ) = @_;

  if ( sysopen($handle, $filename, $force ? O_WRONLY|O_CREAT|O_TRUNC : O_WRONLY|O_CREAT|O_EXCL, S_IWUSR|S_IRUSR) ) {
    $_[0] = $handle if !defined($_[0]);
    return $handle;
  }

  return undef;
}

sub _stat_snapshot ( $ ) {
  my ( $filename ) = @_;
  return undef if !defined($filename);

  my @stats = stat $filename;
  if (!@stats) {
    warn &quot;stat of $filename failed: $!\n&quot; if !@stats;
    return undef;
  }

  return \@stats;
}

sub _check_stat ( $$;$ ) {
  my ( $filename, $statsnap, $force ) = @_;

  if ( !defined($statsnap) || (ref($statsnap) eq 'ARRAY' &amp;&amp; @$statsnap == 0) ) {
    $statsnap = _stat_snapshot( $filename );
    if ( $statsnap ) {
      if ( @_&gt;1 ) {
	if ( !defined($_[1]) ) {
	  $_[1] = $statsnap;
	}
	elsif ( ref($_[1]) eq 'ARRAY' &amp;&amp; @{ $_[1] } == 0 ) {
	  @{ $_[1] } = @$statsnap;
	}
      }
    }
    else {
      return undef;
    }
  }

  if ( S_ISDIR( $statsnap-&gt;[2] ) ) {
    bz_seterror( &amp;BZ_IO_ERROR, &quot;file $filename is a directory&quot; );
    return 0;
  }

  if ( !S_ISREG( $statsnap-&gt;[2] ) ) {
    bz_seterror( &amp;BZ_IO_ERROR, &quot;file $filename is not a normal file&quot; );
    return 0;
  }

  if ( !$force &amp;&amp; S_ISLNK( $statsnap-&gt;[2] ) ) {
    bz_seterror( &amp;BZ_IO_ERROR, &quot;file $filename is a symlink&quot; );
    return 0;
  }

  if ( !$force &amp;&amp; $statsnap-&gt;[3] &gt; 1 ) {
    bz_seterror( &amp;BZ_IO_ERROR, &quot;file $filename has too many hard links&quot; );
    return 0;
  }

  return 1;
}

sub _set_stat_from_snapshot ( $$ ) {
  my ( $filename, $statsnap ) = @_;

  if ( !chmod( S_IMODE( $statsnap-&gt;[2] ), $filename ) ) {
    bz_seterror( &amp;BZ_IO_ERROR, &quot;chmod &quot;.sprintf('%03o', S_IMODE( $statsnap-&gt;[2] )).&quot; $filename failed: $!&quot; );
    return undef;
  }

  if ( !utime @$statsnap[8,9], $filename ) {
    bz_seterror( &amp;BZ_IO_ERROR,
		 &quot;utime &quot; . join(' ',map { strftime('%Y-%m-%d %H:%M:%S', localtime $_) } @$statsnap[8,9] ) .
		 &quot; $filename failed: $!&quot; );
    return undef;
  }

  if ( !chown @$statsnap[4,5], $filename ) {
    bz_seterror( &amp;BZ_IO_ERROR,
		 &quot;chown &quot; . join(':', ( getpwuid($statsnap-&gt;[4]) )[0], ( getgrgid($statsnap-&gt;[5]) )[0]) .
		 &quot; $filename failed: $!&quot; );
    return 0;
  }

  return 1;
}

sub bzip2 ( @ ) {
  return _process_files( 'bzip2', 'cfvks123456789', @_ );
}

sub bunzip2 ( @ ) {
  return _process_files( 'bunzip2', 'cdzfks123456789', @_ );
}

sub bzcat ( @ ) {
  return _process_files( 'bzcat', 'cdzfks123456789', @_ );
}

sub _process_files ( @ ) {
  my $command = shift;
  my $opts = shift;

  local @ARGV = @_;

  my %opts;
  return undef if !getopt( $opts, \%opts );
  # c compress or decompress to stdout
  # d decompress
  # z compress
  # f force
  # v verbose
  # k keep
  # s small
  # 123456789

  $opts{c} = 1 if $command eq 'bzcat';
  $opts{d} = 1 if $command eq 'bunzip2' || $command eq 'bzcat';
  $opts{z} = 1 if $command eq 'bzip2';

  my $read_from_stdin;
  my ( $in, $bzin );
  my ( $out, $bzout );

  if ( !@ARGV ) {
    $read_from_stdin = 1;
    $opts{c} = 1;
    if ( !open( $in, &quot;&lt;&amp;STDIN&quot; ) ) {
      die &quot;Error: failed to input from STDIN: '$!'\n&quot;;
    }

    $bzin = bzopen( $in, &quot;r&quot; );
  }

  if ( $opts{c} ) {
    if ( !open( $out, &quot;&gt;&amp;STDOUT&quot; ) ) {
      die &quot;Error: failed to output to STDOUT: '$!'\n&quot;;
    }

    $bzout = bzopen( $out, &quot;w&quot; );
  }

  if ( !$opts{d} &amp;&amp; !$opts{z} ) {
    die &quot;Error: neither compress nor decompress was indicated.\n&quot;;
  }

  my $doneflag = 0;
  while ( !$doneflag ) {
    my $infile;
    my $outfile;
    my @statbuf;

    if ( !$read_from_stdin ) {
      $infile = shift @ARGV;
      if ( ! -r $infile ) {
	print STDERR &quot;Error: file $infile is not readable\n&quot;;
	next;
      }

      @statbuf = stat _;
      if ( !@statbuf ) {
	print STDERR &quot;Error: failed to stat $infile: '$!'\n&quot;;
	next;
      }

      if ( !_check_stat( $infile, \@statbuf, $opts{f} ) ) {
	print STDERR &quot;Error: file $infile stat check fails: $bzerrno\n&quot;;
	next;
      }
    }

    my $outfile_exists;
    if ( !$opts{c} ) {
      undef $out;
      if ( $opts{d} ) {
	$outfile = $infile . '.bz2';
      }
      elsif ( $opts{z} ) {
	$outfile = $infile =~ /\.bz2$/ ? substr($infile,0,-4) : $infile.'.out';
      }

      $outfile_exists = -e $outfile;
      if ( !_writefileopen( $out, $outfile, $opts{f} ) ) {
	print STDERR &quot;Error: failed to open $outfile for write: '$!'\n&quot;;
	next;
      }
    }

    if ( !$read_from_stdin ) {
      undef $in;
      if ( !open( $in, $infile ) ) {
	print STDERR &quot;Error: unable to open $infile: '$!'\n&quot;;
	unlink( $outfile ) if !$outfile_exists;
	next;
      }
    }

    if ( $opts{d} ) {
      $bzin = bzopen( $in, &quot;r&quot; ) if !$read_from_stdin;

      my $buf;
      my $notdone = 1;
      while ( $notdone ) {
	my $ln = bzread( $in, $buf, 1024 );
	if ( $ln &gt; 0 ) {
	  syswrite( $out, $buf, $ln );
	}
	elsif ( $ln == 0 ) {
	  undef $notdone;
	}
	else {
	}
      }

      close($out);

      if ( !$read_from_stdin ) {
	bzclose($in);
	unlink( $infile ) if !$opts{k};
	_set_stat_from_snapshot( $outfile, \@statbuf );
      }
    }
    elsif ( $opts{z} ) {
      $bzout = bzopen( $out, &quot;w&quot; ) if !$opts{c};

      my $buf;
      my $notdone = 1;
      while ( $notdone ) {
	my $ln = sysread( $in, $buf, 1024 );
	if ( $ln &gt; 0 ) {
	  bzwrite( $bzout, $buf, $ln );
	}
	elsif ( $ln == 0 ) {
	  undef $notdone;
	}
	else {
	}
      }

      close($in);

      if ( !$opts{c} ) {
	bzclose($bzout);
	unlink( $infile ) if !$opts{k};
	_set_stat_from_snapshot( $outfile, \@statbuf );
      }
    }
  }
}

##############################################################################
##############################################################################
## compatibility with Compress::Bzip2 1.03

sub add ( $$ ) {
  my ( $obj, $buffer ) = @_;

  my @res = $obj-&gt;is_write ? $obj-&gt;bzdeflate( $buffer ) : $obj-&gt;bzinflate( $buffer );

  return $res[0];
}

sub finish ( $;$ ) {
  my ( $obj, $buffer ) = @_;
  my ( @res, $out );

  if ( defined($buffer) ) {
    @res = $obj-&gt;is_write ? $obj-&gt;bzdeflate( $buffer ) : $obj-&gt;bzinflate( $buffer );
    return undef if $res[1] != &amp;BZ_OK;

    $out = $res[0];
  }
  $out = '' if !defined($out);

  @res = $obj-&gt;bzclose;
  return undef if $res[1] != &amp;BZ_OK;

  return $out.$res[0];
}

sub input_size ( $ ) {
  my ( $obj ) = @_;
  return $obj-&gt;total_in;
}

sub output_size ( $ ) {
  my ( $obj ) = @_;
  return $obj-&gt;total_out;
}

sub version ( ) {
  return bzlibversion();
}

sub error ( $ ) {
  return $_[0]-&gt;bzerror;
}

##############################################################################
##############################################################################
## THE Compress::Zlib compatibility section

sub _bzerror2gzerror {
  my ( $bz_error_num ) = @_;
  my $gz_error_num =
      $bz_error_num == &amp;BZ_OK ? Z_OK :
      $bz_error_num == &amp;BZ_RUN_OK ? Z_OK :
      $bz_error_num == &amp;BZ_FLUSH_OK ? Z_STREAM_END :
      $bz_error_num == &amp;BZ_FINISH_OK ? Z_STREAM_END :
      $bz_error_num == &amp;BZ_STREAM_END ? Z_STREAM_END :

      $bz_error_num == &amp;BZ_SEQUENCE_ERROR ? Z_VERSION_ERROR :
      $bz_error_num == &amp;BZ_PARAM_ERROR ? Z_ERRNO :
      $bz_error_num == &amp;BZ_MEM_ERROR ? Z_MEM_ERROR :
      $bz_error_num == &amp;BZ_DATA_ERROR ? Z_DATA_ERROR :
      $bz_error_num == &amp;BZ_DATA_ERROR_MAGIC ? Z_DATA_ERROR :
      $bz_error_num == &amp;BZ_IO_ERROR ? Z_ERRNO :
      $bz_error_num == &amp;BZ_UNEXPECTED_EOF ? Z_STREAM_ERROR :
      $bz_error_num == &amp;BZ_OUTBUFF_FULL ? Z_BUF_ERROR :
      $bz_error_num == &amp;BZ_CONFIG_ERROR ? Z_VERSION_ERROR :
      Z_VERSION_ERROR
      ;

  return $gz_error_num;
}

sub gzopen ( $$ ) {
  goto &amp;bzopen;
}

sub gzread ( $$;$ ) {
  goto &amp;bzread;
}

sub gzreadline ( $$ ) {
  goto &amp;bzreadline;
}

sub gzwrite ( $$ ) {
  goto &amp;bzwrite;
}

sub gzflush ( $;$ ) {
  my ( $obj, $flush ) = @_;
  return Z_OK if $flush == Z_NO_FLUSH;
  goto &amp;bzflush;
}

sub gzclose ( $ ) {
  goto &amp;bzclose;
}

sub gzeof ( $ ) {
  goto &amp;bzeof;
}

sub gzsetparams ( $$$ ) {
  ## ignore params
  my ( $obj, $level, $strategy ) = @_;
  return Z_OK;
}

sub gzerror ( $ ) {
  goto &amp;bzerror;
}

sub deflateInit ( @ ) {
  ## ignore all options:
  ## -Level, -Method, -WindowBits, -MemLevel, -Strategy, -Dictionary, -Bufsize

  my @res = bzdeflateInit();
  return $res[0] if !wantarray;

  return ( $res[0], _bzerror2gzerror( $res[1] ) );
}

sub deflate ( $$ ) {
  my ( $obj, $buffer ) = @_;

  my @res = $obj-&gt;bzdeflate( $buffer );

  return $res[0] if !wantarray;
  return ( $res[0], _bzerror2gzerror( $res[1] ) );
}

sub deflateParams ( $;@ ) {
  ## ignore all options
  return Z_OK;
}

sub flush ( $;$ ) {
  my ( $obj, $flush_type ) = @_;

  $flush_type = Z_FINISH if !defined($flush_type);
  return Z_OK if $flush_type == Z_NO_FLUSH;

  my $bz_flush_type;
  my @res;

  $bz_flush_type =
      $flush_type == Z_PARTIAL_FLUSH || $flush_type == Z_SYNC_FLUSH ? &amp;BZ_FLUSH :
      $flush_type == Z_FULL_FLUSH ? &amp;BZ_FINISH :
      &amp;BZ_FINISH;

  @res = $obj-&gt;bzflush( $bz_flush_type );

  return $res[0] if !wantarray;
  return ( $res[0], _bzerror2gzerror( $res[1] ) );
}

sub dict_adler ( $ ) {
  return 1;			# ???
}

sub msg ( $ ) {
  my ( $obj ) = @_;

  return ''.($obj-&gt;bzerror).'';	# stringify
}

sub inflateInit ( @ ) {
  ## ignore all options:
  ## -WindowBits, -Dictionary, -Bufsize

  my @res = bzinflateInit();
  return $res[0] if !wantarray;

  return ( $res[0], _bzerror2gzerror( $res[1] ) );
}

sub inflate ( $$ ) {
  my ( $obj, $buffer ) = @_;

  my @res = $obj-&gt;bzinflate( $buffer );

  return $res[0] if !wantarray;
  return ( $res[0], _bzerror2gzerror( $res[1] ) );
}

sub inflateSync ( $ ) {
  return Z_VERSION_ERROR;	# ?? what
}

sub memGzip ( $ ) {
  goto &amp;memBzip;
}

sub memGunzip ( $ ) {
  goto &amp;memBunzip;
}

sub adler32 ( $;$ ) {
  return 0;
}

sub crc32 ( $;$ ) {
  return 0;
}

# sub compress ( $;$ ) {
#   ## ignore $level
#   my ( $source, $level ) = @_;
#   return memBzip( $source );
# }

sub uncompress ( $ ) {
  my ( $source, $level ) = @_;
  return memBunzip( $source );
}

# Autoload methods go after =cut, and are processed by the autosplit program.

1;

__END__

=pod

=head1 NAME

Compress::Bzip2 - Interface to Bzip2 compression library

=head1 SYNOPSIS

    use Compress::Bzip2 qw(:all :constant :utilities :gzip);

    ($bz, $status) = bzdeflateInit( [PARAMS] );
    ($out, $status) = $bz-&gt;bzdeflate($buffer) ; # compress

    ($bz, $status) = bzinflateInit( [PARAMS] );
    ($out, $status) = $bz-&gt;bzinflate($buffer);  # uncompress

    ($out, $status) = $bz-&gt;bzflush() ;
    ($out, $status) = $bz-&gt;bzclose() ;

    $dest = memBzip($source);
        alias compress
    $dest = memBunzip($source);
        alias decompress

    $bz = Compress::Bzip2-&gt;new( [PARAMS] );

    $bz = bzopen($filename or filehandle, $mode);
        alternate, with $bz created by new():
    $bz-&gt;bzopen($filename or filehandle, $mode);

    $bytesread = $bz-&gt;bzread($buffer [,$size]) ;
    $bytesread = $bz-&gt;bzreadline($line);
    $byteswritten = $bz-&gt;bzwrite($buffer [,$limit]);
    $errstring = $bz-&gt;bzerror();
    $status = $bz-&gt;bzeof();
    $status = $bz-&gt;bzflush();
    $status = $bz-&gt;bzclose() ;

    $status = $bz-&gt;bzsetparams( $param =&gt; $setting );

    $bz-&gt;total_in() ;
    $bz-&gt;total_out() ;

    $verstring = $bz-&gt;bzversion();

    $Compress::Bzip2::bzerrno

=head1 DESCRIPTION

The I&lt;Compress::Bzip2&gt; module provides a Perl interface to the B&lt;bzip2&gt;
compression library (see L&lt;/AUTHOR&gt; for details about where to get
I&lt;Bzip2&gt;). A relevant subset of the functionality provided by I&lt;bzip2&gt;
is available in I&lt;Compress::Bzip2&gt;.

All string parameters can either be a scalar or a scalar reference.

The module can be split into two general areas of functionality, namely
in-memory compression/decompression and read/write access to I&lt;bzip2&gt;
files. Each of these areas will be discussed separately below.

B&lt;NOTE&gt;

I&lt;Compress::Bzip2&gt; is just a simple I&lt;bzip2&gt; binding, comparable to the
old L&lt;Compress::Zlib&gt; library. It is not well integrated into PerlIO,
use the preferred L&lt;IO::Compress::Bzip2&gt; instead.


=head1 FILE READ/WRITE INTERFACE

A number of functions are supplied in I&lt;bzlib&gt; for reading and writing
I&lt;bzip2&gt; files. Unfortunately, most of them are not suitable.  So, this
module provides another interface, built over top of the low level bzlib
methods.

=head2 B&lt;$bz = bzopen(filename or filehandle, mode)&gt;

This function returns an object which is used to access the other
I&lt;bzip2&gt; methods.

The B&lt;mode&gt; parameter is used to specify both whether the file is
opened for reading or writing, with &quot;r&quot; or &quot;w&quot; respectively.

If a reference to an open filehandle is passed in place of the
filename, it better be positioned to the start of a
compression/decompression sequence.

WARNING: With Perl 5.6 you cannot use a filehandle because of
SEGV in destruction with bzclose or an implicit close.

=head2 B&lt;$bz = Compress::Bzip2-E&lt;gt&gt;new( [PARAMS] )&gt;

Create a Compress::Bzip2 object.  Optionally, provide
compression/decompression parameters as a keyword =&gt; setting list.
See I&lt;bzsetparams()&gt; for a description of the parameters.

=head2 B&lt;$bz-E&lt;gt&gt;bzopen(filename or filehandle, mode)&gt;

This is bzopen, but it uses an object previously created by the new
method.  Other than that, it is identical to the above bzopen.

=head2 B&lt;$bytesread = $bz-E&lt;gt&gt;bzread($buffer [, $size]) ;&gt;

Reads B&lt;$size&gt; bytes from the compressed file into B&lt;$buffer&gt;. If
B&lt;$size&gt; is not specified, it will default to 4096. If the scalar
B&lt;$buffer&gt; is not large enough, it will be extended automatically.

Returns the number of bytes actually read. On EOF it returns 0 and in
the case of an error, -1.

=head2 B&lt;$bytesread = $bz-E&lt;gt&gt;bzreadline($line) ;&gt;

Reads the next line from the compressed file into B&lt;$line&gt;.

Returns the number of bytes actually read. On EOF it returns 0 and in
the case of an error, -1.

It IS legal to intermix calls to B&lt;bzread&gt; and B&lt;bzreadline&gt;.

At this time B&lt;bzreadline&gt; ignores the variable C&lt;$/&gt;
(C&lt;$INPUT_RECORD_SEPARATOR&gt; or C&lt;$RS&gt; when C&lt;English&gt; is in use). The
end of a line is denoted by the C character C&lt;'\n'&gt;.

=head2 B&lt;$byteswritten = $bz-E&lt;gt&gt;bzwrite($buffer [, $limit]) ;&gt;

Writes the contents of B&lt;$buffer&gt; to the compressed file. Returns the
number of bytes actually written, or 0 on error.

If $limit is given and non-zero, then only that many bytes from
$buffer will be written.

=head2 B&lt;$status = $bz-E&lt;gt&gt;bzflush($flush) ;&gt;

Flushes all pending output to the compressed file.
Works identically to the I&lt;zlib&gt; function it interfaces to. Note that
the use of B&lt;bzflush&gt; can degrade compression.

Returns C&lt;BZ_OK&gt; if B&lt;$flush&gt; is C&lt;BZ_FINISH&gt; and all output could be
flushed. Otherwise the bzlib error code is returned.

Refer to the I&lt;bzlib&gt; documentation for the valid values of B&lt;$flush&gt;.

=head2 B&lt;$status = $bz-E&lt;gt&gt;bzeof() ;&gt;

Returns 1 if the end of file has been detected while reading the input
file, otherwise returns 0.

=head2 B&lt;$bz-E&lt;gt&gt;bzclose&gt;

Closes the compressed file. Any pending data is flushed to the file
before it is closed.

=head2 B&lt;$bz-E&lt;gt&gt;bzsetparams( [PARAMS] );&gt;

Change settings for the deflate stream C&lt;$bz&gt;.

The list of the valid options is shown below. Options not specified
will remain unchanged.

=over 5

=item B&lt;-verbosity&gt;

Defines the verbosity level. Valid values are 0 through 4,

The default is C&lt;-verbosity =E&lt;gt&gt; 0&gt;.

=item B&lt;-blockSize100k&gt;

For bzip object opened for stream deflation or write.

Defines the buffering factor of compression method.  The algorithm
buffers all data until the buffer is full, then it flushes all the
data out.  Use -blockSize100k to specify the size of the buffer.

Valid settings are 1 through 9, representing a blocking in multiples
of 100k.

Note that each such block has an overhead of leading and trailing
synchronization bytes.  bzip2 recovery uses this information to
pull useable data out of a corrupted file.

A streaming application would probably want to set the blocking low.

=item B&lt;-workFactor&gt;

For bzip object opened for stream deflation or write.

The workFactor setting tells the deflation algorithm how much work
to invest to compensate for repetitive data.

workFactor may be a number from 0 to 250 inclusive.  The default setting
is 30.

See the bzip documentation for more information.

=item B&lt;-small&gt;

For bzip object opened for stream inflation or read.

B&lt;small&gt; may be 0 or 1.  Set C&lt;small&gt; to one to use a slower, less
memory intensive algorithm.

=back

=head2 B&lt;$bz-E&lt;gt&gt;bzerror&gt;

Returns the I&lt;bzlib&gt; error message or number for the last operation
associated with B&lt;$bz&gt;. The return value will be the I&lt;bzlib&gt; error
number when used in a numeric context and the I&lt;bzlib&gt; error message
when used in a string context. The I&lt;bzlib&gt; error number constants,
shown below, are available for use.

  BZ_CONFIG_ERROR
  BZ_DATA_ERROR
  BZ_DATA_ERROR_MAGIC
  BZ_FINISH
  BZ_FINISH_OK
  BZ_FLUSH
  BZ_FLUSH_OK
  BZ_IO_ERROR
  BZ_MAX_UNUSED
  BZ_MEM_ERROR
  BZ_OK
  BZ_OUTBUFF_FULL
  BZ_PARAM_ERROR
  BZ_RUN
  BZ_RUN_OK
  BZ_SEQUENCE_ERROR
  BZ_STREAM_END
  BZ_UNEXPECTED_EOF

=head2 B&lt;$bz-E&lt;gt&gt;bzclearerr&gt;

=head2 B&lt;$bzerrno&gt;

The B&lt;$bzerrno&gt; scalar holds the error code associated with the most
recent I&lt;bzip2&gt; routine. Note that unlike B&lt;bzerror()&gt;, the error is
I&lt;not&gt; associated with a particular file.

As with B&lt;bzerror()&gt; it returns an error number in numeric context and
an error message in string context. Unlike B&lt;bzerror()&gt; though, the
error message will correspond to the I&lt;bzlib&gt; message when the error is
associated with I&lt;bzlib&gt; itself, or the UNIX error message when it is
not (i.e. I&lt;bzlib&gt; returned C&lt;Z_ERRORNO&gt;).

As there is an overlap between the error numbers used by I&lt;bzlib&gt; and
UNIX, B&lt;$bzerrno&gt; should only be used to check for the presence of
I&lt;an&gt; error in numeric context. Use B&lt;bzerror()&gt; to check for specific
I&lt;bzlib&gt; errors. The I&lt;bzcat&gt; example below shows how the variable can
be used safely.

=head2 B&lt;$bz-E&lt;gt&gt;prefix&gt;

Returns the additional 5 byte header which is prepended to the bzip2
header  starting with C&lt;BZh&gt; when using memBzip/compress.

=head1 Compress::Bzip2 Utilities

Options: -d -c -z -f -v -k -s -1..9

=head2 bzip2( [OPTS], filename)

=head2 bunzip2(filename)

=head2 bzcat(filenames...)

=head2 bzlibversion()

=head2 bzinflateInit( opts... )

=head1 Internal Utilties

=head2 bz_seterror(errno, msg)
=head2 $bz-E&lt;gt&gt;is_read()
=head2 $bz-E&lt;gt&gt;is_stream()
=head2 $bz-E&lt;gt&gt;is_write()
=head2 $bz-E&lt;gt&gt;total_in()
=head2 $bz-E&lt;gt&gt;total_out()
=head2 version()

=head1 Compress::Bzip2 1.03 COMPATIBILITY

While the 2.x thread forked off of 1.00, another line of development
came to a head at 1.03.  The 1.03 version worked with bzlib 1.0.2, had
improvements to the error handling, single buffer inflate/deflate, a
streaming interface to inflate/deflate, and a cpan style test suite.

=head2 B&lt;$dest = compress( $string, [$level] )&gt;

Alias to L&lt;memBzip&gt;, this compresses string, using the optional
compression level, 1 through 9, the default being 6.  Returns a string
containing the compressed data.

On error I&lt;undef&gt; is returned.

=head2 B&lt;$dest = decompress($string, [$level])&gt;

Alias to L&lt;memBunzip&gt;, this decompresses the data in string, returning a
string containing the decompressed data.

On error I&lt;undef&gt; is returned.

=head2 uncompress($string, [$level])

Another alias to L&lt;memBunzip&gt;

=head2 B&lt;$stream = compress_init( [PARAMS] )&gt;

Alias to bzdeflateInit.  In addition to the named parameters
documented for bzdeflateInit, the following are accepted:

   -level, alias to -blockSize100k
   -buffer, to set the buffer size.

The -buffer option is ignored.  The intermediate buffer size is not
changeable.

=head2 B&lt;$stream = decompress_init( [PARAMS] )&gt;

Alias to bzinflateInit.  See bzinflateInit for a description of the parameters.
The option &quot;-buffer&quot; is accepted, but ignored.

=head2 B&lt;$output = $stream-E&lt;gt&gt;add( $string )&gt;

Add data to be compressed/decompressed.  Returns whatever output is available
(possibly none, if it's still buffering it), or undef on error.

=head2 B&lt;$output = $stream-E&lt;gt&gt;finish( [$string] )&gt;

Finish the operation; takes an optional final data string.  Whatever is
returned completes the output; returns undef on error.

=head2 B&lt;$stream-E&lt;gt&gt;error&gt;

Like the function, but applies to the current object only.  Note that errors
in a stream object are also returned by the function.

=head2 B&lt;$stream-E&lt;gt&gt;input_size&gt;

Alias to total_in.  Total bytes passed to the stream.

=head2 B&lt;$stream-E&lt;gt&gt;output_size&gt;

Alias to total_out.  Total bytes received from the stream.

=head1 GZIP COMPATIBILITY INTERFACE

Except for the exact state and error numbers, this package presents an
interface very much like that given by the Compress::Zlib package.
Mostly, if you take the method name, state or error number from
Compress::Zlib and replace the &quot;g&quot; with a &quot;b&quot;, your code should work.

To make the interoperability even easier, all the Compress::Zlib method
names have been used as aliases or cover functions for the bzip2 methods.

Therefore, most code that uses Compress::Zlib should be able to use
this package, with a one line change.

Simply change

   $gz = Compress::Zlib::gzopen( &quot;filename&quot;, &quot;w&quot; );

to

   $gz = Compress::Bzip2::gzopen( &quot;filename&quot;, &quot;w&quot; );

Some of the Compress::Zlib aliases don't return anything useful, like
crc32 or adler32, cause bzip2 doesn't do that sort of thing.

=head2 B&lt; $gz = gzopen( $filename, $mode ) &gt;

Alias for bzopen.

=head2 B&lt; $gz-E&lt;gt&gt;gzread( $buffer, [ $length ] ) &gt;

Alias for bzread.

=head2 B&lt; $gz-E&lt;gt&gt;gzreadline( $buffer ) &gt;

Alias for bzreadline.

=head2 B&lt; $gz-E&lt;gt&gt;gzwrite( $buffer ) &gt;

Alias for bzwrite.

=head2 B&lt; $gz-E&lt;gt&gt;gzflush( [$flushtype] ) &gt;

Alias for bzflush, with return code translation.

=head2 B&lt; $gz-E&lt;gt&gt;gzclose( ) &gt;

Alias for bzclose.

=head2 B&lt; $gz-E&lt;gt&gt;gzeof( ) &gt;

Alias for bzeof.

=head2 B&lt; $gz-E&lt;gt&gt;gzerror( ) &gt;

Alias for bzerror.

=head2 B&lt; $gz-E&lt;gt&gt;gzsetparams( $level, $strategy ) &gt;

This is a no-op.

=head2 B&lt; $d = deflateInit( [OPTS] ) &gt;

Alias for bzdeflateInit, with return code translation.

All OPTS are ignored.

=head2 B&lt; $d-E&lt;gt&gt;deflate( $buffer ) &gt;

Alias for bzdeflate, with return code translation.

=head2 B&lt; $d-E&lt;gt&gt;deflateParams( [OPTS] ) &gt;

This is a no-op.

=head2 B&lt; $d-E&lt;gt&gt;flush( [$flushtype] ) &gt;

Cover function for bzflush or bzclose, depending on $flushtype.

See the Compress::Zlib documentation for more information.

=head2 B&lt; $d-E&lt;gt&gt;dict_adler( ) &gt;

This is a no-op.

=head2 B&lt; $d-E&lt;gt&gt;msg( ) &gt;

This is a no-op.

=head2 B&lt; $d = inflateInit( [OPTS] ) &gt;

Alias for bzinflateInit, with return code translation.

All OPTS are ignored.

=head2 B&lt; $d-E&lt;gt&gt;inflate( ) &gt;

Alias for bzinflate, with return code translation.

=head2 B&lt; $d-E&lt;gt&gt;inflateSync( ) &gt;

This is a no-op.

=head2 B&lt; $d-E&lt;gt&gt;adler32( $crc ) &gt;

This is a no-op.

=head2 B&lt; $d-E&lt;gt&gt;crc32( $crc ) &gt;

This is a no-op.

=head2 B&lt; $buffer = memGzip( $buffer ) &gt;

Alias for memBzip.

=head2 B&lt; $buffer = memGunzip( $buffer ) &gt;

Alias for memBunzip.

=head1 IN-MEMORY COMPRESS/UNCOMPRESS

Two high-level functions are provided by I&lt;bzlib&gt; to perform in-memory
compression. They are B&lt;memBzip&gt; and B&lt;memBunzip&gt;. Two Perl subs are
provided which provide similar functionality.

=head2 B&lt;$compressed = memBzip($buffer);&gt;

Compresses B&lt;$buffer&gt;. If successful it returns the compressed
data. Otherwise it returns I&lt;undef&gt;.

The buffer parameter can either be a scalar or a scalar reference.

Essentially, an in-memory bzip file is created. It creates a minimal
bzip header, which adds 5 bytes before the bzip2 specific BZh header.

=head2 B&lt;$uncompressed = memBunzip($buffer);&gt;

Uncompresses B&lt;$buffer&gt;. If successful it returns the uncompressed
data. Otherwise it returns I&lt;undef&gt;.

The source buffer can either be a scalar or a scalar reference.

The buffer parameter can either be a scalar or a scalar reference. The
contents of the buffer parameter are destroyed after calling this
function.

=head1 STREAM DEFLATE (= COMPRESS)

The Perl interface will I&lt;always&gt; consume the complete input buffer
before returning. Also the output buffer returned will be
automatically grown to fit the amount of output available.

Here is a definition of the interface available:

=head2 B&lt;($d, $status) = bzdeflateInit( [PARAMS] )&gt;

Initialises a deflation stream.

If successful, it will return the initialised deflation stream, B&lt;$d&gt;
and B&lt;$status&gt; of C&lt;BZ_OK&gt; in a list context. In scalar context it
returns the deflation stream, B&lt;$d&gt;, only.

If not successful, the returned deflation stream (B&lt;$d&gt;) will be
I&lt;undef&gt; and B&lt;$status&gt; will hold the exact I&lt;bzip2&gt; error code.

The function optionally takes a number of named options specified as
C&lt;-Name=E&lt;gt&gt;value&gt; pairs. This allows individual options to be
tailored without having to specify them all in the parameter list.

Here is a list of the valid options:

=over 5

=item B&lt;-verbosity&gt;

Defines the verbosity level. Valid values are 0 through 4,

The default is C&lt;-verbosity =E&lt;gt&gt; 0&gt;.

=item B&lt;-blockSize100k&gt;

Defines the buffering factor of compression method.  The algorithm
buffers all data until the buffer is full, then it flushes all the
data out.  Use -blockSize100k to specify the size of the buffer.

Valid settings are 1 through 9, representing a blocking in multiples
of 100k.

Note that each such block has an overhead of leading and trailing
synchronization bytes.  bzip2 recovery uses this information to
pull useable data out of a corrupted file.

A streaming application would probably want to set the blocking low.

=item B&lt;-workFactor&gt;

The workFactor setting tells the deflation algorithm how much work
to invest to compensate for repetitive data.

workFactor may be a number from 0 to 250 inclusive.  The default setting
is 30.

See the bzip documentation for more information.

=back

Here is an example of using the B&lt;deflateInit&gt; optional parameter list
to override the default buffer size and compression level. All other
options will take their default values.

    bzdeflateInit( -blockSize100k =&gt; 1, -verbosity =&gt; 1 );

=head2 B&lt;($out, $status) = $d-E&lt;gt&gt;bzdeflate($buffer)&gt;

Deflates the contents of B&lt;$buffer&gt;. The buffer can either be a scalar
or a scalar reference.  When finished, B&lt;$buffer&gt; will be
completely processed (assuming there were no errors). If the deflation
was successful it returns deflated output, B&lt;$out&gt;, and a status
value, B&lt;$status&gt;, of C&lt;Z_OK&gt;.

On error, B&lt;$out&gt; will be I&lt;undef&gt; and B&lt;$status&gt; will contain the
I&lt;zlib&gt; error code.

In a scalar context B&lt;bzdeflate&gt; will return B&lt;$out&gt; only.

As with the internal buffering of the I&lt;deflate&gt; function in I&lt;bzip2&gt;,
it is not necessarily the case that any output will be produced by
this method. So don't rely on the fact that B&lt;$out&gt; is empty for an
error test.  In fact, given the size of bzdeflates internal buffer,
with most files it's likely you won't see any output at all until
flush or close.

=head2 B&lt;($out, $status) = $d-E&lt;gt&gt;bzflush([flush_type])&gt;

Typically used to finish the deflation. Any pending output will be
returned via B&lt;$out&gt;.  B&lt;$status&gt; will have a value C&lt;BZ_OK&gt; if
successful.

In a scalar context B&lt;bzflush&gt; will return B&lt;$out&gt; only.

Note that flushing can seriously degrade the compression ratio, so it
should only be used to terminate a decompression (using C&lt;BZ_FLUSH&gt;) or
when you want to create a I&lt;full flush point&gt; (using C&lt;BZ_FINISH&gt;).

The allowable values for C&lt;flush_type&gt; are C&lt;BZ_FLUSH&gt; and C&lt;BZ_FINISH&gt;.

For a handle opened for &quot;w&quot; (bzwrite), the default is C&lt;BZ_FLUSH&gt;.
For a stream, the default for C&lt;flush_type&gt; is C&lt;BZ_FINISH&gt; (which is
essentially a close and reopen).

It is strongly recommended that you only set the C&lt;flush_type&gt;
parameter if you fully understand the implications of what it
does. See the C&lt;bzip2&gt; documentation for details.

=head2 Example

Here is a trivial example of using B&lt;bzdeflate&gt;. It simply reads standard
input, deflates it and writes it to standard output.

    use strict ;
    use warnings ;

    use Compress::Bzip2 ;

    binmode STDIN;
    binmode STDOUT;
    my $x = bzdeflateInit()
       or die &quot;Cannot create a deflation stream\n&quot; ;

    my ($output, $status) ;
    while (&lt;&gt;)
    {
        ($output, $status) = $x-&gt;bzdeflate($_) ;

        $status == BZ_OK
            or die &quot;deflation failed\n&quot; ;

        print $output ;
    }

    ($output, $status) = $x-&gt;bzclose() ;

    $status == BZ_OK
        or die &quot;deflation failed\n&quot; ;

    print $output ;

=head1 STREAM INFLATE

Here is a definition of the interface:

=head2 B&lt;($i, $status) = inflateInit()&gt;

Initialises an inflation stream.

In a list context it returns the inflation stream, B&lt;$i&gt;, and the
I&lt;zlib&gt; status code (B&lt;$status&gt;). In a scalar context it returns the
inflation stream only.

If successful, B&lt;$i&gt; will hold the inflation stream and B&lt;$status&gt; will
be C&lt;BZ_OK&gt;.

If not successful, B&lt;$i&gt; will be I&lt;undef&gt; and B&lt;$status&gt; will hold the
I&lt;bzlib.h&gt; error code.

The function optionally takes a number of named options specified as
C&lt;-Name=E&lt;gt&gt;value&gt; pairs. This allows individual options to be
tailored without having to specify them all in the parameter list.

For backward compatibility, it is also possible to pass the parameters
as a reference to a hash containing the name=&gt;value pairs.

The function takes one optional parameter, a reference to a hash.  The
contents of the hash allow the deflation interface to be tailored.

Here is a list of the valid options:

=over 5

=item B&lt;-small&gt;

B&lt;small&gt; may be 0 or 1.  Set C&lt;small&gt; to one to use a slower, less
memory intensive algorithm.

=item B&lt;-verbosity&gt;

Defines the verbosity level. Valid values are 0 through 4,

The default is C&lt;-verbosity =E&lt;gt&gt; 0&gt;.

=back

Here is an example of using the B&lt;bzinflateInit&gt; optional parameter.

    bzinflateInit( -small =&gt; 1, -verbosity =&gt; 1 );

=head2 B&lt;($out, $status) = $i-E&lt;gt&gt;bzinflate($buffer)&gt;

Inflates the complete contents of B&lt;$buffer&gt;. The buffer can either be
a scalar or a scalar reference.

Returns C&lt;BZ_OK&gt; if successful and C&lt;BZ_STREAM_END&gt; if the end of the
compressed data has been successfully reached.  If not successful,
B&lt;$out&gt; will be I&lt;undef&gt; and B&lt;$status&gt; will hold the I&lt;bzlib&gt; error
code.

The C&lt;$buffer&gt; parameter is modified by C&lt;bzinflate&gt;. On completion it
will contain what remains of the input buffer after inflation. This
means that C&lt;$buffer&gt; will be an empty string when the return status
is C&lt;BZ_OK&gt;. When the return status is C&lt;BZ_STREAM_END&gt; the C&lt;$buffer&gt;
parameter will contains what (if anything) was stored in the input
buffer after the deflated data stream.

This feature is useful when processing a file format that encapsulates
a compressed data stream.

=head2 Example

Here is an example of using B&lt;bzinflate&gt;.

    use strict ;
    use warnings ;

    use Compress::Bzip2;

    my $x = bzinflateInit()
       or die &quot;Cannot create a inflation stream\n&quot; ;

    my $input = '' ;
    binmode STDIN;
    binmode STDOUT;

    my ($output, $status) ;
    while (read(STDIN, $input, 4096))
    {
        ($output, $status) = $x-&gt;bzinflate(\$input) ;

        print $output
            if $status == BZ_OK or $status == BZ_STREAM_END ;

        last if $status != BZ_OK ;
    }

    die &quot;inflation failed\n&quot;
        unless $status == BZ_STREAM_END ;

=head1 EXAMPLES

Here are some example scripts of using the interface.

=head2 B&lt;A bzcat function&gt;

  use strict ;
  use warnings ;

  use Compress::Bzip2 ;

  die &quot;Usage: bzcat file...\n&quot; unless @ARGV ;

  my $file ;

  foreach $file (@ARGV) {
    my $buffer ;

    my $bz = bzopen($file, &quot;rb&quot;)
       or die &quot;Cannot open $file: $bzerrno\n&quot; ;

    print $buffer while $bz-&gt;bzread($buffer) &gt; 0 ;

    die &quot;Error reading from $file: $bzerrno&quot; . ($bzerrno+0) . &quot;\n&quot;
       if $bzerrno != BZ_STREAM_END ;

    $bz-&gt;bzclose() ;
  }

=head2 B&lt;A grep using bzreadline&gt;

  use strict ;
  use warnings ;

  use Compress::Bzip2 ;

  die &quot;Usage: bzgrep pattern file...\n&quot; unless @ARGV &gt;= 2;

  my $pattern = shift ;

  my $file ;

  foreach $file (@ARGV) {
    my $bz = bzopen($file, &quot;rb&quot;)
       or die &quot;Cannot open $file: $bzerrno\n&quot; ;

    while ($bz-&gt;bzreadline($_) &gt; 0) {
      print if /$pattern/ ;
    }

    die &quot;Error reading from $file: $bzerrno\n&quot;
      if $bzerrno != Z_STREAM_END ;

    $bz-&gt;bzclose() ;
  }

=head2 B&lt;Streaming Compression&gt;

This script, I&lt;bzstream&gt;, does the opposite of the I&lt;bzcat&gt; script
above. It reads from standard input and writes a bzip file to standard
output.

  use strict ;
  use warnings ;

  use Compress::Bzip2 ;

  binmode STDOUT;	# bzopen only sets it on the fd

  my $bz = bzopen(\*STDOUT, &quot;wb&quot;)
     or die &quot;Cannot open stdout: $bzerrno\n&quot; ;

  while (&lt;&gt;) {
    $bz-&gt;bzwrite($_) or die &quot;error writing: $bzerrno\n&quot; ;
  }

  $bz-&gt;bzclose ;

=head1 EXPORT

Use the tags :all, :utilities, :constants, :bzip1 and :gzip.

=head2 Export tag :all

This exports all the exportable methods.

=head2 Export tag :constants

This exports only the BZ_* constants.

=head2 Export tag :bzip1

This exports the Compress::Bzip2 1.x functions, for compatibility.

   compress
   decompress
   compress_init
   decompress_init
   version

These are actually aliases to memBzip and memBunzip.

=head2 Export tag :utilities

This gives an interface to the bzip2 methods.

    bzopen
    bzinflateInit
    bzdeflateInit
    memBzip
    memBunzip
    bzip2
    bunzip2
    bzcat
    bzlibversion
    $bzerrno

=head2 Export tag :gzip

This gives compatibility with Compress::Zlib.

    gzopen
    gzinflateInit
    gzdeflateInit
    memGzip
    memGunzip
    $gzerrno

=head1 Exportable constants

All the I&lt;bzlib&gt; constants are automatically imported when you make use
of I&lt;Compress::Bzip2&gt;.

  BZ_CONFIG_ERROR
  BZ_DATA_ERROR
  BZ_DATA_ERROR_MAGIC
  BZ_FINISH
  BZ_FINISH_OK
  BZ_FLUSH
  BZ_FLUSH_OK
  BZ_IO_ERROR
  BZ_MAX_UNUSED
  BZ_MEM_ERROR
  BZ_OK
  BZ_OUTBUFF_FULL
  BZ_PARAM_ERROR
  BZ_RUN
  BZ_RUN_OK
  BZ_SEQUENCE_ERROR
  BZ_STREAM_END
  BZ_UNEXPECTED_EOF

=head1 SEE ALSO

The documentation for zlib, bzip2 and Compress::Zlib.

=head1 AUTHOR

Rob Janes, E&lt;lt&gt;arjay at cpan.orgE&lt;gt&gt;

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2005 by Rob Janes

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.8.3 or,
at your option, any later version of Perl 5 you may have available.

=head1 AUTHOR

The I&lt;Compress::Bzip2&gt; module was originally written by Gawdi Azem
F&lt;azemgi@rupert.informatik.uni-stuttgart.de&gt;.

The first I&lt;Compress::Bzip2&gt; module was written by Gawdi Azem
F&lt;azemgi@rupert.informatik.uni-stuttgart.de&gt;.  It provided an
interface to the in memory inflate and deflate routines.

I&lt;Compress::Bzip2&gt; was subsequently passed on to Marco Carnut
F&lt;kiko@tempest.com.br&gt; who shepherded it through to version 1.03, a
set of changes which included upgrades to handle bzlib 1.0.2, and
improvements to the in memory inflate and deflate routines.  The
streaming interface and error information were added by David Robins
F&lt;dbrobins@davidrobins.net&gt;.

Version 2 of I&lt;Compress::Bzip2&gt; is due to Rob Janes, of
arjay@cpan.org.  This release is intended to give an interface
close to that of Compress::Zlib.  It's development forks from 1.00,
not 1.03, so the streaming interface is not the same as that in 1.03,
although apparently compatible as it passes the 1.03 test suite.

Minor subsequent fixes and releases were done by Reini Urban,
rurban@cpan.org.

=head1 MODIFICATION HISTORY

See the Changes file.

2.00 Second public release of I&lt;Compress::Bzip2&gt;.

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2Fvendor_perl%2FCompress'>Back to Directory</a>