<h2>Editing File: /lib64/perl5/Time/Piece.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Time::Piece;

use strict;

require DynaLoader;
use Time::Seconds;
use Carp;
use Time::Local;

our @ISA = qw(DynaLoader);
 
use Exporter ();

our @EXPORT = qw(
    localtime
    gmtime
);

our %EXPORT_TAGS = (
    ':override' =&gt; 'internal',
    );

our $VERSION = '1.31';

bootstrap Time::Piece $VERSION;

my $DATE_SEP = '-';
my $TIME_SEP = ':';
my @MON_LIST = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
my @FULLMON_LIST = qw(January February March April May June July
                      August September October November December);
my @DAY_LIST = qw(Sun Mon Tue Wed Thu Fri Sat);
my @FULLDAY_LIST = qw(Sunday Monday Tuesday Wednesday Thursday Friday Saturday);

use constant {
    'c_sec' =&gt; 0,
    'c_min' =&gt; 1,
    'c_hour' =&gt; 2,
    'c_mday' =&gt; 3,
    'c_mon' =&gt; 4,
    'c_year' =&gt; 5,
    'c_wday' =&gt; 6,
    'c_yday' =&gt; 7,
    'c_isdst' =&gt; 8,
    'c_epoch' =&gt; 9,
    'c_islocal' =&gt; 10,
};

sub localtime {
    unshift @_, __PACKAGE__ unless eval { $_[0]-&gt;isa('Time::Piece') };
    my $class = shift;
    my $time  = shift;
    $time = time if (!defined $time);
    $class-&gt;_mktime($time, 1);
}

sub gmtime {
    unshift @_, __PACKAGE__ unless eval { $_[0]-&gt;isa('Time::Piece') };
    my $class = shift;
    my $time  = shift;
    $time = time if (!defined $time);
    $class-&gt;_mktime($time, 0);
}

sub new {
    my $class = shift;
    my ($time) = @_;

    my $self;

    if (defined($time)) {
        $self = $class-&gt;localtime($time);
    }
    elsif (ref($class) &amp;&amp; $class-&gt;isa(__PACKAGE__)) {
        $self = $class-&gt;_mktime($class-&gt;epoch, $class-&gt;[c_islocal]);
    }
    else {
        $self = $class-&gt;localtime();
    }

    return bless $self, ref($class) || $class;
}

sub parse {
    my $proto = shift;
    my $class = ref($proto) || $proto;
    my @components;

    warnings::warnif(&quot;deprecated&quot;, 
        &quot;parse() is deprecated, use strptime() instead.&quot;);

    if (@_ &gt; 1) {
        @components = @_;
    }
    else {
        @components = shift =~ /(\d+)$DATE_SEP(\d+)$DATE_SEP(\d+)(?:(?:T|\s+)(\d+)$TIME_SEP(\d+)(?:$TIME_SEP(\d+)))/;
        @components = reverse(@components[0..5]);
    }
    return $class-&gt;new(_strftime(&quot;%s&quot;, timelocal(@components)));
}

sub _mktime {
    my ($class, $time, $islocal) = @_;
    $class = eval { (ref $class) &amp;&amp; (ref $class)-&gt;isa('Time::Piece') }
           ? ref $class
           : $class;
    if (ref($time)) {
        my @tm_parts = (@{$time}[c_sec .. c_mon], $time-&gt;[c_year]+1900);
        $time-&gt;[c_epoch] = $islocal ? timelocal(@tm_parts) : timegm(@tm_parts);

        return wantarray ? @$time : bless [@$time[0..9], $islocal], $class;
    }
    _tzset();
    my @time = $islocal ?
            CORE::localtime($time)
                :
            CORE::gmtime($time);
    wantarray ? @time : bless [@time, $time, $islocal], $class;
}

my %_special_exports = (
  localtime =&gt; sub { my $c = $_[0]; sub { $c-&gt;localtime(@_) } },
  gmtime    =&gt; sub { my $c = $_[0]; sub { $c-&gt;gmtime(@_)    } },
);

sub export {
  my ($class, $to, @methods) = @_;
  for my $method (@methods) {
    if (exists $_special_exports{$method}) {
      no strict 'refs';
      no warnings 'redefine';
      *{$to . &quot;::$method&quot;} = $_special_exports{$method}-&gt;($class);
    } else {
      $class-&gt;Exporter::export($to, $method);
    }
  }
}

sub import {
    # replace CORE::GLOBAL localtime and gmtime if passed :override
    my $class = shift;
    my %params;
    map($params{$_}++,@_,@EXPORT);
    if (delete $params{':override'}) {
        $class-&gt;export('CORE::GLOBAL', keys %params);
    }
    else {
        $class-&gt;export(scalar caller, keys %params);
    }
}

## Methods ##

sub sec {
    my $time = shift;
    $time-&gt;[c_sec];
}

*second = \&amp;sec;

sub min {
    my $time = shift;
    $time-&gt;[c_min];
}

*minute = \&amp;min;

sub hour {
    my $time = shift;
    $time-&gt;[c_hour];
}

sub mday {
    my $time = shift;
    $time-&gt;[c_mday];
}

*day_of_month = \&amp;mday;

sub mon {
    my $time = shift;
    $time-&gt;[c_mon] + 1;
}

sub _mon {
    my $time = shift;
    $time-&gt;[c_mon];
}

sub month {
    my $time = shift;
    if (@_) {
        return $_[$time-&gt;[c_mon]];
    }
    elsif (@MON_LIST) {
        return $MON_LIST[$time-&gt;[c_mon]];
    }
    else {
        return $time-&gt;strftime('%b');
    }
}

*monname = \&amp;month;

sub fullmonth {
    my $time = shift;
    if (@_) {
        return $_[$time-&gt;[c_mon]];
    }
    elsif (@FULLMON_LIST) {
        return $FULLMON_LIST[$time-&gt;[c_mon]];
    }
    else {
        return $time-&gt;strftime('%B');
    }
}

sub year {
    my $time = shift;
    $time-&gt;[c_year] + 1900;
}

sub _year {
    my $time = shift;
    $time-&gt;[c_year];
}

sub yy {
    my $time = shift;
    my $res = $time-&gt;[c_year] % 100;
    return $res &gt; 9 ? $res : &quot;0$res&quot;;
}

sub wday {
    my $time = shift;
    $time-&gt;[c_wday] + 1;
}

sub _wday {
    my $time = shift;
    $time-&gt;[c_wday];
}

*day_of_week = \&amp;_wday;

sub wdayname {
    my $time = shift;
    if (@_) {
        return $_[$time-&gt;[c_wday]];
    }
    elsif (@DAY_LIST) {
        return $DAY_LIST[$time-&gt;[c_wday]];
    }
    else {
        return $time-&gt;strftime('%a');
    }
}

*day = \&amp;wdayname;

sub fullday {
    my $time = shift;
    if (@_) {
        return $_[$time-&gt;[c_wday]];
    }
    elsif (@FULLDAY_LIST) {
        return $FULLDAY_LIST[$time-&gt;[c_wday]];
    }
    else {
        return $time-&gt;strftime('%A');
    }
}

sub yday {
    my $time = shift;
    $time-&gt;[c_yday];
}

*day_of_year = \&amp;yday;

sub isdst {
    my $time = shift;
    $time-&gt;[c_isdst];
}

*daylight_savings = \&amp;isdst;

# Thanks to Tony Olekshy &lt;olekshy@cs.ualberta.ca&gt; for this algorithm
sub tzoffset {
    my $time = shift;

    return Time::Seconds-&gt;new(0) unless $time-&gt;[c_islocal];

    my $epoch = $time-&gt;epoch;

    my $j = sub {

        my ($s,$n,$h,$d,$m,$y) = @_; $m += 1; $y += 1900;

        $time-&gt;_jd($y, $m, $d, $h, $n, $s);

    };

    # Compute floating offset in hours.
    #
    # Note use of crt methods so the tz is properly set...
    # See: http://perlmonks.org/?node_id=820347
    my $delta = 24 * ($j-&gt;(_crt_localtime($epoch)) - $j-&gt;(_crt_gmtime($epoch)));

    # Return value in seconds rounded to nearest minute.
    return Time::Seconds-&gt;new( int($delta * 60 + ($delta &gt;= 0 ? 0.5 : -0.5)) * 60 );
}

sub epoch {
    my $time = shift;
    if (defined($time-&gt;[c_epoch])) {
        return $time-&gt;[c_epoch];
    }
    else {
        my $epoch = $time-&gt;[c_islocal] ?
          timelocal(@{$time}[c_sec .. c_mon], $time-&gt;[c_year]+1900)
          :
          timegm(@{$time}[c_sec .. c_mon], $time-&gt;[c_year]+1900);
        $time-&gt;[c_epoch] = $epoch;
        return $epoch;
    }
}

sub hms {
    my $time = shift;
    my $sep = @_ ? shift(@_) : $TIME_SEP;
    sprintf(&quot;%02d$sep%02d$sep%02d&quot;, $time-&gt;[c_hour], $time-&gt;[c_min], $time-&gt;[c_sec]);
}

*time = \&amp;hms;

sub ymd {
    my $time = shift;
    my $sep = @_ ? shift(@_) : $DATE_SEP;
    sprintf(&quot;%d$sep%02d$sep%02d&quot;, $time-&gt;year, $time-&gt;mon, $time-&gt;[c_mday]);
}

*date = \&amp;ymd;

sub mdy {
    my $time = shift;
    my $sep = @_ ? shift(@_) : $DATE_SEP;
    sprintf(&quot;%02d$sep%02d$sep%d&quot;, $time-&gt;mon, $time-&gt;[c_mday], $time-&gt;year);
}

sub dmy {
    my $time = shift;
    my $sep = @_ ? shift(@_) : $DATE_SEP;
    sprintf(&quot;%02d$sep%02d$sep%d&quot;, $time-&gt;[c_mday], $time-&gt;mon, $time-&gt;year);
}

sub datetime {
    my $time = shift;
    my %seps = (date =&gt; $DATE_SEP, T =&gt; 'T', time =&gt; $TIME_SEP, @_);
    return join($seps{T}, $time-&gt;date($seps{date}), $time-&gt;time($seps{time}));
}


# Julian Day is always calculated for UT regardless
# of local time
sub julian_day {
    my $time = shift;
    # Correct for localtime
    $time = $time-&gt;gmtime( $time-&gt;epoch ) if $time-&gt;[c_islocal];

    # Calculate the Julian day itself
    my $jd = $time-&gt;_jd( $time-&gt;year, $time-&gt;mon, $time-&gt;mday,
                        $time-&gt;hour, $time-&gt;min, $time-&gt;sec);

    return $jd;
}

# MJD is defined as JD - 2400000.5 days
sub mjd {
    return shift-&gt;julian_day - 2_400_000.5;
}

# Internal calculation of Julian date. Needed here so that
# both tzoffset and mjd/jd methods can share the code
# Algorithm from Hatcher 1984 (QJRAS 25, 53-55), and
#  Hughes et al, 1989, MNRAS, 238, 15
# See: http://adsabs.harvard.edu/cgi-bin/nph-bib_query?bibcode=1989MNRAS.238.1529H&amp;db_key=AST
# for more details

sub _jd {
    my $self = shift;
    my ($y, $m, $d, $h, $n, $s) = @_;

    # Adjust input parameters according to the month
    $y = ( $m &gt; 2 ? $y : $y - 1);
    $m = ( $m &gt; 2 ? $m - 3 : $m + 9);

    # Calculate the Julian Date (assuming Julian calendar)
    my $J = int( 365.25 *( $y + 4712) )
      + int( (30.6 * $m) + 0.5)
        + 59
          + $d
            - 0.5;

    # Calculate the Gregorian Correction (since we have Gregorian dates)
    my $G = 38 - int( 0.75 * int(49+($y/100)));

    # Calculate the actual Julian Date
    my $JD = $J + $G;

    # Modify to include hours/mins/secs in floating portion.
    return $JD + ($h + ($n + $s / 60) / 60) / 24;
}

sub week {
    my $self = shift;

    my $J  = $self-&gt;julian_day;
    # Julian day is independent of time zone so add on tzoffset
    # if we are using local time here since we want the week day
    # to reflect the local time rather than UTC
    $J += ($self-&gt;tzoffset/(24*3600)) if $self-&gt;[c_islocal];

    # Now that we have the Julian day including fractions
    # convert it to an integer Julian Day Number using nearest
    # int (since the day changes at midday we convert all Julian
    # dates to following midnight).
    $J = int($J+0.5);

    use integer;
    my $d4 = ((($J + 31741 - ($J % 7)) % 146097) % 36524) % 1461;
    my $L  = $d4 / 1460;
    my $d1 = (($d4 - $L) % 365) + $L;
    return $d1 / 7 + 1;
}

sub _is_leap_year {
    my $year = shift;
    return (($year %4 == 0) &amp;&amp; !($year % 100 == 0)) || ($year % 400 == 0)
               ? 1 : 0;
}

sub is_leap_year {
    my $time = shift;
    my $year = $time-&gt;year;
    return _is_leap_year($year);
}

my @MON_LAST = qw(31 28 31 30 31 30 31 31 30 31 30 31);

sub month_last_day {
    my $time = shift;
    my $year = $time-&gt;year;
    my $_mon = $time-&gt;_mon;
    return $MON_LAST[$_mon] + ($_mon == 1 ? _is_leap_year($year) : 0);
}

#since %z and %Z are not portable lets just
#parse it out before calling native strftime
#(but only if we are in UTC time)
my %GMT_REPR = (
    '%z' =&gt; '+0000',
    '%Z' =&gt; 'UTC',
);

sub strftime {
    my $time = shift;
    my $format = @_ ? shift(@_) : '%a, %d %b %Y %H:%M:%S %Z';
    if (! $time-&gt;[c_islocal]) {
        $format =~ s/(%.)/$GMT_REPR{$1} || $1/eg;
    }

    return _strftime($format, $time-&gt;epoch, $time-&gt;[c_islocal]);
}

sub strptime {
    my $time = shift;
    my $string = shift;
    my $format = @_ ? shift(@_) : &quot;%a, %d %b %Y %H:%M:%S %Z&quot;;
    my @vals = _strptime($string, $format);
#    warn(sprintf(&quot;got vals: %d-%d-%d %d:%d:%d\n&quot;, reverse(@vals)));
    return scalar $time-&gt;_mktime(\@vals, (ref($time) ? $time-&gt;[c_islocal] : 0));
}

sub day_list {
    shift if ref($_[0]) &amp;&amp; $_[0]-&gt;isa(__PACKAGE__); # strip first if called as a method
    my @old = @DAY_LIST;
    if (@_) {
        @DAY_LIST = @_;
    }
    return @old;
}

sub mon_list {
    shift if ref($_[0]) &amp;&amp; $_[0]-&gt;isa(__PACKAGE__); # strip first if called as a method
    my @old = @MON_LIST;
    if (@_) {
        @MON_LIST = @_;
    }
    return @old;
}

sub time_separator {
    shift if ref($_[0]) &amp;&amp; $_[0]-&gt;isa(__PACKAGE__);
    my $old = $TIME_SEP;
    if (@_) {
        $TIME_SEP = $_[0];
    }
    return $old;
}

sub date_separator {
    shift if ref($_[0]) &amp;&amp; $_[0]-&gt;isa(__PACKAGE__);
    my $old = $DATE_SEP;
    if (@_) {
        $DATE_SEP = $_[0];
    }
    return $old;
}

use overload '&quot;&quot;' =&gt; \&amp;cdate,
             'cmp' =&gt; \&amp;str_compare,
             'fallback' =&gt; undef;

sub cdate {
    my $time = shift;
    if ($time-&gt;[c_islocal]) {
        return scalar(CORE::localtime($time-&gt;epoch));
    }
    else {
        return scalar(CORE::gmtime($time-&gt;epoch));
    }
}

sub str_compare {
    my ($lhs, $rhs, $reverse) = @_;
    if (UNIVERSAL::isa($rhs, 'Time::Piece')) {
        $rhs = &quot;$rhs&quot;;
    }
    return $reverse ? $rhs cmp $lhs-&gt;cdate : $lhs-&gt;cdate cmp $rhs;
}

use overload
        '-' =&gt; \&amp;subtract,
        '+' =&gt; \&amp;add;

sub subtract {
    my $time = shift;
    my $rhs = shift;
    if (UNIVERSAL::isa($rhs, 'Time::Seconds')) {
        $rhs = $rhs-&gt;seconds;
    }

    if (shift)
    {
	# SWAPED is set (so someone tried an expression like NOTDATE - DATE).
	# Imitate Perl's standard behavior and return the result as if the
	# string $time resolves to was subtracted from NOTDATE.  This way,
	# classes which override this one and which have a stringify function
	# that resolves to something that looks more like a number don't need
	# to override this function.
	return $rhs - &quot;$time&quot;;
    }

    if (UNIVERSAL::isa($rhs, 'Time::Piece')) {
        return Time::Seconds-&gt;new($time-&gt;epoch - $rhs-&gt;epoch);
    }
    else {
        # rhs is seconds.
        return $time-&gt;_mktime(($time-&gt;epoch - $rhs), $time-&gt;[c_islocal]);
    }
}

sub add {
    my $time = shift;
    my $rhs = shift;
    if (UNIVERSAL::isa($rhs, 'Time::Seconds')) {
        $rhs = $rhs-&gt;seconds;
    }
    croak &quot;Invalid rhs of addition: $rhs&quot; if ref($rhs);

    return $time-&gt;_mktime(($time-&gt;epoch + $rhs), $time-&gt;[c_islocal]);
}

use overload
        '&lt;=&gt;' =&gt; \&amp;compare;

sub get_epochs {
    my ($lhs, $rhs, $reverse) = @_;
    if (!UNIVERSAL::isa($rhs, 'Time::Piece')) {
        $rhs = $lhs-&gt;new($rhs);
    }
    if ($reverse) {
        return $rhs-&gt;epoch, $lhs-&gt;epoch;
    }
    return $lhs-&gt;epoch, $rhs-&gt;epoch;
}

sub compare {
    my ($lhs, $rhs) = get_epochs(@_);
    return $lhs &lt;=&gt; $rhs;
}

sub add_months {
    my ($time, $num_months) = @_;

    croak(&quot;add_months requires a number of months&quot;) unless defined($num_months);

    my $final_month = $time-&gt;_mon + $num_months;
    my $num_years = 0;
    if ($final_month &gt; 11 || $final_month &lt; 0) {
        # these two ops required because we have no POSIX::floor and don't
        # want to load POSIX.pm
        if ($final_month &lt; 0 &amp;&amp; $final_month % 12 == 0) {
            $num_years = int($final_month / 12) + 1;
        }
        else {
            $num_years = int($final_month / 12);
        }
        $num_years-- if ($final_month &lt; 0);

        $final_month = $final_month % 12;
    }

    my @vals = _mini_mktime($time-&gt;sec, $time-&gt;min, $time-&gt;hour,
                            $time-&gt;mday, $final_month, $time-&gt;year - 1900 + $num_years);
    # warn(sprintf(&quot;got %d vals: %d-%d-%d %d:%d:%d [%d]\n&quot;, scalar(@vals), reverse(@vals), $time-&gt;[c_islocal]));
    return scalar $time-&gt;_mktime(\@vals, $time-&gt;[c_islocal]);
}

sub add_years {
    my ($time, $years) = @_;
    $time-&gt;add_months($years * 12);
}

1;
__END__

=head1 NAME

Time::Piece - Object Oriented time objects

=head1 SYNOPSIS

    use Time::Piece;
    
    my $t = localtime;
    print &quot;Time is $t\n&quot;;
    print &quot;Year is &quot;, $t-&gt;year, &quot;\n&quot;;

=head1 DESCRIPTION

This module replaces the standard C&lt;localtime&gt; and C&lt;gmtime&gt; functions with
implementations that return objects. It does so in a backwards
compatible manner, so that using localtime/gmtime in the way documented
in perlfunc will still return what you expect.

The module actually implements most of an interface described by
Larry Wall on the perl5-porters mailing list here:
http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2000-01/msg00241.html

=head1 USAGE

After importing this module, when you use localtime or gmtime in a scalar
context, rather than getting an ordinary scalar string representing the
date and time, you get a Time::Piece object, whose stringification happens
to produce the same effect as the localtime and gmtime functions. There is 
also a new() constructor provided, which is the same as localtime(), except
when passed a Time::Piece object, in which case it's a copy constructor. The
following methods are available on the object:

    $t-&gt;sec                 # also available as $t-&gt;second
    $t-&gt;min                 # also available as $t-&gt;minute
    $t-&gt;hour                # 24 hour
    $t-&gt;mday                # also available as $t-&gt;day_of_month
    $t-&gt;mon                 # 1 = January
    $t-&gt;_mon                # 0 = January
    $t-&gt;monname             # Feb
    $t-&gt;month               # same as $t-&gt;monname
    $t-&gt;fullmonth           # February
    $t-&gt;year                # based at 0 (year 0 AD is, of course 1 BC)
    $t-&gt;_year               # year minus 1900
    $t-&gt;yy                  # 2 digit year
    $t-&gt;wday                # 1 = Sunday
    $t-&gt;_wday               # 0 = Sunday
    $t-&gt;day_of_week         # 0 = Sunday
    $t-&gt;wdayname            # Tue
    $t-&gt;day                 # same as wdayname
    $t-&gt;fullday             # Tuesday
    $t-&gt;yday                # also available as $t-&gt;day_of_year, 0 = Jan 01
    $t-&gt;isdst               # also available as $t-&gt;daylight_savings

    $t-&gt;hms                 # 12:34:56
    $t-&gt;hms(&quot;.&quot;)            # 12.34.56
    $t-&gt;time                # same as $t-&gt;hms

    $t-&gt;ymd                 # 2000-02-29
    $t-&gt;date                # same as $t-&gt;ymd
    $t-&gt;mdy                 # 02-29-2000
    $t-&gt;mdy(&quot;/&quot;)            # 02/29/2000
    $t-&gt;dmy                 # 29-02-2000
    $t-&gt;dmy(&quot;.&quot;)            # 29.02.2000
    $t-&gt;datetime            # 2000-02-29T12:34:56 (ISO 8601)
    $t-&gt;cdate               # Tue Feb 29 12:34:56 2000
    &quot;$t&quot;                    # same as $t-&gt;cdate

    $t-&gt;epoch               # seconds since the epoch
    $t-&gt;tzoffset            # timezone offset in a Time::Seconds object

    $t-&gt;julian_day          # number of days since Julian period began
    $t-&gt;mjd                 # modified Julian date (JD-2400000.5 days)

    $t-&gt;week                # week number (ISO 8601)

    $t-&gt;is_leap_year        # true if it's a leap year
    $t-&gt;month_last_day      # 28-31

    $t-&gt;time_separator($s)  # set the default separator (default &quot;:&quot;)
    $t-&gt;date_separator($s)  # set the default separator (default &quot;-&quot;)
    $t-&gt;day_list(@days)     # set the default weekdays
    $t-&gt;mon_list(@days)     # set the default months

    $t-&gt;strftime(FORMAT)    # same as POSIX::strftime (without the overhead
                            # of the full POSIX extension)
    $t-&gt;strftime()          # &quot;Tue, 29 Feb 2000 12:34:56 GMT&quot;
    
    Time::Piece-&gt;strptime(STRING, FORMAT)
                            # see strptime man page. Creates a new
                            # Time::Piece object

Note that C&lt;localtime&gt; and C&lt;gmtime&gt; are not listed above.  If called as
methods on a Time::Piece object, they act as constructors, returning a new
Time::Piece object for the current time.  In other words: they're not useful as
methods.

=head2 Local Locales

Both wdayname (day) and monname (month) allow passing in a list to use
to index the name of the days against. This can be useful if you need
to implement some form of localisation without actually installing or
using locales.

  my @days = qw( Dimanche Lundi Merdi Mercredi Jeudi Vendredi Samedi );

  my $french_day = localtime-&gt;day(@days);

These settings can be overridden globally too:

  Time::Piece::day_list(@days);

Or for months:

  Time::Piece::mon_list(@months);

And locally for months:

  print localtime-&gt;month(@months);

=head2 Date Calculations

It's possible to use simple addition and subtraction of objects:

    use Time::Seconds;
    
    my $seconds = $t1 - $t2;
    $t1 += ONE_DAY; # add 1 day (constant from Time::Seconds)

The following are valid ($t1 and $t2 are Time::Piece objects):

    $t1 - $t2; # returns Time::Seconds object
    $t1 - 42; # returns Time::Piece object
    $t1 + 533; # returns Time::Piece object

However adding a Time::Piece object to another Time::Piece object
will cause a runtime error.

Note that the first of the above returns a Time::Seconds object, so
while examining the object will print the number of seconds (because
of the overloading), you can also get the number of minutes, hours,
days, weeks and years in that delta, using the Time::Seconds API.

In addition to adding seconds, there are two APIs for adding months and
years:

    $t-&gt;add_months(6);
    $t-&gt;add_years(5);

The months and years can be negative for subtractions. Note that there
is some &quot;strange&quot; behaviour when adding and subtracting months at the
ends of months. Generally when the resulting month is shorter than the
starting month then the number of overlap days is added. For example
subtracting a month from 2008-03-31 will not result in 2008-02-31 as this
is an impossible date. Instead you will get 2008-03-02. This appears to
be consistent with other date manipulation tools.

=head2 Date Comparisons

Date comparisons are also possible, using the full suite of &quot;&lt;&quot;, &quot;&gt;&quot;,
&quot;&lt;=&quot;, &quot;&gt;=&quot;, &quot;&lt;=&gt;&quot;, &quot;==&quot; and &quot;!=&quot;.

=head2 Date Parsing

Time::Piece has a built-in strptime() function (from FreeBSD), allowing
you incredibly flexible date parsing routines. For example:

  my $t = Time::Piece-&gt;strptime(&quot;Sunday 3rd Nov, 1943&quot;,
                                &quot;%A %drd %b, %Y&quot;);
  
  print $t-&gt;strftime(&quot;%a, %d %b %Y&quot;);

Outputs:

  Wed, 03 Nov 1943

(see, it's even smart enough to fix my obvious date bug)

For more information see &quot;man strptime&quot;, which should be on all unix
systems.

Alternatively look here: http://www.unix.com/man-page/FreeBSD/3/strftime/

=head2 YYYY-MM-DDThh:mm:ss

The ISO 8601 standard defines the date format to be YYYY-MM-DD, and
the time format to be hh:mm:ss (24 hour clock), and if combined, they
should be concatenated with date first and with a capital 'T' in front
of the time.

=head2 Week Number

The I&lt;week number&gt; may be an unknown concept to some readers.  The ISO
8601 standard defines that weeks begin on a Monday and week 1 of the
year is the week that includes both January 4th and the first Thursday
of the year.  In other words, if the first Monday of January is the
2nd, 3rd, or 4th, the preceding days of the January are part of the
last week of the preceding year.  Week numbers range from 1 to 53.

=head2 Global Overriding

Finally, it's possible to override localtime and gmtime everywhere, by
including the ':override' tag in the import list:

    use Time::Piece ':override';

=head1 CAVEATS

=head2 Setting $ENV{TZ} in Threads on Win32

Note that when using perl in the default build configuration on Win32
(specifically, when perl is built with PERL_IMPLICIT_SYS), each perl
interpreter maintains its own copy of the environment and only the main
interpreter will update the process environment seen by strftime.

Therefore, if you make changes to $ENV{TZ} from inside a thread other than
the main thread then those changes will not be seen by strftime if you
subsequently call that with the %Z formatting code. You must change $ENV{TZ}
in the main thread to have the desired effect in this case (and you must
also call _tzset() in the main thread to register the environment change).

Furthermore, remember that this caveat also applies to fork(), which is
emulated by threads on Win32.

=head2 Use of epoch seconds

This module internally uses the epoch seconds system that is provided via
the perl C&lt;time()&gt; function and supported by C&lt;gmtime()&gt; and C&lt;localtime()&gt;.

If your perl does not support times larger than C&lt;2^31&gt; seconds then this
module is likely to fail at processing dates beyond the year 2038. There are
moves afoot to fix that in perl. Alternatively use 64 bit perl. Or if none
of those are options, use the L&lt;DateTime&gt; module which has support for years
well into the future and past.

=head1 AUTHOR

Matt Sergeant, matt@sergeant.org
Jarkko Hietaniemi, jhi@iki.fi (while creating Time::Piece for core perl)

=head1 COPYRIGHT AND LICENSE

Copyright 2001, Larry Wall.

This module is free software, you may distribute it under the same terms
as Perl.

=head1 SEE ALSO

The excellent Calendar FAQ at http://www.tondering.dk/claus/calendar.html

=head1 BUGS

The test harness leaves much to be desired. Patches welcome.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Flib64%2Fperl5%2FTime'>Back to Directory</a>